Hall of Fame/HallofFameCDROM.cdr/rbbs/setup6.lzh/BINK-DIR.ZIP/BINKLEY.BAT

DOS Batch File | 1989-03-20 | 11KB | 342 lines

Rem SETUP6A - Remove the Binkley.bat with SETUP6. 03/20/89

ECHO Off
Rem    This makes it all go!!
Rem    This file is heavily commented to explain operations.
Rem    DSZ log parameter.  If you run off node 2 set it to XFER-2.DEF

SET DSZLOG=XFER-1.DEF

Rem  Fossil driver and Video Fossil

OPUSCOMM

Rem  Next line configures the fossil to lock at 19200.  Delete if not running
Rem  HST modem with 16550A UARTs. (Command is shown for COM1) COM2 IS L2, S2

OCOM_CFG I C L1=19200 S1=1024,1024

Rem  Video Fossil to have Binkley come up in color.  If you have a problem with
Rem  this, run VFOS_BIO.COM instead.

VFOS_IBM
Echo on
:Start
cd\binkley
BT
If ErrorLevel 100 Goto LOCAL
If ErrorLevel  96 Goto GetRBBS
If ErrorLevel  90 Goto SendMail
If ErrorLevel  80 Goto Maint
If ErrorLevel  72 GoTo GetRBBS
If ErrorLevel  70 Goto ClearOut
If ErrorLevel  60 Goto CHECK
If ErrorLevel  50 GoTo Weekly
If ErrorLevel  48 Goto GetRBBS
If ErrorLevel  40 Goto NightMail
If ErrorLevel  30 Goto InputMail
If ErrorLevel  24 Goto GetRBBS
If ErrorLevel  23 GoTo EchoBull
If ErrorLevel  20 Goto HoldMail
If ErrorLevel  12 Goto GetRBBS
If ErrorLevel  10 Goto Start
If ErrorLevel   3 Goto GetRBBS
If ErrorLevel   1 Goto End
Goto Start
Rem
Rem  The next command loads the BBS by passing parameters thru BBSBatch.bat
Rem  to SPAWNBBS.BAT to RBBS.BAT. Sample BBSBatch.bat, SpawnBBS.Bat, and
Rem  RBBS.Bat files are with these docs.
Rem

:GetRBBS
BBSBatch
GoTo Start

Rem  The next line will load your LOCAL (COM0) node of RBBS by pressing the
Rem  F10 Function key. Make sure you change the directory to where you have
Rem  your BBS at.
Rem
:Local
cd\RBBS
RBBS-PC.EXE 2
cd\binkley
Goto Start

Rem  InputMail looks in the \BINKLEY\FILES area for any new mail and then runs
Rem  PKunPAK to deARC them (Change to ARC if that's what you'd rather use). It
Rem  uses the directory listings in AREAS.BBS to determine where the messages
Rem  should be copied to.  ConfMail.Out is used to determine which conferences
Rem  have received mail during this event.


:InputMail
cd\binkley
ConfMail Import AREAS.BBS -F ConfMail.Out -D 500 -A Pkunpak
If ErrorLevel 2 Goto Severe1
Rem
Rem  If Mail is received, then ConfMail returns an errorlevel of 1
Rem

If ErrorLevel 1 Goto Do_Maint
Goto End_Import

Rem This program reads in ConfMail.Out and uses that to link the new messages
Rem in those conferences to previous messages if they were replying to an
Rem earlier message. It also compiles an EchoStat count from this mail packet.

:Do_Maint
cd\binkley
EchoStat -c -e \binkley\areas.bbs -F ConfMail.Out
Replylnk -F ConfMail.Out
Goto End_Import

Rem Now ConfMail runs again and copies these new messages to the OUTBOUND area
Rem and marks them for whatever net/nodes are listed in your AREAS.BBS.  This
Rem is the statement that causes mail written on your BBS to be sent back to
Rem your HOST. It also pakS (OR ARCs) the messages into packets.

:End_Import
cd\binkley
ConfMail Export AREAS.BBS -O c:\binkley\outbound -A PKPAK -oct A
If ErrorLevel 2 Goto Severe2
If ErrorLevel 1 GoTo HoldMail
Goto HoldMail

:Severe2
Goto Start

Rem  This line runs OMMM and RBBSPACK according to SCHED A in the RBBSPACK.CTL
Rem  file. It holds all mail until the proper time of transmission. OMMM also
Rem  reads the NetMail message area, copies them to the OUTBOUND area and ARCs
Rem  them up. ***** NOTE: Put YOUR Net/Node number after RBBSPACK -A8:*****
Rem

:HoldMail
CD\BINKLEY
OMMM -ic:\binkley\binkley.prm -mc:\binkley\messages -hc:\binkley\outbound -cc:\binkley\ommm.ctl -d
RBBSPACK -A8:930/1 -SA -PC:\BINKLEY\OUTBOUND -CC:\BINKLEY\RBBSPACK.CTL -UP -LC:\BINKLEY\RBBSPACK.LOG -CH -CC -V
Goto Start

Rem This line RUNS SCHED B in RBBSPACK.CTL and causes your HOST to be POLLED for
Rem mail, and will also UNHOLD any mail you have for him. Change your Net/Node here too.

:SendMail
CD\BINKLEY
OMMM -ic:\binkley\binkley.prm -mc:\binkley\messages -hc:\binkley\outbound -cc:\binkley\ommm.ctl -d
RBBSPACK -A8:930/1 -SB -PC:\BINKLEY\OUTBOUND -CC:\BINKLEY\RBBSPACK.CTL -UP -LC:\BINKLEY\RBBSPACK.LOG -V
Goto Start

Rem  During Mail operations, you build up a number of small truncated files
Rem  that clutter the OUTBOUND area.  This is run once each day to delete those
Rem  empty files.

:ClearOut
Del c:\binkley\outbound\*.$*
Goto Start

Rem  This performs a Nightly maintenance at midnight that will save your
Rem  current days Binkley.LOG file by its Julian Date and start over with a
Rem  new file. Customize the third line for where you want to store the files.
Rem  It also looks for new nodelists and newsletters and prepares them for you.
Rem  The saved file goes into C:\archive.  Change that to wherever you want.
Rem  This is also a good place to add in statements for RBBS and Games maintenance.
Rem  It also compiles a daily echomail bulletin

:EchoBull
C:
cd\binkley
Echostat -e \binkley\areas.bbs -rd \binkley\EchoStat.dly -x BAD_MSGS

Rem Customize this to where you want the DAILY bulletin placed!

Copy echostat.dly c:\bullet7


:Maint
DAYNBR /-1 RENAME BINKLEY.LOG BINKLOG.@###
DAYNBR /-1 PKPAK M BINKLEY.A@## BINKLOG.*

Rem Change the following line to where you want your old logs stored.

Copy Binkley.A?? C:\archive
DEL Binkley.A??
GoTo Check

:Check
Rem Look for New Nodelist
If Exist C:\BINKLEY\FILES\RBBSLIST.* GOTO NODELIST
Rem Look for new Newsletter
IF EXIST C:\BINKLEY\FILES\RBBSBITS.* GOTO NEWS
Goto Start

:NODELIST
DEL C:\BINKLEY\FILES\TEMPNODE\RBBSLIST.*
CD\BINKLEY\FILES\TEMPNODE
COPY C:\BINKLEY\FILES\RBBSLIST.*

Rem Set next line to wherever you want a nodelist to be held for you.

COPY RBBSLIST.* C:\ARCHIVE
PKUNPAK RBBSLIST.A??
ERASE RBBSLIST.A??
COPY RBBSLIST.* C:\BINKLEY\RBBSLIST.NEW
ERASE RBBSLIST.*
CD\BINKLEY
Rem Run Nodelist compiler
PARSE
GOTO CHECK

Rem Copies newsletter to archive file, change if you store in a different location.
Rem Generally your HOST will send out a NetMail message informing you of the newsletter.
:NEWS
COPY C:\BINKLEY\FILES\RBBSBITS.* C:\ARCHIVE
ERASE C:\BINKLEY\FILES\RBBSBITS.*
GOTO START


Rem This vreates a weekly bulletin of what echos you received

:Weekly
C:
cd\binkley
EchoStat -e \binkley\areas.bbs -rw \binkley\EchoStat.Wky -x BAD_MSGS

Rem Customize this to where you want your Weekly bulletin placed

COPY ECHOSTAT.WKY C:\bullet8
GoTo Start



Rem Customize the following lines for the areas YOU receive. The meaning of the
Rem lines are: -D 15 (Delete messages more than 15 days old)
Rem            -N 1 99 (Keep first message and delete until 99 are remaining)
Rem            -R Renumber messages

:NightMail
Renum -D 15 -N 1 50 -R C:\BINKLEY\MESSAGES
Renum -D 2 -N 1 99 -R C:\MAIL\80XXX
Renum -D 2 -N 1 99 -R C:\MAIL\A_CAD
Renum -D 2 -N 1 99 -R C:\MAIL\ADAM
Renum -D 2 -N 1 99 -R C:\MAIL\ASIAN-AM
Renum -D 5 -N 1 99 -R C:\MAIL\ASTRONOM
Renum -D 5 -N 1 99 -R C:\MAIL\AT&T
Renum -D 5 -N 1 99 -R C:\MAIL\AUDIO
Renum -D 5 -N 1 99 -R C:\MAIL\AUTO
Renum -D 5 -N 1 99 -R C:\MAIL\AUTOMOTI
Renum -D 15 -N 1 99 -R C:\MAIL\AVIATION
Renum -D 5 -N 1 99 -R C:\MAIL\BAT
Renum -D 5 -N 1 130 -R C:\MAIL\BIBLE
Renum -D 10 -N 1 199 -R C:\MAIL\BINKLEY
Renum -D 2 -N 1 99 -R C:\MAIL\BUSINESS
Renum -D 2 -N 1 99 -R C:\MAIL\CBM
Renum -D 5 -N 1 130 -R C:\MAIL\C_ECHO
Renum -D 5 -N 1 99 -R C:\MAIL\CDROM
Renum -D 5 -N 1 130 -R C:\MAIL\CHATTER
Renum -D 5 -N 1 99 -R C:\MAIL\CHESS
Renum -D 5 -N 1 99 -R C:\MAIL\CLIPPER
Renum -D 5 -N 1 99 -R C:\MAIL\COINS
Renum -D 2 -N 1 99 -R C:\MAIL\COCO
Renum -D 5 -N 1 99 -R C:\MAIL\COMICS
Renum -D 5 -N 1 200 -R C:\MAIL\COMM
Renum -D 2 -N 1 99 -R C:\MAIL\CONSULTI
Renum -D 5 -N 1 99 -R C:\MAIL\CONSUMER
Renum -D 5 -N 1 130 -R C:\MAIL\CONTROV
Renum -D 2 -N 1 99 -R C:\MAIL\DBASE
Renum -D 5 -N 1 99 -R C:\MAIL\DBRIDGE
Renum -D 5 -N 1 150 -R C:\MAIL\DEBATE
Renum -D 5 -N 1 150 -R C:\MAIL\DESQVIEW
Renum -D 30 -N 1 99 -R C:\MAIL\DFW_NET
Renum -D 5 -N 1 99 -R C:\MAIL\DISORDER
Renum -D 5 -N 1 99 -R C:\MAIL\DND
Renum -D 5 -N 1 99 -R C:\MAIL\DOORWARE
Renum -D 5 -N 1 99 -R C:\MAIL\DR_DEBUG
Renum -D 5 -N 1 99 -R C:\MAIL\EAT
Renum -D 2 -N 1 99 -R C:\MAIL\EDUCATOR
Renum -D 2 -N 1 99 -R C:\MAIL\FDECHO
Renum -D 30 -N 1 99 -R C:\MAIL\FIGHTBELL
Renum -D 2 -N 1 99 -R C:\MAIL\FILM
Renum -D 5 -N 1 99 -R C:\MAIL\FIREARMS
Renum -D 2 -N 1 99 -R C:\MAIL\FOR-SALE
Renum -D 2 -N 1 99 -R C:\MAIL\FOSSIL
Renum -D 2 -N 1 99 -R C:\MAIL\GALAXY
Renum -D 5 -N 1 99 -R C:\MAIL\GAMING
Renum -D 2 -N 1 99 -R C:\MAIL\GENEALO
Renum -D 2 -N 1 99 -R C:\MAIL\GOURMET
Renum -D 2 -N 1 99 -R C:\MAIL\GRAND_RO
Renum -D 5 -N 1 99 -R C:\MAIL\HAM
Renum -D 5 -N 1 99 -R C:\MAIL\HDCONF
Renum -D 2 -N 1 99 -R C:\MAIL\HDSALE
Renum -D 2 -N 1 99 -R C:\MAIL\HOME
Renum -D 2 -N 1 99 -R C:\MAIL\HOME-N-G
Renum -D 5 -N 1 150 -R C:\MAIL\HST
Renum -D 5 -N 1 99 -R C:\MAIL\HUMOR
Renum -D 5 -N 1 99 -R C:\MAIL\IEEE
Renum -D 5 -N 1 99 -R C:\MAIL\INSURE
Renum -D 2 -N 1 99 -R C:\MAIL\JOBS
Renum -D 2 -N 1 99 -R C:\MAIL\LAN
Renum -D 2 -N 1 99 -R C:\MAIL\LASERPUB
Renum -D 2 -N 1 99 -R C:\MAIL\LAW
Renum -D 5 -N 1 99 -R C:\MAIL\LONI
Renum -D 5 -N 1 99 -R C:\MAIL\LOTUS
Renum -D 2 -N 1 99 -R C:\MAIL\MAIN
Renum -D 12 -N 1 99 -R C:\MAIL\MANAGE
Renum -D 2 -N 1 99 -R C:\MAIL\MEDIC
Renum -D 2 -N 1 99 -R C:\MAIL\MENSA
Renum -D 2 -N 1 99 -R C:\MAIL\MIDI-NET
Renum -D 2 -N 1 99 -R C:\MAIL\MTASK
Renum -D 2 -N 1 99 -R C:\MAIL\MUSIC
Renum -D 2 -N 1 99 -R C:\MAIL\MUSICSYN
Renum -D 2 -N 1 99 -R C:\MAIL\MOD1000
Renum -D 5 -N 1 99 -R C:\MAIL\NOPIRACY
Renum -D 2 -N 1 99 -R C:\MAIL\OS
Renum -D 2 -N 1 99 -R C:\MAIL\PACKET
Renum -D 5 -N 1 150 -R C:\MAIL\PASCAL
Renum -D 5 -N 1 99 -R C:\MAIL\PCWRITE
Renum -D 5 -N 1 99 -R C:\MAIL\PERFECT
Renum -D 5 -N 1 99 -R C:\MAIL\PHOTO
Renum -D 5 -N 1 99 -R C:\MAIL\POLITICS
Renum -D 5 -N 1 99 -R C:\MAIL\PROGMR
Renum -D 5 -N 1 99 -R C:\MAIL\PS_2
Renum -D 5 -N 1 99 -R C:\MAIL\PURSUIT
Renum -D 5 -N 1 150 -R C:\MAIL\QUICKBBS
Renum -D 5 -N 1 150 -R C:\MAIL\QUIK_BAS
Renum -D 10 -N 1 99 -R C:\MAIL\RBBSBITS
Renum -D 10 -N 1 99 -R C:\MAIL\RBBS_DEV
Renum -D 10 -N 1 99 -R C:\MAIL\RBBSMAIL_PAC
Renum -D 10 -N 1 150 -R C:\MAIL\RBBS-PC
Renum -D 10 -N 1 99 -R C:\MAIL\RBBS-SY
Renum -D 5 -N 1 99 -R C:\MAIL\RBASE
Renum -D 2 -N 1 99 -R C:\MAIL\ROBOTIX
Renum -D 2 -N 1 99 -R C:\MAIL\ROUSTER
Renum -D 5 -N 1 150 -R C:\MAIL\SCIENCE
Renum -D 5 -N 1 150 -R C:\MAIL\SCIFOR
Renum -D 2 -N 1 99 -R C:\MAIL\SF
Renum -D 2 -N 1 99 -R C:\MAIL\SFFAN
Renum -D 5 -N 1 99 -R C:\MAIL\SHARE
Renum -D 5 -N 1 99 -R C:\MAIL\SHORTWAV
Renum -D 2 -N 1 99 -R C:\MAIL\SIRIUS
Renum -D 10 -N 1 99 -R C:\MAIL\SMLWARE
Renum -D 5 -N 1 99 -R C:\MAIL\SPACE
Renum -D 5 -N 1 99 -R C:\MAIL\SPORTS
Renum -D 5 -N 1 99 -R C:\MAIL\STOCK
Renum -D 5 -N 1 150 -R C:\MAIL\TECH
Renum -D 5 -N 1 150 -R C:\MAIL\TRADE_WA
Renum -D 5 -N 1 150 -R C:\MAIL\TREK
Renum -D 5 -N 1 99 -R C:\MAIL\TV
Renum -D 5 -N 1 99 -R C:\MAIL\UFGATE
Renum -D 5 -N 1 99 -R C:\MAIL\UFO
Renum -D 2 -N 1 99 -R C:\MAIL\VAX
Renum -D 5 -N 1 99 -R C:\MAIL\VIETNAM
Renum -D 2 -N 1 99 -R C:\MAIL\WAR!
Renum -D 5 -N 1 99 -R C:\MAIL\WARNINGS
Renum -D 5 -N 1 99 -R C:\MAIL\WHO
Renum -D 5 -N 1 99 -R C:\MAIL\WILDCAT
Renum -D 5 -N 1 99 -R C:\MAIL\ZMODEM
Goto Start

:End
cd\