home *** CD-ROM | disk | FTP | other *** search
/ Hall of Fame / HallofFameCDROM.cdr / gamegif / pspice5.lzh / PWRMOS.LIB < prev   
Text File  |  1988-11-02  |  4KB  |  79 lines
  1. * Library of MOSFET model parameters (for "power" MOSFET devices)
  2. *
  3. * This is a reduced version of MicroSim's power MOSFET model library.
  4. *   You are welcome to make as many copies of it as you find convenient.
  5. *
  6. * Release date: November 1988
  7. *
  8. * The parameters in this model library were derived from the data sheets for
  9. * each part.  Each part was characterize using the Parts option.
  10. * Device can also be characterized without Parts as follows:
  11. *    LEVEL        Set to 3 (short-channel device).
  12. *    TOX        Determined from gate ratings.
  13. *    L, LD, W, WD    Assume L=2u.  Calculate from input capacitance.
  14. *    XJ, NSUB    Assume usual technology.
  15. *    IS, RD, RB    Determined from "source-drain diode forward voltage"
  16. *            specification or curve (Idr vs. Vsd).
  17. *    RS        Determine from Rds(on) specification.
  18. *    RDS        Calculated from Idss specification or curves.
  19. *    VTO, UO, THETA    Determined from "output characteristics" curve family
  20. *            (Ids vs. Vds, stepped Vgs).
  21. *    ETA, VMAX, CBS    Set for null effect.
  22. *    CBD, PB, MJ    Determined from "capacitance vs. Vds" curves.
  23. *    RG        Calculate from rise/fall time specification or curves.
  24. *    CGSO, CGDO    Determined from gate-charge, turn-on/off delay and
  25. *            rise time specifications.
  26. *
  27. * NOTE:    when specifying the instance of a device in your circuit file:
  28. *
  29. *    BE SURE to have the source and bulk nodes connected together, as this
  30. *    is the way the real device is constructed.
  31. *
  32. *    DO NOT include values for L, W, AD, AS, PD, PS, NRD, or NDS.
  33. *    The PSpice default values for these parameters are taken into account
  34. *    in the library model statements.  Of course, you should NOT reset
  35. *    the default values using the .OPTIONS statement, either.
  36. *
  37. * Example use:    M17    15 23 7 7    IRF150
  38. *
  39. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  40. *
  41. * The "power" MOSFET device models benefit from relatively complete specifi-
  42. * cation of static and dynamic characteristics by their manufacturers.  The
  43. * following effects are modeled:
  44. *    - DC transfer curves in forward operation,
  45. *    - gate drive characteristics and switching delay,
  46. *    - "on" resistance,
  47. *    - reverse-mode "body-diode" operation.
  48. *
  49. * The factors not modeled include:
  50. *    - maximum ratings (eg. high-voltage breakdown),
  51. *    - safe operating area (eg. power dissipation),
  52. *    - latch-up,
  53. *    - noise.
  54. *
  55. * For high-current switching applications, we advise that you include
  56. * series inductance elements, for the source and drain, in your circuit file.
  57. * In doing so, voltage spikes due to di/dt will be modeled.  According to the
  58. * 1985 International Rectifier databook, the following case styles have lead
  59. * inductance values of:
  60. *    TO-204 (modified TO-3)    source = 12.5nH        drain = 5.0nH
  61. *    TO-220            source =  7.5nH        drain = 3.5-4.5nH
  62. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  63. *
  64. .model IRF150    NMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0
  65. +        Tox=100n Uo=600 Phi=.6 Rs=1.624m Kp=20.53u W=.3 L=2u Vto=2.831
  66. +            Rd=1.031m Rds=444.4K Cbd=3.229n Pb=.8 Mj=.5 Fc=.5 Cgso=9.027n
  67. +        Cgdo=1.679n Rg=13.89 Is=194E-18 N=1 Tt=288n)
  68. *        Int'l Rectifier    pid=IRFC150    case=TO3
  69. *        88-08-25 bam    creation
  70.  
  71. .model IRF9140    PMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0
  72. +        Tox=100n Uo=300 Phi=.6 Rs=70.6m Kp=10.15u W=1.9 L=2u Vto=-3.67
  73. +        Rd=60.66m Rds=444.4K Cbd=2.141n Pb=.8 Mj=.5 Fc=.5 Cgso=877.2p
  74. +        Cgdo=369.3p Rg=.811 Is=52.23E-18 N=2 Tt=140n)
  75. *        Int'l Rectifier  pid=IRFC9140    case=TO3
  76. *        88-08-25 bam    creation
  77.  
  78. * End of library file
  79.