home *** CD-ROM | disk | FTP | other *** search
/ Hall of Fame / HallofFameCDROM.cdr / comm1 / telmt2-1.lzh / OPUS-A.SCR < prev    next >
Text File  |  1989-12-22  |  2KB  |  80 lines
  1. ; This is an advance version of OPUS.SCR
  2. ;
  3. ; 1. Check if BBS is processing mail
  4. ; 2. Quick log on by sending Ctrl-C and ESC to bypass welcome message
  5. ; 3. Go to message section and read messages automatically
  6. ; 4. Simulate Auto Download feature for SEAlink, Telink and Modem7
  7. ; 5. Automatically send ENTER key when you are told to do so
  8.  
  9.  
  10. name = "Winfred Hu"          ; put your name here
  11.  
  12. ON = 1
  13. OFF = 0
  14.  
  15. AutoDownload = ON            ; set this to OFF if you don't need
  16.                              ;  Auto Download SEAlink, Telink and Modem7
  17.  
  18. when "Press ENTER to continue","^M"
  19. when "try again","q^M"       ; set response strings
  20.  
  21. count = 1
  22. repeat                       ; wait for log on prompt
  23.   waitfor "first name","processing mail",2
  24.   if not found
  25.     put "^C~^["              ; put ^C, Esc, Enter
  26.   endif
  27.   if found=2                 ; if BBS is processing mail
  28.     alarm "Processing mail"  ; then alarm, hangup and stop
  29.     hangup
  30.     stop
  31.   endif
  32.   if count=20                 ; quit if no response in 60 seconds
  33.      alarm "No response in 60 seconds"
  34.      hangup
  35.      stop
  36.   endif
  37.   count = count+1
  38. until found
  39. put name," y"                ; put name and confirm
  40.  
  41. repeat                       ; wait for password request
  42.   waitfor "password",2
  43.   if not found
  44.     put "^C"
  45.   endif
  46. until found
  47. put "^&"                     ; put password (defined in Dial window)
  48.  
  49. repeat                       ; wait for main menu
  50.   waitfor "main menu:",2
  51.   if not found
  52.     put "^C"
  53.   endif
  54. until found
  55. put "m"                      ; select message section
  56. waitfor "select",5
  57. put "="                      ; read messages
  58.  
  59. when "try again",""          ; cancel this WHEN statement
  60.  
  61.  
  62. if AutoDownload              ; if ON then wait for download prompt
  63.    while connected
  64.       waitfor "mode:  sealink","mode:  telink","mode:  modem7",15
  65.       if found
  66.          switch found
  67.             case 1: protocol="s"
  68.             case 2: protocol="t"
  69.             case 3: protocol="m"
  70.          endswitch
  71.          delay 20
  72.          receive protocol
  73.       endif
  74.    endwhile
  75. else
  76.    repeat                    ; wait until disconnected
  77.    until not connected       ; make use of WHEN "Press ENTER ..."
  78. endif
  79.  
  80.