home *** CD-ROM | disk | FTP | other *** search
/ Hall of Fame / HallofFameCDROM.cdr / 3x400 / cpyform.lzh / CPYFORM.EXE / arc / CPYFORMR.RPG < prev    next >
Text File  |  1987-07-13  |  5KB  |  119 lines
  1.      H/TITLE   CPYFORMR  08.04  CREATE LIST OF OUTQ SPOOL FILES
  2.      F*
  3.      F* Written by:  Philip R. Widing
  4.      F*              Jarl Extrusions, Inc.
  5.      F*              Elizabethton, TN 37644-0871
  6.      F*              615-543-3561
  7.      F*
  8.      F* Command Processing by "CPYFORM" & "CPYFORMR"
  9.      F*
  10.      F*  This program produces a list of spool file entries in a *DTAQ
  11.      F*  that have the same FORMTYPE as provided in the *ENTRY para-
  12.      F*  meter FORM.  Expansion to more that a hundred entries should
  13.      F*  be easy, if desired.  The layout for the DSPOUTQ file is
  14.      F*  current as of Release 8, but REQUIRES the CPYSPLF command
  15.      F*  to include CTLCHAR(*FCFC).  This is done automatically by
  16.      F*  the CPYFORM CL program (q.v.).
  17.      F*
  18.      F*
  19.      F* Release 8
  20.      F* 02  PRW  87-02-17  Adjust prompt text;  add comments
  21.      F* 03  PRW  87-02-19  Correct minor errors after testing.
  22.      F* 04  PRW  87-07-13  Replace CL Var. param. with *DTAQ I/O !
  23.      F*
  24.      FDSPOUTQ IF  F     245            DISK                           UC
  25.      F*
  26.      IDSPOUTQ NS  01  62 CR  63 CD  64 CY
  27.      I       OR       62 CH  63 CL  64 CD
  28.      I       OR       62 CW  63 CT  64 CR
  29.      I       OR       62 CS  63 CA  64 CV
  30.      I       OR       62 CC  63 CL  64 CO
  31.      I                                        1 245 RECORD
  32.      IDSPOUTQ NS  99
  33.      I/SPACE 3
  34.      IFMT         DS                            245
  35.      I                                        1 245 RECORD
  36.      I*
  37.      I*  THE FILE POSITIONS REQUIRE *FCFC WHEN THE SPOOL FILE IS
  38.      I*  COPIED !
  39.      I*
  40.      I                                        5  14 $FILE
  41.      I                                       16  19 $SPLN
  42.      I                                       21  30 $JOB
  43.      I                                       32  41 $USER
  44.      I                                       43  48 $JOBN
  45.      I                                       50  50 $PRTY
  46.      I                                       55  58 $COUNT
  47.      I                                       59  59 $TYPE
  48.      I                                       62  64 $STAT
  49.      I                                       66  68 $COPY
  50.      I                                       70  79 $FORM
  51.      I/SPACE 3
  52.      IELEM        DS                             40
  53.      I                                        1  10 FILE
  54.      I                                       11  14 SPLNBR
  55.      I                                       15  24 JOB
  56.      I                                       25  34 USER
  57.      I                                       35  40 JOBNBR
  58.      I/EJECT
  59.      C**===---===F1--------OP---F2--------R-----LEN.H++--==COMMENTS-------
  60.      C*
  61.      C           *ENTRY    PLIST
  62.      C                     PARM           FORM   10
  63.      C                     PARM           COUNT  155
  64.      C*
  65.      C**===---===F1--------OP---F2--------R-----LEN.H++--==COMMENTS-------
  66.      C*
  67.      C                     MOVE '1'       TRUE    1
  68.      C                     MOVE '0'       FALSE   1
  69.      C                     MOVE '08.04'   @VM@    6
  70.      C                     MOVEL'DTAQ128' QNAME
  71.      C                     MOVEL'QTEMP'   QLIB
  72.      C*
  73.      C**===---===F1--------OP---F2--------R-----LEN.H++--==COMMENTS-------
  74.      C*
  75.      C* THESE STMTS MAKE THE COMPIILER DEFINE
  76.      C* THE FIELDS FOR DEBUGGING.
  77.      C*
  78.      C           *IN01     IFEQ TRUE                       I--1
  79.      C           *IN01     ANDEQFALSE                      A--1
  80.      C                     MOVE $STAT     $FORM
  81.      C                     MOVE $COPY     $FORM
  82.      C                     MOVE $PRTY     $FORM
  83.      C                     MOVE $COUNT    $FORM
  84.      C                     END                             E--1
  85.      C*
  86.      C**===---===F1--------OP---F2--------R-----LEN.H++--==COMMENTS-------
  87.      C*
  88.      C                     Z-ADD*ZERO     COUNT
  89.      C                     Z-ADD*ZERO     I       50
  90.      C           *LIKE     DEFN I         J
  91.      C                     OPEN DSPOUTQ
  92.      C                     MOVE FALSE     *IN98
  93.      C           *IN98     DOWEQFALSE                      W--1
  94.      C**
  95.      C                     MOVE FALSE     *IN01
  96.      C                     READ DSPOUTQ                9898=EOF
  97.      C           *IN01     IFEQ TRUE                       B--2
  98.      C           $FORM     ANDEQFORM                       A--2
  99.      C                     MOVE $FILE     FILE
  100.      C                     MOVE $SPLN     SPLNBR
  101.      C                     MOVE $JOB      JOB
  102.      C                     MOVE $USER     USER
  103.      C                     MOVE $JOBN     JOBNBR
  104.      C                     ADD  1         I
  105.      C**
  106.      C                     CALL 'QSNDDTAQ'
  107.      C                     PARM           QNAME  10
  108.      C                     PARM           QLIB   10
  109.      C                     PARM 40        QSEND   50
  110.      C                     PARM ELEM      QDATA  40
  111.      C**
  112.      C                     END                             E--2
  113.      C**
  114.      C                     END                             E--1
  115.      C                     CLOSEDSPOUTQ
  116.      C                     Z-ADDI         COUNT
  117.      C                     MOVE TRUE      *INLR
  118.      C                     RETRN
  119.