home *** CD-ROM | disk | FTP | other *** search
/ ftp.wwiv.com / ftp.wwiv.com.zip / ftp.wwiv.com / pub / PROTOCOL / TPHYD100.ZIP / CRC.ASM next >
Assembly Source File  |  1993-08-18  |  11KB  |  307 lines
  1. ; ============================================================ Rev. 15 Jul 1993
  2. ; Routines for table driven CRC-16 & CRC-32, including building tables
  3. ; Refer to CRC.DOC for information and documentation.
  4. ; This file in 80x86 ASM is 100% interchangable with the portable CRC.C
  5. ; Initially written to see how CRC calculation could be optimized in assembly
  6. ; Reads the data in words instead bytes at a time, makes asm even 20-25% faster
  7. ; Tried specifics for 386 and up (SHR EAX,8 etc), but didn't wasn't much faster
  8. ; Source compiles cleanly in TASM. May require some minor adjustments for MASM.
  9. ; -----------------------------------------------------------------------------
  10. ; 
  11. ;              Information collected and edited by Arjen G. Lentz
  12. ;            Sourcecode in C and 80x86 ASM written by Arjen G. Lentz
  13. ;                 COPYRIGHT (C) 1992-1993; ALL RIGHTS RESERVED
  14. ;  
  15. ; 
  16. ; CONTACT ADDRESS
  17. ;  
  18. ; LENTZ SOFTWARE-DEVELOPMENT    Arjen Lentz @
  19. ; Langegracht 7B                AINEX-BBS +31-33-633916
  20. ; 3811 BT  Amersfoort           FidoNet 2:283/512
  21. ; The Netherlands               f512.n283.z2.fidonet.org
  22. ;
  23. ;
  24. ; DISCLAIMER
  25. ;  
  26. ; This information is provided "as is" and comes with no warranties of any
  27. ; kind, either expressed or implied. It's intended to be used by programmers
  28. ; and developers. In no event shall the author be liable to you or anyone
  29. ; else for any damages, including any lost profits, lost savings or other
  30. ; incidental or consequential damages arising out of the use or inability
  31. ; to use this information.
  32. ;  
  33. ;  
  34. ; LICENCE
  35. ;  
  36. ; This package may be freely distributed provided the files remain together,
  37. ; in their original unmodified form.
  38. ; All files, executables and sourcecode remain the copyrighted property of
  39. ; Arjen G. Lentz and LENTZ SOFTWARE-DEVELOPMENT.
  40. ; Licence for any use granted, provided this notice & CRC.DOC are included.
  41. ; For executable applications, credit should be given in the appropriate
  42. ; places in the program and documentation.
  43. ; These notices must be retained in any copies of any part of this
  44. ; documentation and/or software.
  45. ;
  46. ; Any use of, or operation on (including copying/distributing) any of
  47. ; the above mentioned files implies full and unconditional acceptance of
  48. ; this licence and disclaimer.
  49. ;
  50. ; =============================================================================
  51.  
  52. ; Make sure you set the model and language right, or your program will crash!
  53.         .MODEL Large,Pascal    ; Model   : Tiny,Small,Medium,Compact,Large,Huge
  54.                                ; Language: C,Pascal,Basic,Fortran,Prolog
  55.  
  56.  
  57. ; -----------------------------------------------------------------------------
  58.         .CODE
  59.         LOCALS
  60.  
  61.         PUBLIC crc16init,  crc16block
  62.         PUBLIC crc16rinit, crc16rblock
  63.         PUBLIC crc32init,  crc32block
  64.  
  65.  
  66. ; -----------------------------------------------------------------------------
  67. crc16init PROC
  68.         ARG     crctab:DWORD, poly:WORD
  69.         USES    si, di
  70.  
  71.         les     di, [crctab]            ; ES:DI = crctab
  72.         mov     bx, [poly]              ; BX    = polynomial
  73.         sub     si, si                  ; i = 0
  74.         cld
  75.  
  76. @@itop: mov     ax, si                  ; crc = i
  77.         mov     cx, 8                   ; j = 8
  78. @@jtop: shr     ax, 1                   ; crc >>= 1
  79.         jnc     @@jbit                  ; if (!carry)
  80.         xor     ax, bx                  ;    crc ^= poly
  81. @@jbit: loopnz  @@jtop                  ; if (--CX != 0 && crc) goto @@jtop
  82.         stosw                           ; crctab[i] = crc
  83.  
  84.         inc     si
  85.         cmp     si, 255                 ; if (++i <= 255)
  86.         jle     @@itop                  ;    goto @@itop
  87.  
  88.         ret
  89. crc16init ENDP
  90.  
  91.  
  92. ; -----------------------------------------------------------------------------
  93. crc16block PROC
  94.         ARG     crctab:DWORD, crc:WORD, buf:DWORD, len:WORD
  95.         USES    ds, si, di
  96.  
  97.         les     di, [crctab]            ; ES:DI = crctab
  98.         mov     bx, [crc]               ; BX    = crc
  99.         lds     si, [buf]               ; DS:SI = buf
  100.         mov     cx, [len]               ; CX    = len
  101.         cld
  102.  
  103.         shr     cx, 1
  104.         jnc     @@even
  105.  
  106.         lodsb                           ; get single byte
  107.         xor     bl, al                  ; BL ^= AL
  108.         mov     ah, bh                  ; AH = BH
  109.         sub     bh, bh                  ; BH = 0
  110.         shl     bx, 1                   ; BX *= 2 (mul for word array)
  111.         mov     bx, es:[di + bx]        ; BX = crctab[BX]
  112.         xor     bl, ah                  ; BL ^= AH
  113.  
  114. @@even: jcxz    @@fini                  ; if (!len) goto @@fini
  115.  
  116. @@itop: lodsw                           ; get next two bytes
  117.         xor     bl, al                  ; first byte
  118.         xor     ah, bh                  ; already merge with second byte
  119.         sub     bh, bh
  120.         shl     bx, 1
  121.         mov     bx, es:[di + bx]
  122.         xor     bl, ah                  ; second byte
  123.         mov     ah, bh
  124.         sub     bh, bh
  125.         shl     bx, 1
  126.         mov     bx, es:[di + bx]
  127.         xor     bl, ah
  128.  
  129.         loop    @@itop                  ; if (--CX != 0) goto @@itop
  130.  
  131. @@fini: mov     ax, bx
  132.         ret
  133. crc16block ENDP
  134.  
  135.  
  136. ; -----------------------------------------------------------------------------
  137. crc16rinit PROC
  138.         ARG     crctab:DWORD, poly:WORD
  139.         USES    si, di
  140.  
  141.         les     di, [crctab]            ; ES:DI = crctab
  142.         mov     bx, [poly]              ; BX    = polynomial
  143.         sub     si, si                  ; i = 0
  144.         cld
  145.  
  146. @@itop: mov     ax, si                  ; crc = i << 8
  147.         xchg    ah, al
  148.         mov     cx, 8                   ; j = 8
  149. @@jtop: shl     ax, 1                   ; crc <<= 1
  150.         jnc     @@jbit                  ; if (!carry)
  151.         xor     ax, bx                  ;    crc ^= poly
  152. @@jbit: loopnz  @@jtop                  ; if (--CX != 0 && crc) goto @@jtop
  153.         stosw                           ; crctab[i] = crc
  154.  
  155.         inc     si
  156.         cmp     si, 255                 ; if (++i <= 255)
  157.         jle     @@itop                  ;    goto @@itop
  158.  
  159.         ret
  160. crc16rinit ENDP
  161.  
  162.  
  163. ; -----------------------------------------------------------------------------
  164. crc16rblock PROC
  165.         ARG     crctab:DWORD, crc:WORD, buf:DWORD, len:WORD
  166.         USES    ds, si, di
  167.  
  168.         les     di, [crctab]            ; ES:DI = crctab
  169.         mov     bx, [crc]               ; BX    = crc
  170.         lds     si, [buf]               ; DS:SI = buf
  171.         mov     cx, [len]               ; CX    = len
  172.         cld
  173.  
  174.         shr     cx, 1
  175.         jnc     @@even
  176.  
  177.         lodsb                           ; get single byte
  178.         mov     ah, bl                  ; AH = BL
  179.         mov     bl, bh                  ; BL = BH
  180.         xor     bl, al                  ; BL ^= AL
  181.         sub     bh, bh                  ; BH = 0
  182.         shl     bx, 1                   ; BX *= 2 (mul for word array)
  183.         mov     bx, es:[di + bx]        ; BX = crctab[BX]
  184.         xor     bh, ah                  ; BH ^= AH
  185.  
  186. @@even: jcxz    @@fini                  ; if (!len) goto @@fini
  187.  
  188. @@itop: lodsw                           ; get next two bytes
  189.         xor     ah, bl                  ; already merge with second byte
  190.         mov     bl, bh
  191.         xor     bl, al                  ; first byte
  192.         sub     bh, bh
  193.         shl     bx, 1
  194.         mov     bx, es:[di + bx]
  195.         xor     bh, ah                  ; second byte
  196.         mov     ah, bl
  197.         mov     bl, bh
  198.         sub     bh, bh
  199.         shl     bx, 1
  200.         mov     bx, es:[di + bx]
  201.         xor     bh, ah
  202.  
  203.         loop    @@itop                  ; if (--CX != 0) goto @@itop
  204.  
  205. @@fini: mov     ax, bx
  206.         ret
  207. crc16rblock ENDP
  208.  
  209.  
  210. ; -----------------------------------------------------------------------------
  211. crc32init PROC
  212.         ARG     crctab:DWORD, poly:DWORD
  213.         USES    si, di
  214.  
  215.         les     di, [crctab]            ; ES:DI = crctab
  216.         mov     bx, [word ptr poly]     ; BX = poly (low)
  217.         mov     bp, [word ptr poly + 2] ; BP = poly (high)
  218.         sub     si, si                  ; i = 0
  219.  
  220. @@itop: mov     ax, si                  ; crc (low)  = i
  221.         sub     dx, dx                  ; crc (high) = 0
  222.         mov     cx, 8                   ; j = 8
  223. @@jtop: shr     dx, 1                   ; crc (high) >>= 1
  224.         rcr     ax, 1                   ; crc (low)  >>= 1
  225.         jnc     @@jbit                  ; if (!carry)
  226.         xor     ax, bx                  ;    crc (low)  ^= polyl
  227.         xor     dx, bp                  ;    crc (high) ^= polyh
  228. @@jbit: loop    @@jtop                  ; if (--CX != 0) goto @@jtop
  229.         stosw                           ; crctab[i] = crc (low)
  230.         mov     ax, dx
  231.         stosw                           ; crctab[i] = crc (high)
  232.  
  233.         inc     si
  234.         cmp     si, 255                 ; if (++i <= 255)
  235.         jle     @@itop                  ;    goto @@itop
  236.  
  237.         ret
  238. crc32init ENDP
  239.  
  240.  
  241. ; -----------------------------------------------------------------------------
  242. crc32block PROC
  243.         ARG     crctab:DWORD, crc:DWORD, buf:DWORD, len:WORD
  244.         USES    ds, si, di
  245.  
  246.         les     di, [crctab]            ; ES:DI = crctab
  247.         mov     ax, [word ptr crc]      ; AX    = crc (low)
  248.         mov     dx, [word ptr crc + 2]  ; DX    = crc (high)
  249.         lds     si, [buf]               ; DS:SI = buf
  250.         mov     cx, [len]               ; CX    = len
  251.         cld
  252.  
  253.         shr     cx, 1
  254.         jnc     @@even
  255.  
  256.         mov     bl, al                  ; BL = AL
  257.         lodsb                           ; get single byte
  258.         xor     bl, al                  ; BL ^= AL
  259.         mov     al, ah                  ; AL = AH
  260.         mov     ah, dl                  ; AH = DL
  261.         mov     dl, dh                  ; DL = DH
  262.         sub     dh, dh                  ; DH = 0
  263.         sub     bh, bh                  ; BH = 0
  264.         shl     bx, 1                   ; BX *= 4 (mul for dword array)
  265.         shl     bx, 1
  266.         xor     ax, es:[di + bx]        ; AX ^= crctab[BX]
  267.         add     bx, 2                   ; BX += 2 (add for second word)
  268.         xor     dx, es:[di + bx]        ; DX ^= crctab[BX]
  269.  
  270. @@even: jcxz    @@fini                  ; if (!len) goto @@fini
  271.  
  272. @@itop: mov     bx, ax
  273.         lodsw                           ; get next to bytes
  274.         xor     bl, al
  275.         mov     al, bh
  276.         xor     al, ah                  ; already merge with second byte
  277.         mov     ah, dl
  278.         mov     dl, dh
  279.         sub     dh, dh
  280.         sub     bh, bh
  281.         shl     bx, 1
  282.         shl     bx, 1
  283.         xor     ax, es:[di + bx]
  284.         add     bx, 2
  285.         xor     dx, es:[di + bx]
  286.         mov     bl, al
  287.         mov     al, ah
  288.         mov     ah, dl
  289.         mov     dl, dh
  290.         sub     dh, dh
  291.         sub     bh, bh
  292.         shl     bx, 1
  293.         shl     bx, 1
  294.         xor     ax, es:[di + bx]
  295.         add     bx, 2
  296.         xor     dx, es:[di + bx]
  297.  
  298.         loop    @@itop                  ; if (--CX != 0) goto @@itop
  299.  
  300. @@fini: ret
  301. crc32block ENDP
  302.  
  303.  
  304.         END
  305.  
  306. ; end of crc.asm --------------------------------------------------------------
  307.