home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.wwiv.com
/
ftp.wwiv.com.zip
/
ftp.wwiv.com
/
pub
/
MISC
/
EZY200-1.ARJ
/
EZYBATCH.ARJ
/
BBS.BAT
next >
Wrap
DOS Batch File
|
2003-02-22
|
2KB
|
94 lines
@echo off
rem Ezycom Standalone Batch File V1.0
rem Command Format :
rem BBS (for node 1 operation)
rem BBS [node] (for node X operation)
rem [node] is the node number from 1 through to 250
rem eg BBS 2
cd %EZY%
if %1! == ! SET TASK=1
if not %1! == ! SET TASK=%1
:start
ezy -E25
:after_ezy
if errorlevel 27 goto start
if errorlevel 26 goto tossmail
if errorlevel 25 goto start
if errorlevel 24 goto weeklyevent
if errorlevel 23 goto dailyevent
if errorlevel 11 goto start
if errorlevel 10 goto fax
if errorlevel 9 goto start
if errorlevel 8 goto sysopnext
if errorlevel 7 goto netecho
if errorlevel 6 goto netmail
if errorlevel 5 goto echomail
if errorlevel 4 goto modeminit
if errorlevel 3 goto fossil
if errorlevel 2 goto runtimeerror
if errorlevel 1 goto setuperror
goto finish
:weeklyevent
echo Weekly Maintenance Being performed
cd %EZY%
goto start
:dailyevent
echo Daily Maintenance Being performed
cd %EZY%
ezyidx -build
ezyfile -sort -pack -update
ezyadopt -FILEID
usercomp -B20 -S1 -P -D90 -ALIAS
msgcomp -LINK -CLEANUP
ezyutil -STRIPLOG -TEZY%TASK%.LOG -D21
goto start
:tossmail
cd %EZY%
ezymail -toss
ezynet -import -echoarea
:netecho
echo Net/Echo Mail Entered
cd %EZY%
EZYMAIL -SCAN
:netmail
cd %EZY%
EZYNET -EXPORT
goto start
:echomail
cd %EZY%
EZYMAIL -SCAN
goto start
:sysopnext
ezy -L -E25
goto after_ezy
:fax
REM insert your own fax handling routine here
goto start
:fossil
echo Fossil Error
goto finish
:modeminit
echo Modem Init Error
goto finish
:runtimeerror
echo Runtime Error Please consult Errors.log
goto start
:setuperror
echo Setup Error
:finish
echo Ezycom is Down