home *** CD-ROM | disk | FTP | other *** search
/ Compute! Gazette 1998 Special / special1988a.d64 / hrprintchrm (.txt) < prev    next >
Commodore BASIC  |  2022-09-20  |  829b  |  37 lines
  1. 100 rem create character set for
  2. 110 rem 'hi-res print' ml routine
  3. 120 print chr$(142):rem use chr$(14) for  lowercase
  4. 130 print chr$(8):rem disable case change from keyboard
  5. 140 input "location of character set";n
  6. 150 a=n-int(n/256)*256: b=int(n/256)
  7. 160 input "filename";f$
  8. 170 if len(f$)=0 then 160
  9. 180 print "working..."
  10. 190 rem copy first 64 characters from rom character set
  11. 200 poke 56334, peek(56334) and 254
  12. 210 poke 1, peek(1) and 251
  13. 220 for j=0 to 511
  14. 230 poke j+n, peek(53248+j)
  15. 240 next j
  16. 250 poke 1, peek(1) or 4
  17. 260 poke 56334, peek(56334) or 1
  18. 270 close 15:open 15, 8, 15, "i0"
  19. 280 gosub 410
  20. 290 open 2, 8, 2, f$ + ",p,w"
  21. 300 gosub 410
  22. 310 print#2, chr$(a);:print#2, chr$(b);
  23. 320 gosub 410
  24. 330 for j=0 to 511
  25. 340 print#2, chr$(peek(j+n));
  26. 350 next j
  27. 360 gosub 410
  28. 370 close 2:close 15
  29. 380 print chr$(9):rem enable case change from keyboard
  30. 390 end
  31. 400 rem check disk drive error status
  32. 410 input#15,ex,ex$,tr,se
  33. 420 if ex=0 then return
  34. 430 print chr$(18) "disk error"
  35. 440 print ex;ex$;tr;se
  36. 450 goto 370
  37.