home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / zsys / znode-12 / a / chase.bas < prev    next >
Encoding:
BASIC Source File  |  1994-07-13  |  3.4 KB  |  116 lines
  1. 10 REM        C H A S E       V 1.0        1/16/77   GCC III
  2. 20 REM BY HERMAN DEMONSTOY FEB 77 ISSUE KILOBAUD MAG
  3. 30 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT
  4. 40 Z2=0
  5. 50 PRINT"THIS IS THE GAME OF CHASE"
  6. 60 PRINT"YOU ARE IN A HIGH VOLTAGE MAZE WITH FIVE"
  7. 70 PRINT"SECURITY MACHINES (+) TRYING TO DESTROY YOU (X)."
  8. 80 PRINT"YOU MUST MANEUVER THE SECURITY MACHINES INTO"
  9. 90 PRINT"THE HIGH VOLTAGE FENCE POSTS (O), OR INTO EACH OTHER"
  10. 100 PRINT"IN ORDER TO SURVIVE.   GOOD LUCK.
  11. 110 PRINT
  12. 120 PRINT"MOVES ARE:    1 2 3"
  13. 130 PRINT"              8 * 4     0  IS NO MOVE"
  14. 140 PRINT"              7 6 5     9  GIVE UP"
  15. 150 PRINT
  16. 160 REM .............SET UP THE GAME
  17. 170 DIM A(10,20),E(21),F(21)
  18. 180 G=5:M=0
  19. 190 FOR B=1 TO 10
  20. 200 FOR C=1 TO 20
  21. 210 LET A(B,C)=0
  22. 220 IF B=1 THEN A(B,C)=1
  23. 230 IF B=10 THEN A(B,C)=1
  24. 240 IF C=1 THEN A(B,C)=1
  25. 250 IF C=20 THEN A(B,C)=1
  26. 260 NEXT C
  27. 270 PRINT" . ";:REM ..........KEEPS SCREEN GOING WHILE TABLE SET UP
  28. 280 NEXT B
  29. 290 FOR D=1 TO 21
  30. 300 B=INT(RND(1)*8)+2
  31. 310 C=INT(RND(1)*18)+2:REM .......................
  32. 320 IF A(B,C)<>0 GOTO 300
  33. 330 A(B,C)=1
  34. 340 IF D<6 THEN A(B,C)=2
  35. 350 IF D=6 THEN A(B,C)=3
  36. 360 E(D)=B
  37. 370 F(D)=C
  38. 380 NEXT D
  39. 390 PRINT:PRINT
  40. 400 REM ..........PRINT PATTERN
  41. 410 FOR B=1 TO 10
  42. 420 FOR C=1 TO 20
  43. 430 IF A(B,C)=0 THEN  PRINT" ";
  44. 440 IF A(B,C)=1 THEN PRINT"O";
  45. 450 IF A(B,C)=2 THEN PRINT"+";
  46. 460 IF A(B,C)=3 THEN PRINT"X";
  47. 470 NEXT C
  48. 480 IF B=3 THEN PRINT"      ";G;"SECURITY MACHINE";:IF G>1 THEN PRINT"S";
  49. 490 IF B=3 THEN PRINT" LEFT";
  50. 500 IF B=7 THEN PRINT"            1 2 3";
  51. 510 IF B=8 THEN PRINT"            8 * 4     0  IS NO MOVE";
  52. 520 IF B=9 THEN PRINT"            7 6 5     9  GIVE UP";
  53. 530 PRINT
  54. 540 NEXT B
  55. 550 REM .........MAKE MOVE
  56. 560 B=E(6)
  57. 570 C=F(6)
  58. 580 A(B,C)=0
  59. 590 INPUT"MOVE";Y
  60. 600 M=M+1
  61. 610 IF Y=0 GOTO 710
  62. 620 ON Y GOTO 630,630,630,660,650,650,650,660,890
  63. 630 B=B-1
  64. 640 GOTO 660
  65. 650 B=B+1
  66. 660 ON Y GOTO 670,710,690,690,690,710,670,670
  67. 670 C=C-1
  68. 680 GOTO 710
  69. 690 C=C+1
  70. 700 REM ..........CALCULATE THE RESULTS
  71. 710 IF A(B,C)=1 GOTO 920
  72. 720 IF A(B,C)=2 GOTO 950
  73. 730 A(B,C)=3
  74. 740 E(6)=B
  75. 750 F(6)=C
  76. 760 FOR D=1 TO 5
  77. 770 IF A(E(D),F(D))<>2 GOTO 870
  78. 780 A(E(D),F(D))=0
  79. 790 IF E(D)<B THEN E(D)=E(D)+1
  80. 800 IF E(D)>B THEN E(D)=E(D)-1
  81. 810 IF F(D)<C THEN F(D)=F(D)+1
  82. 820 IF F(D)>C THEN F(D)=F(D)-1
  83. 830 IF A(E(D),F(D))=3 GOTO 950
  84. 840 IF A(E(D),F(D))<>0 THEN G=G-1
  85. 850 IF A(E(D),F(D))=0 THEN A(E(D),F(D))=2
  86. 860 IF G=0 GOTO 980
  87. 870 NEXT D
  88. 880 GOTO 410
  89. 890 PRINT:PRINT"SORRY TO SEE YOU QUIT"
  90. 900 PRINT"AFTER ONLY ";M;"MOVE";:IF M>1 THEN PRINT"S";:PRINT"."
  91. 910 PRINT:GOTO 1010
  92. 920 PRINT:PRINT"YOU TOUCHED THE FENCE !!!!!!!!"
  93. 930 PRINT" AFTER ONLY ";M;"MOVES."
  94. 940 GOTO 1010
  95. 950 PRINT:PRINT"** YOU HAVE BEEN DESTROYED BY A LUCKY COMPUTER**"
  96. 960 PRINT"AFTER ONLY ";M;" MOVES.   TOO BAD."
  97. 970 GOTO 1010
  98. 980 PRINT:PRINT"YOU ARE LUCKY * * YOU DESTROYED ALL THE ENEMY * *"
  99. 990 PRINT"IN ONLY ";M;" MOVES."
  100. 1000 Z2=Z2+1
  101. 1010 PRINT"SO FAR YOU HAVE WON ";Z2;" GAME(S)!!!"
  102. 1020 PRINT:PRINT:PRINT"WANT TO PLAY AGAIN(Y OR N)
  103. 1030 INPUT Y$
  104. 1040 PRINT:PRINT
  105. 1050 IF LEFT$(Y$,1)="Y" GOTO 180
  106. 1060 PRINT:PRINT"HOPE YOU DONT FEEL FENCED IN."
  107. 1070 PRINT"TRY AGAIN SOMETIME "
  108. 1080 PRINT"THIS TIME YOU WON ";Z2;" GAME(S)"
  109. 1090 Z2=Z2+1
  110. 1100 PRINT"NEXT TIME YOU MAY WIN ";Z2;", OR MORE!!!!!"
  111. 1110 END
  112. 
  113. 1080 PRINT"THIS TIME YOU WON ";Z2;" GAME(S)"
  114. 1090 Z2=Z2+1
  115. 1100 PRINT"NEXT TIME YOU MAY WIN ";Z2;", OR MORE!!!!!"
  116. 111