home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / zsys / simtel20 / z3lib / zlib1.lbr / Z3APPCL.Z80 < prev    next >
Encoding:
Text File  |  1986-02-07  |  2.0 KB  |  102 lines
  1. ;
  2. ; Z3LIB Module Name:  Z3APPCL
  3. ; Author:  Richard Conn
  4. ; Z3LIB  Version Number:  1.3
  5. ; Module Version Number:  1.1
  6. ;
  7.     public    appcl
  8.  
  9.     ext    getcl1,getcl2
  10.  
  11. ;
  12. ; Macros
  13. ;
  14. putrg    macro
  15.     push    bc
  16.     push    de
  17.     push    hl
  18.     endm
  19.  
  20. getrg    macro
  21.     pop    hl
  22.     pop    de
  23.     pop    bc
  24.     endm
  25.  
  26. ;
  27. ;    APPCL stores a command line in the ZCPR3 command line buffer.
  28. ; This command line is pted to by HL.  On return, A=0 and Zero Flag Set
  29. ; if command line overflow is possible (no change to command line).
  30. ;
  31. appcl:
  32.     putrg            ;save registers
  33.     push    hl        ;save ptr to new line
  34.     call    getcl1        ;is command line available?
  35.     jp    nz,pcl0
  36. ;
  37. ; Error Return
  38. ;
  39. nocl:
  40.     pop    hl        ;get ptr to new line
  41.     getrg            ;restore registers
  42.     xor    a        ;ret Z
  43.     ret
  44. ;
  45. ; Pack old command line
  46. ; 
  47. pcl0:
  48.     ld    b,a        ;count of chars in B
  49.     push    hl
  50.     call    getcl2        ;get address of new first command
  51.     ld    (oldcmd),hl    ;save position
  52.     pop    hl
  53.     ld    de,4        ;pt to first char in buffer
  54.     ex    de,hl
  55.     add    hl,de
  56.     ex    de,hl
  57.     ld    (hl),e        ;store address
  58.     inc    hl
  59.     ld    (hl),d        ;DE pts to first char of buffer
  60.     ld    hl,(oldcmd)    ;get address of first char of remaining CL
  61. ;
  62. ; Copy Old Command Line into Front of Buffer
  63. ;
  64. pcl1:
  65.     ld    a,(hl)        ;copy
  66.     ld    (de),a
  67.     inc    hl
  68.     inc    de
  69.     dec    b        ;count down
  70.     or    a        ;EOL?
  71.     jp    nz,pcl1
  72.     inc    b        ;B = number of bytes left in buffer
  73.     pop    hl        ;HL = address of first char of new command line
  74. ;
  75. ;    HL pts to first char of new command line
  76. ;    DE pts to after ending 0 of old command line
  77. ;    B = number of chars remaining before overflow of Z3 command line
  78. ;
  79.     push    de        ;save ptr on stack
  80. pcl2:
  81.     ld    a,(hl)        ;get next char
  82.     ld    (de),a        ;put next char
  83.     dec    b        ;count down remaining chars
  84.     jp    z,nocl        ;overflow if reached zero
  85.     inc    hl        ;pt to next
  86.     inc    de
  87.     or    a        ;EOL?
  88.     jp    nz,pcl2
  89.     pop    hl        ;get ptr to first char of new line
  90.     dec    hl        ;pt to ending 0 of old line
  91.     ld    (hl),';'    ;store semicolon separator
  92.     getrg
  93.     or    0ffh        ;no error
  94.     ret
  95.  
  96. ;
  97. ; Data
  98. ;
  99. oldcmd:    ds    2        ;pointer to old command line in CL buffer
  100.  
  101.     end
  102.