CP/M/CPM_CDROM.iso/mbug/mbug121.arc/NUCLEAR.ARK/POWER.BAS

BASIC Source File | 1988-02-29 | 17KB | 385 lines

10 '  POWER.BAS
20 POKE 13,50'    SET CPU SPEED TO 4MHZ
30 'NUCLEAR POWER PLANT SIMULATION
40 'FOR H-19 TERMINAL
50 'BASED ON S. R. BERGGREN, CREATIVE COMPUTING DECEMBER 1980 PAGE 128
60 'AS MODIFIED FOR PET BY IVAN SMITH & HUME SMITH
70 'CREATIVE COMPUTING AUGUST 1981 PAGE 144
75 'MOD BY B.MOSKUS 6/85 FOR "SCORE-KEEPING" USING FILE POWER.DAT
80 E$=CHR$(27):RE$=E$+"p":ER$=E$+"q":MV$=E$+"Y":BEL$=CHR$(7)
90 PRINT E$+"E";
100 PRINT "This program simulates the operation of a nuclear power reactor."
110 PRINT "The object is to operate the plant at a maximum average power output"
120 PRINT "without causing a reactor meltdown."
130 PRINT
140 PRINT "The control rods adjust the amount of heat produced by the reactor."
150 PRINT "Primary coolant transfers this heat to the heat exchanger."
160 PRINT "Secondary coolant transfers heat from the heat exchanger to the"
170 PRINT "turbine, where power is produced, and finally to the cooling tower."
180 PRINT "The emergency coolant is used to help shut down the reactor when"
190 PRINT "other systems fail.  Unlike the other coolants, emergency coolant"
200 PRINT "is not recycled."
210 PRINT E$;"x1";E$;"Y8 ";:
    PRINT "Enter 'D' Reactor Diagram, 'I' Working Instructions, 'S' Start";
    :A$=INPUT$(1):PRINT E$;"H";E$;"y1";
220 IF A$="D" OR A$="d" THEN GOSUB 2370:GOTO 210
230 IF A$="S" OR A$="s" THEN 410
240 PRINT E$;"G";E$;"E";
250 PRINT "The controls are operated by typing in the desired control rod"
260 PRINT "setting and flow rates.  (Use values from 0 to 100).  If no entry"
270 PRINT "is made, the values will not change.  The reactor can be operated"
280 PRINT "until a meltdown occurs or the reactor fuel is exhausted.  The"
290 PRINT "fuel will last for about 100 to 150 days.  When the fuel is"
300 PRINT "exhausted, your performance will be evaluated."
310 PRINT :PRINT "If you want to repair damage or replace coolant, bring the"
320 PRINT "reactor temperature down below 100 and shut off the coolant flows."
330 PRINT "This will cause an automatic maintenance shutdown and all coolant"
340 PRINT "will be replenished and repairs made.  The greater the damage, the"
350 PRINT "longer the repairs will take."
360 PRINT
370 PRINT TAB(25)RE$"WARNING:"ER$"  This power plant has"
380 PRINT TAB(25)"no automatic safety devices!!"
390 PRINT
400 GOTO 210
410 CLEAR:E$=CHR$(27):RE$=E$+"p":ER$=E$+"q":MV$=E$+"Y":BEL$=CHR$(7)
420 GOSUB 1420
430 RH=0
440 RL=0
450 DAY%=0
460 TT=0
470 DMGE%=0
480 A%=0:A1%=0:A2%=0
490 '**********   Write report   **********
500 PRINT E$;"G";E$;"E";
510 DAY%=DAY%+1
520 PRINT TAB(30);"Nuclear Power Plant"
530 PRINT TAB(27);"Status Report - Day";DAY%
540 PRINT MV$"# "RE$"Warnings:"ER$
550 IF RT%>800 THEN PRINT BEL$;MV$"$!Reactor Overheated":
    RD%=RD%+1-(RT%>850)-(RT%>900)-2*(RT%>950):
    PD%=PD%+1:ED%=ED%+1-(RT%>850):GOSUB 3570
560 IF XT%>500 THEN PRINT BEL$;MV$"%!Heat Exchanger Overheated":
    XD%=XD%+1-(XT%>600):PD%=PD%+1:SD%=SD%+1:GOSUB 3570
570 IF GO%>2000 THEN PRINT BEL$;MV$"&!Turbine Overloaded":
    TD%=TD%+1-(GO%>2500):SD%=SD%+1:GOSUB 3570
580 IF CT%>300 THEN PRINT BEL$;MV$"'!Cooling tower overheated":SD%=SD%+1:
    GOSUB 3570
590 IF GO%<1000 THEN PRINT BEL$;MV$"(!Power output low":GOSUB 3570
600 IF EV%<200 THEN PRINT BEL$;MV$")!Emergency coolant low":GOSUB 3570
610 IF PV%<100 THEN PRINT BEL$;MV$"*!Primary coolant low":PD%=PD%+1:GOSUB 3570
620 IF SV%<100 THEN PRINT BEL$;MV$"+!Secondary coolant low":SD%=SD%+1:GOSUB 3570
630 PRINT MV$"#G"RE$"Damage:"ER$
640 IF RD%>3 THEN GOSUB 3560:PRINT MV$"$HReactor Core damaged":GOSUB 3570
650 IF PD%>4 THEN GOSUB 3560:PRINT MV$"%HPrimary Coolant Leak - ";PD%;"/day":
    PV%=(PV%-PD%)*-((PV%-PD%)>0):GOSUB 3570
660 IF SD%>4 THEN GOSUB 3560:PRINT MV$"&HSecondary Coolant Leak - ";SD%;"/day":
    SV%=(SV%-SD%)*-((SV%-SD%)>0):GOSUB 3570
670 IF ED%>2 THEN GOSUB 3560:PRINT MV$"'HEmergency Coolant Leak - ";2*ED%;"/day"
    :EV%=(EV%-2*ED%)*-((EV%-2*ED%)>0):GOSUB 3570
680 IF PB%=1 THEN GOSUB 3560:PRINT MV$"(HPrimary Coolant Pump Failure - ";
    10*PD%*-(PD%<10)+100*-(PD%>=10);"%":GOSUB 3570
690 IF SB%=1 THEN GOSUB 3560:PRINT MV$")HSecondary Coolant Pump Failure - ";
    10*SD%*-(SD%<10)+100*-(SD%>=10);"%":GOSUB 3570
700 IF XB%=1 THEN GOSUB 3560:PRINT MV$"*HHeat exchanger failure":GOSUB 3570
710 IF GB%=1 THEN GOSUB 3560:PRINT MV$"+HTurbine failure":GOSUB 3570
720 IF RD%>5 THEN PRINT E$;"x1";RE$;E$;"Y8 ";:
    FOR I=1 TO 7:GOSUB 3580:PRINT "  MELTDOWN!  ";:NEXT:PRINT E$;"H";ER$;:
    FOR I=1 TO 5000:NEXT:PRINT E$;"E";:PRINT E$;"y1";:
    GOTO 1630
730 PRINT RE$;MV$"- Indicators:"ER$
740 PRINT MV$".!";:PRINT "Reactor Temp. <Max 800>        "RE$;USING"#### ";RT%;:
    PRINT ER$;USING" ####";RT%-PRT%:PRT%=RT%' PRT% is previous value
750 PRINT MV$"/!";:PRINT "Heat Exchanger Temp. <Max 500> "RE$;USING"#### ";XT%;:
    PRINT ER$;USING" ####";XT%-PXT%:PXT%=XT%' PXT% is previous value
760 PRINT MV$"0!";:PRINT "Cooling Tower Temp. <Max 300>  "RE$;USING"#### ";CT%;:
    PRINT ER$;USING" ####";CT%-PCT%:PCT%=CT%' PCT% is previous value
770 PRINT MV$"2!";:PRINT USING"Power output <Max 2000KW>      ####KW";GO%;:
    PRINT USING"####";GO%-PGO%:PGO%=GO%' PGO% is previous value
780 KW%=TT/DAY%
790 PRINT MV$"4!";:PRINT USING"Average power output           ####KW/DAY";KW%
800 PRINT MV$".M      Control Rods-         ";"("A%")"
810 PRINT MV$"0L            Coolants"
820 PRINT MV$"1M";:PRINT USING"Emergency  Level-###  Flow- ###";EV%,EF%
830 PRINT MV$"2M";:PRINT USING"Primary    Level-###  Flow- ###";PV%,PF%
840 PRINT MV$"3M";:PRINT USING"Secondary  Level-###  Flow- ###";SV%,SF%
850 IF 100-RL<5 THEN PRINT :PRINT :PRINT "Reactor Fuel Exhausted":GOTO 1780
860 '**********     Get new control values     **********
870 PRINT MV$".b";
880 A2%=A1%:A1%=A%
890 B$=""
900 INPUT B$
910 IF B$="" THEN 940
920 A%=VAL(B$)
930 IF A%>100 THEN A%=100
940 PRINT MV$"1h";
950 B$=""
960 INPUT B$
970 IF B$="" THEN 1010
980 EF%=VAL(B$)
990 IF EF%>100 THEN EF%=100
1000 IF EF%>EV% THEN EF%=EV%
1010 PRINT MV$"2h";
1020 B$=""
1030 INPUT B$
1040 IF B$="" THEN 1070
1050 PF%=VAL(B$)
1060 IF PF%>100 THEN PF%=100
1070 PRINT MV$"3h";
1080 B$=""
1090 INPUT B$
1100 IF B$="" THEN 1130
1110 SF%=VAL(B$)
1120 '''''GOTO 800
1130 IF PF%=0 AND SF%=0 AND RH<1 AND RT%<100 AND A%=0 THEN GOSUB 1420:
    PRINT USING"Maintenance Shutdown - ## days";MD%:FOR I=1 TO 5000:NEXT
1140 IF EF%>EV% THEN EF%=EV%
1150 '**********     DAMAGE ASSESSMENT AND OPERATION CALCULATIONS
1160 EV%=EV%-EF%-2*ED%*-(ED%>3)
1170 PD%=PD%+(-(PF%>90)*-(RND(20)>.95))
1180 SD%=SD%+(-(SF%>90)*-(RND(20)>.92))
1190 PB%=-(PD%>5)
1200 SB%=-(SD%>5)
1210 IF PF%>(100-PD%*10) AND PB%=1 THEN PF%=(100-PD%*10)*-(100-PD%*10>0)
1220 IF SF%>(100-SD%*10) AND B%=1 THEN SF%=(100-SD%*10)*-(100-SD%*10>0)
1230 RL=RL+RH/50
1240 RH=(A%*30+A1%*60+A2%*10)/2500*(100-RL)
1250 PH=PF%*(100*-(PV%>100)+PV%*-(PV%<=100))/350
1260 EH=EF%/200*(RT%-25)
1270 RT%=RT%+RH-EH-PH-5*-(RT%>25)
1280 RT%=25+(RT%-25)*-(RT%>25)
1290 XT%=((RT%-25)*PF%+(CT%-25)*SF%)/(PF%+SF%+1)+25
1300 IF XB%=1 THEN XT%=RT%*.8+5
1310 SH=SF%*(100*-(PV%>100)+PV%*-(PV%<=100))/350*(XT%-CT%)
1320 IF XB%=1 THEN SH=SH*.2
1330 GO%=SH/XT%*(XT%-CT%)*2/3
1340 IF GO%>2600 THEN GO%=2600
1350 GO%=GO%*-(GO%>0)*-(GB%=0)
1360 CT%=25+((XT%-25)*(SH-GO%)/(SH+1)*.75)
1370 CT%=25*-(CT%<=25)+CT%*-(CT%>25)
1380 IF XB%<1 THEN XB%=-(XD%>2)*-(RND(4)>.9)
1390 IF GB%<1 THEN GB%=-(GD%>4)*-(RND(4)>.9)
1400 TT=TT+GO%
1410 GOTO 500
1420 '**********     MAINTENANCE REPAIR SUBROUTINE     **********
1430 EV%=300
1440 PV%=120
1450 SV%=120
1460 RT%=25:PRT%=25
1470 XT%=25:PXT%=25
1480 CT%=25:PCT%=25
1490 DMGE%=DMGE%+2*RD%+ED%+PD%+XD%+SD%+GD%
1500 MD%=5+3*(10*-(RD%>3)-(ED%>3)-(PD%>3)-(SD%>3)+
    2*PB%+2*SB%+3*XB%+3*GB%):DAY%=DAY%+MD%
1510 RD%=0
1520 ED%=0
1530 PD%=0
1540 XD%=0
1550 SD%=0
1560 GD%=0
1570 PB%=0
1580 SB%=0
1590 XB%=0
1600 GB%=0
1610 EF%=0:PF%=0:SF%=0
1620 RETURN
1630 '**********   MELTDOWN ENDING     **********
1640 PRINT
1650 IF RD%>6 THEN 1710
1660 PRINT "The reactor core has been destroyed by uncontrolled thermal runaway."
1670 PRINT "However, the containment building has not yet ruptured."
1680 PRINT
1690 PRINT "Initiate your evacuation plan."
1700 GOTO 2040
1710 PRINT "The reactor core has melted down and produced a steam explosion."
1720 PRINT "The containment building has ruptured.  Lethal radioactive gases"
1730 PRINT "and debris have escaped."
1740 PRINT
1750 PRINT "Initiate your evacuation and radiation cleanup plans and get"
1760 PRINT "medical assistance."
1770 GOTO 2040
1780 '**********   EVALUATION OF GAME RESULTS    **********
1790 PRINT
1800 PRINT USING"Over a period of ### days, you have produced an average";DAY%
1810 PRINT USING"power output of #### kilowatts per day.";KW%
1820 PRINT KW%;"KILOWATTS PER DAY."
1830 AKW%=1+-1*(KW%>1000)+-1*(KW%>1200)+-1*(KW%>1500)+-1*(KW%>1800)
1840 PRINT
1850 PRINT "Your average power production rate is ";
1860 ON AKW% GOTO 1870,1880,1890,1900,1920
1870 PRINT "HORRIBLE!  Find a less demanding job.":GOTO 1940
1880 PRINT "way below your area's power needs.":GOTO 1940
1890 PRINT "adequate.  You could do better.":GOTO 1940
1900 PRINT "excellent!  power costs in your area"
1910 PRINT "will not be increased.":GOTO 1940
1920 PRINT "near the maximum!  Power costs in your"
1930 PRINT "area will drop significantly."
1940 '**********   DAMAGE EVALUATION    **********
1950 PRINT
1960 GOSUB 1420
1970 D%=1+-1*(DMGE%>10)+-1*(DMGE%>20)+-1*(DMGE%>30)
1980 PRINT "The equipment damage sustained during this period was ";
1990 ON D% GOTO 2000,2010,2020,2030
2000 PRINT "very light.":GOTO 2040
2010 PRINT "moderate.":GOTO 2040
2020 PRINT "heavy.":GOTO 2040
2030 PRINT "severe."
2040 '
2050 FOR PAUSE=1 TO 10000:NEXT
2060 '     SCORE.BAS     Score-keeping file routine
2070 PRINT CHR$(27)+"E"
2080 A=0:FORMAT$="#####":GAME$="POWER.DAT"
2090 DIM SCORE(11),NME$(11)
2100 NEWSCORE=KW%
2110 OPEN "I",1,GAME$
2120 IF EOF(1) THEN 2170 ELSE A=A+1
2130 INPUT #1,OLDSCORE,OLDNAME$
2140 IF FLAG=0 AND NEWSCORE=>OLDSCORE THEN SCORE(A)=NEWSCORE:
    NME$(A)=NEWNAME$:FLAG=A:A=A+1
2150 SCORE(A)=OLDSCORE:NME$(A)=OLDNAME$
2160 GOTO 2120
2170 IF FLAG>0 THEN INPUT "Enter your Name ";ANS$
2180 PRINT:PRINT "TOP SCORES :":PRINT
2190 FOR B=1 TO A
2200 IF B=FLAG THEN NME$(B)=ANS$
2210 IF FLAG2=0 THEN PRINT "KW/DAY":FLAG2=1
2220 PRINT USING FORMAT$;SCORE(B);:PRINT " - "NME$(B)
2230 IF B=FLAG THEN B=B+1
2240 NEXT B
2250 CLOSE:OPEN "O",1,GAME$
2260 FOR C=1 TO 10:WRITE #1,SCORE(C),NME$(C):NEXT C:CLOSE
2270 PRINT:PRINT:
2280 INPUT "Would you like to try again  <Y or N> ";A$:A$=LEFT$(A$,1)
2290 IF A$="Y" OR A$="y" THEN GOSUB 1420:GOTO 410
2300 IF A$="N" OR A$="n" THEN 2310 ELSE 2280
2310 PRINT E$;"E";
2320 GOTO 3590'    **********  TO END THE PROGRAM  **********
2330 '
2340 '
2350 '
2360 '**********     display graphics - POWER PLANT     **********
2370 PRINT E$;"w";E$;"H";E$;"J";E$;"G";
2380 PRINT E$;"q ";E$;"F   ";E$;"C       ";E$;
2390 PRINT "G ";E$;"F";E$;"Y 4            ";E$;"Y!!   ";
2400 PRINT "      ` `";E$;"Y!4             ";E$;"Y!H       ";
2410 PRINT "        ";E$;"Y";CHR$(34);"# ";E$;"Y";
2420 PRINT CHR$(34);"&    `";E$;"C`";E$;"p";E$;"Cii";
2430 PRINT E$;"q";E$;"Y";CHR$(34);"B                      ";
2440 PRINT E$;"p";E$;"Y#!i";E$;"Ci";E$;"q ";
2450 PRINT E$;"Y#*`";E$;"C`";E$;"piii";E$;"Y#8i";
2460 PRINT E$;"Ci";E$;"q";E$;"Y";"#B ";E$;"C      ";
2470 PRINT " aaaasaaaa    ";E$;"C";CHR$(95);E$;"p ";
2480 PRINT CHR$(95);E$;"Y#jr ";E$;"qr";E$;"p";
2490 PRINT E$;"Y$!iii";E$;"q";E$;"Y$*`";E$;"C`";
2500 PRINT E$;"pii";E$;"Y$8iii";E$;"q";E$;"Y$B ";
2510 PRINT E$;"C           `      ";E$;"C ";E$;"Y$Z";
2520 PRINT CHR$(95);E$;"p ";CHR$(95);E$;"Y$ir ";E$;"q";
2530 PRINT "r";E$;"Y%  ";E$;"piii";E$;"Cr";E$;
2540 PRINT "G   ";E$;"q";E$;"F";E$;"C`";E$;"C`";
2550 PRINT E$;"pi";E$;"G  ";E$;"F ";CHR$(95);
2560 PRINT E$;"Y%8iii";E$;"q";E$;"Y%A  ";E$;"C ";
2570 PRINT "   faaaaaabaaaaac";E$;"G ";E$;"F ";E$;"G ";
2580 PRINT "  ";E$;"F";CHR$(95);E$;"p ";CHR$(95);E$;
2590 PRINT "Y%hr ";E$;"qr";E$;"p";E$;"Y&";CHR$(34);"i";
2600 PRINT E$;"Cr";E$;"G     ";E$;"q";E$;"F`";
2610 PRINT E$;"p";E$;"G ";E$;"q";E$;"F`";
2620 PRINT E$;"p";E$;"G     ";E$;"F";CHR$(95);
2630 PRINT E$;"Y&9i";E$;"q";E$;"Y&B   ";E$;"pii";
2640 PRINT "i";E$;"q`";E$;"piiiiii";E$;"q`";
2650 PRINT E$;"piiiii";E$;"q`";E$;"piiii";E$;"q";
2660 PRINT E$;"G  ";E$;"p";E$;"F  ";E$;"Y&h ";
2670 PRINT E$;"qr";E$;"G";E$;"Y'  ";E$;"p";
2680 PRINT E$;"F";E$;"Ci";E$;"G";E$;"C      ";
2690 PRINT E$;"q";E$;"F`";E$;"p";E$;"G ";
2700 PRINT E$;"q";E$;"F`";E$;"p";E$;"G      ";
2710 PRINT E$;"F";E$;"Y";"'9i";E$;"q";E$;"Y'Ei";
2720 PRINT E$;"Y'H`      vaaa  `";E$;"G   ";E$;"p";
2730 PRINT E$;"Fiiii ";E$;"Y'h ";E$;"Y(";CHR$(34);"i";
2740 PRINT E$;"G";E$;"C  ";E$;"q";E$;"Fr";
2750 PRINT E$;"Y(*`";E$;"C`";E$;"Y(0";CHR$(95);
2760 PRINT E$;"p";E$;"G  ";E$;"F";E$;"Y(9i";
2770 PRINT E$;"q";E$;"Y(Ei";E$;"G  ";E$;"F`";
2780 PRINT E$;"G   ";E$;"Faaat";E$;"G     ";
2790 PRINT E$;"F`";E$;"G      ";E$;"p";E$;"Fi ";
2800 PRINT E$;"q";E$;"G ";E$;"p";E$;"F";
2810 PRINT E$;"Y(h ";E$;"Y)";CHR$(34);"i";E$;"G";
2820 PRINT E$;"C  ";E$;"q";E$;"F";E$;"Y)*`";
2830 PRINT E$;"C`";E$;"p";E$;"G";E$;"Y)1  ";
2840 PRINT E$;"F";E$;"Y)9i";E$;"q";E$;"Cfaaaaac";
2850 PRINT E$;"G";E$;"Y)D ";E$;"Fi";E$;"G  ";
2860 PRINT E$;"F`";E$;"G      ";E$;"Fvaaa";E$;
2870 PRINT "G  ";E$;"F`";E$;"G      ";E$;"p";
2880 PRINT E$;"Fi ";E$;"Y)h ";E$;"q";E$;"Y*  ";
2890 PRINT E$;"p";E$;"Ci";E$;"G";E$;"C  ";
2900 PRINT E$;"Y*(  ";E$;"q";E$;"F`";E$;"p";
2910 PRINT E$;"G ";E$;"q";E$;"F`";E$;"p";
2920 PRINT E$;"G  ";E$;"Y*1  ";E$;"F";E$;"Y*9i";
2930 PRINT E$;"q";E$;"C`";E$;"C ";E$;"Y*A`";
2940 PRINT E$;"Y*Ei";E$;"Y*H`";E$;"G";E$;"C  ";
2950 PRINT E$;"Faaat";E$;"G     ";E$;"F`";E$;"G";
2960 PRINT "      ";E$;"p";E$;"Fi ";E$;"Y*h ";
2970 PRINT E$;"Y+";CHR$(34);"iiiiiii";E$;"G ";E$;"q";
2980 PRINT E$;"F`";E$;"p";E$;"G ";E$;"q";
2990 PRINT E$;"F`";E$;"p";E$;"G ";E$;"F";"iiiiiiii";
3000 PRINT "iiiii";E$;"q`";E$;"pii";E$;"q";E$;
3010 PRINT "Cii`iiii";E$;"Y+H`";E$;"G";E$;"Y+L   ";
3020 PRINT E$;"Fvaaa";E$;"G  ";E$;"F`";E$;"G   ";
3030 PRINT "   ";E$;"p";E$;"Fi ";E$;"Y+h ";E$;
3040 PRINT "G";E$;"Y,$  ";E$;"F";E$;"Y,(i";E$;"G";
3050 PRINT " ";E$;"q";E$;"F`";E$;"p";E$;"G ";
3060 PRINT E$;"q";E$;"F`";E$;"p";E$;"G ";
3070 PRINT E$;"Fi";E$;"G";E$;"Y,1  ";E$;"q";
3080 PRINT E$;"F";E$;"Y,;`";E$;"p";E$;"Ci";
3090 PRINT E$;"q";E$;"Ci";E$;"C`";E$;"Y,E ";
3100 PRINT E$;"Y,H`";E$;"Y,Laaat";E$;"Y,U`";
3110 PRINT E$;"p";E$;"Y,\i ";E$;"Y,h ";E$;"G";
3120 PRINT E$;"Y-$  ";E$;"F";E$;"Y-(i";E$;"G ";
3130 PRINT E$;"q";E$;"F`";E$;"p";E$;"G ";
3140 PRINT E$;"q";E$;"F`";E$;"p";E$;"G ";
3150 PRINT E$;"Fi";E$;"G";E$;"Y-1  ";E$;"q";
3160 PRINT E$;"F";E$;"Y-;`";E$;"p";E$;"Ci";
3170 PRINT E$;"q";E$;"Ci";E$;"C`";E$;"Y-E ";
3180 PRINT E$;"Y-H`      vaaa  `";E$;"p";E$;"Y-\i ";
3190 PRINT E$;"Y-h ";E$;"G";E$;"Y.$  ";E$;"F";
3200 PRINT E$;"Y.(i";E$;"G ";E$;"q";E$;"F`";
3210 PRINT E$;"p";E$;"G ";E$;"q";E$;"F`";
3220 PRINT E$;"p";E$;"G ";E$;"Fi";E$;"G";
3230 PRINT E$;"Y.1  ";E$;"q";E$;"F";E$;"Y.;`";
3240 PRINT E$;"p";E$;"Ci";E$;"q";E$;"Ci";
3250 PRINT E$;"C`";E$;"Y.E ";E$;"Y.H`";E$;"Y.La";
3260 PRINT "aad";E$;"Y.U`";E$;"p";E$;"Y.\i ";
3270 PRINT E$;"Y.h ";E$;"Y/";CHR$(34);"iiiiiii";E$;"G";
3280 PRINT " ";E$;"q";E$;"F`";E$;"p";E$;"G ";
3290 PRINT E$;"q";E$;"F`";E$;"p";E$;"G ";
3300 PRINT E$;"F";"iiiiiiiiiiiii";E$;"q`";E$;"pii";
3310 PRINT E$;"q";E$;"Cii`";E$;"piiii";E$;"q";"e";
3320 PRINT "aaaaaaaaaaaad";E$;"p";E$;"Y/\i ";E$;"Y/h ";
3330 PRINT E$;"Y";"0";CHR$(34);"i";E$;"G";E$;"C  ";
3340 PRINT E$;"Y0(  ";E$;"q";E$;"F`";E$;"p";
3350 PRINT E$;"G ";E$;"q";E$;"F`";E$;"p";
3360 PRINT E$;"G  ";E$;"Y";"01  ";E$;"q";E$;"F";
3370 PRINT E$;"Y0";"`";E$;"Y0A`";E$;"p";E$;"Y0Ei";
3380 PRINT E$;"Y0\i ";E$;"Y0h ";E$;"Y1";CHR$(34);"i";
3390 PRINT E$;"G";E$;"C  ";E$;"Y11  ";E$;"q";
3400 PRINT E$;"F";E$;"Y1;eaaaaad";E$;"p";E$;"Y1";
3410 PRINT "Eiiiiiiiiiiiiiiiiiiiiiiii ";E$;"Y1h ";E$;"Y2";
3420 PRINT CHR$(34);"i";E$;"q";E$;"C";CHR$(95);E$;"p";
3430 PRINT E$;"G ";E$;"F";CHR$(95);E$;"Y20r";
3440 PRINT E$;"G ";E$;"q";E$;"Fr";E$;"Y2E ";
3450 PRINT E$;"p";E$;"Y2[   ";E$;"Y2h   ";E$;"Y";
3460 PRINT "3";CHR$(34);"i";E$;"q";E$;"Y3%";CHR$(95);
3470 PRINT E$;"p";E$;"G           ";E$;"q";E$;
3480 PRINT "Fr";E$;"Y3E ";E$;"Y4&";CHR$(95);E$;"p";
3490 PRINT E$;"G         ";E$;"q";E$;"Fr";E$;"Y";
3500 PRINT "4E ";E$;"p";E$;"Y5";CHR$(34);"i";E$;"q";
3510 PRINT E$;"Y5'";CHR$(95);E$;"p";E$;"G       ";
3520 PRINT E$;"q";E$;"Fr";E$;"Y5E ";E$;"Y6E ";
3530 PRINT E$;"p";E$;"Y7";CHR$(34);"i";E$;"q";
3540 PRINT E$;"G"
3550 RETURN
3560 FOR BEL=1 TO 100:PRINT BEL$;:NEXT:RETURN
3570 FOR PAUSE=1 TO 1000:NEXT:RETURN
3580 FOR BEL=1 TO 10:PRINT BEL$;:FOR PAUSE=1 TO 100:NEXT:NEXT:RETURN
3590 POKE 13,34'    SET CPU SPEED TO 2MHZ
3600 RUN "MENU"'    from line #10330
PRINT BEL$;:FOR PAUSE=1 TO 100:NEXT:NEXT:RETURN
3590 POKE 13,34