home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
CP/M
/
CPM_CDROM.iso
/
mbug
/
mbug121.arc
/
NORAD.ARK
/
SHOAX.BAS
< prev
Wrap
BASIC Source File
|
1986-11-28
|
8KB
|
171 lines
10 DIM A$(100):CLS: KEY OFF
20 PRINT "WAITING FOR DIALTONE":FOR X=1 TO 1000:NEXT X: PRINT "DIALING 203/456-7685"
30 SPEED = 300: BA$="1 203 456 7685": GOSUB 1650
40 RANDOMIZE VAL(MID$(TIME$,7,2))
50 PRINT:PRINT "WAITING FOR CONNECTION.....";: FOR X=1 TO 3000: NEXT X
60 LNE = INT(RND*5):FOR X = 1 TO 1000:NEXT X
70 IF LNE = 0 GOTO 120 ' CONNECTED
80 IF LNE = 1 THEN PRINT "BUSY": GOTO 20
90 LNE = INT(RND*5)
100 IF LNE <4 THEN PRINT "RING..."; : ELSE GOTO 120
110 FOR X = 1 TO 3000: NEXT X : GOTO 90
120 PRINT "CONNECTED": FOR X = 1 TO 500: NEXT X : CLS
130 SPEED = 65
140 rem
150 PRINT: PRINT: BA$="NORTH AMERICAN AIR DEFENSE COMMAND CONTROL SYSTEM":GOSUB 1650: PRINT: PRINT
160 BA$= "N O R A D S Y S T E M C O M C O N 4 . . . "+CHR$(7)+"CONNECTED"
170 GOSUB 1650
180 PRINT: BA$ = DATE$+" "+TIME$: GOSUB 1650 :PRINT
190 PRINT: BA$ = "AUTHORITY CODE": GOSUB 1650 : GOSUB 630
200 PRINT:PRINT: BA$ = "PROCESSING.....": GOSUB 1650
210 GOSUB 670
220 PRINT: PRINT: BA$ ="N O R A D P R I M E A C C E S S": GOSUB 1650
230 PRINT:PRINT: BA$= "PLEASE STAND BY....." : GOSUB 1650
240 GOSUB 640
250 PRINT: PRINT
260 BA$ = CHR$(7)+CHR$(7)+CHR$(7)+CHR$(7)+"WARNING!!!!!"+CHR$(7):GOSUB 1650: PRINT
270 PRINT: BA$ ="INCOMING CALLERS SUBJECT TO UNITED STATES MILITARY": GOSUB 1650
280 PRINT: BA$ ="TRIBUNAL JUSTICE SYSTEM. FOREIGN ACCESS STRICTLY": GOSUB 1650
290 PRINT: BA$="PROHIBITED. ACCESS IS ON A NEED TO KNOW, EYES-ONLY":GOSUB 1650
300 PRINT: BA$ ="BASIS FOR ALL BUT COMMAND AUTHORITY. AT THIS POINT":GOSUB 1650
310 PRINT: BA$="IMPROPER IDENTIFICATION WILL RESULT IN AUTOMATIC": GOSUB 1650
320 PRINT: BA$= "SURVEILLANCE OF CONNECTING TELEPHONE LINE AND INFORMATION": GOSUB 1650
330 PRINT: BA$= "SO GATHERED WILL BE PROVIDED TO THE PROPER LOCAL": GOSUB 1650
340 PRINT: BA$= "POLICE AND GOVERNMENTAL AGENCIES...................": GOSUB 1650
350 PRINT: BA$="ACKNOWLEDGED? (Y/N)": GOSUB 1650 : INPUT D$
360 IF D$="Y" GOTO 380
370 IF D$="N" GOTO 1540
380 CLS
390 PRINT: PRINT: BA$="N O R A D P R I M E A C C E S S" : GOSUB 1650
400 PRINT: PRINT
410 PRINT: BA$="PLEASE ENTER YOUR EYES-ONLY CODE": GOSUB 1650: GOSUB 630
420 PRINT:PRINT: BA$= "PROCESSING.....": GOSUB 1650
430 PRINT: PRINT: PRINT: PRINT
440 GOSUB 660
450 PRINT: BA$="CODE ENTERED IMPLIES COMMAND AUTHORITY": GOSUB 1650
460 PRINT:BA$="ENTER YOUR VERIFICATION AS GIVEN IN...": GOSUB 1650
470 FOR X=1 TO 2000: NEXT X
480 PRINT: BA$=">>>>>BOOK 12RY-OLIVE<<<<<": GOSUB 1650
490 PRINT: PRINT: BA$= "ENTER": GOSUB 1650: GOSUB 630
500 GOSUB 660
510 PRINT: PRINT
520 PRINT: BA$ = "SIR, COMCON4 REPORTS UPTIME VERIFIED FOR NEXT ONE HOUR.": GOSUB 1650
530 PRINT: BA$ ="N O R A D COMMAND CENTER CAN BE REACHED AT ANY TIME": GOSUB 1650
540 PRINT: BA$="WITH PASSWORDS AS PROVIDED IN THE LANGLEY PROTOCOLS.": GOSUB 1650
550 PRINT: PRINT: PRINT: BA$="ENTERING DIRECT COMMAND MODE...." : GOSUB 1650
560 PRINT: PRINT : BA$= "INTERNAL AUTHORIZATION CODE " : GOSUB 1650
570 GOSUB 680
580 CLS
590 PRINT: PRINT: PRINT: BA$ ="N O R A D C O M M A N D L E V E L": GOSUB 1650
600 PRINT: PRINT : BA$ ="REPEAT AUTHORIZATION CODE": GOSUB 1650
610 GOTO 570
620 END
630 BA$ ="===>": GOSUB 1650: INPUT A$: RETURN
640 FOR X=1 TO 2000:NEXT X:RETURN
650 FOR X=1 TO 4000:NEXT X:RETURN
660 FOR X=1 TO 6000: NEXT X: RETURN
670 FOR X=1 TO 6000: NEXT X: CLS: RETURN
680 PRINT: PRINT: BA$ ="===>": GOSUB 1650:INPUT A$
690 IF LEFT$(A$,7)= "LANGLEY" THEN GOSUB 750
700 PRINT: BA$ ="SEARCHING FOR SUBPROGRAM....":GOSUB 1650:FOR X=1 TO 2000: NEXT X: PRINT:BA$="....RUNNING "+A$+" ON CPU"+STR$(INT(RND(1)*20+1)): GOSUB 1650
710 GOSUB 670
720 A=INT(RND(1)*4 +1)
730 ON A GOSUB 910,1140,1280,1430
740 RETURN
750 GOSUB 670
760 CLS:FOR X=1 TO 4:PRINT: BA$= CHR$(7):GOSUB 1650:NEXT X: PRINT:BA$="COMCON4....REQUEST RECORDED": GOSUB 1650
770 PRINT: BA$="PROCESSING, STANDBY": GOSUB 1650
780 FOR X=1 TO 4000: NEXT X: GOSUB 670
790 PRINT: BA$="N O R A D C E N T R A L C O M M A N D": GOSUB 1650
800 PRINT: BA$=" ---------------------------------" : GOSUB 1650
810 PRINT: PRINT: PRINT: BA$="THIS IS LANGLEY CENTER" : GOSUB 1650
820 PRINT: BA$="PRIMARY INTELLIGENCE VERIFICATION CODE, PLEASE":GOSUB 1650:GOSUB 630
830 PRINT
840 GOSUB 660
850 FOR X=1 TO 4:PRINT CHR$(7);:NEXT X:PRINT:BA$="EXECUTIVE POWER CLAIM ENTERED..." : GOSUB 1650
860 PRINT: PRINT: PRINT:BA$="AIRFORCE ONE FALLBACK ALERT!": GOSUB 1650
870 PRINT: PRINT: PRINT:BA$="MR PRESIDENT, PLEASE ENTER YOUR TOTAL COMMAND AUTHORIZATION": GOSUB 1650: GOSUB 630
880 PRINT
890 GOSUB 660
900 GOTO 1520
910 REM
920 GOSUB 640
930 PRINT: PRINT: PRINT:BA$="N O R A D C O M M A N D L E V E L": GOSUB 1650
940 PRINT
950 PRINT :BA$="COMCON4 RUNNING..."+A$: GOSUB 1650 : GOSUB 640
960 PRINT: PRINT:BA$= A$+"...IMPLIES COMMAND AUTHORITY.": GOSUB 1650
970 GOSUB 1070
980 PRINT : BA$ = "PLEASE DECODE THE FOLLOWING:":GOSUB 1650 :PRINT
990 FOR X=1 TO INT(RND(1)*5)+1
1000 FOR Y=1 TO 20
1010 BA$=BA$+STR$(INT(RND(1)*9 +1))+" "
1020 NEXT Y: NEXT X
1030 GOSUB 1650: PRINT: PRINT
1040 BA$ = "MAKE DECODED ENTRY AND PRESS RETURN":GOSUB 1650: INPUT C$
1050 RESTORE
1060 RETURN
1070 REM COMMAND SUBROUTINE
1080 PRINT: FOR X=1 TO 5: READ B$(X): NEXT X
1090 DATA "GREEN","GOLD", "CRIMSON", "VIOLET", "GREY"
1100 PRINT: BA$= "USING BOOK"+STR$(INT(RND(1)*99 + 1))+B$(INT(RND(1)*5)): GOSUB 1650
1110 PRINT
1120 RESTORE
1130 RETURN
1140 REM SECOND FAKE OUTPUT
1150 PRINT: PRINT: PRINT: BA$="N O R A D C O M M A N D L E V E L":GOSUB 1650
1160 PRINT: PRINT: BA$="COMCON4 RUNNING....."+A$:GOSUB 1650: PRINT: PRINT :BA$="PLEASE DECODE THE FOLLOWING:": GOSUB 1650
1170 GOSUB 1070
1180 GOSUB 640
1190 BA$=""
1200 FOR X=1 TO INT(RND(1)*10 + 1)
1210 FOR Y=1 TO INT(RND(1)*1 + 1)
1220 Z=INT(RND(1)*26 + 65)
1230 BA$=BA$+CHR$(Z)+" "
1240 NEXT Y
1250 NEXT X: GOSUB 1650
1260 PRINT: PRINT: PRINT: BA$= "MAKE DECODED ENTRY AND PRESS RETURN":GOSUB 1650:INPUT A$
1270 RETURN
1280 REM THIRD FAKE OUTPUT
1290 CK=CK+1
1300 GOSUB 1070
1310 CLS
1320 PRINT: PRINT: PRINT:BA$ ="N O R A D C O M M A N D L E V E L": GOSUB 1650
1330 PRINT: PRINT: PRINT: PRINT: PRINT: FOR X=1 TO 4: PRINT CHR$(7);: NEXT X: PRINT:BA$="SIR--YOUR PROGRAM, "+A$+" IS NOT IN CPU CATALOG": GOSUB 1650
1340 PRINT:BA$="PLEASE RE-ENTER YOUR COMMAND AUTHORITY CODE": GOSUB 1650: GOSUB 630
1350 IF CK >4 THEN GOTO 1520
1360 PRINT: PRINT:PRINT:BA$="PROCESS A":GOSUB 1650:FOR X=1 TO 2000:NEXT X: BA$="..COMPARING..":GOSUB 1650: FOR X=1 TO 2000: NEXT X: BA$="ACCEPTED!" : GOSUB 1650
1370 GOSUB 640
1380 PRINT: PRINT:BA$="SIR, PLEASE CHECK YOUR PROGRAM CODES. COMCON4 IS PROGRAMMED": GOSUB 1650
1390 PRINT:BA$= "TO TERMINATE CALL ON FIFTH ILLEGAL PROGRAM CODE FOR": GOSUB 1650
1400 PRINT: BA$="REASONS OF NATIONAL SECURITY UNDER EXECUTIVE ORDER STAR5.": GOSUB 1650
1410 FOR X=1 TO 5000: NEXT X
1420 RETURN
1430 REM FOURTH FAKE OUTPUT
1440 GOSUB 1070
1450 CLS
1460 PRINT: BA$="N O R A D C O M M A N D L E V E L" : GOSUB 1650
1470 PRINT: PRINT: PRINT: FOR X=1 TO 4: PRINT CHR$(7);:NEXT:BA$= "CONNECTION TERMINATED WITH PREJUDICE": GOSUB 1650
1480 PRINT: PRINT:BA$="PAGE "+STR$(INT(RND(1)*1000))+" IN CODE BOOK "+B$+" IS": GOSUB 1650
1490 PRINT:BA$="STILL OPERATIVE AS IN PRIMARY DIRECTIVES.": GOSUB 1650
1500 FOR X=1 TO 5000: NEXT X
1510 GOTO 1610
1520 REM DESTRUCT
1530 CLS
1540 PRINT: BA$="N O R A D **AUTO-LOGOFF**" : GOSUB 1650
1550 PRINT: PRINT: PRINT:BA$="AUTHORIZATION CODE"+CHR$(7)
1560 GOSUB 1650
1570 BA$=CHR$(7)+" FAILURE": GOSUB 1650
1580 PRINT: PRINT: PRINT: FOR X=1 TO 4: NEXT X: PRINT:BA$= CHR$(7)+"CONNECTION TERMINATED WITH PREJUDICE.": GOSUB 1650
1590 PRINT:BA$="JOINT CHIEFS OF STAFF HAVE BEEN NOTIFIED.": GOSUB 1650
1600 PRINT:BA$="LOCAL POLICE INFORMED OF CIVILLIAN OVERRIDE ATTEMPT.": GOSUB 1650
1610 PRINT
1620 PRINT: PRINT: PRINT :BA$="COMCON4......"+CHR$(7)+"DISCONNECTING AT: ": GOSUB 1650
1630 BA$= DATE$+" "+TIME$: GOSUB 1650:PRINT:BA$="~`./":GOSUB 1650
1640 END
1650 REM THIS SLOWS DOWN THE SCREEN PROCESSING
1660 FOR A = 1 TO LEN(BA$)
1670 PRINT MID$(BA$,A,1);
1680 FOR PUS = 1 TO SPEED: NEXT PUS
1690 NEXT A
1700 RETURN