CP/M/CPM_CDROM.iso/mbug/mbug107.arc/REFERENC.LBR/MAIN.RQF/MAIN.REF

Text File | 1979-12-31 | 6KB | 206 lines

* DATE 04/24/85  19:35
* main command program of database
STOR CHR(PEEK(063)) TO dr
REST from rdata additive
USE &dr.:&base
SET INDEX TO &dr.:&tindex
STOR t TO first
* set up the loop
DO WHIL t
* if first time this trip
 IF first
  ERAS
  STOR '<A>dd, <B>ackward, <D>elete/Recall, <E>dit, <F>orward, <H>elp,' TO prompt1
  STOR '<M>aintainence, <P>rint, <R>eports, <S>earch  or <Q>uit ' TO prompt2
  STOR 'Main Database Menu' TO mode
  @ 0,65 SAY "Code: "
  @ 1, 0 SAY "+-------------------------------------------------"
  @ 1,50 SAY "-----------------------------+"
  @ 2, 2 SAY "Author:"
  @ 3,54 SAY ">>> ACTION >>>>>"
  @ 4, 1 SAY "Title 1:"
  @ 6, 1 SAY "Title 2:"
  @ 7, 0 SAY "JrnlCite:"
  @ 9, 0 SAY "Ed-Trans:"
  @ 9,56 SAY "Edn:"
  @ 10, 0 SAY "Pub data:"
  @ 10,55 SAY "Pg #:"
  @ 11, 0 SAY "Lib data:"
  @ 13, 3 SAY "Chron:"
  @ 13,55 SAY "Type:"
  @ 14, 0 SAY "Wks disc:"
  @ 16, 0 SAY "Comments:"
  @ 18,52 SAY "Updated:"
  @ 19, 0 SAY "+-------------------------------------------------"
  @ 19,50 SAY "-----------------------------+"
  @ 20, 2 SAY prompt1
  @ 21, 2 SAY prompt2
 ENDI first
 STOR f TO first
 STOR '?' TO command
* find out if the current record is marked for deletion
 IF *
  STOR 'Deleted' TO deleted
 ELSE
  STOR '       ' TO deleted
 ENDI *
* show the current record, and find out what to do next
 @ 0,27 SAY mode
 @ 0,72 SAY code
 @ 0, 0 SAY deleted
 @ 2,10 SAY author
 @ 3,72 SAY action
 @ 4,10 SAY $(title1,1,60)
 @ 5,10 SAY $(title1,61,60)
 @ 6,10 SAY title2
 @ 7,10 SAY journal
 @ 9,10 SAY edtrans
 @ 9,61 SAY edition
 @ 10,10 SAY publdat
 @ 10,61 SAY pageno
 @ 11,10 SAY librdat
 @ 13,10 SAY chron
 @ 13,61 SAY type
 @ 14,10 SAY $(worksdis,1,60)
 @ 15,10 SAY $(worksdis,61,60)
 @ 16,10 SAY $(comments,1,60)
 @ 17,10 SAY $(comments,60,60)
 @ 18,10 SAY $(comments,121,40)
 @ 18,61 SAY dayu
 @ 22,64 SAY "WHAT NEXT"
 @ 22,76 GET command PICTURE '!'
 READ
* perform selected function
 DO CASE
 CASE command = 'A'
  DO add.ref
 CASE (command = 'B' .OR. command = ',' )
* move backwards one record
  SKIP -1
 CASE command = 'D'
* switch the current record from deleted to recalled
  IF *
   RECA
  ELSE
   DELE
  ENDI *
 CASE command = 'E'
  SET console OFF
  RECA
  STOR # TO rec:number
  SET INDEX TO
  IF rec:number=0
   GO 1
  ELSE
   GO rec:number
  ENDI rec:number=0
  SET console ON
  RELE rec:number
  DO EDIT.ref
 CASE (command = 'F' .OR. command = '.' )
* move forward one record
  SKIP
 CASE (command = 'H' .OR. command = '?' )
* display a screen full of instructions
  STOR t TO first
  ERAS
TEXT


                  M A I N   M E N U   H E L P   F I L E

    Welcome to the SIG/M Reference Manager program.

    I am here to help you and you can call me anytime by just entering
    a ? mark at any place where this program asks for a command.

    When you go back to the screen you will see a line. On top of the
    line is the information you or someone else put into the data base
    with respect to the reference material.  This information tells
    you all data you should need with respect to a particular item.






               If you press any key I will tell you more.


ENDT
  SET CONSOLE OFF
  WAIT
  SET CONSOLE ON
  ERAS
TEXT


The information on screen is clear, so let's look below the line.  This shows
what you can do.  To look at the next record -  hit 'F' (or a period).  To go
back one record - hit 'B' (or a comma). To delete a record hit 'D' and a sign
will appear at the upper right corner.  To remove the delete - hit 'D' again.
Don't worry  -   you cannot accidentally delete a record just by hitting 'D'.
You must run another program on the Maintenance Menu (purge) to delete.   You
will also find on the Maintenance Menu modules to back up the file, to browse
through it    (although because of the nature of this data base large editing
jobs had best be done in the dBASE program rather than in this program.)

To find a file - hit 'S' for search.  To edit an entry hit 'E'  (although you
usually would search for a file - and Edit from the search menu.) To add more
books, just hit 'A' for add. To print the information on the screen - hit 'P'
for Print.  To prepare a report hit 'R' for Reports. You can also display the
records on screen on the report menu.



                      Please hit any key to continue

ENDT
  SET CONSOLE OFF
  WAIT
  SET CONSOLE ON
  ERAS
TEXT







   -------------------------------------------------------------------------
   WHATEVER YOU DO  -  NEVER SHUT OFF THE MACHINE OR REMOVE A DISK UNTIL YOU
   FIRST RETURN TO THE MAIN MENU AND THEN QUIT TO THE OPERATING SYSTEM.

   If you ever get a SYNTAX error that just hitting ENTER does not correct,
   hit the ESCAPE key and type Quit. Then try all over again.

   EVERY SO OFTEN YOU WILL FIND YOU WANT TO USE THE ESCAPE KEY AND WHEN YOU
   TRY TO TYPE 'QUIT' NOTHING HAPPENS. AT A FEW POINTS IN THIS PROGRAM SCREEN
   ACCESS HAS BEEN ELIMINATED. THEREFORE, TYPE 'QUIT' EVEN THOUGH IT DOES NOT
   APPEAR ON THE SCREEN - AND UNLESS THE MACHINE IS LOCKED UP - YOU WILL EXIT
   TO THE OPERATING SYSTEM.
   -------------------------------------------------------------------------

             Please hit any key to get back to the data base

ENDT
  SET CONSOLE OFF
  WAIT
  SET CONSOLE ON
  ERAS
 CASE command = 'P'
  DO PRINT.ref
 CASE command = 'M'
  DO MAINTAIN.ref
 CASE command = 'R'
  DO report.ref
 CASE command = 'Q'
  SET CONSOLE OFF
  QUIT
 CASE command = 'S'
  DO search.ref
 ENDC
* loop back again
ENDD WHILE t