home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / mbug / mbug059.arc / DIRECTOR.DOC < prev    next >
Text File  |  1979-12-31  |  17KB  |  441 lines
  1. 100 REM Program Directory for the Genealogy ON DISPLAY Programs
  2. 110 REM All data is in the form of DATA statements.
  3. 130 REM By:  Melvin O. Duke.  Updated June, 1983.
  4. 140 DATA Genealogy
  5. 150 DATA Program Directory
  6. 160 DATA -1
  7. 170 DATA 1
  8. 180 INDENT = 0
  9. 200 REM Program begins here
  10. 210 READ TITLE$, DOC.NAME$, PAGE.NO, LINE.NO
  11. 220 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
  12. 230 GOSUB 4000  'For trim line and heading space
  13. 240 FOR I = 1 TO 6 : LPRINT : NEXT I
  14. 245 LPRINT CHR$(14);  'Set Expanded Print
  15. 250 LPRINT TAB(TAB.POS-2);TITLE$
  16. 255 LPRINT CHR$(18);  'Return to normal
  17. 260 FOR I = 1 TO 3 : LPRINT : NEXT I
  18. 265 LPRINT CHR$(27); "E"; 'Set Emphasized mode
  19. 270 LPRINT TAB(TAB.POS+12);"ON DISPLAY"
  20. 275 LPRINT CHR$(27); "F"; 'Return to normal
  21. 277 LPRINT : LPRINT : LPRINT
  22. 278 LPRINT TAB(TAB.POS+11);"Version 1.3"
  23. 280 FOR I = 1 TO 11 : LPRINT : NEXT I
  24. 290 LPRINT TAB(TAB.POS+8); DOC.NAME$
  25. 300 LINE.NO = LINE.NO + 27
  26. 310 '
  27. 400 READ REPLY$
  28. 410 IF LEFT$(REPLY$,1) = "." THEN GOSUB 8000: GOTO 400
  29. 420 IF LINE.NO > 44 THEN GOSUB 4100
  30. 430 REM Print the line if not a command
  31. 440 LPRINT TAB(TAB.POS);REPLY$
  32. 450 LINE.NO = LINE.NO + 1
  33. 470 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
  34. 480 GOTO 400
  35. 490 REM Data for the Copyright Page
  36. 494 DATA ".pa"
  37. 498 DATA "Anyone may request a copy of these"
  38. 502 DATA "programs by sending two blank diskettes"
  39. 506 DATA "to the author of the programs (one for"
  40. 510 DATA "the programs and the second for the"
  41. 514 DATA "documentation)."
  42. 518 DATA ".sp"
  43. 522 DATA "An addressed, postage-paid return"
  44. 526 DATA "mailer must accompany the diskettes (no"
  45. 530 DATA "exceptions, please).
  46. 534 DATA ".sp"
  47. 538 DATA "A copy of the programs with documenta-"
  48. 542 DATA "tion will be sent by return mail."
  49. 546 DATA ".sp"
  50. 550 DATA "Regardless of whether a contribution"
  51. 554 DATA "is made, the user is encouraged to"
  52. 558 DATA "copy and share the program with others."
  53. 562 DATA "Payment for use is discretionary on"
  54. 566 DATA "the part of each subsequent user."
  55. 570 DATA ".vt 3"
  56. 574 DATA "If you are using these programs, and"
  57. 578 DATA "finding them of value, your contribution"
  58. 582 DATA "($35 suggested) will be appreciated."
  59. 586 DATA ".sp"
  60. 590 DATA "Melvin O. Duke"
  61. 594 DATA "P. O. Box 20836"
  62. 598 DATA "San Jose, CA  95160"
  63. 602 DATA ".vt 3"
  64. 606 DATA "Copyright (c) 1983, by:"
  65. 610 DATA "Melvin O. Duke."
  66. 614 DATA ".sp"
  67. 618 DATA "All rights reserved."
  68. 622 '
  69. 4000 REM Top of each page routine
  70. 4005 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
  71. 4010 LPRINT
  72. 4020 LPRINT TAB(30); "(Trim-line)"
  73. 4030 LPRINT "+"+STRING$(54,45)+"+" 'Dashes
  74. 4040 FOR I = 1 TO 6
  75. 4050  LPRINT
  76. 4070 NEXT I
  77. 4080 LINE.NO = LINE.NO + 6
  78. 4090 RETURN
  79. 4099 '
  80. 4100 REM Bottom of each page Routine
  81. 4105 IF PAGE.NO < 1 THEN LPRINT : LPRINT : LPRINT : GOTO 4150
  82. 4110 LPRINT TAB(TAB.POS); STRING$(40,45)  'on line 46
  83. 4120 LPRINT TAB(TAB.POS+3); TITLE$+" ON DISPLAY.  Version 1.3" 'on line 47
  84. 4121 IF PAGE.NO MOD 2 = 1 THEN 4130
  85. 4122 LPRINT TAB(TAB.POS);"Page";PAGE.NO;
  86. 4123 LPRINT TAB(TAB.POS+23);"Program Directory"
  87. 4124 GOTO 4150
  88. 4130 LPRINT TAB(TAB.POS); "Program Directory";
  89. 4132 IF PAGE.NO < 10 THEN DELTA = 34
  90. 4133 IF PAGE.NO >  9 THEN DELTA = 33
  91. 4134 IF PAGE.NO > 99 THEN DELTA = 32
  92. 4140 LPRINT TAB(TAB.POS+DELTA); "Page"; PAGE.NO  'on line 48
  93. 4150 LPRINT : LPRINT : LPRINT
  94. 4160 LPRINT "+"+STRING$(54,45)+"+" 'dashes after 51
  95. 4170 LPRINT TAB(30); "(Trim-line)"
  96. 4180 LPRINT CHR$(12);
  97. 4190 PAGE.NO = PAGE.NO + 1
  98. 4200 LINE.NO = 1
  99. 4202 IF REPLY$ = ".eof" THEN 4215  'Bypass after last page
  100. 4210 GOSUB 4000  'For top of next page
  101. 4215 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
  102. 4220 RETURN
  103. 4230 '
  104. 8000 REM Command Processor
  105. 8010 IF LEFT$(REPLY$,3) = ".h1" THEN 8100
  106. 8020 IF LEFT$(REPLY$,3) = ".h2" THEN 8200
  107. 8030 IF LEFT$(REPLY$,3) = ".h3" THEN 8300
  108. 8040 IF LEFT$(REPLY$,3) = ".sp" THEN 8400
  109. 8050 IF LEFT$(REPLY$,4) = ".eof" THEN 8500
  110. 8060 IF LEFT$(REPLY$,3) = ".pa" THEN 8600
  111. 8070 IF LEFT$(REPLY$,3) = ".vt" THEN 8700
  112. 8080 IF LEFT$(REPLY$,3) = ".pk" THEN 8900
  113. 8081 IF LEFT$(REPLY$,3) = ".in" THEN 9000
  114. 8090 STOP
  115. 8100 REM Head 1 Processor
  116. 8110 FOR I = LINE.NO TO 44
  117. 8120  LPRINT
  118. 8130 NEXT I
  119. 8140 GOSUB 4100  'Bottom of page Routine
  120. 8142 IF PAGE.NO MOD 2 = 0 THEN GOSUB 8600  'For h1 on Odd pages
  121. 8145 LPRINT CHR$(14);  'Set expanded print
  122. 8146 IF PAGE.NO MOD 2 = 0 THEN ADJUST = -4 ELSE ADJUST = -7
  123. 8150 LPRINT TAB(TAB.POS+ADJUST); RIGHT$(REPLY$,LEN(REPLY$)-4)
  124. 8155 LPRINT CHR$(18);  'Return to normal
  125. 8160 LINE.NO = LINE.NO+1
  126. 8165 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
  127. 8170 RETURN
  128. 8180 '
  129. 8200 REM Head 2 Processor
  130. 8205 IF LINE.NO = 7 THEN 8215 'skip spacing if at top of page
  131. 8210 IF LINE.NO > 43 THEN GOSUB 8600 ELSE LPRINT:LPRINT:LINE.NO = LINE.NO+2
  132. 8215 LPRINT CHR$(27); "E"; 'Set emphasized print
  133. 8220 LPRINT TAB(TAB.POS); RIGHT$(REPLY$,LEN(REPLY$)-4)
  134. 8225 LPRINT CHR$(27); "F"; 'Return to normal
  135. 8230 LPRINT
  136. 8240 LINE.NO = LINE.NO + 2
  137. 8245 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
  138. 8250 RETURN
  139. 8260 '
  140. 8300 REM Head 3 Processor
  141. 8305 IF LINE.NO = 7 THEN 8315 'skip spacing if at top of page
  142. 8310 IF LINE.NO > 43 THEN GOSUB 8600 ELSE LPRINT:LPRINT:LINE.NO = LINE.NO+2
  143. 8315 LPRINT CHR$(27); "E"; 'Set emphasized print
  144. 8320 LPRINT TAB(TAB.POS); RIGHT$(REPLY$,LEN(REPLY$)-4)
  145. 8325 LPRINT CHR$(27); "F"; 'Return to normal
  146. 8330 LPRINT
  147. 8340 LINE.NO = LINE.NO + 2
  148. 8345 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
  149. 8350 RETURN
  150. 8360 '
  151. 8400 REM Single Space Processor
  152. 8405 IF LINE.NO = 7 THEN 8415
  153. 8410 IF LINE.NO > 44 THEN GOSUB 8600 ELSE LPRINT : LINE.NO = LINE.NO + 1
  154. 8415 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
  155. 8420 RETURN
  156. 8500 REM End of File Processor
  157. 8510 GOSUB 8600 'Bottom of Page
  158. 8530 LPRINT CHR$(12);
  159. 8540 GOTO 13490
  160. 8600 REM Page Eject Processor
  161. 8610 FOR I = LINE.NO TO 44
  162. 8620  LPRINT
  163. 8630  LINE.NO = LINE.NO + 1
  164. 8640 NEXT I
  165. 8680 GOSUB 4100  'Bottom of Page Processing
  166. 8690 RETURN
  167. 8700 REM Vertical Tab Processor
  168. 8705 IF LINE.NO = 7 THEN 8800
  169. 8710 QTY = VAL(RIGHT$(REPLY$,LEN(REPLY$)-3))
  170. 8720 FOR I = 1 TO QTY
  171. 8730  LPRINT
  172. 8740  LINE.NO = LINE.NO + 1
  173. 8760  IF LINE.NO > 44 THEN I = QTY
  174. 8770 NEXT I
  175. 8780 IF LINE.NO > 44 THEN GOSUB 4100  'End of page
  176. 8800 RETURN
  177. 8900 REM Pack Processor
  178. 8905 IF LINE.NO > 44 THEN GOSUB 4100
  179. 8910 IF TAB.POS = 8 THEN ADJUST = 4
  180. 8911 IF TAB.POS = 13 THEN ADJUST = 7
  181. 8920 TAB.POS = TAB.POS + ADJUST + INDENT
  182. 8930 LPRINT CHR$(15); 'Packed printing
  183. 8935 WIDTH "lpt1:", 132 'set condensed width
  184. 8940 LPRINT TAB(TAB.POS); RIGHT$(REPLY$,LEN(REPLY$)-3)
  185. 8950 LPRINT CHR$(18); 'Return to normal
  186. 8952 WIDTH "lpt1:", 80  'return to normal
  187. 8955 LINE.NO = LINE.NO + 1
  188. 8960 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
  189. 8980 RETURN
  190. 9000 REM Indent Processor
  191. 9010 INDENT = VAL(RIGHT$(REPLY$,LEN(REPLY$)-3))
  192. 9020 RETURN
  193. 10000 DATA ".h1 INTRODUCTION"
  194. 10010 DATA ".h2 OVERVIEW"
  195. 10020 DATA "This Program Directory contains the"
  196. 10030 DATA "information about the contents of the"
  197. 10040 DATA "Documentation Diskette, and the"
  198. 10060 DATA "Program Diskette for the Genealogy"
  199. 10065 DATA "ON DISPLAY programs.
  200. 10070 DATA ".h2 CONTENT"
  201. 10080 DATA "The Documentation Diskette contains"
  202. 10090 DATA "the following Programs:"
  203. 10100 DATA ".sp"
  204. 10110 DATA "  Program    Program      Program"
  205. 10120 DATA "  Name       Language        Size"
  206. 10130 DATA "  --------   --------   ---------"
  207. 10140 DATA "  director   basic         13,824"
  208. 10150 DATA "  tableofc   basic         11,008"
  209. 10160 DATA "  introduc   basic         12,416"
  210. 10170 DATA "  general    basic         18,176"
  211. 10180 DATA "  usingthe   basic         23,296"
  212. 10190 DATA "  referenc   basic         14,080"
  213. 10200 DATA "  appendix   basic         27,776"
  214. 10220 DATA ".pa"
  215. 11000 DATA "The Program Diskette contains the"
  216. 11010 DATA "following Programs:"
  217. 11020 DATA ".sp"
  218. 11030 DATA "  Program    Program      Program"
  219. 11040 DATA "  Name       Language        Size"
  220. 11050 DATA "  --------   --------   ---------"
  221. 11060 DATA "  creatper   basic          3,200"
  222. 11070 DATA "  creatmar   basic          2,944"
  223. 11080 DATA "  creatord   basic          3,328"
  224. 11090 DATA "  updatper   basic         10,496"
  225. 11100 DATA "  updatmar   basic          7,040"
  226. 11110 DATA "  updatord   basic         12,800"
  227. 11120 DATA "  indexpc    basic          4,992"
  228. 11130 DATA "  indexmar   basic          4,864"
  229. 11140 DATA "  printper   basic          5,888"
  230. 11150 DATA "  printmar   basic          4,736"
  231. 11160 DATA "  listper    basic          3,840"
  232. 11170 DATA "  listmar    basic          4,608"
  233. 11180 DATA "  listpci    basic          3,840"
  234. 11190 DATA "  alphaper   basic          5,376"
  235. 11200 DATA "  alphamar   basic          4,608"
  236. 11210 DATA "  display    basic         20,736"
  237. 11220 DATA "  pedigree   basic         18,560"
  238. 11230 DATA "  family     basic         16,896"
  239. 11390 DATA ".pa"
  240. 11400 DATA ".h2 REQUIREMENTS"
  241. 11410 DATA ".h3 Hardware Requirements"
  242. 11420 DATA "IBM Personal Computer, with:"
  243. 11430 DATA ".sp"
  244. 11440 DATA "   At least two diskette drives."
  245. 11450 DATA "   (Either single- or double-sided)."
  246. 11455 DATA "   (Note:  May be customized to one.)"
  247. 11460 DATA ".sp"
  248. 11470 DATA "   IBM Matrix Printer, or equivalent"
  249. 11480 DATA "   printer with 132 print positions."
  250. 11500 DATA ".sp"
  251. 11510 DATA "   At least 96 K of Storage."
  252. 11520 DATA ".sp"
  253. 11530 DATA "   IBM Monochrome Display."
  254. 11540 DATA ".sp"
  255. 11550 DATA ".h2 Software Requirements."
  256. 11560 DATA "IBM PC-DOS.
  257. 11570 DATA "   (1.0, 1.05, 1.1 or 2.0)
  258. 11580 DATA ".sp"
  259. 11590 DATA "Disk BASIC (or Advanced BASIC).
  260. 11600 DATA "   (1.0, 1.05, 1.1 or 2.0)
  261. 11610 DATA ".h1 GENERAL INFORMATION"
  262. 11620 DATA ".h2 DOCUMENTATION"
  263. 11630 DATA "Seven documentation programs are included"
  264. 11640 DATA "on the Documentation Diskette.  These are"
  265. 11650 DATA "BASIC programs, which can be 'loaded',"
  266. 11660 DATA "and then 'run'."
  267. 11670 DATA ".sp"
  268. 11680 DATA "The documentation programs contain their"
  269. 11690 DATA "own formatting capability, as well as"
  270. 11700 DATA "the content of the documents which they"
  271. 11710 DATA "will produce."
  272. 11720 DATA ".sp"
  273. 11730 DATA "By 'loading' and then 'running' these"
  274. 11740 DATA "documentation programs, the user is able"
  275. 11750 DATA "to obtain as many copies of the actual"
  276. 11760 DATA "documents as he desires."
  277. 11770 DATA ".vt 2"
  278. 11780 DATA "These documentation programs are:"
  279. 11790 DATA ".sp
  280. 11800 DATA "  1.  director  (documentation of the"
  281. 11810 DATA "      content of the two diskettes)."
  282. 11820 DATA ".sp"
  283. 11830 DATA "      Produces this document."
  284. 11840 DATA ".vt 2"
  285. 11850 DATA "  2 through 7.  Documentation for the"
  286. 11860 DATA "      Genealogy ON DISPLAY Programs."
  287. 11870 DATA ".sp"
  288. 11880 DATA "      Produces a User's Manual for use"
  289. 11890 DATA "      with the Genealogy ON DISPLAY"
  290. 11900 DATA "      programs."
  291. 11910 DATA ".pa"
  292. 11920 DATA "  2.  tableofc  (table of contents for"
  293. 11930 DATA "      the User's Manual)."
  294. 11940 DATA ".sp"
  295. 11950 DATA "  3.  introduc  (introduction for the"
  296. 11960 DATA "      User's Manual)."
  297. 11970 DATA ".sp"
  298. 11980 DATA "  4.  general  (general information for"
  299. 11990 DATA "      the User's Manual)."
  300. 12000 DATA ".sp"
  301. 12010 DATA "  5.  usingthe  (using the programs, for"
  302. 12020 DATA "      the User's Manual)."
  303. 12030 DATA ".sp"
  304. 12040 DATA "  6.  referenc  (reference material for"
  305. 12050 DATA "      the User's Manual)."
  306. 12060 DATA ".sp"
  307. 12070 DATA "  7.  appendix  (appendices for the"
  308. 12080 DATA "      User's Manual)."
  309. 12190 DATA ".pa"
  310. 12200 DATA ".h2 PROGRAMS"
  311. 12210 DATA "Eighteen programs are included on the"
  312. 12220 DATA "Program Diskette.  They are:"
  313. 12230 DATA ".sp"
  314. 12240 DATA "  1.  creatper"
  315. 12250 DATA "      Creates a Persons File."
  316. 12260 DATA ".vt 2"
  317. 12270 DATA "  2.  creatmar"
  318. 12280 DATA "      Creates a Marriages File."
  319. 12290 DATA ".vt 2"
  320. 12300 DATA "  3.  creatord"
  321. 12310 DATA "      Creates an Ordinances File."
  322. 12320 DATA ".vt 2"
  323. 12330 DATA "  4.  updatper"
  324. 12340 DATA "      Updates the Persons File."
  325. 12350 DATA ".vt 2"
  326. 12360 DATA "  5.  updatmar"
  327. 12370 DATA "      Updates the Marriages File."
  328. 12380 DATA ".vt 2"
  329. 12390 DATA "  6.  updatord"
  330. 12400 DATA "      Updates an Ordinances File."
  331. 12410 DATA ".vt 2"
  332. 12420 DATA "  7.  indexpc"
  333. 12430 DATA "      Creates a Parent/Child Index."
  334. 12440 DATA ".pa"
  335. 12450 DATA "  8.  indexmar"
  336. 12460 DATA "      Creates a Marriages Index."
  337. 12470 DATA ".vt 2"
  338. 12480 DATA "  9.  printper"
  339. 12490 DATA "      Prints the combined contents of the"
  340. 12500 DATA "      Persons and Ordinances Files."
  341. 12510 DATA ".vt 2"
  342. 12520 DATA " 10.  printmar"
  343. 12530 DATA "      Prints the contents of the Marriages"
  344. 12540 DATA "      File."
  345. 12550 DATA ".vt 2"
  346. 12560 DATA " 11.  listper"
  347. 12570 DATA "      Prints a List of the Persons in the"
  348. 12580 DATA "      Persons File."
  349. 12590 DATA ".vt 2"
  350. 12600 DATA " 12.  listmar"
  351. 12610 DATA "      Prints an List of the Marriages in"
  352. 12620 DATA "      the Marriages File."
  353. 12630 DATA ".vt 2"
  354. 12640 DATA " 13.  listpci"
  355. 12650 DATA "      Lists the Parent/Child Index."
  356. 12660 DATA ".vt 2"
  357. 12670 DATA " 14.  alphaper"
  358. 12680 DATA "      Provides an alphabetical list of the"
  359. 12690 DATA "      persons in the Persons File."
  360. 12700 DATA ".vt 2"
  361. 12710 DATA " 15.  alphamar"
  362. 12720 DATA "      Provides an alphabetical list of the"
  363. 12730 DATA "      marriages in the Marriages File."
  364. 12740 DATA ".pa"
  365. 12750 DATA " 16.  display"
  366. 12760 DATA "      Provides for displaying all of the"
  367. 12770 DATA "      information in all of the files,"
  368. 12780 DATA "      in the form of pedigrees, family"
  369. 12790 DATA "      groups, personal, and ordinance"
  370. 12800 DATA "      information."
  371. 12810 DATA ".vt 2"
  372. 12820 DATA " 17.  pedigree"
  373. 12830 DATA "      Provides a printout of a pedigree"
  374. 12840 DATA "      chart for any person."
  375. 12850 DATA ".vt 2"
  376. 12860 DATA " 18.  family"
  377. 12870 DATA "      Provides a printout of a family"
  378. 12880 DATA "      group sheet for any marriage."
  379. 12890 DATA ".h1 USING THE PROGRAMS"
  380. 12900 DATA ".h2 FIRST TIME USAGE"
  381. 12910 DATA "There is nothing unique about using the"
  382. 12920 DATA "BASIC programs which are on the Program"
  383. 12930 DATA "and Documentation diskettes for the"
  384. 12940 DATA "first time.  The user should take the"
  385. 12950 DATA "normal precautionary steps to copy the"
  386. 12960 DATA "diskettes to backup diskettes."
  387. 12970 DATA ".sp"
  388. 12980 DATA "The user should also have available two"
  389. 12990 DATA "empty (formatted) diskettes, which have"
  390. 13000 DATA "be formatted without DOS (no /s). These"
  391. 13010 DATA "will be used for data files."
  392. 13020 DATA ".h2 GETTING STARTED"
  393. 13030 DATA "The user should perform the following"
  394. 13040 DATA "steps in starting any of the BASIC"
  395. 13050 DATA "programs."
  396. 13060 DATA ".sp"
  397. 13070 DATA "1.  Insert the PC DOS diskette into"
  398. 13080 DATA "    Drive 'a:'."
  399. 13090 DATA ".sp"
  400. 13100 DATA "2.  Turn the Printer On."
  401. 13110 DATA ".sp"
  402. 13120 DATA "3.  Turn the System-unit On."
  403. 13130 DATA ".sp"
  404. 13140 DATA "4.  Enter today's date when the system"
  405. 13150 DATA "    asks the user to Enter today's"
  406. 13160 DATA "    date (mm-dd-yy):"
  407. 13170 DATA ".pa"
  408. 13180 DATA "5.  Respond when prompted for the time,"
  409. 13190 DATA "    (hh:mm:ss): with the appropriate"
  410. 13200 DATA "    time."
  411. 13210 DATA ".sp"
  412. 13220 DATA "6.  Type: basica/s:256"
  413. 13230 DATA "          and press the return key."
  414. 13240 DATA ".sp"
  415. 13250 DATA "7.  Type: load (followed by a quote),"
  416. 13260 DATA "          (or press the F3 key),"
  417. 13270 DATA "          and type the program name."
  418. 13280 DATA "          Then press the return key."
  419. 13290 DATA ".sp"
  420. 13300 DATA "8.  Insert the data diskette in Drive"
  421. 13310 DATA "          'a:', and the ordinances"
  422. 13320 DATA "          diskette in Drive 'b:'."
  423. 13330 DATA ".sp"
  424. 13340 DATA "8.  Type: run"
  425. 13350 DATA "          and press the return key."
  426. 13360 DATA "    (or press the F2 key)."
  427. 13370 DATA ".h2 HOW TO STOP"
  428. 13380 DATA "The user may stop at any time during"
  429. 13390 DATA "the running of any of the BASIC programs"
  430. 13400 DATA "by pressing (and holding down) the"
  431. 13410 DATA "control (Ctrl) key, and then pressing"
  432. 13420 DATA "the Break key."
  433. 13430 DATA ".sp"
  434. 13440 DATA "Individual programs may have other"
  435. 13450 DATA "methods of stopping, such as referring"
  436. 13460 DATA "to record #0.  (See the Genealogy ON"
  437. 13470 DATA "DISPLAY User's Manual.)"
  438. 13480 DATA ".eof"
  439. 13490 END
  440. M All data is in the form of DATA statements.
  441. 130 REM By