home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / mbug / mbug055.arc / ELIZA.BAS < prev    next >
BASIC Source File  |  1979-12-31  |  8KB  |  207 lines
  1. 1 PRINT CHR$(12);TAB(26);"ELIZA":CLEAR 2000
  2. 2 PRINT TAB(20);"CREATIVE COMPUTING"
  3. 3 PRINT TAB(18);"MORRISTOWN, NEW JERSEY"
  4. 4 PRINT:PRINT:PRINT
  5. 80 REM     -----INITIALIZATION-----
  6. 100 DIM S(36),R(36),N(36)
  7. 110 N1=36:N2=12:N3=112
  8. 120 FOR X=1 TO N1+N2+N3:READ Z$:NEXT X:REM SAME AS RESTORE
  9. 130 FOR X=1 TO N1
  10. 140 READ S(X),L:R(X)=S(X):N(X)=S(X)+L-1
  11. 150 NEXT X
  12. 160 PRINT "HI!  I'M ELIZA.  WHAT'S YOUR PROBLEM?"
  13. 170 REM
  14. 180 REM     -----USER INPUT SECTION-----
  15. 190 REM
  16. 200 INPUT I$
  17. 201 I$=" "+I$+"  "
  18. 210 REM  GET RID OF APOSTROPHES
  19. 220 FOR L=1 TO LEN(I$)
  20. 230 IF MID$(I$,L,1)="'"THEN I$=LEFT$(I$,L-1)+RIGHT$(I$,LEN(I$)-L):GOTO 230
  21. 240 IF L+4<=LEN(I$)THEN IF MID$(I$,L,4)="SHUT"THEN PRINT"SHUT UP...":END
  22. 250 NEXT L
  23. 255 IF I$=P$ THEN PRINT "PLEASE DON'T REPEAT YOURSELF!":GOTO 170
  24. 260 REM
  25. 270 REM     -----FIND KEYWORD IN I$-----
  26. 280 REM
  27. 290 RESTORE
  28. 295 S=0
  29. 300 FOR K=1 TO N1
  30. 310 READ K$
  31. 315 IF S>0 THEN 360
  32. 320 FOR L=1 TO LEN(I$)-LEN(K$)+1
  33. 340 IF MID$(I$,L,LEN(K$))=K$THEN S=K:T=L:F$=K$
  34. 350 NEXT L
  35. 360 NEXT K
  36. 365 IF S>0 THEN K=S:L=T:GOTO 390
  37. 370 K=36:GOTO 570:REM  WE DIDN'T FIND ANY KEYWORDS
  38. 380 REM
  39. 390 REM     TAKE RIGHT PART OF STRING AND CONJUGATE IT
  40. 400 REM     USING THE LIST OF STRINGS TO BE SWAPPED
  41. 410 REM
  42. 420 RESTORE:FOR X=1 TO N1:READ Z$:NEXT X:REM SKIP OVER KEYWORDS
  43. 430 C$=" "+RIGHT$(I$,LEN(I$)-LEN(F$)-L+1)
  44. 440 FOR X=1 TO N2/2
  45. 450 READ S$,R$
  46. 460 FOR L= 1 TO LEN(C$)
  47. 470 IF L+LEN(S$)>LEN(C$) THEN 510
  48. 480 IF MID$(C$,L,LEN(S$))<>S$ THEN 510
  49. 490 C$=LEFT$(C$,L-1)+R$+RIGHT$(C$,LEN(C$)-L-LEN(S$)+1)
  50. 495 L=L+LEN(R$)
  51. 500 GOTO 540
  52. 510 IF L+LEN(R$)>LEN(C$)THEN 540
  53. 520 IF MID$(C$,L,LEN(R$))<>R$ THEN 540
  54. 530 C$=LEFT$(C$,L-1)+S$+RIGHT$(C$,LEN(C$)-L-LEN(R$)+1)
  55. 535 L=L+LEN(S$)
  56. 540 NEXT L
  57. 550 NEXT X
  58. 555 IF MID$(C$,2,1)=" "THEN C$=RIGHT$(C$,LEN(C$)-1):REM ONLY 1 SPACE
  59. 560 REM
  60. 570 REM     NOW USING THE KEYWORD NUMBER (K) GET REPLY
  61. 580 REM
  62. 590 RESTORE:FOR X= 1 TO N1+N2:READ Z$:NEXT X
  63. 600 FOR X=1 TO R(K):READ F$:NEXT X:REM  READ RIGHT REPLY
  64. 610 R(K)=R(K)+1: IF R(K)>N(K) THEN R(K)=S(K)
  65. 620 IF RIGHT$(F$,1)<>"*" THEN PRINT F$:P$=I$:GOTO 170
  66. 630 PRINT LEFT$(F$,LEN(F$)-1);C$
  67. 640 P$=I$:GOTO 170
  68. 1000 REM
  69. 1010 REM     -----PROGRAM DATA FOLLOWS-----
  70. 1020 REM
  71. 1030 REM     KEYWORDS
  72. 1040 REM
  73. 1050 DATA "CAN YOU","CAN I","YOU ARE","YOURE","I DONT","I FEEL"
  74. 1060 DATA "WHY DONT YOU","WHY CANT I","ARE YOU","I CANT","I AM","IM "
  75. 1070 DATA "YOU ","I WANT","WHAT","HOW","WHO","WHERE","WHEN","WHY"
  76. 1080 DATA "NAME","CAUSE","SORRY","DREAM","HELLO","HI ","MAYBE"
  77. 1090 DATA " NO","YOUR","ALWAYS","THINK","ALIKE","YES","FRIEND"
  78. 1100 DATA "COMPUTER","NOKEYFOUND"
  79. 1200 REM
  80. 1210 REM     STRING DATA FOR CONJUGATIONS
  81. 1220 REM
  82. 1230 DATA " ARE "," AM ","WERE ","WAS "," YOU "," I ","YOUR ","MY "
  83. 1235 DATA " IVE "," YOUVE "," IM "," YOURE "
  84. 1300 REM
  85. 1310 REM     REPLIES
  86. 1320 REM
  87. 1330 DATA "DON'T YOU BELIEVE THAT I CAN*"
  88. 1340 DATA "PERHAPS YOU WOULD LIKE TO BE ABLE TO*"
  89. 1350 DATA "YOU WANT ME TO BE ABLE TO*"
  90. 1360 DATA "PERHAPS YOU DON'T WANT TO*"
  91. 1365 DATA "DO YOU WANT TO BE ABLE TO*"
  92. 1370 DATA "WHAT MAKES YOU THINK I AM*"
  93. 1380 DATA "DOES IT PLEASE YOU TO BELIEVE I AM*"
  94. 1390 DATA "PERHAPS YOU WOULD LIKE TO BE*"
  95. 1400 DATA "DO YOU SOMETIMES WISH YOU WERE*"
  96. 1410 DATA "DON'T YOU REALLY*"
  97. 1420 DATA "WHY DON'T YOU*"
  98. 1430 DATA "DO YOU WISH TO BE ABLE TO*"
  99. 1440 DATA "DOES THAT TROUBLE YOU?"
  100. 1450 DATA "TELL ME MORE ABOUT SUCH FEELINGS."
  101. 1460 DATA "DO YOU OFTEN FEEL*"
  102. 1470 DATA "DO YOU ENJOY FEELING*"
  103. 1480 DATA "DO YOU REALLY BELIEVE I DON'T*"
  104. 1490 DATA "PERHAPS IN GOOD TIME I WILL*"
  105. 1500 DATA "DO YOU WANT ME TO*"
  106. 1510 DATA "DO YOU THINK YOU SHOULD BE ABLE TO*"
  107. 1520 DATA "WHY CAN'T YOU*"
  108. 1530 DATA "WHY ARE YOU INTERESTED IN WHETHER OR NOT I AM*"
  109. 1540 DATA "WOULD YOU PREFER IF I WERE NOT*"
  110. 1550 DATA "PERHAPS IN YOUR FANTASIES I AM*"
  111. 1560 DATA "HOW DO YOU KNOW YOU CAN'T*"
  112. 1570 DATA "HAVE YOU TRIED?"
  113. 1580 DATA "PERHAPS YOU CAN NOW*"
  114. 1590 DATA "DID YOU COME TO ME BECAUSE YOU ARE*"
  115. 1600 DATA "HOW LONG HAVE YOU BEEN*"
  116. 1610 DATA "DO YOU BELIEVE IT IS NORMAL TO BE*"
  117. 1620 DATA "DO YOU ENJOY BEING*"
  118. 1630 DATA "WE WERE DISCUSSING YOU -- NOT ME."
  119. 1640 DATA "OH, I*"
  120. 1650 DATA "YOU'RE NOT REALLY TALKING ABOUT ME, ARE YOU?"
  121. 1660 DATA "WHAT WOULD IT MEAN TO YOU IF YOU GOT*"
  122. 1670 DATA "WHY DO YOU WANT*"
  123. 1680 DATA "SUPPOSE YOU SOON GOT*"
  124. 1690 DATA "WHAT IF YOU NEVER GOT*"
  125. 1700 DATA "I SOMETIMES ALSO WANT*"
  126. 1710 DATA "WHY DO YOU ASK?"
  127. 1720 DATA "DOES THAT QUESTION INTEREST YOU?"
  128. 1730 DATA "WHAT ANSWER WOULD PLEASE YOU THE MOST?"
  129. 1740 DATA "WHAT DO YOU THINK?"
  130. 1750 DATA "ARE SUCH QUESTIONS ON YOUR MIND OFTEN?"
  131. 1760 DATA "WHAT IS IT THAT YOU REALLY WANT TO KNOW?"
  132. 1770 DATA "HAVE YOU ASKED ANYONE ELSE?"
  133. 1780 DATA "HAVE YOU ASKED SUCH QUESTIONS BEFORE?"
  134. 1790 DATA "WHAT ELSE COMES TO MIND WHEN YOU ASK THAT?"
  135. 1800 DATA "NAMES DON'T INTEREST ME."
  136. 1810 DATA "I DON'T CARE ABOUT NAMES -- PLEASE GO ON."
  137. 1820 DATA "IS THAT THE REAL REASON?"
  138. 1830 DATA "DON'T ANY OTHER REASONS COME TO MIND?"
  139. 1840 DATA "DOES THAT REASON EXPLAIN ANYTHING ELSE?"
  140. 1850 DATA "WHAT OTHER REASONS MIGHT THERE BE?"
  141. 1860 DATA "PLEASE DON'T APOLOGIZE!"
  142. 1870 DATA "APOLOGIES ARE NOT NECESSARY."
  143. 1880 DATA "WHAT FEELINGS DO YOU HAVE WHEN YOU APOLOGIZE."
  144. 1890 DATA "DON'T BE SO DEFENSIVE!"
  145. 1900 DATA "WHAT DOES THAT DREAM SUGGEST TO YOU?"
  146. 1910 DATA "DO YOU DREAM OFTEN?"
  147. 1920 DATA "WHAT PERSONS APPEAR IN YOUR DREAMS?"
  148. 1930 DATA "ARE YOU DISTURBED BY YOUR DREAMS?"
  149. 1940 DATA "HOW DO YOU DO... PLEASE STATE YOUR PROBLEM."
  150. 1950 DATA "YOU DON'T SEEM QUITE CERTAIN."
  151. 1960 DATA "WHY THE UNCERTAIN TONE?"
  152. 1970 DATA "CAN'T YOU BE MORE POSITIVE?"
  153. 1980 DATA "YOU AREN'T SURE?"
  154. 1990 DATA "DON'T YOU KNOW?"
  155. 2000 DATA "ARE YOU SAYING NO JUST TO BE NEGATIVE?"
  156. 2010 DATA "YOU ARE BEING A BIT NEGATIVE."
  157. 2020 DATA "WHY NOT?"
  158. 2030 DATA "ARE YOU SURE?"
  159. 2040 DATA "WHY NO?"
  160. 2050 DATA "WHY ARE YOU CONCERNED ABOUT MY*"
  161. 2060 DATA "WHAT ABOUT YOUR OWN*"
  162. 2070 DATA "CAN YOU THINK OF A SPECIFIC EXAMPLE?"
  163. 2080 DATA "WHEN?"
  164. 2090 DATA "WHAT ARE YOU THINKING OF?"
  165. 2100 DATA "REALLY, ALWAYS?"
  166. 2110 DATA "DO YOU REALLY THINK SO?"
  167. 2120 DATA "BUT YOU ARE NOT SURE YOU*"
  168. 2130 DATA "DO YOU DOUBT YOU*"
  169. 2140 DATA "IN WHAT WAY?"
  170. 2150 DATA "WHAT RESEMBLANCE DO YOU SEE?"
  171. 2160 DATA "WHAT DOES THE SIMILARITY SUGGEST TO YOU?"
  172. 2170 DATA "WHAT OTHER CONNECTIONS DO YOU SEE?"
  173. 2180 DATA "COULD THERE REALLY BE SOME CONNECTION?"
  174. 2190 DATA "HOW?"
  175. 2200 DATA "YOU SEEM QUITE POSITIVE."
  176. 2210 DATA "ARE YOU SURE?"
  177. 2220 DATA "I SEE."
  178. 2230 DATA "I UNDERSTAND."
  179. 2240 DATA "WHY DO YOU BRING UP THE TOPIC OF FRIENDS?"
  180. 2250 DATA "DO YOUR FRIENDS WORRY YOU?"
  181. 2260 DATA "DO YOUR FRIENDS PICK ON YOU?"
  182. 2270 DATA "ARE YOU SURE YOU HAVE ANY FRIENDS?"
  183. 2280 DATA "DO YOU IMPOSE ON YOUR FRIENDS?"
  184. 2290 DATA "PERHAPS YOUR LOVE FOR FRIENDS WORRIES YOU."
  185. 2300 DATA "DO COMPUTERS WORRY YOU?"
  186. 2310 DATA "ARE YOU TALKING ABOUT ME IN PARTICULAR?"
  187. 2320 DATA "ARE YOU FRIGHTENED BY MACHINES?"
  188. 2330 DATA "WHY DO YOU MENTION COMPUTERS?"
  189. 2340 DATA "WHAT DO YOU THINK MACHINES HAVE TO DO WITH YOUR PROBLEM?"
  190. 2350 DATA "DON'T YOU THINK COMPUTERS CAN HELP PEOPLE?"
  191. 2360 DATA "WHAT IS IT ABOUT MACHINES THAT WORRIES YOU?"
  192. 2370 DATA "SAY, DO YOU HAVE ANY PSYCHOLOGICAL PROBLEMS?"
  193. 2380 DATA "WHAT DOES THAT SUGGEST TO YOU?"
  194. 2390 DATA "I SEE."
  195. 2400 DATA "I'M NOT SURE I UNDERSTAND YOU FULLY."
  196. 2410 DATA "COME, COME, ELUCIDATE YOUR THOUGHTS."
  197. 2420 DATA "CAN YOU ELABORATE ON THAT?"
  198. 2430 DATA "THAT IS QUITE INTERESTING."
  199. 2500 REM
  200. 2510 REM     DATA FOR FINDING RIGHT REPLIES
  201. 2520 REM
  202. 2530 DATA 1,3,4,2,6,4,6,4,10,4,14,3,17,3,20,2,22,3,25,3
  203. 2540 DATA 28,4,28,4,32,3,35,5,40,9,40,9,40,9,40,9,40,9,40,9
  204. 2550 DATA 49,2,51,4,55,4,59,4,63,1,63,1,64,5,69,5,74,2,76,4
  205. 2560 DATA 80,3,83,7,90,3,93,6,99,7,106,6
  206. ,9,40,9,40,9,40,9,40,9
  207. 2550 DATA 49,2,