home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / lambda / soundpot / p / z33rcp02.lbr / RCPREG.LZB / RCPREG.LIB
Encoding:
Text File  |  1993-10-25  |  2.9 KB  |  138 lines
  1.     page
  2.  
  3. ; RCP-REG.Z80
  4.  
  5. ;
  6. ;Section 5J
  7. ;Command: REG
  8. ;Function:  Manipulate Memory Registers
  9. ;
  10. ;Forms:
  11. ;    REG D or REG        <-- Display Register Value
  12. ;    REG Mreg        <-- Decrement Register Value
  13. ;    REG Preg        <-- Increment Register Value
  14. ;    REG Sreg value        <-- Set Register Value
  15.  
  16. register:
  17.     ld    de,fcb1+2    ; Pt to first arg
  18.     ld    a,(de)        ; Get possible digit
  19.     call    regptr        ; Pt to register
  20.     dec    de        ; Pt to command
  21.     ld    a,(de)        ; Get command
  22.     cp    'S'        ; Set?
  23.     jr    z,rset
  24.     cp    'P'        ; Plus?
  25.     jr    z,rinc
  26.     cp    'M'        ; Minus?
  27.     jr    z,rdec
  28.  
  29. ; SHOW REGISTER VALUES
  30.  
  31. rshow:
  32.     xor    a        ; Select register 0
  33.     ld    b,a        ; Counter set to 0 in B
  34.     call    regp2        ; HL pts to register 0
  35. rshow1:
  36.     ld    a,b        ; Get counter value
  37.     cp    10
  38.     ret    z        ; Exit if done
  39.     call    print
  40.     db    '    Reg',' '+80h
  41.     ld    a,b        ; Print register number
  42.     add    '0'
  43.     call    conout
  44.     call    print
  45.     db    ' ','='+80h
  46.     push    bc        ; Save counter
  47.     push    hl        ; Save pointer
  48.     call    regout1        ; Print register value (no error flag setting)
  49.     pop    hl        ; Get pointer
  50.     pop    bc        ; Get counter
  51.     inc    b        ; Increment counter
  52.     ld    a,b        ; Check for new line
  53.     cp    5        ; New line after fifth register display
  54.     call    z,crlf
  55.     inc    hl        ; Pt to next register
  56.     jr    rshow1
  57.  
  58. ; INCREMENT REGISTER VALUE
  59. ;    HL PTS TO MEMORY REGISTER ON INPUT
  60.  
  61. rinc:
  62.     inc    (hl)        ; Increment it
  63.     jr    regout        ; Print result
  64.  
  65. ; DECREMENT REGISTER VALUE
  66. ;    HL PTS TO MEMORY REGISTER ON INPUT
  67.  
  68. rdec:
  69.     dec    (hl)        ; Decrement value
  70.     jr    regout        ; Print result
  71.  
  72. ; SET REGISTER VALUE
  73. ;    HL PTS TO REGISTER ON INPUT
  74.  
  75. rset:
  76.     ld    de,fcb2+1    ; Pt to value
  77.     ld    b,0        ; Init value to zero
  78. rset1:
  79.     ld    a,(de)        ; Get next digit
  80.     inc    de        ; Pt to next
  81.     sub    '0'        ; Convert to binary
  82.     jr    c,rset2
  83.     cp    10        ; Range?
  84.     jr    nc,rset2
  85.     ld    c,a        ; Digit in c
  86.     ld    a,b        ; Multiply old by 10
  87.     add    a,a        ; *2
  88.     add    a,a        ; *4
  89.     add    a,b        ; *5
  90.     add    a,a        ; *10
  91.     add    a,c        ; Add in new digit
  92.     ld    b,a        ; Result in b
  93.     jr    rset1
  94. rset2:
  95.     ld    (hl),b        ; Set value
  96.  
  97. regout:                ; Entry point with setting of error flag
  98.      if    seterr        ; Set error flag
  99.     ld    a,(hl)        ; Get register value
  100.     ld    (z3msg+6),a    ; Copy into program error flag
  101.      endif
  102. regout1:            ; Entry point for not setting error flag
  103.     call    print        ; Print leading space
  104.     db    ' '+80h
  105.     ld    a,(hl)        ; Get register value
  106.     ld    l,a        ; Value in HL
  107.     xor    a
  108.     ld    h,a
  109.     ld    de,100        ; Print 100's
  110.     ld    b,80h        ; Set flag to print leading space for zero
  111.     jp    decdsp3        ; Display three digits and return
  112.  
  113.  
  114. ; SET HL TO POINT TO MEMORY REGISTER WHOSE INDEX IS PTED TO BY HL
  115. ;    ON INPUT, A CONTAINS REGISTER CHAR
  116. ;    ON OUTPUT, HL = ADDRESS OF MEMORY REGISTER (REG 0 ASSUMED IF ERROR)
  117.  
  118. regptr:
  119.     ld    b,0        ; Init to zero
  120.     sub    '0'        ; Convert
  121.     jr    c,regp1
  122.     cp    10        ; Range
  123.     jr    nc,regp1
  124.     ld    b,a        ; Value in b
  125. regp1:
  126.     ld    a,b        ; Value in a
  127. regp2:
  128.     ld    hl,z3msg+30h    ; Pt to memory registers
  129.     add    a,l        ; Pt to proper register
  130.     ld    l,a
  131.     ld    a,h
  132.     adc    0
  133.     ld    h,a        ; Hl pts to register
  134.     ret
  135. ;
  136. ; End RCP-REG.Z80
  137.  
  138.