home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / lambda / soundpot / p / serial23.lbr / SERIAL.AZM / SERIAL.ASM
Encoding:
Assembly Source File  |  1993-10-25  |  6.4 KB  |  340 lines
  1. ;----------------------------------------------------
  2. ;OSBORNE ONE SERIAL PORT CONTROL UTILITY
  3. ;COPYRIGHT 1983 BY GEORGE SCOTT 
  4. ;PERMISSION GRANTED FOR PRIVATE USE
  5. ;CONTACT AUTHOR FOR COMMERICAL USE
  6. ;
  7. ;
  8. ;VERSION 2.3       JAN 1983
  9. ;
  10. ;PROGRAM IS MENU DRIVEN AND ALLOWS FOR SELECTION
  11. ;OF CLOCK DIVISION (AND HENCE BAUD RATE) WORD
  12. ;FORMATTING (LENGTH, STOP BITS, PARITY) AND VARIOUS
  13. ;HARDWARE HANDSHAKE HANDLING.  EXITING EARLY, FROM
  14. ;ANY MENU, ABORTS THE PROCESS.  THE LAST OPPORTUNITY
  15. ;TO DO THIS IS FROM THE RECEIVE INTERRUPT MENU.  A
  16. ;BELL IS SOUNDED TO WARN THAT THIS IS THE LAST MENU 
  17. ;BEFORE THE CONTROL WORD IS WRITTEN.
  18. ;----------------------------------------------------
  19. ;
  20. ;SETUP CALL AND DATA EQUATES
  21. ;
  22. CLEAR    EQU    26
  23. PBUFF    EQU    9
  24. CR    EQU    0DH
  25. LF    EQU    0AH
  26. MBUFF    EQU    4010H
  27. RGET    EQU    1
  28. BZY    EQU    0BH
  29. FLAGPOS    EQU    0EF08H
  30. BDOS    EQU    5
  31. ACIA    EQU    2A00H    ;ADDRESS OF ACIA
  32. SLSP    EQU    10B     ;CLOCK DIVISION WORDS
  33. HISP    EQU    01B    ;DEFAULT (DIVIDE BY 16)
  34. UHSP    EQU    00B
  35. BELL    EQU    07
  36. RESET    EQU    11B
  37. WRITE    EQU    5000H
  38. F7BE2    EQU    00000B    ;WORD LENGTH/STOP BIT/PARITY
  39. F7BO2    EQU    00100B    ;WORDS
  40. F7BE1    EQU    01000B    ;NEXT COMMENT SHOWS WHAT VARIABLE NAME MEANS:
  41. F7BO1    EQU    01100B    ;F=FORMAT,7B=7 BIT,O=ODD,1=1 STOP BIT
  42. F8BN2    EQU    10000B
  43. F8BN1    EQU    10100B    ;DEFAULT
  44. F8BE1    EQU    11000B    
  45. F8BO1    EQU    11100B
  46. LTID    EQU    0000000B;RTS LINE HANDLING WORDS     
  47. LTIE    EQU    0100000B
  48. HTID    EQU    1000000B;DEFAULT
  49. LTBR    EQU    1100000B
  50. RIE    EQU    10000000B;RECEIVE INTERRUPT HANDLING WORDS
  51. RID    EQU    0B    ;DEFAULT
  52. ;
  53. ;
  54.     ORG    0100H
  55. ;
  56. ;
  57.     LXI    D,WRITE    ;SET PARMS FOR BLOCK MOVE
  58.     LXI    H,SOURCE
  59.     MVI    B,21
  60.     CALL    LIFTER    ;XEQ BLOCK MOVE TO COPY SWITCH
  61.             ;ROUTINE TO HIGH MEMORY (5000H)
  62.             ;TO ALLOW BANK SWITCHING
  63.             ;TO XEQ PROPERLY
  64.     MVI    B,0     
  65. ;
  66. ;CLOCK DIVISION (BAUD RATE) SELECTION MENU
  67. ;    
  68. SMENU    CALL    SAVR
  69.     LXI    D,SPEED
  70.     CALL    PRINT    ;DISPLAY SPEED SELECT MENU
  71.     CALL    INPUT
  72.     CALL    RSTR
  73.     CPI    'U'
  74.     JZ    ULTRA
  75.     CPI    'F'
  76.     JZ    FAST
  77.     CPI    'S'
  78.     JZ    SLOW 
  79.     CPI    CR
  80.     JZ    FAST
  81.     CPI    'E'
  82.     JZ    00
  83.     JMP    SMENU    ;NO VALID KEYBOARD INPUT BRANCH
  84. ;
  85. ;WORD LENGTH/PARITY/STOP BIT SELECT MENU
  86. ;
  87. WMENU    CALL    SAVR
  88.     LXI    D,WORD
  89.     CALL    PRINT
  90.     CALL    INPUT
  91.     CALL    RSTR
  92.     CPI    '1'
  93.     JZ    WORD1
  94.     CPI    '2'
  95.     JZ    WORD2
  96.     CPI    '3'
  97.     JZ    WORD3
  98.     CPI    '4'
  99.     JZ    WORD4
  100.     CPI    '5'
  101.     JZ    WORD5
  102.     CPI    '6'
  103.     JZ    WORD6
  104.     CPI    '7'
  105.     JZ    WORD7
  106.     CPI    '8'
  107.     JZ    WORD8
  108.     CPI    CR
  109.     JZ    WORD6
  110.     CPI    'E'
  111.     JZ    00
  112.     JMP    WMENU
  113. ;
  114. ;RTS LINE HANDLING SELECT MENU
  115. ;
  116. RMENU    CALL    SAVR
  117.     LXI    D,RTSP
  118.     CALL    PRINT
  119.     CALL    INPUT
  120.     CALL    RSTR
  121.     CPI    '1'
  122.     JZ    RTS1
  123.     CPI    '2'
  124.     JZ    RTS2
  125.     CPI    '3'    
  126.     JZ    RTS3
  127.     CPI    '4'
  128.     JZ    RTS4
  129.     CPI    CR
  130.     JZ    RTS3
  131.     CPI    'E'
  132.     JZ    00
  133.     JMP    RMENU
  134. ;
  135. ;RECEIVE INTERRUPT ENABLE/DISABLE
  136. ;
  137. DMENU    CALL    SAVR
  138.     LXI    D,DCDP
  139.     CALL    PRINT
  140.     CALL    INPUT
  141.     CALL    RSTR
  142.     CPI    '1'
  143.     JZ    DCD1
  144.     CPI    '2'
  145.     JZ    DCD2
  146.     CPI    CR
  147.     JZ    DCD1
  148.     CPI    'E'
  149.     JZ    00
  150.     JMP    DMENU
  151. ;
  152. ;WRITE CONTROL BYTE TO RESET ACIA THEN WRITE
  153. ;CONTROL BYTE NOW STORED IN REGISTER B
  154. ; 
  155. WINDUP    CALL    SAVR
  156.     MVI    B,RESET    ;SET B FOR ACIA RESET
  157.     CALL    WRITE    ;XEQ WRITE ROUTINE IN HIGH MEMORY
  158.     CALL    RSTR    ;MOVE CONTROL BYTE TO B REGISTER
  159.     CALL    WRITE    ;WRITE IT TO ACIA
  160.     JMP    00    ;GO AWAY
  161. ;
  162. ;
  163. ;THE FOLLOWING ROUTINES BUILD THE CONTROL WORD AND 
  164. ;STORE IT IN THE B REGISTER AS DATA IS SELECTED FROM
  165. ; THE KEYBOARD
  166. ;
  167. ;SPEED SUBROUTINES
  168. ;
  169. ULTRA    MOV    A,B
  170.     ORI    UHSP
  171.     JMP    SPLT
  172. FAST    MOV    A,B
  173.     ORI    HISP
  174.     JMP    SPLT
  175. SLOW    MOV    A,B
  176.     ORI    SLSP
  177. SPLT    MOV    B,A
  178.     JMP    WMENU
  179. ;
  180. ;WORD PARAMETER ROUTINES
  181. ;
  182. WORD1    MOV    A,B
  183.     ORI    F7BE2
  184.     JMP    WSPLT
  185. WORD2    MOV    A,B
  186.     ORI    F7BO2
  187.     JMP    WSPLT
  188. WORD3    MOV    A,B
  189.     ORI    F7BE1
  190.     JMP    WSPLT
  191. WORD4    MOV    A,B
  192.     ORI    F7BO1
  193.     JMP    WSPLT
  194. WORD5    MOV    A,B
  195.     ORI    F8BN2
  196.     JMP     WSPLT
  197. WORD6    MOV    A,B
  198.     ORI    F8BN1
  199.     JMP    WSPLT
  200. WORD7    MOV    A,B
  201.     ORI    F8BE1
  202.     JMP    WSPLT
  203. WORD8    MOV    A,B
  204.     ORI    F8BO1
  205. WSPLT     MOV    B,A
  206.     JMP    RMENU
  207. ;
  208. ;RTS LINE HANDLING SELECT ROUTINES
  209. ;
  210. RTS1    MOV    A,B
  211.     ORI    LTID
  212.     JMP    RSPLT
  213. RTS2    MOV    A,B
  214.     ORI    LTIE
  215.     JMP    RSPLT
  216. RTS3    MOV    A,B
  217.     ORI    HTID  
  218.     JMP    RSPLT
  219. RTS4    MOV    A,B
  220.     ORI    LTBR
  221. RSPLT    MOV    B,A
  222.     JMP    DMENU
  223. ;
  224. ;DCD HANDLING ROUTINES
  225. ;
  226. DCD1    MOV    A,B
  227.     ORI    RID
  228.     JMP    DSPLT
  229. DCD2    MOV    A,B
  230.     ORI    RIE
  231. DSPLT    MOV    B,A
  232.     JMP    WINDUP     
  233. ;
  234. ;CODE TO BE COPIED TO HI MEMORY BY LIFTER
  235. ;THAT WILL FORM THE BANK SWITCH/WRITE ROUTINE 
  236. ;AT 5000H
  237. ;
  238. SOURCE    DI
  239.     OUT    00H
  240.     MVI    A,00
  241.     STA    FLAGPOS
  242.     LXI    H,ACIA 
  243.     MOV    M,B
  244.     OUT    01H
  245.     MVI    A,01H
  246.     STA    FLAGPOS
  247.     EI
  248.     RET
  249. ;
  250. ;CONSOLE OUTPUT UTILITY
  251. ;
  252. PRINT    MVI    C,PBUFF
  253.     CALL    BDOS
  254.     RET
  255. ;
  256. ;INPUT UTILITY ROUTINE RETURNS ONE CHARACTER FROM
  257. ;KEYBOARD IN THE A REGISTER
  258. ;
  259. INPUT    MVI    C,BZY
  260.     CALL    BDOS
  261.     CPI    00
  262.     JZ    INPUT
  263.     MVI    C,RGET
  264.     CALL    BDOS
  265.     RET
  266. ;
  267. ;BLOCK MOVE UTILITY
  268. ;
  269. LIFTER    MOV    A,M
  270.     STAX    D
  271.     DCR    B
  272.     RZ
  273.     INX    H
  274.     INX    D
  275.     JMP    LIFTER
  276. ;
  277. ;THIS SUBROUTINE WILL SAVE THE CONTROL WORD AT
  278. ;MEMORY LOCATION MBUFF
  279. ;
  280. SAVR    PUSH    H
  281.     LXI    H,MBUFF
  282.     MOV    M,B
  283.     POP    H
  284.     RET 
  285. ;
  286. ;THIS SUBROUTINE REVERSES THE ABOVE PROCESS
  287. ;THIS IS NECCESSARY BECAUSE THE NEEDED CALLS
  288. ;TO BDOS CORRUPT THE REGISTERS
  289. ;
  290. RSTR    PUSH    H
  291.     LXI    H,MBUFF
  292.     MOV    B,M
  293.     POP    H
  294.     RET
  295. ;
  296. ;MENU SELECT ITEMS
  297. ;
  298. SPEED    DB    CLEAR
  299.     DB    'RS-232 CONTROL UTILITY',CR,LF,LF
  300.     DB    'SELECT MENU ITEMS BY INPUTTING FIRST LETTER',CR,LF
  301.     DB    'OF DESIRED FUNCTION.  ',CR,LF 
  302.     DB    'CARRIAGE RETURN SELECTS DEFAULT VALUE WHICH IS',CR,LF
  303.     DB    'THE ITEM ENCLOSED IN BRACES: [...]',CR,LF
  304.     DB    'SELECTING EXIT FROM ANY MENU ABORTS THIS TASK',CR,LF,LF
  305.     DB    'BAUD RATE SELECT MENU',CR,LF,LF
  306.     DB    '(U)LTRAFAST    19,200/38,400 BAUD  <XMIT ONLY>',CR,LF
  307.     DB    '[F]AST        1,200/2,400 BAUD',CR,LF
  308.     DB    '(S)LOW        300/600    BAUD',CR,LF,LF
  309.     DB    '(E)XIT    ',CR,LF,LF
  310.     DB    'INPUT SELECTION:$'
  311. WORD    DB    CLEAR
  312.     DB    'DATA FORMAT SELECT MENU',CR,LF,LF
  313.     DB    '   DATA BITS    PARITY       STOP BITS',CR,LF
  314.     DB    '   +++++++++    ++++++       +++++++++',CR,LF
  315.     DB    '(1) SEVEN    EVEN        TWO',CR,LF
  316.     DB    '(2) SEVEN    ODD        TWO',CR,LF
  317.     DB    '(3) SEVEN    EVEN        ONE',CR,LF
  318.     DB    '(4) SEVEN    ODD        ONE',CR,LF
  319.     DB    '(5) EIGHT    NONE        TWO',CR,LF
  320.     DB    '[6] EIGHT    NONE        ONE',CR,LF
  321.     DB    '(7) EIGHT    EVEN        ONE',CR,LF
  322.     DB    '(8) EIGHT    ODD        ONE',CR,LF,LF
  323.     DB    '(E)XIT',CR,LF,LF
  324.     DB    'INPUT SELECTION:$'
  325. RTSP    DB    CLEAR
  326.     DB    'RTS HANDLING SELECTION MENU',CR,LF,LF
  327.     DB    '(1) LOW DISABLES XMIT INTERRUPT',CR,LF
  328.     DB    '(2) LOW  ENABLES XMIT INTERRUPT <NOT FOR OSBORNE!>',CR,LF
  329.     DB    '[3] HIGH DISABLES XMIT INTERRUPT',CR,LF
  330.     DB    '(4) LOW TRANSMITS BREAK',CR,LF,LF
  331.     DB    '(E)XIT',CR,LF,LF
  332.     DB    'INPUT SELECTION:$'
  333. DCDP    DB    CLEAR,BELL
  334.     DB    'DCD HANDLING MENU',CR,LF,LF
  335.     DB    '[1] RECEIVE INTERRUPT DISABLED',CR,LF
  336.     DB    '(2) RECEIVE INTERRUPT ENABLED',CR,LF,LF
  337.     DB    '(E)XIT  <LAST CHANCE TO ABORT>',CR,LF,LF
  338.     DB    'INPUT SELECTION:$'
  339.     END
  340.