home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / z3util / jltools.lbr / RCPSAMPL.AZM / RCPSAMPL.ASM
Encoding:
Assembly Source File  |  1993-06-07  |  10.3 KB  |  507 lines
  1. title    RCPSAMPL.ASM 7/8/88
  2. ;
  3. .xlist
  4. ; Author:    Bridger Mitchell (Plu*Perfect Systems)
  5. ; Program:    RCPSAMPL.ASM
  6. ; Date:        7/8/88
  7. ; Systems:    Z-Systems on CP/M 2.2 or CP/M Plus
  8. ;
  9. ;
  10. ; This is a small, sample Resident Command Processor source file.
  11. ; Its purpose is to illustrate the use of named-common relocation
  12. ; bases to create Z-System Relocatable (ZRL) files for use on any
  13. ; Z-System.
  14. ;
  15. ; The basic routines are somewhat modified from those in the
  16. ; RCP package supplied with ZCPR33, (c) 1987 Jay Sage.
  17. ;
  18. ; Significant changes from Jay's code are marked in the right
  19. ; margin with "++".
  20. ;
  21. ; The key points are:
  22. ;   1. All intersegment references must either --
  23. ;      a. be computed from an address in the external environment
  24. ;      e.g. whl address
  25. ;
  26. ;      b. or be obtained from a named-common relocation base equate.
  27. ;      e.g. z3env
  28. ;
  29. ;   2. The address of the ccp is obtained from the extended environment.
  30. ;
  31. ;   3. For CP/M Plus (CP/M 3) compatibility, disk space must
  32. ;      be calculated by using the bdos function #46 for that purpose.
  33. ;      (Joe Wright contributed the compact divide-by-eight routine).
  34. ;
  35. ;  The resulting REL file can be loaded with JetLDR.  For easy
  36. ;  identification it should be renamed to type ZRL.
  37. ;
  38. ;  See JetLDR.MMO for information about named-commons.
  39. ;
  40. ;
  41. ;  Declare the module name: "RCP" plus version/feature characters.
  42. ;
  43. name    RCP000                            ;    ++
  44. ;
  45. ;
  46. ;  The _ID_ common data are embedded in the ZRL file and displayed by
  47. ;  JetLDR.  Terminate the information with a nul byte.  Don't
  48. ;  exceed 255 bytes.
  49. ;
  50. ;
  51. COM    /_ID_/                            ;    ++
  52. ;                                ;    ++
  53.  db    'RCPSAMPL - example of an RCP in named-common ZRL form.';    ++
  54.  db    CR,LF                            ;    ++
  55.  db    'Also CP/M 3-compatible SP and H commands'        ;    ++
  56.  db    CR,LF                            ;    ++
  57.  db    'SP, WHL, H',0                        ;    ++
  58. ;
  59. ;
  60. ; Include the named-common relocation base declarations.
  61. ;
  62. maclib    Z3COMMON                        ;    ++
  63. ;
  64. ;
  65. CR    equ    0dh
  66. LF    equ    0ah
  67. ;
  68. bdos    equ    5
  69. fcb1    equ    5ch
  70. tbuff    equ    80h
  71.  
  72. offcmd        equ    25    ; Offset to command table
  73. cmdsline    equ    5    ; # commands per line
  74. cmdspace    equ    8    ; MUST BE > # chars in a command!
  75.  
  76. CSEG
  77. origin:
  78.     db    'Z3RCP'        ; Package ID
  79.     db    4        ; Length of each command name
  80. ;
  81.     db    'SP  '        ; first command
  82.     dw    space        ; address
  83.     db    'H   '
  84.     dw    clist
  85.     db    'WHL '
  86.     dw    whl
  87.     db    0        ; NUL marks end of command jump table
  88.  
  89. ; Name of RCP
  90. ;
  91. rcpname:
  92.     db    'RCP-sample ZRL segmen','t'+80h
  93.  
  94. ;
  95. ;----------------------------------------
  96. page
  97. ;
  98. ;    D I S K    S P A C E    C O M M A N D
  99. ;
  100. ; Command:    SP (CP/M 2 and CP/M 3 compatible)            ++
  101. ; Function:    Shows space remaining on designated drive
  102. ; Syntax:    SP [DIR:|DU:]
  103.  
  104. space:    ld    a,(fcb1)    ; Determine requested drive
  105.     or    a        ; If drive explicitly selected
  106.     jr    nz,space1    ; ..then skip
  107. ;
  108.     ld    c,25        ; BDOS get current drive function
  109.     call    bdos
  110.     inc    a        ; Shift to range 1..16
  111. ;
  112. space1:    dec    a        ; Shift to range 0..15
  113.     ld    e,a        ; Save in E for selecting disk below
  114.     ld    (spacedrv),a    ; save for cp/m 3             ++
  115.     add    'A'        ; Convert to letter and
  116.     ld    (seldrv),a    ;   save in message string below
  117.     ld    c,14        ; BDOS select disk function
  118.     call    bdos        ; Not needed if no drive selected, but
  119.                 ; .. smallest possible code size this way.
  120. ;
  121. ; check for cp/m 3        ;                    ++
  122. ;
  123.     ld    c,12        ; get bdos version            ++ 
  124.     call    bdos        ; if not cp/m 3 system            ++
  125.     cp    30h        ;                    ++
  126.     jr    c,dparams    ; ..jump to calculate from alv        ++
  127. ;
  128.     ld    de,0080h    ; set default dma at 0080h        ++
  129.     ld    c,26        ;                    ++
  130.     call    bdos        ;                    ++
  131.     ld    c,46        ; get disk freespace             ++
  132. spacedrv equ    $+1        ;                    ++
  133.     ld    e,00        ; ..on this drive            ++
  134.     call    bdos        ;                    ++
  135. ;
  136. ; Disk space is returned by CPM+ at tbuff for 3 bytes.            ++
  137. ;
  138.     ld    hl,(tbuff)    ; Low to L, Mid to H            ++
  139.     ld    a,(tbuff+2)    ; High to A                ++
  140.     ld    b,3        ; Divide by 8 (SHR 3)            ++
  141. ;
  142. ; Shift everything right into HL (64 MB max reportable) [jww]        ++
  143. ;
  144. div:    or    a        ; Clear carry                ++
  145.     rra            ; High                    ++
  146.     rr    h        ; Mid                    ++
  147.     rr    l        ; Low                    ++
  148.     djnz    div        ; Again?                ++
  149. ;
  150.     jr    free6        ; result: hl = space free in Kbytes    ++
  151. ;
  152. ; For CP/M 2 use this method:    ;                    ++
  153. ; Here we extract the following disk parameter information from the disk
  154. ; parameter block (DPB):
  155. ;    BLKSHF: block shift factor (1 byte)
  156. ;    BLKMAX:    max number of blocks on disk (2 bytes)
  157.  
  158. dparams:
  159.     ld    c,31        ; BDOS get disk parameters function
  160.     call    bdos
  161.     inc    hl        ; Advance to block shift factor byte
  162.     inc    hl
  163.     ld    a,(hl)        ; Get value and
  164.     ld    (blkshf),a    ; ..save it in code below
  165.     inc    hl        ; Advance to max block number word
  166.     inc    hl
  167.     inc    hl
  168.     ld    e,(hl)        ; Get value into HL
  169.     inc    hl
  170.     ld    d,(hl)
  171.     inc    de        ; Add 1 for max number of blocks
  172.  
  173. ; Compute amount of free space left on disk
  174.  
  175. dfree:
  176.     ld    c,27        ; BDOS get allocation vector function
  177.     push    de        ; Save BLKMAX value
  178.     call    bdos        ; Get allocation vector into HL
  179.     ld    b,h        ; Copy allocation vector to BC
  180.     ld    c,l
  181.     pop    hl        ; Restore MAXBLK value to HL
  182.     ld    de,0        ; Inititialize count of free blocks
  183.  
  184. ; At this point we have
  185. ;    BC = allocation vector address
  186. ;    DE = free block count
  187. ;    HL = number of blocks on disk
  188.  
  189. free1:
  190.     push    bc        ; Save allocation address
  191.     ld    a,(bc)        ; Get bit pattern of allocation byte
  192.     ld    b,8        ; Set to process 8 blocks
  193. free2:
  194.     rla            ; Rotate allocated block bit into carry flag
  195.     jr    c,free3        ; If set (bit=1), block is allocated
  196.     inc    de        ; If not set, block is not allocated, so
  197.                 ; ..increment free block count
  198. free3:
  199.     ld    c,a        ; Save remaining allocation bits in C
  200.     dec    hl        ; Count down number of blocks on disk
  201.     ld    a,l        ; See if we are down to zero
  202.     or    h
  203.     jr    z,free4        ; Branch if no more blocks to check
  204.     ld    a,c        ; Get back current allocation bit pattern
  205.     djnz    free2        ; Loop through 8 bits
  206.     pop    bc        ; Get pointer to allocation vector
  207.     inc    bc        ; Point to next allocation byte
  208.     jr    free1        ; Continue by processing next allocation byte
  209.  
  210. free4:
  211.     pop    bc        ; Clean up stack
  212.     ex    de,hl        ; Free block count to HL
  213. blkshf    equ    $+1        ; Pointer for in-the-code modification
  214.     ld    a,0        ; Get block shift factor
  215.     sub    3        ; Convert to log base 2 of K per block
  216.     jr    z,free6        ; Done if single density (1k per block)
  217.  
  218. ; Convert for blocks of more than 1K each
  219.  
  220. free5:
  221.     add    hl,hl
  222.     dec    a
  223.     jr    nz,free5
  224.  
  225. ;
  226. ; At this point HL = amount of free space on disk in K
  227.  
  228. free6:
  229.     call    print
  230.     db    ' Space on '
  231. seldrv:    db    0        ; Modified above to contain drive letter
  232.     db    ':',[' '+80h]
  233.  
  234. ; Display decimal value of HL
  235.  
  236.     ld    b,0        ; Initialize count of digits already printed
  237.     ld    de,10000    ; Divisor in DE
  238.     call    decdsp        ; Print digit (or space if leading '0')
  239.     ld    de,1000
  240.     call    decdsp
  241.     call    decdsp3        ; Display hundreds, tens, and units
  242.     ld    a,'K'
  243.     jp    conout        ; Final return from space routine
  244.  
  245. ; 
  246.  
  247. ;----------------------------------------
  248. page
  249. ;Command: WHL/WHLQ
  250. ;Function:  Set the Wheel Byte on or off
  251. ;
  252. ;Form:
  253. ;    WHL        -- turn Wheel Byte OFF
  254. ;    WHL password    -- turn Wheel Byte ON if password is correct
  255. ;    WHLQ        -- find out status of Wheel Byte
  256. ;
  257. whl:
  258.     ld    hl,fcb1+1    ; Pt to first char
  259.     ld    a,(hl)        ; Get it
  260.     cp    ' '        ; Turn byte off if no password
  261.     jr    z,whloff
  262.     ld    de,whlpass
  263.     ld    b,8        ; Check 8 chars
  264.     call    comp        ; Compare
  265.     jr    nz,whlmsg
  266.  
  267. ; TURN ON WHEEL BYTE
  268.  
  269.     ld    a,0ffh        ; Turn on wheel byte
  270.     jr    whlset
  271.  
  272. ; TURN OFF WHEEL BYTE
  273.  
  274. whloff:
  275.     xor    a        ; Turn off wheel byte
  276. whlset:
  277.     ld    hl,(z3env+29h)    ; Set wheel byte and print message    ++
  278.     ld    (hl),a        ;                    ++
  279.  
  280. ; PRINT WHEEL BYTE MESSAGE
  281.  
  282. whlmsg:
  283.     call    print
  284.     db    ' Wheel Byte',' '+80h
  285.     call    testz3whl    ; Get wheel byte            ++
  286.     jr    z,offm        ; Zero is off
  287.     call    print
  288.     db    'O','N'+80h
  289.     ret
  290. offm:
  291.     call    print
  292.     db    'OF','F'+80h
  293.     ret
  294.  
  295. ;
  296. ; Test wheel byte
  297. ;
  298. testz3whl:
  299.     push    hl        ;                    ++
  300.     ld    hl,(z3env+29h)    ;                    ++
  301.     ld    a,(hl)        ;                    ++
  302.     or    a        ;                    ++
  303.     pop    hl        ;                    ++
  304.     ret            ;                    ++
  305.  
  306.     db    'Z'-'@'        ; Leading ^z to block attempt to type rcp file
  307. whlpass:
  308.     db    'PASSWORD'
  309. ;
  310. ;
  311. ;----------------------------------------
  312.     page
  313. ;
  314. ;    H E L P    C O M M A N D
  315. ;
  316. ; This command displays a list of all resident commands that are supported,
  317. ; including those in the CPR (command processor), RCP, and FCP.
  318.  
  319. ;
  320. ; All inter-segment references are obtained from named-common bases
  321. ; (z3env, ccp).
  322. ;
  323. clist:
  324.  
  325. ; Print the FCP-resident command names
  326.  
  327.     call    print
  328.     db    lf
  329.     db    'FC','P'+80h
  330.     ld    hl,(z3env+12h)    ; Point to FCP command table        ++
  331.     ld    de,5
  332.     add    hl,de
  333.     call    cmdlist
  334. ;
  335. ; Print the CPR-resident command names
  336.  
  337.     call    print
  338.     db    lf
  339.     db    'CP','R'+80h
  340.     ld    hl,(z3env+3fh)    ; Point to command table in CPR        ++
  341.     ld    de,offcmd    ;                    ++
  342.     add    hl,de        ;                    ++
  343.     call    cmdlist
  344.  
  345. ; Print the RCP-resident command names
  346.  
  347.     call    crlf        ; Skip a line
  348.     ld    hl,rcpname    ; Print RCP name
  349.     call    printhl
  350.     ld    hl,(z3env+0ch)    ; Point to RCP command table        ++
  351.     ld    de,5
  352.     add    hl,de
  353.  
  354. cmdlist:
  355.     call    crlf
  356.     ld    e,(hl)
  357.     ld    d,0
  358.     inc    hl
  359.     ld    c,cmdsline    ; Set names-per-line value
  360.  
  361. cmdlist1:
  362.     ld    a,(hl)
  363.     or    a
  364.     jr    nz,cmdlist1a
  365.     ld    a,cmdsline
  366.     cp    c
  367.     call    nz,crlf
  368.     ret
  369.  
  370. cmdlist1a:
  371.     rla
  372.     jr    nc,cmdlist2
  373.     call    testz3whl
  374.     jr    nz,cmdlist2
  375.     add    hl,de
  376.     jr    cmdlist5
  377.  
  378. ; Print leading spaces between names
  379.  
  380. cmdlist2:
  381.     ld    a,cmdspace    ; Spacing between command names
  382.     sub    e
  383.     ld    b,a
  384.     ld    a,' '
  385. cmdlist3:
  386.     call    conout
  387.     djnz    cmdlist3
  388.  
  389. ; Print name of command
  390.  
  391.     ld    b,e
  392. cmdlist4:
  393.     ld    a,(hl)
  394.     call    conout
  395.     inc    hl
  396.     djnz    cmdlist4
  397.  
  398.     dec    c
  399.     jr    nz,cmdlist5
  400.     call    crlf
  401.     ld    c,cmdsline
  402.  
  403. ; Skip to next command name
  404.  
  405. cmdlist5:
  406.     inc    hl
  407.     inc    hl
  408.     jr    cmdlist1
  409.  
  410. ;----------------------------------------
  411.  
  412. ; Subroutines extracted from rcpsubs.lib for zcpr33.
  413. ; (c)  1987 Jay Sage
  414. ;
  415. crlf:
  416.     call    print
  417.     db    cr,lf+80h
  418.     ret
  419.  
  420. decdsp3:
  421.     ld    de,100
  422.     call    decdsp
  423.     ld    e,10
  424.     call    decdsp
  425.     ld    a,l
  426.     add    '0'
  427.     jr    conout
  428.  
  429. decdsp:
  430.     ld    c,'0'-1
  431.     xor    a
  432.  
  433. decdsp1:
  434.     inc    c
  435.     sbc    hl,de
  436.     jr    nc,decdsp1
  437.     add    hl,de
  438.     ld    a,c
  439.     cp    '0'
  440.     jr    nz,decdsp2
  441.     ld    a,b
  442.     or    a
  443.     ld    a,' '
  444.     ret    z
  445. decdsp2:
  446.     inc    b
  447.     ld    a,c
  448. ;
  449. ; fall thru to conout
  450.  
  451. ;  Console Output Routine
  452.  
  453. conout:
  454.     push    bc
  455.     push    de
  456.     push    hl
  457.     push    af
  458.     and    7fh
  459.     ld    e,a
  460.     ld    c,2
  461.     call    bdos
  462.     pop    af
  463.     pop    hl
  464.     pop    de
  465.     pop    bc
  466.     ret
  467.  
  468. print:
  469.     ex    (sp),hl
  470.     call    printhl
  471.     ex    (sp),hl
  472.     ret
  473.  
  474. printhl:
  475.     ld    a,(hl)
  476.     inc    hl
  477.     or    a
  478.     ret    z
  479.     call    conout
  480.     ret    m
  481.     jr    printhl
  482.  
  483. ;
  484. ;  comp compares de w/hl for b bytes; ret w/carry if de<hl
  485. ;    msb is disregarded
  486. ;
  487. comp:
  488.     ld    a,(hl)
  489.     and    7fh
  490.     ld    c,a
  491.     ld    a,(de)
  492.     and    7fh
  493.     cp    c
  494.     ret    nz
  495.     inc    hl
  496.     inc    de
  497.     djnz    comp
  498.     ret
  499. ;
  500.  
  501.     end
  502. 
  503.     inc    hl
  504.     inc    hl
  505.     jr    cmdlist1
  506.  
  507. ;---------------------------------