home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / z3sys / zbye12z.mac < prev    next >
Encoding:
Text File  |  1994-09-02  |  39.0 KB  |  1,618 lines
  1.     .sall 
  2.     .sfcond 
  3. ; Program:   ZBYE 
  4. ; Author:    Jay Denebeim 
  5. ; Assembler: M80 Version 3.44 or greater. (SLRMAC    ETB)
  6. version    equ    12 
  7. rev    equ    'Z' 
  8. ; 
  9. ;                                 ZCPR Bye RCP 
  10. ; 
  11. ;  This program implements BYE as an RCP under ZCPR3.  It handles all modem 
  12. ; IO by replacing the console routines.  All other functions are passed to 
  13. ; the ZCPR CCP for execution.  Where BYE normally uses equates, I.E. password 
  14. ; connection, carrier lost commands, etc., ZBYE passes command lines to ZCPR. 
  15. ; This should reduce the bugs introduced by tons of conditional assemblies 
  16. ; that has plagued the recent versions of BYE.  It has also allowed room to 
  17. ; do more functions than BYE normally has done in the past.  Please folks, 
  18. ; lets keep the conditional assemblies down to a minimum. 
  19. ; 
  20. ;  There are several new features in this program: 
  21. ;      Since its an RCP BYE can remain resident while the SYSOP is using 
  22. ;    the computer locally.  ZBye will answer the phone while in this mode,  
  23. ;    and allow the operator to accept the call while in another program. 
  24. ;      A chat mode has been implemented, this allows either single way, or 
  25. ;    two way communication between the sysop and the caller. 
  26. ;      It will also allow changes of the Maximum drive and user area 
  27. ;    without disabling the modem IO. 
  28. ; 
  29. ;  The function key descriptions: 
  30. ;    ^L - Toggle Local only IO.  This toggles the modem IO on and off. 
  31. ;    ^O - Toggle Open access.  This switches the wheel, maxdrive, and 
  32. ;        maxuser bytes of ZCPR3.  NOTE: this is the location your 
  33. ;        BBS, XMODEM, and whatever else should check.  Its no longer 
  34. ;        in the BYE header.  Also, be sure to watch the user while 
  35. ;        he's on in this mode, either disable the modem, or be ready 
  36. ;        with the ^N. 
  37. ;    ^N - Nerdkey, Hang up on the bozo 
  38. ;    ^Q - Query the user, (CHAT mode), end with ^C.  This is a very 
  39. ;        rudimentrary chat.  If local only, he can't type back, 
  40. ;        but if not, its two way.  Be sure to announce yourself 
  41. ;        'cause ZBYE doesn't anounce when its going into chat mode. 
  42. ;        the only editing commands implimented are expansion of 
  43. ;        <cr> to <cr><lf>. 
  44. ; 
  45. ;  To install this program, install your terminal dependent code following 
  46. ; the .8080 psudo-op.  ZBYE was set up to use MBYE overlays, these are either 
  47. ; very similar, or identical to BYE2.x or 3.x overlays.  Remember that 
  48. ; EQUates can't have :'s in front of them for M80, so you'll probably have 
  49. ; to do a global replace of :^IEQU with ^IEQU.  I'd really appreciate it if 
  50. ; you would send me a copy of your overlay when you finish it. 
  51. ;      You will also have to change the terminal dependent cursor 
  52. ; functions to match your own system. 
  53. ; 
  54. ;  This program is the first in a series of ZCPR RCPM software.  Look for 
  55. ; ZBBS, ZXMODEM, ZDIR, and ZCHAT at a RCPM near you. 
  56. ; 
  57. ;  Copyright 1985, by Jay Denebeim.  This program is released to the public 
  58. ; domain.  It can be freely given, but under no circumstances will this 
  59. ; software be charged for, except a copying fee not to exceed the price of 
  60. ; the media copied to. 
  61. ; 
  62. ;  I hope you enjoy using this program as much as I enjoyed writing it. 
  63. ;  If you make any modifications to this program, or have any suggestions, 
  64. ; please feel free to contact me. 
  65. ;  Thanks a bunch, 
  66. ;  Jay Denebeim 
  67. ;  1800 Williamsburg Rd Apt 13-E    <- NOTE: Address and phone number new. 
  68. ;  Durham, NC  27707 
  69. ;  (919) 489-1785 (voice) 
  70. ;  (919) 489-6737 (data) 
  71. ; 
  72. ;----------------------------------------------------------------------- 
  73. ; 
  74. ; Revision History: 
  75. ;
  76. ; 1.2Z    Extensive revisions to accomodate a dumb UART which cannot detect
  77. ;    carrier or cause the modem to answer or hangup.  Code reorganized
  78. ;    to place all UART code in one place where it can be handled as
  79. ;    an overlay, all modem code in another overlay (smart or dumb)
  80. ;    and all terminal code in another overlay (25th line for status
  81. ;    or not).  Added conditional code generation to prevent meddling
  82. ;    with the wheel byte if z3whl=0.
  83. ;                    Earl T. Boone 
  84. ; 
  85. ; 1.2A        *** Release Version ***        Fourth public release. 
  86. ;    Implemented answer routines for a dumb modem.  Set the equate 
  87. ;    DUMB to yes and baud rate will be set by carriage return 
  88. ;    sence.  Also moved initializing modem message to the right place. 
  89. ;                        Jay Denebeim 09/08/85 
  90. ; 
  91. ; 1.1F    Added equates for most major functions of this program.  Also moved 
  92. ;    the command lines to the top of the file so they're easier to find. 
  93. ;    Please, when adding functions, make sure they turn all the way off 
  94. ;    CREF is great for finding code that isn't used when functions are 
  95. ;    turned off.                Jay Denebeim 09/14/85 
  96. ; 
  97. ; 1.1E  Added KILCALR equate.  This switches on routines that will kill 
  98. ;    the caller if the byte at 0 is not equal to C3.  NOTE: this brought 
  99. ;    the size over the limit on my system.  The dumb modem routines 
  100. ;    are enough smaller that this will fit in dumb mode. 
  101. ;                        Jay Denebeim 09/09/85 
  102. ; 
  103. ; 1.1D    Added an equate to allow the printer to be enabled by the wheel. 
  104. ;    Set the LSTDEV equate to YES if you want the printer available 
  105. ;    while ZBye is running.  Do be careful with this, most CP/M systems 
  106. ;    lock up if the printer is not on-line during an attempt to print. 
  107. ;    Don't run any programs that print remotely unless you're sure the 
  108. ;    printer is on-line.            Jay Denebeim 08/19/85 
  109. ; 
  110. ; 1.1C        *** Release Version ***        Third public release. 
  111. ;    While modifing LUX4.0 to 4.1, I was reminded that time outs are 
  112. ;    very similar to carrier losses.  So, the carrier loss interupt 
  113. ;    also means time out.  To the program running under ZBYE, the reason 
  114. ;    for the loss of user isn't important.    Jay Denebeim 02/15/85 
  115. ; 
  116. ; 1.1B    Made Wheel on status line follow what the wheel was actually 
  117. ;    set to.  Input Timed out msg was in the wrong place, and was erased 
  118. ;    when bye ran again.            Jay Denebeim 02/02/85 
  119. ; 
  120. ; 1.1A        *** Release Version ***        Second public release. 
  121. ;    Cleaned up the comments, and stripped out the modem dependent 
  122. ;    routines.                Jay Denebeim 01/11/85 
  123. ; 1.0G    Changed carrier lost routine to restart # 30 so that programs 
  124. ;    could do their own thing on CLOSS.  Added check for wheel change 
  125. ;    so the sysop drives would follow the wheel. 
  126. ;                        Jay Denebeim 01/11/85 
  127. ; 1.0F    Moved BYE initialization routines into low memory.  This freed 
  128. ;    up some memory, and allowed another bit to implement another 
  129. ;    routine.  This routine runs a set of programs before hanging 
  130. ;    the modem up                Jay Denebeim 01/10/85 
  131. ; 1.0E    Moved local char status, and bye mode bytes into low memory 
  132. ;    so they will be available for other programs. 
  133. ;                        Jay Denebeim 01/09/85 
  134. ; 1.0D    If wrong characters typed during local mode answer, the caller 
  135. ;        would get hung up on.        Jay Denebeim 01/09/85 
  136. ; 1.0C    Reduced the size of the program.  RCP was overflowing. 
  137. ;                        Jay Denebeim 01/08/85 
  138. ; 1.0B    Answer phone while in local mode.    Jay Denebeim 01/07/85 
  139. ; 1.0A    First public release.  by - Jay Denebeim  12/23/84 
  140. ; 
  141. ;----------------------------------------------------------------------- 
  142. ; 
  143. ; 
  144. ; Equates for this program 
  145. ; 
  146.     .xlist 
  147.     maclib    E:Z3BASE.LIB 
  148.     .list 
  149. ; 
  150. no    equ    0 
  151. yes    equ    not no 
  152. cr    equ    0dh     ; carriage return
  153. lf    equ    0ah     ; line feed
  154. ; 
  155. bdos    equ    5 
  156. bios    equ    0 
  157. ; 
  158. mhz    equ    20    ; CPU speed times 10 
  159. closs    equ    1    ; Number of seconds to wait after loss of carrier 
  160. clrou    equ    30h    ; Routine to call on loss of carrier 
  161. jump    equ    0c3h    ; 8080/Z80 jump instruction 
  162. ; 
  163. ; Conditional assembly macros.  Use these to switch functions on and 
  164. ;  off. 
  165. ;
  166. etb    equ    yes    ; Special functions for Earl T Boone
  167. ; 
  168. obye    equ    no    ; Emulate BYE3.x ? 
  169. dumb    equ    no    ; Is this system running under a dumb modem? 
  170. lstdev    equ    no    ; Enable printer when wheel is set? 
  171. kilcalr    equ    yes    ; Kill the caller if memory location 0 <> C3 
  172. timeout    equ    yes    ; yes, auto logout for sleepy callers 
  173. tomins    equ    2    ; minutes to auto logout 
  174. tmins    equ    ((tomins*mhz)+5)/10    ;(don't change this one...) 
  175. statln    equ    no    ; display the status on line 25
  176.             ; (see terminal dependent section)
  177. chatf    equ    yes    ; provide chat function 
  178. lclans    equ    yes    ; answer modem while in local mode 
  179. ; 
  180. cdrive    equ    'E'-'@'    ; Callers Maximum Drive 
  181. cuser    equ    31    ; Callers Maximum User Area 
  182. ; 
  183. lclst    equ    003bh    ; Local Console generated character flag 
  184. bymode    equ    003fh    ; Bye control byte 
  185. ;
  186. ;   The BYE mode byte is bit mapped and has the following attributes: 
  187. ;
  188. bymmio    equ    80h    ; 7 = Modem IO enable 
  189. bymcio    equ    40h    ; 6 = Console IO enable 
  190. bymica    equ    20h    ; 5 = Ignore Carrier 
  191. bymncc    equ    10h    ; 4 = Next Caller Commands Running 
  192. bymclc    equ    08h    ; 3 = Carrier Lost Commands Running 
  193. bymnor    equ    04h    ; 2 = Normal Mode Commands Running 
  194. bymaoc    equ    02h    ; 1 = Alert Operator on Call 
  195. bymphu    equ    01h    ; 0 = Pre-Hangup Commands Running 
  196. ; 
  197. ;----------------------------------------------------------------------- 
  198. ; 
  199. ;  Global Macros 
  200. ; 
  201. cmdln    macro    cmd 
  202.     local    cmdst,msg,cmdend 
  203. cmdst:    dw    z3cl+msg-cmdst 
  204.     db    z3cls,0 
  205. msg:    db    cmd 
  206.     db    0 
  207. cmdend: 
  208.     endm 
  209. ;----------------------------------------------------------------------- 
  210. ; 
  211. ;  Command line macros 
  212. ; 
  213. byecl    macro    ; Executed during initialization 
  214.     cmdln    'BYE' 
  215.     endm 
  216. ; 
  217. gbcl    macro    ; Executed before normal disconnection 
  218.     cmdln    'BYE' 
  219.     endm 
  220. ; 
  221. nccl    macro    ; Executed between calls 
  222. ;    cmdln    'A0:;LDR RCPM.NDR;PATH A0:;BYE' ; JD's original
  223.     cmdln    'A0:;PATH E0: A0: A15: E0:;BYE' ; ETB's revision
  224.     endm 
  225. ; 
  226. nmcl    macro    ; Executed upon connection 
  227. ;    cmdln    'A0:;RBBS;MENU'         ; JD's original
  228.     cmdln    'E0:;LDSK B:;LDSK C:'         ; ETB's revision
  229.     endm 
  230. ; 
  231. clcl    macro    ; Executed if carrier lost 
  232.     cmdln    'BYE' 
  233.     endm 
  234. ; 
  235. tocl    macro    ; Executed if timed out 
  236.     cmdln    'BYE' 
  237.     endm 
  238. ; 
  239. kccl    macro    ; Executed if call killed by higher process 
  240.     cmdln    'BYE' 
  241.     endm 
  242. ; 
  243. ;----------------------------------------------------------------------- 
  244. ;                            TPA starts here 
  245. ;----------------------------------------------------------------------- 
  246. ; 
  247. ; Lets get this show on the road 
  248. ; 
  249.     MACLIB    Z80
  250.     aseg 
  251.     org    100h 
  252. ; 
  253. ; Lets see if BYE is already resident. 
  254. ; 
  255.     lxi    h,rcp        ; Point to RCP area 
  256.     lxi    d,bybeg        ; Point to RCP's name 
  257.     lxi    b,5        ; Length of name 
  258. chbye1:    ldax    d        ; Get next char 
  259.     cci            ; Is it the same? 
  260.     jrnz    nbye        ; Nope, re-locate the RCP 
  261.     jpo    ybye        ; If done, its there 
  262.     inx    d        ; Point to next char 
  263.     jr    chbye1        ; Do it again 
  264. ; 
  265. nbye:    mvi    c,9 
  266.     lxi    d,nbst 
  267.     call    5 
  268.     xra    a 
  269.     sta    lclst        ; Clear out local status 
  270.     sta    bymode        ; and Bye's operating mode 
  271.     lxi    h,bybeg 
  272.     lxi    d,rcp 
  273.     lxi    b,byend-bybeg 
  274.     ldir            ; Re-Locate BYE 
  275.     mvi    a,jump        ; load A with JUMP instruction 
  276.     sta    clrou        ; and put in restart 
  277.     lxi    h,lostit    ; do the same 
  278.     shld    clrou+1        ; with original closs command line 
  279.     call    byeini 
  280.     jmp    ybye 
  281. nbst:    db    'ZBye version ' 
  282.     db    '0'+(version/10), '.', '0'+(version mod 10), rev 
  283.     db    ' - By Jay Denebeim  Copyright (C) 1985',cr,lf 
  284.     db    'Making BYE',cr,lf,'$' 
  285. ; 
  286. ybye:    lxi    h,bye 
  287.     lxi    d,z3cl 
  288.     lxi    b,byelen 
  289.     ldir            ; Load 'BYE' into command line 
  290. ; 
  291.     jmp    0 
  292. ; 
  293. bye:    byecl 
  294. byelen    equ    $-bye 
  295. ; 
  296. byeini:    lda    z3env+2ch    ; store away, sysop's Highest drive 
  297.     sta    sdrive
  298.     lda    z3env+2dh    ; and user area. 
  299.     sta    suser
  300.     lda    fstprv        ; Store first letter of private 
  301.     sta    prvlet        ; commands 
  302.     call    newbio 
  303.     call    clrbuf 
  304.     call    modini 
  305.     mvi    a,bymmio+bymcio+bymica+bymclc 
  306.     sta    bymode
  307.     ret 
  308. ;
  309. ; The folowing code should logically be located in the UART and MODEM
  310. ; hardware specific overlay area of the code. It is located here
  311. ; to save space in the RCP by doing these initialization functions
  312. ; (only executed once) in the TPA.
  313. ; 
  314. ; Initialize the UART (interface to modem) 
  315. ; 
  316. modini:
  317.     call    mdinit        ; Initialize serial port 
  318.     mvi    b,3 
  319.     call    ldelay        ; delay .3 sec 
  320.     call    mdansw        ; raise dtr 
  321.     call    delay 
  322.     call    set1200        ; 1200 baud 
  323.     call    delay 
  324.     mvi    a,bymmio+bymica 
  325.     sta    bymode        ; enable modem io 
  326.      if    not dumb
  327.     call    prinlo        ; reset modem 
  328.     db    'ATZ',cr+80h     ; at this point we don't know
  329.                 ; whether the command will be echoed
  330.                 ; or whether the status will be
  331.                 ; numeric or verbal
  332.     call    l2char        ; is it status
  333.     cnz    l2char        ; if not - try again
  334. ;
  335. ; the next command will echo or not based strictly on the physical
  336. ; switches on the modem itself
  337. ;
  338.     call    prinlo        ; set our way 
  339.     db    'ATS0=0'    ; never answer
  340.     db    'V0'        ; numeric status codes
  341.     db    'E0'        ; no command echo
  342.     db    'X1'        ; extended status
  343.     db    'M1',cr+80h    ; speaker off at connect time 
  344.     call    l2char        ; get echo
  345.     cnz    l2char        ; get status
  346.     jnz    modini        ; status ok?
  347.      endif    ; dumb
  348.     ret
  349. ;----------------------------------------------------------------------
  350. ;                            RCP starts here 
  351. ;----------------------------------------------------------------------
  352. bybeg: 
  353.     .phase    rcp 
  354.     db    'ZBYE '        ; RCP's name for ZCPR 
  355.     db    3        ; Command name length 
  356. fstcmd:    db    'BYE' 
  357.     dw    start 
  358. fstprv:    db    'OFF' 
  359.     dw    byeoff 
  360.     db    0 
  361. ; 
  362. start: 
  363.     pop    h        ; Get ZCPR3's return address 
  364.     shld    z3ret        ; Save it 
  365.     lxi    h,bymode 
  366.     bit    0,m 
  367.     jnz    prophu        ; Process pre-hangup commands 
  368.     bit    1,m 
  369.     jnz    prolcl        ; Process a local exit 
  370.     bit    2,m 
  371.     jnz    pronor        ; Process a normal exit 
  372.     bit    3,m 
  373.     jnz    proclc        ; Carrier lost commands finished 
  374.     bit    4,m 
  375.     jnz    proncc        ; Next caller commands finished 
  376.     call    prinpl 
  377.     db    'Invalid BYE mode!  BYE terminating',7,cr,lf+80h 
  378.     jr    byeof1 
  379. ; 
  380. byeoff:
  381.     pop    h        ; Get ZCPR3's return address 
  382.     shld    z3ret        ; Save it 
  383. byeof1:    call    oldbio 
  384.     mvi    a,0 
  385.     sta    rcp        ; Disable RCP recognition 
  386.     sta    fstcmd        ; and for the CCP 
  387.     lxi    h,bymode 
  388.     res    7,m        ; Turn off modem IO 
  389.      if statln 
  390.     call    prinlc 
  391.     enab25    no 
  392.     cls    yes        ; enable 25th line and clear screen 
  393.      endif    ; statln 
  394.     call    prinpl 
  395.     db    'Bye is gone',cr,lf+80h 
  396.     jmp    exit 
  397. ; 
  398. ; Local storage initialized by loader 
  399. sdrive:    db    0         ; sysop's max drive
  400. suser:    db    0         ; sysop's max user
  401. prvlet:    db    0         ; priviledged letter
  402. ; 
  403. ; Process pre-hangup commands 
  404. ; 
  405. prophu:    mvi    a,bymcio+bymmio+bymnor    ;con enab, modem enab, normal caller 
  406.     sta    bymode
  407. ; 
  408.     lxi    h,gbcmd        ; Load next command string 
  409.     lxi    b,gblen 
  410.     lxi    d,z3cl 
  411.     ldir 
  412.     jmp    exit 
  413. ; 
  414. gbcmd:    gbcl 
  415. gblen    equ    $-gbcmd 
  416. ; 
  417. ; Process a local exit, actually a modified normal answer, but must check 
  418. ;    for carrier present. 
  419. ; 
  420. prolcl:    call    mdcarck 
  421.     jrz    prolc1        ; If no carrier, just get ready for next call 
  422.     mvi    a,0ffh        ; set flag 
  423.     sta    prlct1
  424.     jr    prolc2        ; get ready for next caller 
  425. ; 
  426. prlct1:    ds    1 
  427. ; 
  428. ; Process a normal exit.  This routine runs any programs to end the 
  429. ;    session, says Bye, hangs up the modem, turns off the modem IO,  
  430. ;    then runs the routines to get ready for the next caller. 
  431. ; 
  432. pronor:    call    prinpl 
  433.     db    'Goodbye, call again soon!',cr,lf+80h 
  434. ; 
  435. prolc1:
  436.     call    prtsta
  437.     db    60,,13 
  438. ;
  439. ; If carrier lost, no point in printing msg 
  440. ; 
  441. proclc:
  442.     call    mdinit 
  443. prolc2:    mvi    a,bymcio+bymncc    ;con enab, nxt calr mode 
  444.     sta    bymode
  445. ; 
  446.     call    clrbuf 
  447.     call    ressec 
  448. ; 
  449.     lxi    h,nccmd        ; Load next command string 
  450.     lxi    d,z3cl 
  451.     lxi    b,nclen 
  452.     ldir 
  453.     jmp    exit 
  454. ; 
  455. nccmd:    nccl 
  456. nclen    equ    $-nccmd 
  457. ; 
  458. ; Ready for next caller.  Set secure mode, then wait for arrival. 
  459. ; 
  460. proncc:
  461.     call    cursoff        ; turn off cursor
  462.     call    prtsta
  463.     db    40,,19
  464.     call    clrscr        ; clear screen
  465.     call    setsec 
  466.     mvi    a,bymcio+bymphu 
  467.     sta    bymode
  468.     lda    prlct1        ; ending local mode ? 
  469.     cpi    0ffh 
  470.     push    psw 
  471.     xra    a 
  472.     sta    prlct1        ; zero it anyway 
  473.     pop    psw 
  474.     jrz    pronc2 
  475.     call    nxtcal 
  476. pronc1:    call    modans 
  477.     call    mdcarck        ; No Carrier? 
  478.     jrz    pronc1        ; Then loop 
  479. pronc2:
  480.     call    curson        ; turn cursor on
  481.     call    prtsta
  482.     db    60,'Connected',0
  483.     lxi    h,bymode 
  484.     setb    7,m        ; Make sure modem is on 
  485.     res    5,m        ; and carrier significant 
  486.     call    prinpl 
  487.     db    'Welcome to ZBoard',cr,lf 
  488.     db    'You are now running under ZBYE version ' 
  489.     db    '0'+(version/10), '.', '0'+(version mod 10), rev, cr, lf+80h 
  490. ; 
  491.     lxi    h,nmcmd    ; Load normal entry command string 
  492.     lxi    d,z3cl 
  493.     lxi    b,nmlen 
  494.     ldir 
  495.     jmp    exit 
  496. ; 
  497. nmcmd:    nmcl 
  498. nmlen    equ    $-nmcmd 
  499. ; 
  500. ; Set ZCPR into a secure mode 
  501. ; 
  502.      if    z3whl
  503. setsec:    call    usrdru 
  504.     xra    a 
  505.     sta    z3whl        ; Clear the wheel 
  506.     sta    fstprv        ; And private commands 
  507.     ret 
  508. ; 
  509. ; Set highest drive and user area for caller. 
  510. ; 
  511. usrdru:    mvi    a,cdrive    ; Set Caller's highest drive 
  512.     sta    z3env+2ch
  513.     mvi    a,cuser 
  514.     sta    z3env+2dh    ; and user area. 
  515.     push    psw 
  516.     push    h 
  517.     call    prtsta
  518.     db    40,'Not Wheel',0
  519.     pop    h 
  520.     pop    psw 
  521.     ret 
  522.      else
  523. setsec:    ret            ; not a secure system
  524.      endif    ;z3whl
  525. ; 
  526. ; Set ZCPR into sysop mode 
  527. ; 
  528.      if    z3whl
  529. ressec:    call    sysdru 
  530.     xra    a 
  531.     cma 
  532.     sta    z3whl        ; Set the wheel 
  533.     lda    prvlet        ; and private commands 
  534.     sta    fstprv
  535.     ret
  536. ; 
  537. ; Set highest drive and user area for SysOp. 
  538. ; 
  539. sysdru:    lda    sdrive        ; Set Sysop's highest drive 
  540.     sta    z3env+2ch
  541.     lda    suser 
  542.     sta    z3env+2dh    ; and user area. 
  543.     call    prtsta
  544.     dc    40,'    Wheel',0
  545.     ret 
  546.      else
  547. ressec:    ret            ; not a secure system
  548.      endif    ;z3whl 
  549. ; 
  550. ; Clear ZCPR's internal buffers 
  551. ; 
  552. clrbuf:    xra    a 
  553. ; 
  554.      if    z3env 
  555.     lxi    h,z3env+80h    ; Clear TCAP area 
  556.     lxi    d,z3env+81h 
  557.     lxi    b,7eh        ; TCAP length-1 (always?) 
  558.     mov    m,a 
  559.     ldir 
  560.      endif    ;z3env 
  561. ; 
  562.      if    shstk 
  563.     lxi    h,shstk        ; Clear Shell Stack 
  564.     lxi    d,shstk+1 
  565.     lxi    b,shstks*shsize-1 
  566.     mov    m,a 
  567.     ldir 
  568.      endif    ;shstk 
  569. ; 
  570.      if    z3msg 
  571.     lxi    h,z3msg        ; Clear Message Buffers 
  572.     lxi    d,z3msg+1 
  573.     lxi    b,4eh        ; Message buffer length -1 
  574.     mov    m,a 
  575.     ldir 
  576.      endif    ;z3msg 
  577. ; 
  578.     ret 
  579. ; 
  580. ; Answer modem and wait for carrier.  Set baud as appropriate. 
  581. ; 
  582. modans:
  583.     call    prtsta
  584.     db    30,'Awaiting Call',0
  585. mdans00    call    modans0
  586.     rz
  587.     cpi    'C'-'@'        ; Control C from console? 
  588.     jnz    mdans00        ; Nope 
  589.     lxi    h,bymode 
  590.     bit    1,m        ; if in local bye active mode 
  591.     jnz    mdans00        ; then forget the console 
  592.     res    7,m        ; inhibit modem IO 
  593.     setb    1,m        ; go into local bye active mode 
  594.     res    0,m        ; make sure not in pre-hangup 
  595.     call    ressec
  596.     call    curson        ; turn on cursor
  597.     call    prtsta
  598.     db    60,'Local',7
  599.      if    lclans 
  600.     jmp    exit 
  601.      else 
  602.     jmp    byeof1 
  603.      endif    ; lclans 
  604. ; 
  605. ;  Get ready for next caller 
  606. ; 
  607. nxtcal:
  608.      if    timeout 
  609.     xra    a        ; Clear timeout 
  610.     sta    tocnt
  611.     sta    tocnt+1
  612.     mvi    a,tmins 
  613.     sta    toval
  614.      endif    ;timeout 
  615. ; 
  616.     call    mdinit        ; drop DTR 
  617.     mvi    b,3 
  618.     call    ldelay        ; wait awhile 
  619.     call    mdansw        ; raise it 
  620.     call    delay 
  621.     call    set1200 
  622.     call    delay 
  623.     call    sync        ; synchronize modem
  624. ; 
  625.      if    lclans 
  626. ;    Check for call coming in during local mode.  If so, answer it. 
  627. ; 
  628. chkcal:    lda    chkt1 
  629.     ora    a 
  630.     rnz            ; return if already doing function 
  631.     call    mdcarck        ; check for call still in progress 
  632.     jrnz    chkca4        ; yup 
  633.     xra    a 
  634.     sta    chkt2        ; he's gone 
  635. chkca4:    lda    chkt2 
  636.     ora    a        ; if this function already run 
  637.     rnz            ; return to caller 
  638.     mov    a,m        ; Get BYMODE 
  639.     sta    chkt1        ; indicate function running 
  640.     push    psw 
  641.     res    6,m        ; Turn off console 
  642.     setb    7,m        ; Turn on modem 
  643.     setb    5,m        ; Ignore Carrier 
  644.     call    incmcl        ; check for incoming call
  645.     jz    chkca1
  646.     call    mdcarck        ; Got carrier? 
  647.     jz    chkca1        ; Nope 
  648.     lxi    h,bymode 
  649.     res    6,m 
  650.     push    h 
  651.     call    prinpl 
  652.     db    cr,lf,'Asking SYSOP if you can get on.',cr,lf+80h 
  653.     call    mdcarck        ; Hung up? 
  654.     jz    chkca1        ; Oh well 
  655. chkca2:    call    oconst 
  656.     jrz    chkca3 
  657.     call    conin 
  658.     jr    chkca2        ; Eat console characters if any 
  659. chkca3:     if    statln 
  660.     call    go25 
  661.     call    prinlc 
  662.     curpos    0,24,no
  663.      else
  664.     call    prinlc 
  665.      endif    ; statln 
  666.     dc    'Caller, let on ? ' 
  667.     call    oconin 
  668.     sta    chkt1
  669.      if    statln 
  670.     call    no25 
  671.      endif    ; statln 
  672.     call    mdcarck        ; Still with us? 
  673.     pop    h 
  674.     jrz    chkca1        ; Nope, his loss 
  675.     setb    7,m 
  676.     res    6,m        ; Set for remote IO 
  677.     lda    chkt1 
  678.     ani    'Y' 
  679.     cpi    'Y' 
  680.     jrz    letliv        ; If Y or y let him on 
  681.     call    prinpl 
  682.     db    'Sorry, try again later',cr,lf+80h 
  683.     call    nxtcal 
  684.     jr    chkca1 
  685. letliv:    call    prinpl 
  686.     db    'He will let you on soon, please hold',cr,lf+80h 
  687.     mvi    a,0ffh 
  688.     sta    chkt2        ; indicate call in progress 
  689. chkca1:    xra    a 
  690.     sta    chkt1        ; zero out storage 
  691.     pop    psw        ; Get original BYMODE 
  692.     sta    bymode
  693.     ret 
  694. chkt1:    ds    1 
  695. chkt2:    ds    1 
  696. ; 
  697.      endif    ; lclans 
  698. ; 
  699. ; Check for carrier available.  If not there, return with zero flag set. 
  700. ; 
  701. carok:    push    h        ; Do we care? 
  702.     lxi    h,bymode 
  703.     bit    5,m 
  704.     pop    h 
  705.     rnz            ; Nope 
  706.     push    b 
  707.     mvi    b,closs*10 
  708. carok1:    call    mdcarck        ; Got carrier? 
  709.     jrnz    carok2        ; Yup, great 
  710.     call    delay        ; nope, wait awhile 
  711.     djnz    carok1        ; try again 
  712. carok2:    pop    b 
  713.     ret 
  714. ; 
  715. ; Carrier lost.  Drop Dead. 
  716. ; 
  717. lostit:    lda    clgat 
  718.     ora    a 
  719.     jrnz    lstit1        ; Check for no status gate 
  720. ; 
  721.     call    prtsta
  722.     db    60,'Carrier Lost',0
  723. ; 
  724.     mvi    a,bymcio+bymclc 
  725.     sta    bymode
  726.     lxi    h,clcmd        ; this is what we want to do 
  727.     lxi    d,z3cl        ; point to zcpr's command line 
  728.     lxi    b,cllen 
  729.     ldir 
  730. lstit1:
  731.     mvi    a,jump        ; just to be safe
  732.     sta    0
  733.     xra    a 
  734.     sta    clgat        ; Clear no status gate 
  735.     jmp    0        ; Gotta exit this way 
  736. ; 
  737. clcmd:    clcl 
  738. cllen    equ    $-clcmd 
  739. clgat:    db    0        ; gate for carrier lost command 
  740. ; 
  741.      if    timeout 
  742. ; 
  743. ; Must be too late at night.  He's asleep. 
  744. ; Input timed out. 
  745. ; 
  746. timout:
  747.      if    etb
  748.     mvi    a,0
  749.     sta    carion        ; mark 'carrier off'
  750.      endif
  751.     mvi    a,0ffh 
  752.     sta    clgat        ; Flag the timeout 
  753.     call    prinpl 
  754.     db    'Input timed out',7,cr,lf+80h 
  755.     call    prtsta
  756.     db    60,'Timed Out',3
  757. ; 
  758.     mvi    a,bymcio+bymclc 
  759.     sta    bymode
  760.     lxi    h,tocmd        ; this is what we want to do 
  761.     lxi    d,z3cl        ; point to zcpr's command line 
  762.     lxi    b,tolng 
  763.     ldir 
  764.     rst    clrou/8        ; Do a CLOSS restart 
  765. ; 
  766. tocmd:    tocl 
  767. tolng    equ    $-tocmd 
  768. ; 
  769.      endif    ;timeout 
  770. ; 
  771.      if    kilcalr        ; allow programs to commit suicide 
  772. ; 
  773. ;  Memory Location 0 not C3H program abort 
  774. ;    If the base of memory is not a jump instruction, this routine will 
  775. ;    be executed.  It is similar to a carrier lost, or timeout routine. 
  776. ;    Any program which changes the byte will cause the caller to be 
  777. ;    dropped unceremoniously. 
  778. ; 
  779. kilcal:    mvi    a,0ffh 
  780.     sta    clgat        ; Set the gate 
  781.     mvi    a,jump 
  782.     sta    0        ; replace the jump instruction 
  783.     call    prtsta
  784.     db    60,'Call Killed',1
  785. ; 
  786.     mvi    a,bymcio+bymclc 
  787.     sta    bymode
  788.     lxi    h,kccmd        ; this is what we want to do 
  789.     lxi    d,z3cl        ; point to zcpr's command line 
  790.     lxi    b,kclng 
  791.     ldir 
  792. ;    rst    clrou        ; Do a CLOSS restart 
  793.     rst    clrou/8        ; assembler uses other syntax
  794. ; 
  795. kccmd:    kccl 
  796. kclng    equ    $-kccmd 
  797.      endif    ; kilcalr 
  798. ; 
  799. ;  Routines which process local function keys. 
  800. ; 
  801. ;    Here are the descriptions 
  802. ;    ^L - Toggle Local IO 
  803. ;    ^O - Toggle Open access 
  804. ;    ^N - Nerdkey, Hang up on the bozo 
  805. ;    ^Q - Query the user, (CHAT mode) 
  806. ; 
  807. fkeys:    lxi    h,bymode    ; BYE in inactive state? 
  808.     bit    1,m 
  809.     rnz            ; Yes, return 
  810.     cpi    'L'-'@'        ; Control-L ? 
  811.     jrz    toglcl        ; if so, toggle local mode 
  812.     cpi    'O'-'@'        ; Control-O ? 
  813.     jrz    togope        ; Yes? Toggle security 
  814.     cpi    'N'-'@'        ; Control-N ? 
  815.     jz    twitem        ; Goodbye bozo 
  816. ; 
  817.      if    chatf 
  818.     cpi    'Q'-'@'        ; Control-Q 
  819.     jz    bychat        ; Go into Chat Mode 
  820.      endif    ;chatf 
  821. ; 
  822.     ret            ; Not a BYE function Key 
  823. ; 
  824. ;  Toggle Local IO Mode 
  825. ; 
  826. toglcl:    bit    7,m 
  827.     jrz    toglc1        ; If set, reset it. 
  828.     res    7,m 
  829.     call    prtsta
  830.     db    51,'Local Disabled',0
  831.     jr    endfun 
  832. toglc1:    setb    7,m 
  833.     call    prtsta
  834.     db    51,'Local',8
  835.     jr    endfun 
  836. ; 
  837. ;  Toggle Security 
  838. ; 
  839. togope:    lda    fstprv 
  840.     ora    a        ; Secure? 
  841.     jrz    togop1        ; If so, remove it 
  842.     call    setsec        ; Turn on security 
  843.     jr    endfun 
  844. togop1:    call    ressec        ; Turn it off 
  845.     jr    endfun 
  846. ; 
  847. ;  Hang up on the bum. 
  848. ; 
  849. twitem:
  850.     call    curson
  851.     call    prtsta
  852.     db    60,'Twitted off',0
  853.     jmp    proclc        ; Same as Carrier loss 
  854. ; 
  855. ;  End Function Key routines 
  856. ; 
  857. endfun:    xra    a        ; No character entered 
  858.     ret 
  859. ; 
  860.      if    chatf 
  861. ; 
  862. ;  Bye's Chat Mode 
  863. ; 
  864. bychat:
  865.     call    conin        ; pitch out the ^Q 
  866.     call    prtsta
  867.     db    46,'Chat',0
  868.     call    prinpl
  869.     dc    'Chat',cr,lf
  870. bycha2:    call    conin        ; end on control c 
  871.     cpi    'C'-'@' 
  872.     jrz    bycha3 
  873. bycha1:    push    psw 
  874.     push    h 
  875.     push    b 
  876.     mov    c,a 
  877.     call    conout 
  878.     pop    b 
  879.     pop    h 
  880.     pop    psw 
  881.     push    psw 
  882.     bit    7,m 
  883.     cz    mconout        ; print it to modem if not enabled 
  884.     pop    psw 
  885.     cpi    'M'-'@' 
  886.     jrnz    bycha2        ; Loop if not a carriage return 
  887.     mvi    a,'J'-'@' 
  888.     jr    bycha1        ; And append linefeed if there 
  889. bycha3:
  890.     call    prinpl
  891.     dc    'End Chat',cr,lf
  892.     call    prtsta
  893.     db    46,,4 
  894.     jmp    endfun 
  895. ; 
  896.      endif    ; chatf 
  897. ; 
  898. exit: 
  899. z3ret    equ    $+1        ; point to code to modify 
  900.     jmp    $-$        ; ZCPR's return address 
  901. ; 
  902. prinlc:    lda    bymode        ; Get current Mode 
  903.     sta    pritmp        ; Save it 
  904.     res    7,a        ; turn off modem IO 
  905.     setb    6,a        ; turn on lcl IO 
  906.     sta    bymode
  907.     xtix            ; print the string 
  908.     call    print 
  909.     xtix    
  910.     lda    pritmp        ; restore mode 
  911.     sta    bymode
  912.     ret 
  913. pritmp:    db    0 
  914. ; 
  915. prinpl:    xtix            ; Get string starting address 
  916.     call    print        ; Print it 
  917.     xtix            ; Since we're pointing to next code location 
  918.     ret            ; Go there! 
  919. ; 
  920. prinlo:    xtix            ; Get string starting address 
  921.     call    print        ; Print it 
  922. ;    call    delay        ; My modem is too d**n slow 
  923.     xtix            ; Since we're pointing to next code location 
  924.     ret            ; Go there! 
  925. ; 
  926. print:    ldx    a,0        ; Get next char 
  927.     bit    7,a        ; Check for Carry 
  928.     push    psw 
  929.     res    7,a        ; Mask Carry Bit 
  930.     mov    c,a 
  931.     call    conout        ; Print it 
  932.     inxix            ; point to next char 
  933.     pop    psw 
  934.     rnz    
  935.     jr    print 
  936. ; 
  937. ; 
  938. ;.1 sec delay routine 
  939. ; 
  940. delay:    push    b 
  941.     lxi    b,4167*(mhz/10)+417*(mhz mod 10) ; constant * MHz10x 
  942. ; 
  943. delay1:    dcx    b 
  944.     mov    a,b 
  945.     ora    c 
  946.     jrnz    delay1 
  947.     pop    b 
  948.     ret 
  949. ; 
  950. ;.001 sec delay routine 
  951. ; 
  952. sdelay:    push    b 
  953.     lxi    b,42*(mhz/10)+4*(mhz mod 10) ; constant * MHz10x 
  954.     jr    delay1 
  955. ; 
  956. ; Long delay routine, B contains # of .1 sec delays 
  957. ; 
  958. ldelay:    call    delay 
  959.     dcr    b 
  960.     jrnz    ldelay 
  961.     ret 
  962. ; 
  963. newbio:    lhld    bios+1        ; Point to bios start 
  964.     mvi    l,0 
  965.     lxi    d,tolst        ; Point to storage table 
  966.     lxi    b,tolen-tolst    ; table length 
  967.     ldir            ; Save old jump table 
  968.     lxi    h,tnlst        ; Point to new jump table 
  969.     lded    bios+1 
  970.     mvi    e,0 
  971.     lxi    b,tnlen-tnlst 
  972.     ldir            ; We are now running under BYE 
  973.     ret 
  974. ; 
  975. oldbio:    lxi    h,tolst        ; Put things back the way they were 
  976.     lded    bios+1 
  977.     mvi    e,0 
  978.     lxi    b,tolen-tolst 
  979.     ldir 
  980.     ret 
  981. ; 
  982. tolst: 
  983. ocboot:        jmp    0 
  984. owboot:        jmp    0    ; This will hold the BIOS routines 
  985. oconst:        jmp    0    ;  BYE will modify 
  986. oconin:        jmp    0 
  987. oconout:    jmp    0 
  988. olist:        jmp    0 
  989. opunch:        jmp    0 
  990. oreader:    jmp    0 
  991. tolen: 
  992. ; 
  993. tnlst: 
  994. cboot: 
  995.          if    obye    ; Emulate Old BYE? 
  996.         jmp    fakeit 
  997.          else 
  998.         jmp    0 
  999.          endif 
  1000. wboot:        jmp    owboot    ; Here is the new jump table 
  1001. const:        jmp    bconst 
  1002. conin:        jmp    bconin 
  1003. conout:        jmp    bconout 
  1004.          if    lstdev    ; retain printer for sysop? 
  1005. list:        jmp    whlst 
  1006.          else 
  1007. list:        jmp    mconout 
  1008.          endif    ; lstdev 
  1009. punch:        jmp    bconout 
  1010. reader:        jmp    bconin 
  1011. tnlen: 
  1012. ; 
  1013. ;  Structure to look like the old byes 
  1014. ; 
  1015.      if obye 
  1016. fakeit:    ds    15 
  1017.     dw    oconout 
  1018.     db    'BYE' 
  1019.      endif 
  1020. ; 
  1021. ;  Routines patched in by BYE 
  1022. ; 
  1023. bconst:
  1024.      if    z3whl
  1025.     lda    z3whl 
  1026.     lxi    h,owheel    ; check for wheel change 
  1027.     cmp    m 
  1028.     jrz    bcst3 
  1029.     sta    owheel
  1030.     ora    a        ; wheel set? 
  1031.     cz    usrdru        ; then set remote dru 
  1032.     cnz    sysdru        ; else set sysop dru 
  1033.      endif    ;z3whl
  1034. bcst3:    lxi    h,bymode    ; local console enabled? 
  1035.     bit    6,m 
  1036.     jrz    bcst1        ; nope, don't check 
  1037.     push    h        ; used later 
  1038.      if    lclans 
  1039.     bit    1,m        ; In local mode ? 
  1040.     cnz    chkcal        ; check for a caller 
  1041.      endif    ; lclans 
  1042.     lda    lchar        ; got an uneaten one? 
  1043.     ora    a 
  1044.     jrnz    bcst2        ; Yup, still have it 
  1045.     call    oconst        ; check con status 
  1046.     ora    a 
  1047.     pop    h 
  1048.     sta    lchar        ; flag local char 
  1049.     sta    lclst
  1050.     jrz    bcst1        ; no char 
  1051.     push    h 
  1052.     call    oconin        ; get local char 
  1053.     call    fkeys        ; check and process local function keys 
  1054. bcst2:    pop    h 
  1055.     sta    lchar        ; store away char 
  1056.     ora    a        ; make flags follow a 
  1057.     ret 
  1058. ; 
  1059. bcst1:    bit    7,m        ; Modem enabled? 
  1060.     rz            ; Nope, don't bother 
  1061. ; 
  1062.      if    kilcalr        ; Kill caller if loc 0 <> jump 
  1063.     lda    0 
  1064.     cpi    jump 
  1065.     jnz    kilcal        ; Kill him if instructed by higher program 
  1066.      endif    ; kilcalr 
  1067. ; 
  1068.     call    carok        ; Check for carrier 
  1069.     jz    clrou        ; Fool dropped carrier on us 
  1070.     call    mdinst        ; Check for modem status 
  1071.     rnz            ; Everything's hunkey dory 
  1072. ; 
  1073.      if    timeout 
  1074.     push    h 
  1075.     lxi    h,bymode 
  1076.     bit    5,m        ; Paying attention to carrier 
  1077.     jrnz    ndata 
  1078.     lxi    h,tocnt        ;No data, incr. timeout counter 
  1079.     inr    m
  1080.     jrnz    ndata        ;don't timeout yet 
  1081.     inx    h 
  1082.     inr    m        ;next byte of counter 
  1083.     jrnz    ndata 
  1084.     lxi    h,toval        ;1 "minute", no data 
  1085.     dcr    m
  1086.     jrnz    ndata        ;still not timed out... 
  1087.     jmp    timout        ;finally... timed out... 
  1088. ; 
  1089. ndata: 
  1090.     xra    a        ;no character for sure 
  1091.     pop    h 
  1092.      endif    ; Timeout 
  1093. ; 
  1094.     ret 
  1095. ; 
  1096. toval:    ds    1 
  1097. tocnt:    ds    2 
  1098. lchar:    db    0 
  1099. owheel:    db    0 
  1100. ; 
  1101. bconin:    call    bconst        ; Wait for char avail 
  1102.     ora    a 
  1103.     jrz    bconin 
  1104. ; 
  1105.      if    timeout 
  1106.     xra    a        ; Clear timeout 
  1107.     sta    tocnt
  1108.     sta    tocnt+1
  1109.     mvi    a,tmins 
  1110.     sta    toval
  1111.      endif    ;timeout 
  1112. ; 
  1113.     lxi    h,bymode    ; local con enabled? 
  1114.     bit    6,m 
  1115.     jrz    bcin1        ; Nope, skip 
  1116.     lda    lchar        ; Get local status 
  1117.     ora    a 
  1118.     jrz    bcin1        ; it was not local 
  1119.     push    psw 
  1120.     xra    a        ; clear local character 
  1121.     sta    lchar        ; hit. 
  1122.     pop    psw 
  1123.     ret 
  1124. bcin1:    jmp    mdinp 
  1125. ; 
  1126. bconout: 
  1127.     lxi    h,bymode    ; local con enabled? 
  1128.     bit    7,m        ; remote con enabled? 
  1129.     jrz    bcou1        ; nope, skip 
  1130.     push    h 
  1131.     push    b        ; in case of trashed char 
  1132.     call    carok        ; Check for carrier 
  1133.     jz    clrou        ; Fool dropped carrier on us 
  1134.     call    mconout 
  1135.     pop    b 
  1136.     pop    h 
  1137. ; 
  1138. bcou1:    bit    6,m 
  1139.     rz            ; nope, done 
  1140.     call    oconout        ; print it 
  1141.     ret 
  1142. ; 
  1143.      if    lstdev 
  1144. ; 
  1145. ;  Wheel check for List Device 
  1146. ; 
  1147. whlst:    sta    wlst        ; better to be safe than sorry. 
  1148.     lda    z3whl 
  1149.     ora    a        ; is wheel set? 
  1150.     lda    wlst 
  1151.     jz    mconout        ; nope, hope they like double characters. 
  1152.     jmp    olist        ; let's hope there's a printer out there. 
  1153. ; 
  1154. wlst:    ds    1 
  1155.      endif    ; lstdev 
  1156. ; 
  1157. ;  Modem Conout routine 
  1158. ; 
  1159. mconout: 
  1160.     call    mdoutst 
  1161.     jrz    mconout        ; wait till we can do it 
  1162.     mov    a,c 
  1163.     call    mdoutp        ; do it 
  1164.     ret 
  1165. ; 
  1166. ;---------------- Modem dependent routines start here ---------------------- 
  1167. ;
  1168. ; This should really be done as two entirely independent overlays -
  1169. ; one for smart (Hayes compatible) modems and one for dumb.  Then there
  1170. ; would be no need for the if-else-endif.
  1171. ;
  1172.      if    not dumb     ; smart "Hayes" modem
  1173. modans0    call    conin         ; wait for a character
  1174.     mov    b,a
  1175.     lda    lclst 
  1176.     ora    a        ; Was it a local char? 
  1177.     mov    a,b
  1178.     rnz            ; yes - return with nz flag
  1179.     lxi    h,bymode    ; We're probably going to set a mode soon 
  1180.     cpi    '2'        ; Is it a RING? 
  1181.     jrz    mdans1 
  1182.     cpi    '1'        ; How 'bout connect 300? 
  1183.     jrz    mdans3 
  1184.     cpi    '5'        ; connect 1200? 
  1185.     jrz    mdans4 
  1186.     cpi    '3'        ; No Carrier 
  1187.     jrnz    modans0
  1188.      if    etb
  1189.     xra    a        ; set z flag
  1190.     sta    carion        ; assume carrier on
  1191.      endif
  1192.     ret
  1193. ; 
  1194. mdans1:    res    6,m        ; turn off local console
  1195.     push    h 
  1196.     call    prinlo 
  1197.     db    'ATA',cr+80h    ; answer the phone 
  1198.     pop    h 
  1199.     setb    6,m        ; turn on local console
  1200.     jr    modans0 
  1201. mdans3:    call    set300 
  1202.     jrnz    mdans7
  1203.     jr    mdans5 
  1204. mdans4:    call    set1200
  1205.     jrnz    mdans7 
  1206. mdans5:    call    delay 
  1207.     res    5,m        ; Carrier enabled 
  1208.      if    etb
  1209.     mvi    a,0ffh
  1210.     sta    carion        ; mark 'carrier on'
  1211. ; If hardware carrier detect is available leave this in else remove it
  1212.     mvi    b,10        ; Check carrier for 1.0 seconds 
  1213. mdans6:    call    carok 
  1214.     jrz    mdans7 
  1215.     call    delay 
  1216.     djnz    mdans6 
  1217.      endif    ; etb
  1218.     ret 
  1219. mdans7:    lxi    h,bymode 
  1220.     call    nxtcal
  1221.     setb    5,m 
  1222.     xra    a
  1223.     ret 
  1224. ;
  1225. sync:    lxi    h,bymode 
  1226.     setb    7,m 
  1227.     setb    5,m        ; ignore carrier 
  1228.     setb    6,m        ; turn dual io on 
  1229.     ret
  1230. ;
  1231. ; check for incoming call
  1232. ;
  1233. incmcl:    call    bconst        ; char avail from modem? 
  1234.     rz            ; nope, continue
  1235. incmcl1    call    bconin        ; Get modem char 
  1236.     cpi    '2'        ; RING? 
  1237.     jrz    incmcl2
  1238.     xra    a        ; set z flag
  1239.     ret
  1240. incmcl2    lxi    h,bymode 
  1241.     setb    1,m 
  1242.     call    mdans1        ; Answer the phone 
  1243.     ori    0ffh        ; set nz flag
  1244.     ret
  1245. ;.............. this is the dumb modem overlay .....................
  1246.      else                 ; dumb modem
  1247. modans0    call    const 
  1248.     jrz     mdansC        ; got a character? 
  1249.     call    conin 
  1250.     mov    b,a
  1251.     lda    lclst 
  1252.     ora    a        ; Was it a local char? 
  1253.     mov    a,b
  1254.     rnz            ; yes 
  1255. mdansC    call    mdcarck        ; someone here? 
  1256.     jrz    modans0        ; if so, set baud 
  1257. mdans8:    mvi    b,5        ; five tries to get baud right 
  1258.     lxi    h,bymode 
  1259.     setb    6,m        ; enable console IO 
  1260.     setb    7,m        ; enable modem IO 
  1261. mdans9:    call    mdcarck        ; did they drop carrier? 
  1262.     rz    
  1263. ;
  1264.     push    b        ; save 'em 
  1265.     call    set300         ; try 300 baud
  1266.     call    conin 
  1267.     pop    b
  1268.     cpi    cr        ; did we get a CR? 
  1269.     rz
  1270. ;
  1271.     push    b
  1272.     call    set1200     ; try 1200 baud
  1273.     call    conin 
  1274.     pop    b
  1275.     cpi    cr        ; did we get a CR? 
  1276.     rz
  1277. ;
  1278.     djnz    mdans9 
  1279.     call    nxtcal        ; somethings confused, hang up on 'em 
  1280.     xra    a        ; set z flag
  1281.     ret 
  1282. ;
  1283. sync:    ret             ; just return if dumb modem
  1284. ;
  1285. incmcl:                ; check for incoming call
  1286.     call    mdcarck        ; someone on the line? 
  1287.     rz            ; nope
  1288.     call    mdans8        ; set up for dumb remote caller 
  1289.     ori    0ffh        ; set nz flag
  1290.     ret
  1291.      endif    ; dumb 
  1292. ;
  1293. ; If you can put the phone on-hook and off-hook via the UART then this
  1294. ; label and appropriate code should be in the UART overlay.
  1295. ;
  1296. ; The following code uses "smart" modem capabilities to compensate for
  1297. ; the fact that my UART is so dumb.   ETB
  1298. ;
  1299. mdansw
  1300.     lxi    h,bymode    ; save bymode
  1301.     mov    a,m
  1302.     push    psw
  1303.     setb    7,m        ; modem on
  1304.     res    6,m        ; console off
  1305.     setb    5,m
  1306.     mvi    b,15
  1307.     call    ldelay        ; wait 1.5 sec before +++
  1308.     call    prinlo
  1309.     db    '++','+'+80h    ; switch modem to command mode
  1310.     mvi    b,15
  1311.     call    ldelay        ; wait 1.5 sec after +++
  1312.     call    prinlo
  1313.     db    'ATH',cr+80h    ; hang up phone
  1314.     call    l2char        ; get echo (if any)
  1315.     call    l2char        ; get status
  1316.      if    etb
  1317.     lxi    h,carion
  1318.     mvi    m,0        ; set 'carrier off'
  1319.      endif
  1320.     lxi    h,bymode
  1321.     pop    psw        ; restore bymode
  1322.     mov    m,a
  1323.     ret
  1324. ;
  1325. ; .................................................................
  1326. ;
  1327. getc:    lxi    b,80*mhz    ; nr times to try
  1328.                 ; to get char from modem
  1329. ; the nr of times to try is sensitive to the speed of the const function
  1330. ; if zbye won't get started try raising the 80 to 160 or more.  The only
  1331. ; adverse effect should be to slow the program down some.
  1332. getc3    push    b
  1333.     call    const        ; check status
  1334.     pop    b
  1335.     ora    a
  1336.     jrnz    getc2        ; char avail?
  1337.     dcx    b        ; no - count tries
  1338.     mov    a,b
  1339.     ora    c
  1340.     jrnz    getc3        ; try again?
  1341.     stc            ; i'm exhausted, lets quit
  1342.     ret
  1343. getc2    call    conin        ; get the character
  1344.     ora    a        ; clear carry
  1345.     ret
  1346. ;
  1347. ; get characters from modem till it times out then test the last 2 chars
  1348. ; to see if they are '0' and car ret.
  1349. ;
  1350. l2char    lxi    h,0        ; get last 2 chars from modem
  1351. l2c2    push    h
  1352.     call    getc
  1353.     pop    h
  1354.     jrc    l2c1        ; no chars left
  1355.     mov    h,l
  1356.     mov    l,a
  1357.     jr    l2c2
  1358. l2c1
  1359.     mov    a,h
  1360.     cpi    '0'
  1361.     rnz
  1362.     mov    a,l
  1363.     cpi    cr
  1364.     ret
  1365. ;
  1366. ;------------------- Start of UART dependent routines ------------------ 
  1367. ; 
  1368. ; the following code is specific for ETB's modem port and would have
  1369. ; to be extensively modified for anyone else.
  1370. ;
  1371. dport    equ    0e3f8h        ; modem data port
  1372. sport    equ    dport+1        ; modem status port
  1373. ;
  1374. dav    equ    4        ; data available bit
  1375. tbmt    equ    8        ; transmit bufr empty bit
  1376. err    equ    13h        ; overrun, framing, and parity error bits
  1377. ;
  1378. ; This routine is supposed to "turn off everyting on the modem, hang it up,
  1379. ; and get it ready to wait for a RING. (DTR off)" but most of this is
  1380. ; either impossible or undesireable on mys system. ETB
  1381. ;
  1382. mdinit                ; initialize port
  1383.     lda    dport        ; discard existing data
  1384.     ret
  1385. ;
  1386. set300:                ; 300 baud not supported
  1387.     ori    0ffh
  1388.     ret
  1389. ;
  1390. set1200                ; set 1200 baud
  1391.     ora    a    
  1392.     ret
  1393. ;
  1394. ; The following uses software 'carrier detect' because ETB's system
  1395. ; does not provide hardware carrier detect.
  1396. ;
  1397. mdcarck
  1398.     lda    carion        ; is carrier on?
  1399.     ora    a
  1400.     ret
  1401. carion    db    0ffh        ; software 'carrier on' switch
  1402. ;
  1403. mdinst                ; modem input status
  1404.     lda    sport
  1405.     cma            ; invert bits
  1406.     mov    b,a        ; save status
  1407.     ani    dav        ; data available?
  1408.     rz            ; no
  1409.     mov    a,b        ; get stat back
  1410.     ani    err        ; check for errors
  1411.     jrz    mdinst1        ; noerror
  1412.     lda    dport        ; discard data
  1413.     xra    a        ; clear status
  1414.     ret
  1415. mdinst1    ori    0ffh        ; data avail
  1416.     ret
  1417. ;
  1418. mdinp                ; modem input 
  1419.     lda    dport        ; get data
  1420.     cma            ; invert bits
  1421.     ani    7fh        ; delete hi bit
  1422.     ret
  1423. ;
  1424. mdoutst                ; modem output status
  1425.     lda    sport        ; get status
  1426.     cma            ; invert bits
  1427.     ani    tbmt        ; buffer empty?
  1428.     ret
  1429. ;
  1430. mdoutp                ; modem output
  1431.     cma            ; invert bits
  1432.     sta    dport        ; send data
  1433.     ret
  1434. ;
  1435. ;----------------- Start of Terminal dependent routines-------------------
  1436. ; 
  1437. ; There are essentially 3 options available for printing status info on
  1438. ; the local console;
  1439. ;
  1440. ; 1) print it on the "25th line" where it will not scroll. This is obtained
  1441. ; by setting "statln equ yes" and then seeing to it that the code below
  1442. ; corresponds to your particular terminal configuration.
  1443. ;
  1444. ; 2) print it just like any other info and let it scroll. This is obtained
  1445. ; by setting "statln equ no".  This option makes absolutely no unusual
  1446. ; demands on the terminal and should run on any system.
  1447. ;
  1448. ; 3) don't print it at all.  This is obtained by converting the subroutine
  1449. ; prtsta into a dummy (ret instruction).  If desired you may then discard
  1450. ; most if not all of this overlay.
  1451. ;
  1452. ; These macros indicate the characters sequences to cause the specified
  1453. ; action on a specific terminal. You will probably have to change the 
  1454. ; data below if you wish to use "line 25". 
  1455. ;
  1456.      if    statln
  1457. curpos    macro    x,y,last    ; Position Cursor to X,Y (0 offset) 
  1458.     db    1bh,'=',' '+y,' '+x+(80h and last) 
  1459.     endm 
  1460. ; 
  1461. enab25    macro    last        ; Enable 25th line 
  1462.     db    1bh,'C','7'+(80h and last) 
  1463.     endm 
  1464. ; 
  1465. disab25    macro    last        ; Disable 25th line 
  1466.     db    1bh,'B','7'+(80h and last) 
  1467.     endm 
  1468. ; 
  1469. pucu    macro    last        ; Push cursor 
  1470.     db    1bh,'B','6'+(80h and last) 
  1471.     endm 
  1472. ; 
  1473. pocu    macro    last        ; Pop cursor 
  1474.     db    1bh,'C','6'+(80h and last) 
  1475.     endm 
  1476. ; 
  1477. cls    macro    last        ; Clear Screen 
  1478.     db    1ah+(80h and last) 
  1479.     endm 
  1480. ; 
  1481. curof    macro    last        ; Cursor off 
  1482.     db    1bh,'C','4'+(80h and last) 
  1483.     endm 
  1484. ; 
  1485. curon    macro    last        ; Cursor on 
  1486.     db    1bh,'B','4'+(80h and last) 
  1487.     endm 
  1488.      endif    ; statln
  1489. ;
  1490. ; . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
  1491. ;
  1492. ;
  1493. ; Print status information on the local terminal.  The calling sequence
  1494. ; is    call    prtsta
  1495. ;    db    m,string,n
  1496. ; where m is the column number on the screen where string is to be printed
  1497. ; followed by n blanks.
  1498. ;
  1499. prtsta:
  1500. ;    ret            ; to turn off all status reports
  1501.                 ; activate this ret instruction
  1502.     xthl
  1503.     mov    a,m        ; get ptr to column
  1504.     inx    h
  1505.     xthl
  1506.      if    statln        ; fancy terminal
  1507.     adi    ' '+80h
  1508.     sta    prtstax
  1509.     call    prinlc
  1510.     enab25    no        ; enable line 25
  1511.     pucu    no        ; push cursor
  1512.     curpos    0,24,yes    ; move cursor
  1513. prtstax    equ    $-1
  1514.      else            ; plain terminal
  1515.     mov    b,a
  1516.     ora    a        ; column 0?
  1517.     cnz    tab        ; print blanks til col is reached
  1518.      endif    ; statln
  1519. ;
  1520.     xthl            ; point to string
  1521. prtstas    mov    a,m        ; get next char in string
  1522.     inx    h        ; increment ptr
  1523.     cpi    32        ; end of string?
  1524.     jrc    prtsta2
  1525.     mov    c,a
  1526.     push    h
  1527.     call    oconout        ; print char on console
  1528.     pop    h
  1529.     jr    prtstas
  1530. prtsta2    xthl            ; return adr
  1531.     mov    b,a        ; nr blanks to print
  1532.     ora    a
  1533.     cnz    tab        ; print them
  1534. ;
  1535.      if    statln
  1536.     call    no25
  1537.      else
  1538.     call    prinlc
  1539.     dc    cr,lf
  1540.      endif    ;statln
  1541.     ret
  1542. ;
  1543. go25:
  1544.      if    statln
  1545.     call    prinlc 
  1546.     enab25    no         ; enable 25th line
  1547.     pucu    yes         ; push cursor
  1548.      endif    ; statln
  1549.     ret 
  1550. ;
  1551. no25:
  1552.      if    statln
  1553.     call    prinlc 
  1554.     pocu    no         ; pop cursor
  1555.     disab25    yes         ; disable 25th line
  1556.      endif    ; statln 
  1557.     ret
  1558. ;
  1559. cursoff:
  1560.      if    statln
  1561.     call    prinlc
  1562.     curoff    yes        ; cursor off
  1563.      endif    ; statln
  1564.     ret
  1565. ;
  1566. curson:
  1567.      if    statln
  1568.     call    prinlc
  1569.     curon    yes        ; cursor on
  1570.      endif    ; statln
  1571.     ret
  1572. ;
  1573. clrscr:
  1574.      if    statln
  1575.     call    prinlc        ; clear screen
  1576.     cls    yes
  1577.      endif    ; statln
  1578.     ret
  1579. ; 
  1580. ; Print (on local console) number of spaces contained in B register. 
  1581. ; 
  1582. tab:
  1583.     push    b 
  1584.     mvi    c,' ' 
  1585.     call    oconout 
  1586.     pop    b 
  1587.     djnz    tab 
  1588.     ret 
  1589. ;
  1590. ;-------------------- End of terminal dependent routines ---------------------
  1591. ;
  1592. ;    .z80 
  1593. ; 
  1594. ;     if2    ; this is turned off because I use a one pass assembler ETB 
  1595.      if    $ ge (rcp+rcps*128) 
  1596.     .printx ->This RCP is too large, don't try to run it.<- 
  1597.      endif 
  1598. ;     endif 
  1599. ; 
  1600.     .dephase 
  1601. byend: 
  1602.     end 
  1603. cp+rcps*128) 
  1604.     .    cls    yes
  1605.      endif    ; statln
  1606.     ret
  1607. ; 
  1608. ; Print (on local console) number of spaces contained in B register. 
  1609. ; 
  1610. tab:
  1611.     push    b 
  1612.     mvi    c,' ' 
  1613.     call    oconout 
  1614.     pop    b 
  1615.     djnz    tab 
  1616.     ret 
  1617. ;
  1618. ;-------------------- End of terminal dependent routines ---------