home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / z3sys / rcpspace.lbr / RCPSPACE.AQM / RCPSPACE.AZM
Encoding:
Text File  |  1993-06-08  |  5.0 KB  |  229 lines
  1. ; SPACE routine for Z-systems RCP. 3-24-86 by Carson Wilson
  2. ; This routine is written as a complete program for demonstration and
  3. ; testing purposes. 
  4. ;
  5. ; It is written in in the Z80 instruction set, and is compatible with
  6. ; public domain ZASM.COM or Z80MR.COM.
  7. ; 
  8. ; To insert the SPACE procedure into your RCP, follow instructions marked with
  9. ; '*' below.
  10. ;
  11. ; * omit the next 3 lines for RCP: ---------
  12. bdos    equ    5
  13. fcb1    equ    5ch
  14.     org    100h
  15. ;
  16. ctab1:
  17. ; * remove ';'s and insert the following 2 lines at the beginning of 
  18. ;   "ctab1" in RCP:
  19. ;    db    'S   '        ; get disk space on current drive
  20. ;    dw    space        ; C. Wilson
  21. ;
  22. ; * insert the following 153 lines at the beginning of the list of routines
  23. ;   in your RCP.    -----------------
  24. ;
  25. ;SPACE shows space remaining on logged drive
  26. ; * remove semicolons from next 2 lines:
  27. ;crSPACE:            ; used to call SPACE after other subroutines
  28. ;    call    crlf        ; (e.g., CP, ERA) 
  29. SPACE:    
  30. getdsk:    call    print
  31.     db    'Space on',(' '+80h)
  32.  
  33.     ld    a,(fcb1)
  34.     cp    0        ; drive explicitly selected?
  35.     jr    nz,skip        ; yes
  36.  
  37.     ld    c,25
  38.     call    bdos        ; get current disk
  39.     jr    skip2
  40.  
  41. skip:    sub    1        ; subtract 1 from A
  42. skip2:    ld    e,a
  43.  
  44.      add    a,65
  45.     call    conout
  46.  
  47.     ld    c,14        ; select disk
  48.     call    bdos        ; not needed if no drive selected, but smallest
  49.                 ; possible code size this way.
  50.     call    print
  51.     db    ':',(' '+80h)
  52. ;
  53. ;*  THIS ROUTINE EXTRACTS DISK PARAMETER INFORMATION FROM THE DPB AND
  54. ;*    STORES THIS INFORMATION IN:
  55. ;*    BLKSHF    <-- BLOCK SHIFT FACTOR (1 BYTE)
  56. ;*    BLKMAX    <-- MAX NUMBER OF BLOCKS ON DISK (2 BYTES)
  57. ;*
  58. DPARAMS:
  59. ;*
  60. ;*  VERSION 2.x OR MP/M
  61. ;*
  62.     LD    C,31        ; 2.x OR MP/M...REQUEST DPB
  63.     CALL    BDOS
  64.     INC    HL
  65.     INC    HL
  66.     LD    A,(HL)        ; GET BLOCK SHIFT
  67.     LD    (BLKSHF),A    ; BLOCK SHIFT FACTOR
  68.     INC    HL        ; GET BLOCK MASK
  69.     INC    HL
  70.     INC    HL
  71.     LD    E,(HL)        ; GET MAX BLOCK NUMBER
  72.     INC    HL
  73.     LD    D,(HL)
  74.     EX    DE,HL
  75.     INC    HL        ; ADD 1 FOR MAX NUMBER OF BLOCKS
  76.     LD    (BLKMAX),HL    ; MAXIMUM NUMBER OF BLOCKS
  77. ;*
  78. ;*  PARAMETERS EXTRACTED
  79. ;*  COMPUTE AMOUNT OF FREE SPACE LEFT ON DISK
  80. ;*    THE DPARAMS ROUTINE MUST BE CALLED BEFORE THIS ROUTINE IS USED
  81. ;*
  82. DFREE:
  83.     LD    C,27    ; GET ADDRESS OF ALLOCATION VECTOR
  84.     CALL    BDOS
  85.     EX    DE,HL
  86.     LD    HL,(BLKMAX)    ; GET LENGTH OF ALLOCATION VECTOR
  87.     LD    BC,0    ; INIT BLOCK COUNT TO 0
  88. ;*
  89. ;*  BC IS ACCUMULATOR FOR SPACE
  90. ;*
  91. FREE1:
  92.     PUSH    DE    ; SAVE ALLOC ADDRESS
  93.     LD    A,(DE)    ; GET BIT PATTERN OF ALLOCATION BYTE
  94.     LD    E,8    ; SET TO PROCESS 8 BLOCKS
  95. FREE2:
  96.     RLA        ; ROTATE ALLOCATED BLOCK BIT INTO CARRY FLAG
  97.     jr    C,FREE3    ; IF SET (BIT=1), BLOCK IS ALLOCATED
  98.     INC    BC    ; IF NOT SET, BLOCK IS NOT ALLOCATED, SO INCREMENT
  99.             ;   FREE BLOCK COUNT
  100. FREE3:
  101.     LD    D,A    ; SAVE REMAINING ALLOCATION BITS IN D
  102.     DEC    HL    ; COUNT DOWN NUMBER OF BLOCKS ON DISK
  103.     LD    A,L
  104.     OR    H
  105.     jr    Z,FREE4    ; DONE IF NO MORE BLOCKS LEFT
  106.     LD    A,D    ; A=CURRENT ALLOCATION BIT PATTERN
  107.     DEC    E    ; HAVE ALL 8 BITS BEEN EXAMINED?
  108.     jr    NZ,FREE2    ; CONTINUE IF NOT
  109.     POP    DE    ; GET POINTER TO ALLOCATION VECTOR
  110.     INC    DE    ; POINT TO NEXT ALLOCATION BYTE
  111.     jr    FREE1    ; CONTINUE BY PROCESSING NEXT ALLOCATION BYTE
  112. ;*
  113. ;*  BC = TOTAL AMOUNT OF FREE SPACE IN TERMS OF BLOCKS
  114. ;*
  115. FREE4:
  116.     POP    DE    ; CLEAR DE FROM STACK
  117.     LD    L,C    ; HL=BC=NUMBER OF FREE BLOCKS
  118.     LD    H,B
  119.     LD    A,(BLKSHF)    ; GET BLOCK SHIFT FACTOR
  120.     SUB    3    ; CONVERT NUMBER OF BLOCKS TO K
  121.     jr    Z,FREE6    ; DONE IF SINGLE DENSITY (1K PER BLOCK)
  122.  
  123. ;*
  124. ;*  WE ARE AT A MORE ADVANCED DENSITY LEVEL; MULTIPLY THE NUMBER OF BLOCKS
  125. ;*    BY THE SIZE OF A BLOCK IN K
  126. ;*
  127. FREE5:
  128.     ADD    HL,HL    ; 2, 4, 8, 16, ETC K/BLK, SO BLOCK SHIFT FACTOR
  129.     DEC    A    ;   IS A POWER-OF-TWO MULTIPLE
  130.     JR    NZ,FREE5
  131. ;*
  132. ;*  AT THIS POINT, HL=AMOUNT OF FREE SPACE ON DISK IN K
  133. ;*
  134. FREE6:
  135. ;
  136. DECOUT:            ; output free space in decimal
  137.     ld    b,0
  138.     ld    de,-10000    
  139.     call    subtr    
  140.     ld    de,-1000
  141.     call    subtr
  142.     ld    de,-100
  143.     call    subtr
  144.     ld    de,-10
  145.     call    subtr
  146.     ld    a,l
  147.     add    a,'0'        ; ASCII bias
  148.     call    conout
  149.     ld    a,'k'
  150.     call    conout
  151.     ret            ; final return from SPACE routine
  152. ;
  153. subtr:    ld    c,'0'-1
  154. subt2:    inc    c
  155.     add    hl,de
  156.     jr    c,subt2
  157.     or    a
  158.     sbc    hl,de
  159.     ld    a,c
  160.     cp    '1'
  161.     jr    nc,nzero
  162.     ld    a,b
  163.     or    a
  164.     ld    a,c
  165.     ret    z
  166.     call    conout
  167.     ret
  168. ;        
  169. nzero:    ld    b,0ffh
  170.     call    conout
  171.     ret
  172. ;
  173. blkshf:    db    0
  174. blkmax:    dw    0
  175. ;
  176. ; * RCP IMPLANT ENDS HERE --------------------------    
  177. ;   CRLF, CONOUT, AND PRINT should already be implemented in your RCP, so
  178. ;   omit these procedures from implant.
  179. ; 
  180.  
  181. crlf:    call    print
  182.     db    0dh,(0ah+80h)
  183.     ret
  184. ;
  185. ;  Console Output Routine
  186. ;
  187. conout:
  188.     push    hl        ; save regs
  189.     push    de
  190.     push    bc
  191.     push    af
  192.     and    7fh        ; mask MSB
  193.     ld    e,a        ; char in E
  194.     ld    c,2        ; output
  195.     call    bdos
  196.     pop    af        ; get regs
  197.     pop    bc
  198.     pop    de
  199.     pop    hl
  200.     ret
  201. ;
  202. ;  Print String (terminated in 0 or MSB Set) at Return Address
  203. ;
  204. print:
  205.     ex    (sp),hl        ; get address
  206.     call    print1
  207.     ex    (sp),hl        ; put address
  208.     ret
  209. ;
  210. ;  Print String (terminated in 0 or MSB Set) pted to by HL
  211. ;
  212. print1:
  213.     ld    a,(hl)        ; done?
  214.     inc    hl        ; pt to next
  215.     or    a        ; 0 terminator
  216.     ret    z
  217.     call    conout        ; print char
  218.     ret    m        ; MSB terminator
  219.     jr    print1
  220. ;
  221.  
  222. ; * omit this end statement for RCP, of course. 
  223.     end
  224.     call    conout        ; print char
  225.     ret    m        ; MSB terminator
  226.     jr    print1
  227. ;
  228.  
  229. ; * omit this end statement