home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / z3lib / freset10.asm < prev    next >
Encoding:
Assembly Source File  |  1993-06-07  |  3.8 KB  |  139 lines
  1. ; Routine:    FRESET -- fast drive reset and login
  2. ; Author:    Bridger Mitchell (Plu*Perfect Systems)
  3. ; CPU:        Z80-compatible
  4. ; Date:        January 2, 1988
  5. ; Version:    1.0
  6. ; 
  7. ; This routine (fast-)resets and logs in the CP/M drive in register
  8. ; (A).  When possible, it uses BDOS function 37 (logoff drives). 
  9. ; In most cases FRESET is significantly faster than using function 13
  10. ; (reset all drives) to do a general reset.
  11. ; 
  12. ; FRESET functions correctly with Digital Research's CP/M 2.2 BDOS,
  13. ; which contains a bug that does not allow the logged-in drive to
  14. ; be reset with function 37.
  15. ; 
  16. ; Some CP/M BDOS emulators (such as ZRDOS, PZDOS, ...) have changed
  17. ; the operation of the general-reset function 13, in order to speed
  18. ; up warm-boots and disk-resets on systems with hard-drives. In this
  19. ; case, a non-removable drive (hard disk, ram disk), after it
  20. ; has been initially logged in, remains logged in after a general
  21. ; reset.
  22. ; 
  23. ; On such systems it is **essential** that any program that uses
  24. ; BIOS disk functions to write to a non-removable drive also cause
  25. ; the disk's allocation map to be rebuilt before any BDOS disk
  26. ; functions are used.  DU (DU3) and UNERASE are probably the most
  27. ; common examples of such programs; they modify the disk directory.
  28. ; For these systems, the drive must first be logged off with
  29. ; function 37 and then logged in.  Calling FRESET within such
  30. ; programs will ensure that the disk's allocation map is recomputed.
  31. ; 
  32. ; The FRESET algorithm:
  33. ;
  34. ;   if requested_drive is logged in
  35. ;     if a second drive is logged in
  36. ;         log into the second drive
  37. ;     logoff requested drive (fn.37)
  38. ;         if no second drive was logged in
  39. ;         do general reset (fn. 13)    
  40. ;   log into requested drive
  41. ; 
  42. ; Note:  Unnumbered version dated 12/27/87 did not provide for
  43. ; logging out the drive in one special case, namely when only that
  44. ; one drive is currently logged in.  Thanks to Howard Goldstein
  45. ; for spotting the problem.
  46. ;
  47. xbdos    equ    5
  48.  
  49. ;    Fast-reset drive (A)
  50. ;    A = 0 ... 15  for  A: ... P:
  51. ;    
  52. CSEG
  53. freset:
  54.     ld    (reqdrv),a    ; save requested drive
  55.     push    af
  56.     ld    c,24        ; get vector of logged-in drives
  57.     call    xbdos
  58.     pop    af        ; (recover requested drive)
  59.     push    hl        ; save logged-in vector
  60.     call    fshftr        ; shift requested drive's bit to bit 0
  61.     bit    0,l        ; is requested drive logged in?
  62.     pop    hl        ;  (recover (unshifted) logged vector)
  63.     jr    z,flogit    ; ..z - no, just log it in
  64.     ld    e,0        ;  initialize drive index/count
  65.     jr    frese2
  66. ;
  67. frese1:    ld    a,1        ; shift vector right 1 bit
  68.     call    fshftr
  69. frese2:    bit    0,l        ; if drive is not logged in
  70.     jr    z,frese3    ; ..check next drive
  71.     ld    a,(reqdrv)    ; or if it is the requested drive
  72.     cp    e        ; 
  73.     jr    z,frese3    ; ..check next drive
  74. ;
  75. ; found a second logged-in drive, so switch to it
  76. ;
  77.     call    fslctit        ; select e'th drive
  78.     call    flogout        ; log out requested drive
  79.     jr    flogit        ; then log into it and exit.
  80. ;
  81. frese3:    inc    e        ; increment drive count
  82.     ld    a,e        
  83.     cp    16
  84.     jr    c,frese1    ; .. and continue for 16 drives 
  85. ;
  86. ; no second drive found,
  87. ;
  88.     call    flogout        ; log out requested drive
  89.     ld    c,13        ; do general reset, then (re)log requested
  90.     call    xbdos        ; 
  91. ;
  92. ; log into requested drive
  93. ;
  94. flogit:    ld    a,(reqdrv)
  95.     ld    e,a
  96. ;
  97. fslctit:ld    c,14        ; select bdos drive
  98. jxbdos:    jp    xbdos    
  99. ;
  100. ; log out the requested drive
  101. ;
  102. flogout:ld    a,(reqdrv)    ; set up bit to log out drive
  103.     ld    hl,1
  104.     call    fshftl
  105.     ex    de,hl
  106.     ld    c,37        ; log out drive in DE vector
  107.     jr    jxbdos
  108. ;
  109. ;
  110. ; shift hl right (a) bits
  111. ;
  112. fshftr:
  113.     inc    a
  114. shftr1:    dec    a
  115.     ret    z
  116.     srl    h
  117.     rr    l    
  118.     jr    shftr1
  119. ;
  120. ;
  121. ; shift hl left (a) bits
  122. ;
  123. fshftl:
  124.     inc    a
  125. shftl1:    dec    a
  126.     ret    z
  127.     add    hl,hl
  128.     jr    shftl1    
  129.  
  130. ;--------------------
  131. DSEG
  132. reqdrv:    ds    1
  133.  
  134.     end
  135.     z,frese3    ; ..check next drive
  136. ;
  137. ; found a second logged-in drive, so switch to it
  138. ;
  139.     call    fslctit        ; select e'