home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / uploads / zslsrc36.lbr / ZFILEIO.ZZ0 / ZFILEIO.Z80
Encoding:
Text File  |  1992-02-04  |  11.5 KB  |  384 lines
  1. ; Library:    ZSLIB
  2. ; Version:    3.5
  3. ; Module:    ZFILEIO
  4. ; Version:    1.0
  5. ; Author:    Gene Pizzetta
  6. ; Date:        December 15, 1991
  7. ; Changes:    Based on SYSLIB 3.6 SFILEIO module by Richard Conn and Al
  8. ;        Dunsmuir.  Added drive and user support.  Code is heavily
  9. ;        modified and tightened for a considerable size savings.
  10. ;
  11. ; This module is for internal use by the byte-oriented file I/O routines
  12. ; in the Z0FILE to Z3FILE modules.  Entry points here are not appropriate
  13. ; for calling from user programs.
  14. ; 
  15. ; FR@OPEN, FW@OPEN -- Open files for byte-oriented input and output.
  16. ; FR@CLOSE, FW@CLOSE -- Close files after byte-oriented input and output.
  17. ; F@GET -- Returns next byte from the input file.
  18. ; F@PUT -- Inserts a byte into the output file.
  19. ;
  20. ; The open routines obtain the current drive and user area from the DOS
  21. ; store them in the control table.  The other routines log into the drive
  22. ; and user in the control table whenever disk access is needed; no further
  23. ; attention need be paid to the drive/user by the calling routines or by
  24. ; the programmer.
  25. ;
  26. ; Only the first 12 bytes of the user's file control block are significant
  27. ; when opening a file.  The open routines use only the filename and filetype;
  28. ; the drive byte is ignored.  Once a file is open, its original file control
  29. ; block is no longer referenced.  Thus a single abbreviated FCB may be used
  30. ; and re-used to open multiple files.  Both an input and output file can be
  31. ; opened from the default file control blocks at 5Ch and 6Ch without moving
  32. ; the filenames.
  33. ;
  34. ; Do not use the same buffer for both input and output.
  35. ;
  36. ; Error Diagnostics are returned to the caller via the zero flag and the A
  37. ; register.  If the zero flag is set (Z), it always means no error occurred
  38. ; and the A register contains either 0 or the required returned value.  If
  39. ; the zero flag is reset (NZ), the A register contains an error code and no
  40. ; other register value should be considered to be valid.  The returned error
  41. ; codes in A are as follows:
  42. ;
  43. ;     Code    Meaning
  44. ;    1    Get or put attempted on unopened file (F@GET and F@PUT)
  45. ;    2    Disk full (F@PUT and FW@OPEN)
  46. ;    3    Input file not found (FR@OPEN)
  47. ;    4    End of file (F@GET) or input file empty (FR@OPEN)
  48. ;    5    Directory full (FW@OPEN)
  49. ;    6    Error in closing a file (FR@CLOSE and FW@CLOSE)
  50. ;    7    Attempt to open file that is already open (FR@OPEN and FW@OPEN)
  51. ;
  52. ; Error code 1 is actually returned to the program by the calling routines
  53. ; in the ZnFILE modules and not by the routines in this module.  Error code
  54. ; 4 for F@GET is not really an error, but indicates that the end of the file
  55. ; has been reached and there is no more data.  F@GET, F@PUT, and the close
  56. ; routines are not called by the ZnFILE routines if the file is not open
  57. ; (an attempt to close an unopened file does nothing, but returns no error).
  58. ;
  59. ; FR@OPEN -- Opens file for input.
  60. ; Entry:  DE = address of FCB, HL = address of input control table,
  61. ;      Zero flag reset (NZ) if file already opened
  62. ; Exit:      A = 0, zero flag set (Z) if okay
  63. ;      A = code, zero flag reset (NZ) if error
  64. ;        3 = file not found
  65. ;        4 = file empty
  66. ;        7 = file already open
  67. ; Uses:      AF, HL
  68. ;
  69. ; FW@OPEN -- Open file for output.
  70. ; Entry:  DE = address of FCB, HL = address of output control table
  71. ;      Zero flag reset (NZ) if file already opened
  72. ; Exit:      A = 0, zero flag set (Z) if okay
  73. ;      A = code, zero flag reset (NZ) if error
  74. ;        5 = directory full
  75. ;        7 = file already open
  76. ; Uses:      AF, HL
  77. ;
  78. ; FR@CLOSE -- Close file opened for input.
  79. ; Entry:  HL = address of input control table
  80. ; Exit:      A = 0, zero flag set (Z) if okay
  81. ;      A = code, zero flag reset (NZ) if error
  82. ;        6 = close error
  83. ; Uses:      AF, HL
  84. ;
  85. ; FW@CLOSE -- Close file opened for output.
  86. ; Entry:  HL = address of output control table
  87. ; Exit:      A = 0, zero flag set (Z) if okay
  88. ;      A = code, zero flag reset (NZ) if error
  89. ;        2 = disk full
  90. ;        6 = close error
  91. ; Uses:      AF, HL
  92. ;
  93. ; F@GET -- Get byte from input file.
  94. ; Entry:  HL = address of input control table
  95. ;      HL should have been pushed onto the stack
  96. ; Exit:      A = byte, zero flag set (Z) if okay
  97. ;      A = code, zero flag reset (NZ) if error
  98. ;        4 = end of file (not really an error)
  99. ;      HL is popped from the stack
  100. ; Uses:      AF
  101. ;
  102. ; F@PUT -- Put byte in A into output file.
  103. ; Entry:  A = byte
  104. ;      HL = address of output control table
  105. ;      HL should have been pushed onto stack
  106. ; Exit:      A = byte, zero flag set (Z) if okay
  107. ;      A = code, zero flag reset (NZ) if error
  108. ;        2 = disk full
  109. ;      HL is popped from the stack
  110. ; Uses:      AF
  111. ;
  112.     PUBLIC    FR@OPEN,FR@CLOSE,F@GET
  113.     PUBLIC    FW@OPEN,FW@CLOSE,F@PUT
  114. ;
  115.     EXTRN    SETDMA,INITFCB,RETUD,LOGUD        ; SYSLIB
  116.     EXTRN    F$OPEN,F$MOPEN,F$CLOSE,F$READ,F$WRITE
  117. ;
  118. Bdos    equ    5        ; BDOS entry
  119. CpmDma    equ    80h        ; default DMA buffer
  120. CpmEof    equ    1Ah        ; CP/M end of file (^Z)
  121. ;
  122. ; FR@OPEN -- Opens file for input.
  123. ;
  124. FR@OPEN:
  125.     ld    a,7        ; error code (already open error)
  126.     ret    nz        ; (if so, exit)
  127.     push    bc        ; save BC, DE
  128.     push    de
  129.     call    iniopn        ; prepare for open
  130.     call    F$OPEN        ; open file
  131.     ld    a,3        ; error code (input file not found)    
  132.     jr    nz,fexit    ; (if so, exit)
  133.     call    rdblk        ; read first block
  134.     jr    z,fopen1    ; (OK, so set up file table)
  135.     ld    a,4        ; error code (file empty)
  136.     jr    fexit
  137. ;
  138. ; FW@OPEN -- Open file for output.
  139. ;
  140. FW@OPEN:
  141.     ld    a,7        ; error code (file already open)
  142.     ret    nz        ; (if so, exit)
  143.     push    bc        ; save BC, DE
  144.     push    de
  145.     call    iniopn        ; prepare for open
  146.     call    F$MOPEN        ; open or create file
  147.     ld    a,5        ; error code (directory full)
  148.     jr    nz,fexit    ; (if so, exit)
  149. ;
  150. fopen1:    ld    hl,(iotbl)    ; get address of control table
  151.     inc    hl        ; set character count
  152.     inc    hl
  153.     ld    (hl),128
  154.     inc    hl        ; point to character pointer
  155.     ex    de,hl        ; ..and move it to DE
  156.     ld    hl,36+2        ; get buffer address
  157.     add    hl,de
  158.     ex    de,hl        ; ..into DE
  159.     ld    (hl),e        ; save buffer start address
  160.     inc    hl
  161.     ld    (hl),d
  162.     xor    a        ; file opened OK, so fall through
  163. ;
  164. fexit:    pop    de        ; restore registers
  165.     pop    bc
  166.     or    a        ; set flags
  167.     ret
  168. ;
  169. ; FR@CLOSE -- Close file opened for input.
  170. ;
  171. FR@CLOSE:
  172.     push    bc        ; save BC, DE
  173.     push    de
  174.     call    setdu
  175. ;
  176. close1:    inc    hl        ; get FCB address
  177.     inc    hl
  178.     inc    hl
  179.     ex    de,hl        ; ..in DE
  180.     call    F$CLOSE        ; close file
  181.     ld    a,6        ; error code (close error)
  182.     jr    nz,fexit    ; (if so, exit)
  183.     xor    a        ; input/output file closed OK
  184.     jr    fexit        ; restore registers and exit
  185. ;
  186. ; FW@CLOSE -- Close file opened for output.
  187. ;
  188. FW@CLOSE:
  189.     push    bc        ; save BC, DE
  190.     push    de
  191.     ld    (iotbl),hl    ; save output control table address
  192.     call    setdu
  193.     ld    a,(hl)        ; get bytes remaining (buffer free space count)
  194.     cp    128
  195.     jr    z,close1    ; (if buffer is empty, close)
  196.     ld    a,CpmEof    ; put ^Z
  197.     call    FPutI
  198. closlp:    ld    a,(hl)        ; get number of bytes remaining
  199.     cp    128
  200.     jr    z,close1    ; (if block just written, close)
  201.     xor    a        ; put zeroes to fill buffer
  202.     call    FPutI
  203.     jr    closlp        ; loop while space remains
  204. ;
  205. ; FPutI - Internal call to F@PUT with stack management
  206. ;
  207. FPutI:    push    hl        ; save HL
  208.     ld    hl,(iotbl)    ; get address of output control table
  209. ;
  210. ; F@PUT -- Put byte in A into output file.
  211. ;
  212. F@PUT:    push    bc        ; save BC, DE
  213.     push    de
  214.     ld    (byte),a    ; save byte to output
  215.     ld    (iotbl),hl    ; save address of output control table
  216.     inc    hl        ; ->user
  217.     inc    hl        ; pt to char pointer
  218.     inc    hl
  219.     ld    e,(hl)        ; get char pointer
  220.     inc    hl
  221.     ld    d,(hl)
  222.     ld    a,(byte)    ; get byte to output
  223.     ld    (de),a        ; PUT data byte
  224.     inc    de        ; pt to next output byte
  225.     ld    (hl),d        ; update current Output buffer address
  226.     dec    hl
  227.     ld    (hl),e
  228.     dec    hl        ; pt to buffer data count
  229.     dec    (hl)        ; decrement count
  230.     jr    nz,gpexit    ; (exit if space remains in buffer)
  231. ;
  232. ; Output buffer is full, so write it and reset pointers and count
  233. ;
  234.     ld    (hl),128    ; set char count
  235.     inc    hl        ; pt to char pointer
  236.     ex    de,hl        ; ..in DE
  237.     ld    hl,36+2        ; get buffer address
  238.     add    hl,de
  239.     ex    de,hl        ; ..in DE
  240.     ld    (hl),e        ; save buffer start address
  241.     inc    hl
  242.     ld    (hl),d
  243.     call    wrtblk        ; write next block
  244.     jr    z,gpexit    ; (PUT completed OK, exit)
  245.     ld    a,2        ; error code (disk full)
  246. gperr:    or    a        ; reset zero flag
  247.     jr    gpxit2
  248. ;
  249. ; F@GET -- Get byte from input file.
  250. ;
  251. F@GET:    push    bc        ; save BC, DE
  252.     push    de
  253.     ld    (iotbl),hl    ; save address of input control table
  254.     inc    hl
  255.     inc    hl        ; point to character pointer
  256.     inc    hl
  257.     ld    e,(hl)        ; get character pointer
  258.     inc    hl
  259.     ld    d,(hl)
  260.     ld    a,d        ; EOF was reached if pointer is zero
  261.     or    e
  262.     ld    a,4        ; error code (end of file)
  263.     jr    z,gperr        ; (end of file, exit)
  264.     ld    a,(de)        ; GET data byte
  265.     ld    (byte),a    ; save byte for return
  266.     inc    de        ; point to next input byte
  267.     ld    (hl),d        ; update current input buffer address
  268.     dec    hl
  269.     ld    (hl),e
  270.     dec    hl        ; point to buffer data count
  271.     dec    (hl)        ; decrement count
  272.     jr    nz,gpexit    ; exit if data remains in buffer
  273. ;
  274. ; Input buffer empty, so read next block and reset pointers and count
  275. ;
  276.     ld    (hl),128    ; set char count
  277.     inc    hl        ; point to char pointer
  278.     ex    de,hl        ; ..in DE
  279.     ld    hl,36+2        ; get buffer address
  280.     add    hl,de
  281.     ex    de,hl        ; ..in DE
  282.     ld    (hl),e        ; save buffer start address
  283.     inc    hl
  284.     ld    (hl),d
  285.     call    rdblk        ; read next block
  286.     jr    z,gpexit    ; (all okay)
  287.     ld    hl,(iotbl)    ; get address of input/output control table
  288.     inc    hl
  289.     inc    hl        ; point to character pointer
  290.     inc    hl
  291.     ld    (hl),0        ; zero indicates EOF reached
  292.     inc    hl
  293.     ld    (hl),0
  294. ;
  295. ; Exits for GET or PUT
  296. ;
  297. gpexit:    xor    a        ; all is okay
  298.     ld    a,(byte)    ; get data byte to return
  299. gpxit2:    pop    de        ; restore registers
  300.     pop    bc
  301.     pop    hl        ; HL was saved before entry
  302.     ret
  303. ;
  304. ; Subroutines . . .
  305. ;
  306. ; rdblk -- Read block from input file into input buffer.
  307. ; Entry:  None
  308. ; Exit:      Zero flag set (Z) if okay, zero flag reset (NZ) if end of file
  309. ; Uses:      AF, BC, DE, HL
  310. ;
  311. rdblk:    ld    de,(iotbl)    ; get input control table address into DE
  312.     ld    hl,36+2+1+2    ; get buffer address into HL
  313.     add    hl,de
  314.     call    SETDMA
  315.     ex    de,hl        ; control table address to HL
  316.     call    setdu        ; log into file directory
  317.     ex    de,hl
  318.     inc    de        ; point to input FCB
  319.     inc    de
  320.     inc    de
  321.     call    F$READ        ; read in a block from file
  322.     ld    hl,CpmDma    ; reset DMA address (for compatability)
  323.     jp    SETDMA        ; return Z to caller if read okay
  324. ;
  325. ; wrtblk -- Write block from output buffer into output file.
  326. ; Entry:  None
  327. ; Exit:      Zero flag set (Z) if okay, zero flag reset (NZ) if disk full
  328. ; Uses:      AF, BC, DE, HL
  329. ;
  330. wrtblk:    ld    de,(iotbl)    ; get output control table address into DE
  331.     ld    hl,36+2+1+2    ; get buffer address into HL
  332.     add    hl,de
  333.     call    SETDMA
  334.     ex    de,hl        ; control table address to HL
  335.     call    setdu        ; log into file directory
  336.     ex    de,hl
  337.     inc    de        ; get address of output FCB
  338.     inc    de
  339.     inc    de
  340.     call    F$WRITE        ; write block to file
  341.     ld    hl,CpmDma    ; reset DMA address (for compatability)
  342.     jp    SETDMA        ; return Z to caller if write okay
  343. ;
  344. ; iniopn -- Gets file directory, moves filename, and initializes FCB for
  345. ; open routines.
  346. ; Entry:  HL = address of input control table, DE = address of user's FCB
  347. ; Exit:      DE = address of our FCB
  348. ; Uses:      BC, DE, HL
  349. ;
  350. iniopn:    ld    (iotbl),hl    ; save address of input control table
  351.     call    RETUD        ; get drive and user
  352.     ld    (hl),b
  353.     inc    hl
  354.     ld    (hl),c
  355.     inc    hl        ; point to open FCB
  356.     inc    hl
  357.     inc    hl
  358.     inc    hl
  359.     push    hl        ; save our FCB pointer
  360.     ld    bc,12        ; we only need the first 12 bytes
  361.     ex    de,hl        ; HL = user's FCB, DE = our FCB
  362.     ldir
  363.     pop    de        ; get our FCB pointer into DE
  364.     jp    INITFCB        ; initialize FCB and return
  365. ;
  366. ; setdu -- Sets drive and user for current file.
  367. ; Entry:  HL = address of drive byte, followed by user byte.
  368. ; Return:  HL = address of byte following user.  Also uses BC.
  369. ;
  370. setdu:    ld    b,(hl)        ; get drive
  371.     inc    hl
  372.     ld    c,(hl)        ; get user
  373.     inc    hl
  374.     jp    LOGUD        ; jump and return to caller
  375. ;
  376. ; Storage for all global routines
  377. ;
  378.     DSEG
  379. ;
  380. iotbl:    ds    2        ; address of input/output control table
  381. byte:    ds    1        ; data byte storage
  382. ;
  383.     end
  384.