home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / uploads / xbnote.lbr / NZPAT.ZZ0 / NZPAT.Z80
Encoding:
Text File  |  1990-12-07  |  4.3 KB  |  162 lines
  1. ;
  2. ; Patch Overlay for NZCOM.COM            AWH
  3. ;
  4. ;    1) Patch location 280H to connect the XBIOS BSX jumps
  5. ;       to the DOS installed ( ZSDOS )
  6. ;    2) Patch path to B0: $$ B0:, as system boots with RAM disk A:
  7. ;    3) Patch command line to B0:STARTZCM
  8. ;
  9. ;    Revision 1.0        5  Dec 90    Release
  10. ;
  11. ; Patch origins:
  12. ; 
  13. patch1     equ    0280H        ; user patch area
  14. patch2     equ    0680H        ; path
  15. patch3     equ    0690H        ; command line
  16. ;
  17. ; the ususal:
  18. ;
  19. cr    equ    0dH        
  20. lf    equ    0aH
  21. ;
  22. ; cp/m locations:
  23. ;
  24. os$base    equ    0        ; memory base
  25. biospg    equ    os$base+2    ; warmboot target hi-order byte
  26. bdos    equ    os$base+5    ; bdos entry
  27. ;
  28. prbuff    equ    9        ; bdos print string 
  29. ;
  30. ; nzcom environment location & offsets
  31. ;
  32. nzenv    equ    0100H        ; NZCOM.COM target system environment
  33. nzbiopg equ    nzenv+2        ; Hi byte of const jump in XBIOS
  34. nzdos    equ    nzenv+042H    ; pointer to DOS addr
  35. ;
  36. ; pointers to patch locations
  37. ;
  38. dosoff    equ    0007h        ; DOS patch at DOS+dosoff
  39. xbent    equ    004eh        ; XBIOS entry for BSX string
  40. xbtag    equ    00dch        ; location of 'XBIOS' string in XBIOS 
  41. xbret    equ    02a8h        ; XBIOS BSX return addr stored here
  42. ;
  43. ;---------------------------------------------------------------------
  44. ;
  45. ; Patch BSX jump into new DOS, and DOS return into XBIOS
  46. ;
  47. ;---------------------------------------------------------------------    
  48. ;  
  49.     org    patch1
  50. ;
  51. pat1:    cp    0        ; non nzcom system running?
  52.     jr    z,a0        ; yes, find XBIOS location
  53.     cp    1        ; nzcom running?
  54.     jr    z,a1        ; get XBIOS location
  55.     cp    3        ; new system loaded?
  56.     jr    z,a3        ; install patches
  57.     ret            ; none of the above, pass 
  58. ;
  59. ; NZCOM not loaded, get XBIOS page from page 0 warm boot vector
  60. ;
  61. a0:    ld    hl,biospg    ; point to hi byte
  62.     jr    a01com        ; join common code
  63. ;
  64. ; NZCOM loaded, find XBIOS page from ENV pointer to const routine
  65. ;
  66. a1:    ld    hl,nzbiopg    ; point to hi byte
  67. a01com:    ld    de,xbbase+1    ; point to buffer
  68.     ld    a,(hl)        ; save byte
  69.     ld    (de),a
  70.     ld    c,prbuff    ; use bdos to print banner
  71.     ld    de,signon    
  72.     jp    bdos        ; remember, call pending
  73. ;
  74. ; New system in place, patch return in XBIOS and jump in DOS
  75. ; First, test for XBIOS & ZSDOS
  76. ;
  77. a3:    ld    hl,(xbbase)    ; get XBIOS base addr
  78.     ld    de,xbtag    ; offset to XBIOS string
  79.     add    hl,de        ; form address
  80.     ld     de,xbstr    ; point to baseline string
  81.     ld    a,(xbct)    ; byte counter
  82.     ld    b,a        ; where we need it 
  83. ckxb:    ld    a,(de)        ; get good character
  84.     cp    a,(hl)        ; compare to BIOS character
  85.     ret    nz             ; not a match, gong this routine
  86.     inc    de        ; point to next character
  87.     inc    hl
  88.     djnz    ckxb        ; check them all
  89. ;
  90.     ld    hl,(nzdos)    ; get DOS base addr
  91.     ld    de,dosstr    ; point to baseline string
  92.     ld    a,(dosct)    ; character count
  93.     ld    b,a        ; where we need it
  94. ckdos:    ld    a,(de)        ; get good character
  95.     cp    a,(hl)        ; compare to DOS character
  96.     ret      nz             ; not a match, gong this routine
  97.     inc    de        ; point to next character
  98.     inc    hl
  99.     djnz    ckdos        ; check them all
  100. ;
  101. ; Everything looks ok, patch jump target at DOS+7 into XBIOS return,
  102. ; and XBIOS BSX entry into DOS+7
  103. ;
  104.     ld    hl,(xbbase)    ; get XBIOS base addr
  105.     ld    de,xbret    ; offset to XBIOS return
  106.     add    hl,de        ; form complete addr
  107.     push    hl        ; save on stack
  108.     ld    hl,(nzdos)    ; get DOS base addr
  109.     ld    de,dosoff    ; offset to jump loc
  110.     add    hl,de        ; complete addr
  111.     pop    de        ; XBIOS addr now in de
  112.     push    hl        ; save DOS addr
  113.     ldi            ; move 1 byte twice
  114.     ldi            ; from DOS to XBIOS
  115. ;
  116.     ld    hl,(xbbase)    ; get XBIOS base addr
  117.     ld    de,xbent    ; offset to entry
  118.     add    hl,de        ; form complete addr
  119.     ld    (xbbsx),hl    ; and save
  120.     ld    hl,xbbsx    ; point to entry
  121.     pop    de        ; get DOS jump addr
  122.     ldi            ; move bytes
  123.     ldi
  124. ;
  125.     ret            ; fini
  126. ;
  127. ; data storage
  128. ;
  129. xbbase:    dw    0f200H        ; True location of bios
  130. xbbsx:    dw    0f24eH        ; xbios entry for BSX
  131. ;
  132. signon:    db    cr,lf,'Patching BSX entry and return',cr,lf,'$'
  133. xbstr:    db     'XBIOS'
  134. xbct:    db    $-xbstr        ; char count
  135. dosstr:    db    'ZSDOS'    
  136. dosct:    db    $-dosstr
  137. ;
  138. ;---------------------------------------------------------------------
  139. ;
  140. ; Patch path to be B0: $$ b0:
  141. ;
  142. ;---------------------------------------------------------------------    
  143. ;  
  144.     org    patch2
  145. ;
  146. pat2:    db    02,00        ; B0:
  147.     db    '$$'        ; curently logged drive
  148.     db    02,00
  149.     db    0,-1        ; terminator
  150. ;
  151. ;---------------------------------------------------------------------
  152. ;
  153. ; Patch command line
  154. ;
  155. ;---------------------------------------------------------------------    
  156. ;  
  157.     org    patch3
  158. ;
  159. pat3    db    'B0:STARTZCM'
  160.     db    0,-1        ; terminator
  161. ;
  162.     end