home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / uploads / sfxio.z80 < prev    next >
Encoding:
Text File  |  1994-09-02  |  14.3 KB  |  602 lines
  1.     TITLE    SYSLIB - Byte-Oriented I/O w User-Supplied Buffers, Append
  2. ;
  3. ; SYSLIB Module Name:  SFXIO
  4. ; Author:  Richard Conn
  5. ; SYSLIB Version Number:  3.6
  6. ; Module Version Number:  1.3
  7.  
  8.     public    fxi$open,fx$get,fxi$close
  9.     public    fxo$open,fx$put,fxo$close
  10.     public    fxa$open
  11.  
  12. ;  Date:     10 Nov 86
  13. ;  Revised: Michael Bate
  14. ;  Changes:    - Added new entry point FXA$OPEN to open a file for
  15. ;          appending.  Called same as FXO$OPEN, except that
  16. ;          If the file already exists, text will be appended
  17. ;          to the text that is in it already.
  18. ;
  19. ;  Date:     28 Apr 85
  20. ;  Revised: Al Dunsmuir
  21. ;  Changes:    - FX$GET and FX$PUT routines optimized for speed
  22. ;          (PUTADR/GETADR not used if disk I/O not required)
  23. ;        - Use direct DMA vs DMA to TBUFF and software move.
  24. ;          Makes byte I/O a bit faster AND safer.
  25. ;        - Some misc. code optimization also performed.
  26. ;            
  27. ;   Previous Version:    1.0 (16 Jan 84)
  28.  
  29. ;
  30. ;    SFXIO provides a group of routines which can perform byte-oriented
  31. ; file I/O with a user-defined buffer size.  All of these routines work with
  32. ; an I/O Control Block which is structured as follows:
  33. ;
  34. ;        Byte    Length (Bytes)    Function
  35. ;          0         1    Number of 128-byte pages in
  36. ;                        working buffer (set by user)
  37. ;          1         1    End of File Flag (set and used
  38. ;                        by SFXIO)
  39. ;          2         2    Byte Counter (set and used by SFXIO)
  40. ;          4         2    Next Byte Pointer (set and used by
  41. ;                        SFXIO)
  42. ;          6         2    Address of Working Buffer (set by user)
  43. ;          8        36    FCB of File (FN and FT Fields set by
  44. ;                        user, rest set by SFXIO)
  45. ;
  46. ;    The following DB/DS structure can be used in the calling program
  47. ; to implement the I/O Control Block:
  48. ;
  49. ;    IOCTL:    DB    8    ; Use 8 128-byte pages (1K)
  50. ;        DS    1    ; Filled by SFXIO
  51. ;        DS    2    ; Filled by SFXIO
  52. ;        DS    2    ; Filled by SFXIO
  53. ;        DW    WORKBF    ; Address of Working Buffer
  54. ;
  55. ;    IOCFCB:    DB    0    ; Current Disk (Inited by SFXIO)
  56. ;        DB    'MYFILE  '    ; File Name
  57. ;        DB    'TXT'        ; File Type
  58. ;        DS    24    ; Fill Out 36 Bytes
  59. ;
  60. ;    WORKBF:    DS    1024    ; Working Buffer
  61. ;
  62. ;    All uses of the routines contain the address of IOCTL in DE.
  63. ; Note that if you use a buffer for input, DO NOT use it for output also!
  64. ;
  65.  
  66. ;
  67. ;  External SYSLIB References
  68. ;
  69.     EXT    F$OPEN        ;Open File
  70.     EXT    F$MOPEN        ;Open/Create file
  71.     EXT    INITFCB        ;Init FCB
  72.     EXT    F$CLOSE        ;Close file
  73.     EXT    SHFTRH        ;Shift HL right one bit.
  74.     EXT    SHFTLH        ;Shift HL left one bit.
  75.     EXT    f$exist        ;File existence test
  76.     EXT    f$appl        ;Append to a file
  77.  
  78. ;  CP/M Equates and ASCII Constants
  79. ;
  80. TBUFF    EQU    80H        ;Temporary File I/O buffer
  81. CTRLZ    EQU    'Z'-'@'        ;^Z
  82.  
  83. BDOS    EQU    5        ;BDOS entry point
  84. B$CL    EQU    16        ; Close file
  85. B$RD    EQU    20        ; Read next record
  86. B$WR    EQU    21        ; Write next record
  87. B$DMA    EQU    26        ; Set DMA address
  88.  
  89.  
  90. ; **** Macro Routines for FXIO ****
  91. ;
  92. PUTRG    MACRO            ;Save BC, DE, HL
  93.     PUSH    BC
  94.     PUSH    DE
  95.     PUSH    HL
  96.     ENDM
  97.  
  98. GETRG    MACRO            ;Restore BC, DE, HL
  99.     POP    HL
  100.     POP    DE
  101.     POP    BC
  102.     ENDM
  103.  
  104.  
  105. ; **** Support Routines for FXIO ****
  106. ;
  107. ;
  108. ;  FXIO0 - Routine to read next buffer-full from disk
  109. ;
  110. FXIO0:    LD    A,(EOF)        ;Check for EOF
  111.     OR    A        ;Abort if already at EOF
  112.     RET    NZ        ;NZ is error code
  113. ;
  114.     LD    HL,(BUFADR)    ;Get address of input buffer
  115.     LD    A,(BCNT)    ;Get block count
  116.     LD    B,A        ;... in B 
  117.  
  118. FXIO1:    PUSH    BC        ;Save remaining block count.    
  119.     PUSH    HL        ;Save current Input buffer ptr
  120.     EX    DE,HL        ;Get buffer addr in DE
  121.     LD    C,B$DMA        ;Point BDOS DMA ptr to input buffer
  122.     CALL    BDOS
  123. ;
  124.     LD    HL,(FCB)    ;Get FCB address
  125.     EX    DE,HL        ;... IN DE
  126.     LD    C,B$RD        ;Read block via BDOS
  127.     CALL    BDOS
  128.     POP    HL        ;Restore input buffer ptr
  129.     POP    BC        ;Restore remaining block count
  130.     OR    A        ;Check Read return code.
  131.     JR    NZ,FXIO2    ;Br if End-of-File
  132. ;
  133.     LD    DE,128        ;Get block length
  134.     ADD    HL,DE        ;Update buffer addr to point to next block
  135. ;
  136.     djnz    FXIO1        ;Loop until all blocks written.
  137.     JR    FXIO3        ;Done.
  138.  
  139. FXIO2:    LD    A,0FFH        ;Set "EOF" condition
  140.     LD    (EOF),A        ;Set EOF flag
  141. ;
  142. FXIO3:    LD    HL,(BUFADR)    ;Pt to first byte in buffer
  143.     LD    (BYTENXT),HL    ; as "next byte" address
  144. ;
  145.     LD    A,(BCNT)    ;Get block count
  146.     SUB    B        ;Adjust by # empty blocks
  147.     LD    H,A        ;Convert to bytes
  148.     LD    L,0
  149.     CALL    SHFTRH        
  150.     LD    (BYTECNT),HL    ;Set byte count
  151. ;
  152.     PUSH    HL        ;Save byte count
  153.     LD    DE,TBUFF    ;Reset DMA address (for compatability)
  154.     LD    C,B$DMA
  155.     CALL    BDOS
  156.     POP    HL        ;Get byte count
  157. ;
  158.     LD    A,H        ;Set EOF return code based on byte count
  159.     OR    L
  160.     JR    Z,FXIO4
  161.     XOR    A        ;Set no error (data available)
  162.     RET
  163. FXIO4:
  164.     OR    0FFH        ;Set error (no data available)
  165.     RET
  166.  
  167. ;
  168. ;  FXOO0 - Routine to flush buffer to disk and set up for next write
  169. ;
  170. FXOO0:    LD    HL,(BYTECNT)    ;Get # of bytes yet to go
  171.     CALL    SHFTLH        ;Convert to blocks
  172.     LD    A,(BCNT)    ;Get # of blocks in buffer
  173.     SUB    H        ;Compute number to write
  174.     LD    B,A        ;Get final block count in B
  175.     LD    HL,(BUFADR)    ;Pt to first byte to write
  176. ;
  177. FXOO1:    LD    A,B        ;Check if write complete
  178.     OR    A        ;0=Done
  179.     JR    Z,FXOO2
  180. ;
  181.     DEC    B        ;Decrement block counter
  182.     PUSH    BC        ;Save remaining block count
  183.     PUSH    HL        ;Save current Output buffer ptr
  184.     EX    DE,HL        ;Get buffer addr in DE
  185.     LD    C,B$DMA        ;Point BDOS DMA ptr to output buffer
  186.     CALL    BDOS
  187. ;
  188.     LD    HL,(FCB)    ;Get FCB address
  189.     EX    DE,HL        ;... IN DE
  190.     LD    C,B$WR        ;Write block via BDOS
  191.     CALL    BDOS
  192.     POP    HL        ;Restore output buffer ptr
  193.     POP    BC        ;Restore remaining block count
  194. ;
  195.     LD    DE,128        ;Get block length
  196.     ADD    HL,DE        ;Update buffer addr to point to next block
  197. ;
  198.     OR    A        ;Check Write return code.
  199.     JR    Z,FXOO1        ;If OK, Loop until all blocks have been written
  200. ;
  201.     OR    0FFH        ;Set error code
  202.     RET
  203.  
  204.  
  205. ;  FXOO2 - Routine to init buffers for next write
  206. ;
  207. FXOO2:    LD    HL,(BUFADR)    ;Pt to first byte in buffer
  208.     LD    (BYTENXT),HL    ; as "next byte" address
  209. ;
  210.     XOR    A        ;SET NO EOF
  211.     LD    (EOF),A
  212. ;
  213.     LD    A,(BCNT)    ;Get block count
  214.     LD    H,A        ;Convert to bytes
  215.     LD    L,0
  216.     CALL    SHFTRH        
  217.     LD    (BYTECNT),HL    ;Set byte count
  218. ;
  219.     LD    DE,TBUFF    ;Reset DMA address (for compatability)
  220.     LD    C,B$DMA
  221.     CALL    BDOS
  222. ;
  223.     XOR    A        ;No Error
  224.     RET
  225.  
  226.  
  227. ; **** Base Routines for FXIO ****
  228. ;
  229. ;
  230. ;  FXI$OPEN - Open file/buffers for Byte-Oriented Input (GET)
  231. ;    on input, DE pts to I/O Control Block
  232. ;    on output, A=0 and Zero flag set if error (File not found)
  233. ;
  234. FXI$OPEN:
  235.     PUTRG            ;Save registers
  236.     CALL    PUTADR        ;Copy I/O Control Block data
  237.     XOR    A        ;Set no EOF
  238.     LD    (EOF),A
  239.     LD    HL,(FCB)    ;Get FCB address
  240.     EX    DE,HL        ;... in DE 
  241.     CALL    INITFCB        ;Init FCB
  242.     CALL    F$OPEN        ;Attempt to open file
  243.     JR    NZ,ERRET    ;NZ = Error (File not found)
  244. ;
  245.     CALL    FXIO0        ;OK - Fill buffer with data
  246. ;
  247. ;   Normal return
  248. ;
  249. OKRET:    CALL    GETADR        ;Update I/O Control Block data
  250.     GETRG            ;Restore regs
  251.     OR    0FFH        ;Indicate success
  252.     RET
  253.  
  254. ;   Error return    
  255. ;
  256. ERRET:    GETRG            ;Restore regs
  257.     XOR    A        ;Indicate Error
  258.     RET
  259.  
  260.  
  261. ;  FXO$OPEN - Open file/buffers for Byte-Oriented Output (PUT)
  262. ;    on input, DE pts to I/O Control Block
  263. ;    on output, A=0 and Zero flag set if error (No Directory space)
  264. ;
  265. FXO$OPEN:
  266.     PUTRG            ;Save registers
  267.     CALL    PUTADR        ;Copy I/O Control Block data
  268.     CALL    FXOO2        ;Init buffers
  269.     LD    HL,(FCB)    ;Get FCB address
  270.     EX    DE,HL        ;... in DE 
  271.     CALL    INITFCB        ;Init FCB
  272.     CALL    F$MOPEN        ;Open and/or Create file
  273.     JR    NZ,ERRET    ;NZ = Error (No Directory Space)
  274.     JR    OKRET        ;OK- Return and update I/O Control Block
  275.  
  276.  
  277. ;  FXA$OPEN - Open file/buffers for Byte-Oriented Output (PUT) with Append
  278. ;    on input, DE pts to I/O Control Block
  279. ;    on output, A=0 and Zero flag set if error (No Directory space or
  280. ;                            File is full)
  281. ;
  282. FXA$OPEN:
  283.     PUTRG            ;Save registers
  284.     CALL    PUTADR        ;Copy I/O Control Block data
  285.     CALL    FXOO2        ;Init buffers
  286.     LD    HL,(FCB)    ;Get FCB address
  287.     EX    DE,HL        ;... in DE 
  288.     CALL    INITFCB        ;Init FCB
  289.     CALL    F$EXIST        ; See if file exists
  290.     JR    NZ,START
  291.     CALL    F$MOPEN        ; File does NOT exist -- create it
  292.     JR    NZ,ERRET    ; NZ = Error (No Directory Space)
  293.     JR    OKRET
  294. start:
  295.     CALL    F$APPL        ; Open file for append
  296.     JR    Z,START1
  297.     CP    3
  298.     JR    NZ,ERRET    ; Error - file full
  299.     JR    OKRET        ; take this jump if file is empty
  300. start1:
  301.     LD    DE,(BUFADR)    ; Scan buffer for Ctl-Z
  302.     LD    HL,TBUFF
  303.     PUSH    DE
  304.     LD    BC,080h
  305.     PUSH    BC
  306.     LDIR
  307.     POP    BC
  308.     POP    HL
  309.     LD    A,CTRLZ
  310.     CPIR
  311.     JR    NZ,START2    ; ctl-Z not found
  312.     DEC    HL        ; found ctl-Z in buffer
  313.     INC    BC
  314. start2:
  315.     LD    (BYTENXT),HL    ; Set place to store next byte
  316.     LD    A,(BCNT)    ; Get count of blocks minus 1
  317.     DEC    A
  318.     LD    H,A        ; Convert to bytes
  319.     LD    L,0
  320.     CALL    SHFTRH
  321.     ADD    HL,BC        ; Add # bytes from first sector
  322.     LD    (BYTECNT),HL    ; Store in # available bytes
  323.     JR    OKRET
  324. ;
  325. ;  FX$GET - Get next byte from buffer/file 
  326. ;    on input, DE pts to I/O Control Block
  327. ;    on output, A=Char and Zero flag set if past EOF
  328. ;
  329. FX$GET:
  330.     PUTRG            ;Save registers
  331. ;
  332. ; Check if data byte is in buffer. 
  333. ;
  334.     EX    DE,HL        ;HL -> I/O Control Block data
  335.     INC    HL        ;Get caller's BYTECNT in DE
  336.     INC    HL
  337.     LD    E,(HL)
  338.     INC    HL
  339.     LD    D,(HL)
  340.  
  341.     DEC    HL        ;Pt to caller's BYTECNT again.
  342.     LD    A,D        ;Is the data byte in the buffer?
  343.     OR    E
  344.     JR    Z,FXGET1    ;No - Fill buffer and GET byte.
  345. ;
  346. ; It is. GET it and update BYTECNT, BYTENXT as quickly as possible.
  347. ; 
  348.     DEC    DE        ;Update byte count
  349.     LD    (HL),E        ;Update caller's BYTECNT.
  350.     INC    HL
  351.     LD    (HL),D
  352. ;
  353.     INC    HL        ;Get caller's BYTENXT.
  354.     LD    E,(HL)
  355.     INC    HL
  356.     LD    D,(HL)    
  357. ;
  358.     LD    A,(DE)        ;GET data byte from buffer
  359.     LD    (BYTE),A    ;Save for return.
  360. ;
  361.     INC    DE        ;Update caller's BYTENXT.
  362.     LD    (HL),D
  363.     DEC    HL
  364.     LD    (HL),E
  365. ;
  366.     GETRG            ;Restore regs
  367.     OR    0FFH        ;Indicate success
  368.     LD    A,(BYTE)    ;Get data byte
  369.     RET
  370. ;
  371. ; Data byte not in buffer - Fill buffer from file first
  372. ;
  373. FXGET1:    EX    DE,HL        ;DE -> I/O Control Block data.
  374.     DEC    DE
  375.     DEC    DE
  376.     CALL    PUTADR        ;Copy I/O Control Block data
  377.     CALL    FXIO0        ;Fill buffer from file
  378.     JP    NZ,ERRET    ;NZ = Error (End of File)
  379. ;
  380.     LD    HL,(BYTENXT)    ;Pt to first byte in buffer
  381.     LD    A,(HL)        ;GET from buffer
  382.     LD    (BYTE),A    ;Save it
  383.     INC    HL        ;Pt to next byte
  384.     LD    (BYTENXT),HL    ;Update next byte pointer
  385.     LD    HL,(BYTECNT)    ;One less byte in buffer
  386.     DEC    HL
  387.     LD    (BYTECNT),HL    ;Update byte count
  388. ;
  389. ;   Normal return
  390. ;
  391. OKRET1:    CALL    GETADR        ;Update I/O Control Block data
  392.     GETRG            ;Restore regs
  393.     OR    0FFH        ;Indicate success
  394.     LD    A,(BYTE)    ;Get data byte
  395.     RET
  396.  
  397.  
  398. ;  FX$PUT - Put next byte into buffer/file 
  399. ;    on input, A=char and DE pts to I/O Control Block
  400. ;    on output, A=Char and Zero flag set if write error
  401. ;
  402. FX$PUT:
  403.     PUTRG            ;Save registers
  404.     LD    (BYTE),A    ;Save byte to output 
  405. ;
  406. ; Check if data byte will fit in buffer. 
  407. ;
  408.     EX    DE,HL        ;HL -> I/O Control Block data
  409.     INC    HL        ;Get caller's BYTECNT in DE
  410.     INC    HL
  411.     LD    E,(HL)
  412.     INC    HL
  413.     LD    D,(HL)
  414.  
  415.     DEC    HL        ;Pt to caller's BYTECNT again.
  416.     LD    A,D        ;Will the data byte fit in the buffer?
  417.     OR    E
  418.     JR    Z,FXPUT1    ;No - Flush buffer to file and PUT byte.
  419. ;
  420. ; It is. PUT it and update BYTECNT, BYTENXT as quickly as possible.
  421. ; 
  422.     DEC    DE        ;Update byte count
  423.     LD    (HL),E        ;Update caller's BYTECNT.
  424.     INC    HL
  425.     LD    (HL),D
  426. ;
  427.     INC    HL        ;Get caller's BYTENXT.
  428.     LD    E,(HL)
  429.     INC    HL
  430.     LD    D,(HL)    
  431. ;
  432.     LD    A,(BYTE)    ;Get data byte
  433.     LD    (DE),A        ;PUT data byte in buffer
  434. ;
  435.     INC    DE        ;Update caller's BYTENXT.
  436.     LD    (HL),D
  437.     DEC    HL
  438.     LD    (HL),E
  439. ;
  440.     GETRG            ;Restore regs
  441.     OR    0FFH        ;Indicate success
  442.     LD    A,(BYTE)    ;Get data byte
  443.     RET
  444. ;
  445. ; Data byte will not fit in buffer - Flush buffer to file first.
  446. ;
  447. FXPUT1:    EX    DE,HL        ;DE -> I/O Control Block data.
  448.     DEC    DE
  449.     DEC    DE
  450.     CALL    PUTADR        ;Copy I/O Control Block data
  451.     CALL    FXOO0        ;NO - Flush buffer to file
  452.     JP    NZ,ERRET    ;NZ = Error (Write error)
  453. ;
  454.     LD    HL,(BYTENXT)    ;Pt to first byte in buffer
  455.     LD    A,(BYTE)    ;Get next byte
  456.     LD    (HL),A        ;PUT in buffer
  457.     INC    HL        ;Pt to next byte
  458.     LD    (BYTENXT),HL    ;Update next byte pointer
  459.     LD    HL,(BYTECNT)    ;One less byte of free space in buffer
  460.     DEC    HL
  461.     LD    (BYTECNT),HL    ;Update byte count
  462.     JR    OKRET1        ;OK-return with byte and updated control block
  463.  
  464.  
  465. ;  FXI$CLOSE - Close file/buffers for Byte-Oriented Input (GET)
  466. ;    on input, DE pts to I/O Control Block
  467. ;    on output, A=0 and Zero flag set if error (Error in closing file)
  468. ;
  469. FXI$CLOSE:
  470.     PUTRG            ;Save registers
  471.     CALL    PUTADR        ;Copy I/O Control Block data
  472.     LD    HL,(FCB)    ;Get FCB address
  473.     EX    DE,HL        ;... in DE 
  474.     CALL    F$CLOSE        ;Close file
  475.     JP    NZ,ERRET    ;NZ = Error (Close file error)
  476.     JP    OKRET        ;OK- Return and update I/O Control Block
  477.  
  478.  
  479. ;  FXO$CLOSE - Close file/buffers for Byte-Oriented Output (PUT)
  480. ;    on input, DE pts to I/O Control Block
  481. ;    on output, A=0 and Zero flag set if error (Error in closing file)
  482. ;
  483. FXO$CLOSE:
  484.     PUTRG            ;Save registers
  485.     CALL    PUTADR        ;Copy I/O Control Block data
  486. ;
  487. ;  Fill last block with ^Z
  488. ;
  489. FXOCL1:    LD    HL,(BYTECNT)    ;Get free space count.
  490.     LD    A,L        ;If on page boundary, done
  491.     AND    7FH
  492.     JR    Z,FXOCL2
  493.     DEC    HL        ;One less byte of free space in buffer
  494.     LD    (BYTECNT),HL    ;Update byte count
  495.     LD    HL,(BYTENXT)    ;Pt to next byte
  496.     LD    (HL),CTRLZ    ;Store EOF char
  497.     INC    HL
  498.     LD    (BYTENXT),HL
  499.     JR    FXOCL1        ;Loop until last block is full
  500. ;
  501. ;  Close file and exit
  502. ;
  503. FXOCL2:    CALL    FXOO0        ;Flush buffers to disk
  504.     LD    HL,(FCB)    ;Get FCB address
  505.     EX    DE,HL        ;... in DE 
  506.     CALL    F$CLOSE        ;Close file
  507.     JP    NZ,ERRET    ;NZ = Error (Close file error)
  508.     JP    OKRET        ;OK- Return and update I/O Control Block
  509.  
  510.  
  511. ;  PUTADR - Copy I/O Control Block data to local storage
  512. ;
  513. PUTADR:    EX    DE,HL        ;Get I/O Control Block addr in HL
  514.     LD    (BUFFER),HL    ;Save I/O Control Block address
  515. ;
  516.     LD    A,(HL)        ;Get block count
  517.     LD    (BCNT),A
  518. ;
  519.     INC    HL
  520.     LD    A,(HL)        ;Get eof flag
  521.     LD    (EOF),A
  522. ;
  523.     INC    HL
  524.     LD    E,(HL)        ;Get low count
  525.     INC    HL
  526.     LD    D,(HL)
  527.     EX    DE,HL
  528.     LD    (BYTECNT),HL    ;Put byte count
  529. ;
  530.     EX    DE,HL
  531.     INC    HL
  532.     LD    E,(HL)        ;Get low address
  533.     INC    HL
  534.     LD    D,(HL)
  535.     EX    DE,HL
  536.     LD    (BYTENXT),HL    ;Put next byte ptr
  537. ;
  538.     EX    DE,HL
  539.     INC    HL
  540.     LD    E,(HL)        ;Get low address
  541.     INC    HL
  542.     LD    D,(HL)
  543.     EX    DE,HL
  544.     LD    (BUFADR),HL    ;Put buffer address ptr
  545. ;
  546.     EX    DE,HL
  547.     INC    HL
  548.     LD    (FCB),HL    ;Save address of FCB
  549.     RET
  550.  
  551.  
  552. ;  GETADR - Update I/O Control Block data from local storage
  553. ;
  554. GETADR:    LD    HL,(BUFFER)    ;Get I/O Control Block address
  555. ;
  556.     INC    HL        ;Skip block count
  557. ;
  558.     LD    A,(EOF)        ;Get EOF flag
  559.     LD    (HL),A
  560. ;
  561.     EX    DE,HL
  562.     LD    HL,(BYTECNT)    ;Get byte count
  563.     EX    DE,HL
  564.     INC    HL
  565.     LD    (HL),E        ;Set low count
  566.     INC    HL
  567.     LD    (HL),D
  568.     EX    DE,HL
  569. ;
  570.     LD    HL,(BYTENXT)    ;Get next byte pointer
  571.     EX    DE,HL
  572.     INC    HL
  573.     LD    (HL),E        ;Set low address
  574.     INC    HL
  575.     LD    (HL),D
  576.     RET
  577.  
  578. ;
  579. ;  BUFFERS
  580. ;
  581. BYTE:    DS    1        ;Data byte
  582. BUFFER:    DS    2        ;Starting address of I/O control block
  583.  
  584. ;  The following mirrors the structure of the I/O Control Block
  585. ;
  586. BCNT:     DS    1        ;Number of blocks in buffer
  587. EOF:     DS    1        ;EOF flag (0=not at EOF, 0FFH=at EOF)
  588. BYTECNT: DS    2        ;Number of bytes to go yet
  589. BYTENXT: DS    2        ;Address of next byte to PUT/GET
  590. BUFADR:     DS    2        ;Address of working buffer
  591. FCB:     DS    2        ;Address of FCB
  592.  
  593.     END
  594. ress
  595.     INC    HL
  596.     LD    D,(HL)
  597.     EX    DE,HL
  598.     LD    (BUFADR),HL    ;Put buffer address ptr
  599. ;
  600.     EX    DE,HL
  601.     INC    HL
  602.     LD    (FCB),HL    ;S