home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / uploads / gst03.lbr / LINE.ZZ0 / LINE.Z80
Encoding:
Text File  |  1993-06-07  |  3.8 KB  |  164 lines
  1. ;********************************************************************
  2. ;
  3. ;    LINE: A ZCPR 3.3+ compatible routine, using the version 4
  4. ;        libraries, to place a graphics line on the screen
  5. ;        for use in alias scripts.
  6. ;
  7. ; Version 3.0D (July 7, 1990) - Updated and re-linked based upon 
  8. ;  VLIB4D and version 4 libraries.  Assembled with SLR's Z80ASM and 
  9. ;  linked with DRI's LINK.  Thanks go to Dave Ramsey for producing
  10. ;  an excellent set of command-level graphics tools.   Bob Dean
  11. ;   
  12. ;
  13. ; Author: Dave Ramsey            Date: May 25, 1989
  14. ;  Versions 1.0 and 2.0.    
  15. ;
  16. ;********************************************************************
  17. ;
  18. ; VLIB/Z3LIB/SYSLIB references:
  19. ;
  20.     ext    gz3init,tinit,dinit,drhorz,drvert,vpstr
  21.     ext    eval10,argv
  22. ;
  23. ; Constants defined:
  24. ;
  25. VERSION    equ     3
  26. MONTH    equ     7
  27. DAY    equ     5
  28. YEAR    equ    90
  29. ;
  30. DOS    equ     5
  31. BUFFER    equ    080h
  32. CR    equ    13
  33. LF    equ    10
  34. ARGCNT    equ     5
  35. ; 
  36. start:
  37.     jp    main
  38.     db    'Z3ENV'
  39.     db    1
  40. z3eadr:    ds    2
  41. main:
  42.     ld    hl,(z3eadr)
  43.     call    gz3init        ; check for presence of extended TCAP
  44.     and    a,0fh
  45.     jr    nz,stack    ; if present, proceed
  46.     ld    hl,oldtcpmsg    ; else tell user
  47.     call    vpstr        ; and exit
  48.     ret
  49. ;
  50. ; setup stack...
  51. ;
  52. stack:
  53.     ld    hl,0
  54.     add    hl,sp
  55.     ld    (oldsp),hl    ; save old stack pointer
  56.     ld    hl,(DOS+1)
  57.     ld    l,0
  58.     ld    a,h
  59.     add    a,-8
  60.     ld    h,a        ; set stack below CCP
  61.     ld    sp,hl
  62. ;
  63. ; Get command line parms, there should be 5, and store results
  64. ;
  65.     ld    a,0ffh        ; null terminate argument strings
  66.     ld    hl,BUFFER+1
  67.     ld    de,tokentbl
  68.     call    argv
  69.     ld    a,(numtok)
  70.     cp    a,ARGCNT    ; did the user get it right?
  71.     jp    nz,gethelp    ; nope, tell him how to call us.
  72. ;
  73. ; Else, store parm results directly inline for the drbox call and execute
  74. ;
  75.     ld    hl,(parm1)
  76.     call    eval10
  77.     ld    (type),a
  78.     ld    hl,(parm2)
  79.     call    eval10
  80.     ld    (hrow),a    ; save row number
  81.     ld    hl,(parm3)
  82.     call    eval10
  83.     ld    (col),a        ; save column number
  84.     ld    hl,(parm4)
  85.     call    eval10
  86.     ld    (length),a    ; save height
  87.     ld    hl,(parm5)
  88.     call    eval10
  89.     ld    (direct),a    ; save width
  90. ;
  91. ; else... init terminal as per V4 lib conventions
  92. ;
  93.     call    tinit
  94.     ld    a,(type)
  95.     or    a,a
  96.     jr    z,drawhline    ; if a=0, draw horizontal line else
  97.     ld    bc,4
  98.     ld    de,vrow
  99.     ld    hl,hrow
  100.     ldir            ; get arguments
  101.     call    drvert        ; draw vertical line
  102. vrow    ds    4
  103.     jp    fini
  104. ;
  105. ; Call DRBOX routine to draw the box.
  106. ;
  107. drawhline:
  108.     call    drhorz        ; draw horizontal line
  109. hrow:    db    0
  110. col:    db    0
  111. length: db    0
  112. direct:    db    0
  113.  
  114. ;
  115. ; deinit terminal and restore stack
  116. ;
  117. fini:
  118.     call    dinit
  119. ;
  120. fini2:
  121.     ld    hl,(oldsp)
  122.     ld    sp,hl
  123.     ret
  124. ;
  125. ;
  126. gethelp:
  127.     ld    hl,helpmsg
  128.     call    vpstr
  129.     jp    fini2
  130.  
  131. ;
  132. oldsp:    ds    2
  133. ;
  134. tokentbl:
  135. maxtok: db    ARGCNT    ; I don't want to see more than 5 arguments,
  136. numtok: db    0    ; but how many were there really?
  137. parm1:    ds    2    ; address arg 1 - line type
  138. parm2:    ds    2    ; address arg 2 - row
  139. parm3:    ds    2    ; address arg 3 - col
  140. parm4:    ds    2    ; address arg 4 - length
  141. parm5:    ds    2    ; address arg 5 - direction
  142. ;
  143. type:    db    0    ; flag for type of LINE to draw
  144. ;
  145. helpmsg:
  146.     db    'LINE, Version ',VERSION/10+'0','.',VERSION MOD 10+'0',CR,LF
  147.     db    'LINE - Draws a LINE on the screen.',CR,LF
  148.     db    'Syntax:',CR,LF
  149.     db    '     LINE <type> <row> <col> <height> <width>',CR,LF
  150.     db    'Where:',CR,LF
  151.     db    '     <type> is an integer 0 for horizontal lines or',CR,LF
  152.     db    '            an integer 1 for vertical lines;',CR,LF
  153.     db    '     <row>  is the start row of the line on the screen;',CR,LF
  154.     db    '     <col>  is the start column on the screen;',CR,LF
  155.     db    '     <length> is the length of the line;',CR,LF
  156.     db    '     <direct> is the direction of the line, where:',CR,LF
  157.     db    '            0 = left-to-right OR top-to-bottom; and',CR,LF
  158.     db    '            1 = right-to-left OR bottom-to-top.',CR,LF,0
  159. ;
  160. oldtcpmsg:
  161.     db    'Extended TCAP not present.',CR,LF,0
  162. ;
  163.     end
  164.