home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / uploads / gst03.lbr / ISEC.ZZ0 / ISEC.Z80
Encoding:
Text File  |  1993-06-07  |  3.6 KB  |  175 lines
  1. ;********************************************************************
  2. ;
  3. ;    ISEC: A ZCPR 3.3+ compatible routine, using the version 4
  4. ;        libraries, to draw an intersection character  
  5. ;        on the screen, for use in alias scripts.
  6. ;
  7. ; Version 3.0D (July 7, 1990) - Updated and re-linked based upon 
  8. ;  VLIB4D and version 4 libraries.  Assembled with SLR's Z80ASM and 
  9. ;  linked with DRI's LINK.  Thanks go to Dave Ramsey for producing
  10. ;  an excellent set of command-level graphics tools.   Bob Dean
  11. ;
  12. ; Author: Dave Ramsey            Date: May 25, 1989
  13. ;  Versions 1.0 and 2.0.    
  14. ;
  15. ;********************************************************************
  16. ;
  17. ; VLIB/Z3LIB/SYSLIB references:
  18. ;
  19.     ext    gz3init,tinit,dinit,at,ltisec,rtisec,uisec,lisec,isec,vpstr
  20.     ext    eval10,argv
  21. ;
  22. ; Constants defined:
  23. ;
  24. VERSION    equ     1
  25. MONTH    equ     7
  26. DAY    equ     5
  27. YEAR    equ     90
  28. ;
  29. DOS    equ    5
  30. BUFFER    equ    080h
  31. CR    equ    13
  32. LF    equ    10
  33. ARGCNT    equ    3
  34. ; 
  35. start:
  36.     jp    main
  37.     db    'Z3ENV'
  38.     db    1
  39. z3eadr:    ds    2
  40. main:
  41.     ld    hl,(z3eadr)
  42.     call    gz3init
  43.     and    a,0fh        ; check for presence of exended tcap
  44.     jr    nz,stack
  45.     ld    hl,oldtcpmsg
  46.     call    vpstr        ; print old tcap warning message
  47.     ret            ; return to CCP
  48. ;
  49. ; setup stack...
  50. ;
  51. stack:
  52.     ld    hl,0
  53.     add    hl,sp
  54.     ld    (oldsp),hl
  55.     ld    hl,(DOS+1)
  56.     ld    l,0
  57.     ld    a,h
  58.     add    a,-8
  59.     ld    h,a
  60.     ld    sp,hl
  61. ;
  62. ; Get command line parms, there should be 3 and store results
  63. ;
  64.     ld    a,0ffh        ; null terminate argument strings
  65.     ld    hl,BUFFER+1
  66.     ld    de,tokentbl
  67.     call    argv
  68.     ld    a,(numtok)
  69.     cp    a,ARGCNT    ; did the user get it right?
  70.     jp    nz,gethelp    ; nope, tell him how to call us.
  71. ;
  72. ; Else, store parm results directly inline for the drbox call and execute
  73. ;
  74.     ld    hl,(parm1)
  75.     call    eval10
  76.     ld    (type),a
  77.     ld    hl,(parm2)
  78.     call    eval10
  79.     ld    (row),a        ; save row number
  80.     ld    hl,(parm3)
  81.     call    eval10
  82.     ld    (col),a        ; save column number
  83. ;
  84. ; else... init terminal as per V4 lib conventions
  85. ;
  86.     call    tinit
  87. ;
  88. ; Call AT to position cursor.
  89. ;
  90.     call    at
  91. row:    db    0
  92. col:    db    0
  93. ;
  94. ; Now select the intersection character to draw.
  95. ;
  96. left:
  97.     ld    a,(type)
  98.     cp    a,1
  99.     jr    nz,right
  100.     call    ltisec
  101.     jp    fini
  102. right:
  103.     cp    a,2
  104.     jr    nz,upper
  105.     call    rtisec
  106.     jp    fini
  107. upper:
  108.     cp    a,3
  109.     jr    nz,lower
  110.     call    uisec
  111.     jp    fini
  112. lower:
  113.     cp    a,4
  114.     jr    nz,inter
  115.     call    lisec
  116.     jp    fini
  117. inter:
  118.     cp    a,5
  119.     jr    nz,badval
  120.     call    isec
  121.     jp    fini
  122. badval:
  123.     ld    hl,badchmsg
  124.     call    vpstr
  125.  
  126. ;
  127. ; deinit terminal and restore stack
  128. ;
  129. fini:
  130.     call    dinit
  131. ;
  132. fini2:
  133.     ld    hl,(oldsp)
  134.     ld    sp,hl
  135.     ret
  136. ;
  137. ;
  138. gethelp:
  139.     ld    hl,helpmsg
  140.     call    vpstr
  141.     jp    fini2
  142.  
  143. ;
  144. oldsp:    ds    2
  145. ;
  146. tokentbl:
  147. maxtok: db    ARGCNT    ; I don't want to see more than 5 arguments,
  148. numtok: db    0    ; but how many were there really?
  149. parm1:    ds    2    ; address arg 1 - intersection char
  150. parm2:    ds    2    ; address arg 2 - row
  151. parm3:    ds    2    ; address arg 3 - col
  152. ;
  153. type:    db    0
  154. ;
  155. helpmsg:
  156.     db    'ISEC, Version ',VERSION/10+'0','.',VERSION MOD 10+'0',CR,LF
  157.     db    'ISEC - Draws an intersection character on the screen.',CR,LF
  158.     db    'Syntax:',CR,LF
  159.     db    '     ISEC <type> <row> <col> ',CR,LF
  160.     db    'Where:',CR,LF
  161.     db    '     <type> is an integer 1 for a left intersection, ',CR,LF
  162.     db    '            an integer 2 for a right intersection, ',CR,LF
  163.     db    '            an integer 3 for an upper intersection, ',CR,LF
  164.     db    '            an integer 4 for a lower intersection,',CR,LF
  165.     db    '            an integer 5 for a center intersection;',CR,LF
  166.     db    '     <row>  is the row on the screen to place the char;',CR,LF
  167.     db    '     <col>  is the column on the screen to place the char.'
  168.     db    CR,LF,0
  169. ;
  170. badchmsg:
  171.     db    'Invalid intersection character requested.',CR,LF,0
  172. oldtcpmsg:
  173.     db    'Extended TCAP not present.',CR,LF,0
  174.     end
  175.