home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / uploads / datenull.ark / DATENULL.MAC < prev    next >
Encoding:
Text File  |  1989-12-05  |  3.1 KB  |  109 lines
  1. ;   DateNull.MAC
  2. ; Traps F_MAKE System Call 22 and sets a null file date under CP/M+ ONLY!
  3. ;
  4. ;    m80 =datenull
  5. ;
  6. ;    link datenull[op]
  7. ;    rename datenull.rsx=datenull.prl
  8. ;
  9. ; In this case by installing in NULU.COM it will prevent the system from
  10. ; stamping extracted files with current date as "update" or "creation"
  11. ; dates (see DateNull.Doc):
  12. ; 
  13. ;    gencom NULU datenull.rsx
  14. ;
  15. ; ------------------------------------------------------------------------
  16. ; December 5, 1989
  17. ;
  18. ; The heart of this RSX is a CP/M+ "Set File Date and Time Stamp" function.
  19. ; 
  20. ; It does this by denying the system access to the BIOS Time function while
  21. ; the system time is set to the time to be stamped and the file is "made",
  22. ; in this case by F_Make (BDOS 22).
  23. ;
  24. ; This affects only Creation and Update stamping when the referenced drive
  25. ; has a directory label that requests such stamping and File Control Block
  26. ; (FCB) extent field is equal to zero.
  27. ;
  28. ; This RSX has no bearing on Access date/time stamping by F_Open (BDOS 15)
  29. ; or on Update stamping by the first F_Write (BDOS 21), first F_WriteRand
  30. ; (BDOS 34), or first F_WriteZF (BDOS 40) to follow an F_Open call.
  31. ;
  32. ; The hardware clock is undisturbed by all this and real time is restored
  33. ; to the system once it regains access to this clock via the BIOS Time
  34. ; function.
  35. ;
  36. ; Gary R. Welles, P.O. Box 1, Old Mystic, CT  06372-0001
  37. ; MCI Mail/Telex 650 117-8863 MCI UW
  38. ; ------------------------------------------------------------------------
  39.     .Z80
  40.     
  41. ;    RSX Header
  42. ;
  43. Serial:    db    0,0,0,0,0,0    ; CP/M serial number filled in by loader
  44. Start:    jp    Main        ; jump to start of program
  45. Next:    db    0C3h        ; JMP
  46.     dw    0        ; Addr of NEXT RSX or BDOS provided by loader
  47. Prev:    dw    0        ; Addr of Previous RSX provided by loader
  48. Remove:    db    0FFh        ; Remove after one use, 0h if not removed
  49. NonBank:
  50.     db    0        ; Banked System
  51. Name:    db    'DateNull'    ; Must be exactly 8 characters
  52. Loader:    db    0,0,0        ; Provided by loader
  53. ;
  54. ; -----------------------------------------------------------------------
  55.  
  56. ;    BDOS Functions
  57.  
  58. cpm    equ    5
  59.  
  60. F_Make    equ    22    ;Make file
  61. T_Set    equ    104    ;Set date and time
  62.  
  63. ;    BIOS Functions
  64.  
  65. wboot    equ    1    ;Bios Warm Boot address
  66. time    equ    75    ;Offset to BIOS Time function
  67.  
  68. ;    Z80 instructions
  69.  
  70. on    equ    0C3h    ;Z80 jump (jp)
  71. off    equ    0C9h    ;Z80 return (ret)
  72.  
  73. ;CP/M date and time
  74. ;
  75. ; The date is represented as a 16-bit integer with day 1
  76. ; corresponding to January 1, 1978.  The time is represented
  77. ; as two bytes: hours and minutes are stored as two BCD digits.
  78.  
  79. DaT:    db    0,0    ;Date field
  80.     db    0    ;Hour field
  81.     db    0    ;Minute field
  82.  
  83. Main:
  84.     ld    a,c    ; Put BDOS Call number in A
  85.     cp    F_Make    ; Check to see if this is F_Make
  86.     jp    nz,Next    ; pass the call to next RSX or BDOS if not
  87.  
  88.     push    ix    ;save calling program registers
  89.     push    de
  90.     push    bc
  91.  
  92.     ld    ix,(wboot)    ;Block system access to
  93.     ld    (ix+time),off    ; the current time
  94.  
  95.     ld    c,T_Set        ;Set system time
  96.     ld    de,DaT
  97.     call    cpm
  98.  
  99.     pop    bc        ;do F_Make as requested
  100.     pop    de
  101.     call    Next
  102.  
  103.     ld    ix,(wboot)    ;Restore system access to
  104.     ld    (ix+time),on    ; the current time
  105.     pop    ix
  106.     ret
  107.  
  108.     end
  109.