home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / tcj / tcj37-l2.wsa < prev    next >
Encoding:
Text File  |  1994-09-02  |  3.6 KB  |  137 lines
  1.  
  2. ; PROGRAM:  UTILPAT -- Utility Patch
  3. ; AUTHOR:   Jay Sage
  4. ; DATE:     November 30, 1988
  5.  
  6. ; This patch *may* allow BIOS-specific utilities to
  7. ; work under NZ-COM.
  8.  
  9. ; The address below must be set to the first free byte
  10. ; after the utility's code.
  11.  
  12. patchaddr    equ    0000h
  13.  
  14. ; The address below must be set to the address at which
  15. ; execution will continue after the patch code is
  16. ; executed.
  17.  
  18. startaddr    equ    0000h
  19.  
  20. ; The following macro should be filled in with any opcodes
  21. ; that were at address 100H and following and had to be
  22. ; replaced by the jump to the patch code.  If the utility
  23. ; began with a JP STARTADDR instruction, then leave this
  24. ; macro blank
  25.  
  26. replaced    macro
  27.                 ; put instructions here
  28.         endm
  29.  
  30. ; The macro below is used to enter the list of addresses
  31. ; at which LD HL,(0001) instructions appear that must be
  32. ; patched.  Replace the symbol ADDR1 by the first such
  33. ; address and insert additional similar lines for any other
  34. ; addresses to be patched.
  35. ; 
  36. addrlist    macro
  37.     dw    addr1        ; Repeat for each address
  38.         endm
  39.  
  40. ldhl    equ    21h        ; Load-hl-direct opcode
  41. offset    equ    5ah - 3        ; Offset from BIOS warm boot entry
  42.                 ; ..to the NZ-COM signature
  43.  
  44. ; The following code will be patched in at address 100h to
  45. ; vector control to the patch code.
  46.  
  47.     org    100h
  48.  
  49.     jp    patchaddr
  50.  
  51. ; The actual patch code begins here.
  52.  
  53.     org    patchaddr
  54.  
  55. ; If NZ-COM is running, HL will now contain the ENV address.
  56. ; We will need this later, so we save it.
  57.  
  58.     ld    (envaddr),hl
  59.  
  60. ; Now we must find out if NZ-COM is running.  This is done
  61. ; by looking for its signature "NZ-COM" at a specific offset
  62. ; from the virtual BIOS warm boot entry point.  If this
  63. ; signature is not found, the patch can be skipped.
  64.  
  65.     ld    hl,(0001)    ; Get possible virtual
  66.                 ; ..BIOS address
  67.     ld    de,offset    ; Offset to signature
  68.     add    hl,de
  69.     ld    de,signature    ; Point to what the
  70.                 ; ..signature should be
  71.     ld    b,sigsize    ; Length of signature
  72. sigloop:
  73.     ld    a,(de)
  74.     cp    (hl)        ; Check character
  75.     inc    de        ; Advance pointers
  76.     inc    hl
  77.     jr    nz,exitpatch    ; Jump if not NZ-COM system
  78.     djnz    sigloop        ; Loop through signature
  79.  
  80. ; We get here if NZ-COM is running.  Now we must make the
  81. ; necessary patches to the utility.  First we must determine
  82. ; the address of the warm boot entry to the real BIOS.
  83. ; NZ-COM keeps the page address at offset 2 into the ENV.
  84.  
  85. envaddr    equ    $ + 1
  86.     ld    hl,$-$        ; Filled in by code above
  87.     inc    hl        ; Advance to CBIOS page
  88.     inc    hl
  89.     ld    a,(hl)        ; Get page of CBIOS
  90.     ld    (cbiospage),a    ; Put it into code below
  91.  
  92. ; Now we patch in the changes to the utility code.
  93.  
  94.     ld    de,table    ; Point to address table
  95.     ld    b,tablesize    ; Addresses in table
  96. patchloop:
  97.     ld    a,(de)        ; Low byte of address
  98.     inc    de        ; Advance pointer
  99.     ld    l,a        ; Put in low byte of HL
  100.     ld    a,(de)        ; High byte of address
  101.     inc    de        ; Advance pointer
  102.     ld    h,a        ; Put in high byte of HL
  103.     ld    (hl),ldhl    ; Patch in direct-load opcode
  104.     inc    hl
  105.     ld    (hl),03H    ; Low warm boot address
  106.     inc    hl
  107. cbiospage equ    $ + 1
  108.     ld    (hl),0        ; Filled in by code above
  109.     djnz    patchloop    ; Loop through address list
  110.  
  111. exitpatch:
  112.  
  113. ; Here we have to exit from the patch and resume execution
  114. ; of the original utility.  First we execute instructions, if
  115. ; any, replaced by the patch intercept code.
  116.  
  117.     replaced        ; Macro
  118.  
  119. ; Then we jump to the utility code.
  120.  
  121.     jp    startaddr
  122.  
  123. ; The following is what the NZ-COM signature should look like.
  124.  
  125. signature:
  126.     db    'NZ-COM'
  127. sigsize    equ    $ - signature
  128.  
  129. ; We put the table of addresses to patch here.
  130.  
  131. table:
  132.     addrlist        ; Macro with address list
  133. tablesize    equ    ( $ - table ) / 2
  134.  
  135.     end
  136.  
  137.