home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / jsage / znode3 / ampro / diskpram.asm < prev    next >
Encoding:
Assembly Source File  |  1994-09-02  |  9.9 KB  |  513 lines
  1. ; DISKPRAM.ASM
  2. ; 
  3. ; 
  4. ; DISKPRAM intended use is to determine the the values of the DISK
  5. ; PARAMETER BLOCK and the SKEW TRANSLATION TABLE of a system alien
  6. ; to Ampro MULTIDSK program.  After the host system parameters are
  7. ; are determined ESET may be used to set up the E: drive on the 
  8. ; AMPRO system
  9. ;
  10. ; DISKPRAM displays the disk parameter block and the skew translation
  11. ; table maintained in the target cp/m 2.2 bios in any selected system
  12. ;
  13. ; DISKPRAM is the conbination of DPB.ASM and SKEW.ASM by 
  14. ; Robert C. Kuhman, Sysop of the Cro's Nest RCP/M. 
  15. ;
  16. ;****************************************************************
  17. ; Revisions:
  18. ;        V1.00 as of 27/10/84  Fred Willink
  19. ;****************************************************************
  20. ;
  21. BOOT    EQU    0        ;
  22. BDOS    EQU    05H        ;
  23. FCB1    EQU    5CH        ;
  24. ;
  25. ;  other equates
  26. ;
  27. ACROSS    EQU    8
  28. ;
  29. ; ampro bios disk id save area
  30. ;
  31. ; ascii equates
  32. ;
  33. BELL    EQU    07H        ; bell
  34. TAB    EQU    09H        ; horz tab
  35. LF    EQU    0AH        ; line feed
  36. CR    EQU    0DH        ; carriage return
  37. SPC    EQU    20H        ; space
  38. ;
  39.     ORG    100H
  40. ;
  41. START:    LXI    H,0
  42.     DAD    SP        ; hl=ccp stack pointer
  43.     LXI    SP,STACK    ; set up local stack
  44.     PUSH    H        ; save the ccp pointer for return
  45. TEST:    LDA    FCB1+1
  46.     CPI    '/'
  47.     JZ    HELP        ; help
  48.     CPI    '?'
  49.     JZ    HELP
  50.     CALL    DPB
  51.     CALL    SKEW
  52.     JMP    EXIT
  53. ;
  54. HELP:    LXI    H,HLPMSG    ; point to help message
  55.     CALL    COSTR        ; display help
  56. ;
  57. ; exit no warm boot
  58. ;
  59. EXIT:    POP    H        ; recover ccp"s stack ptr
  60.     SPHL
  61.     RET
  62. ;
  63. DPB:    LDA    FCB1        ; drive code given ?
  64.     DCR    A        ; convert a=1 to 0
  65.     JP    DPB2
  66.     CALL    FCN25
  67. DPB2:    MOV    E,A        ; save for select
  68.     ADI    'A'        ; make drive code printable
  69.     STA    DRIVE
  70.     CALL    FCN14
  71.     CALL    FCN31
  72.     PUSH    H        ; save it for dump
  73. ;
  74.     LXI    D,SPT        ; make dph values printable
  75.     CALL    CVT2
  76.     LXI    D,BSH
  77.     CALL    CVT1
  78.     LXI    D,BLM
  79.     CALL    CVT1
  80.     LXI    D,EXM
  81.     CALL    CVT1
  82.     LXI    D,DSM
  83.     CALL    CVT2
  84.     LXI    D,DRM
  85.     CALL    CVT2
  86.     LXI    D,ALV0
  87.     CALL    CVT1
  88.     LXI    D,ALV1
  89.     CALL    CVT1
  90.     LXI    D,CKS
  91.     CALL    CVT2
  92.     LXI    D,OFF
  93.     CALL    CVT2
  94. ;
  95.     LXI    H,DSPLAY    ; dph table
  96.     CALL    COSTR        ; print it all
  97.     POP    H
  98.     MVI    B,15
  99.     CALL    HEXDMP        ; print hexdump of dpb
  100.     CALL    COCRLF
  101.     CALL    COCRLF
  102.     RET
  103. ;
  104. SKEW:    MVI    A,ACROSS    ; number of records to display across screen
  105.     STA    NPRINT        ; save
  106.     LDA    FCB1        ; see if drive was specified
  107.     DCR    A        ; test ff=no
  108.     JP    REC2        ; yes, select drive
  109.     CALL    FCN25        ; no, get current drive
  110. REC2:    MOV    E,A
  111.     MOV    C,A
  112.     CALL    FCN14        ; select drive
  113.     CALL    FCN31        ; get address of dph
  114.     MOV    E,M
  115.     INX    H
  116.     MOV    D,M
  117.     XCHG
  118.     SHLD    NRECS        ; save dph address for records per track
  119.     MVI    A,24        ; offset for seldsk:
  120.     CALL    BIOS        ; hl=dph, de=xlate table
  121.     MOV    E,M
  122.     INX    H
  123.     MOV    D,M        ; de=dph
  124.     PUSH    H
  125.     PUSH    D
  126.     PUSH    B
  127.     XCHG            ; dph in hl
  128.     SHLD    DPHADR        ; and save
  129.     CALL    HEXADR        ; display dph address
  130.     LXI    H,DPH        ; trailer message for address
  131.     CALL    COSTR        ; display
  132.     POP    B
  133.     POP    D
  134.     POP    H
  135.     MOV    A,E        ; get low byte
  136.     ORA    D        ; or with high
  137.     JNZ    REC3        ; if zero no translate done
  138.     LXI    H,NXLATE    ; no translate message
  139.     CALL    COSTR
  140.     RET
  141. ;
  142. REC3:    LXI    B,0        ; clear record number
  143.     XRA    A        ; clear a
  144.     STA    POSIT        ; initialize counter
  145. ;
  146. RECLOP:    MVI    A,45        ; offset to sectran
  147.     CALL    BIOS        ; hl=xlate (bc)
  148.     CALL    PRINT        ; display results
  149.     LHLD    NRECS        ; 
  150.     DCX    H
  151.     MOV    A,L
  152.     ORA    H
  153.     JZ    SHOWD
  154.     SHLD    NRECS
  155.     INX    B
  156.     JMP    RECLOP        ; till through
  157. ;
  158. SHOWD:    LXI    H,TBLMSG    ; for skew table
  159.     CALL    COSTR        ; display
  160.     MVI    A,20        ; number of entries
  161.     STA    POSIT        ; set counter
  162.     LHLD    DPHADR        ; get dph address
  163.     SHLD    LAST        ; save it
  164.     JMP    ENTRY
  165. ;
  166. MORE:    LHLD    LAST        ; get last position
  167.     INX    H        ; update and
  168.     SHLD    LAST        ; save it
  169. ENTRY:    MOV    E,M        ; get byte
  170.     MVI    D,0        ; zero d
  171.     MOV    A,E        ; value in a
  172.     CPI    27        ; largest value
  173.     JNC    ZERFIL        ;
  174.     CPI    1        ; start of table
  175.     JZ    WHERE        ; what position
  176.     CPI    0        ;
  177.     JNZ    NOPE        ; none of those
  178. WHERE:    LDA    POSIT        ; see where in table
  179.     CPI    20        ; first position of 20
  180.     JNZ    ZERFIL        ; see if need zeros
  181. NOPE:    XCHG            ; hl has value
  182.     CALL    DECOUT        ; print decimal value
  183.     LDA    POSIT        ; get count
  184.     CPI    0        ; see if done
  185.     RZ            ; yes, return
  186.     MVI    A,','        ; insert comma
  187.     CALL    COUT
  188.     CALL    COSPAC        ; insert space
  189.     LDA    POSIT        ; see if done
  190.     CPI    0
  191.     JZ    ZERFIL        ; fill remainder
  192. NOTDON:    DCR    A        ; count down
  193.     STA    POSIT        ; and save
  194.     JMP    MORE
  195. ;
  196. ZERFIL:    LDA    POSIT        ; how many zero's
  197.     CPI    0
  198.     RZ            ; done if zero
  199.     DCR    A        ; count down
  200.     STA    POSIT        ; and save
  201.     MVI    A,'0'
  202.     CALL    COUT        ; print '0'
  203.     LDA    POSIT
  204.     CPI    0        ; see if through now
  205.     RZ
  206.     MVI    A,','
  207.     CALL    COUT        ; print ','
  208.     CALL    COSPAC        ; print space
  209.     JMP    ZERFIL
  210. ;
  211. ; convert binary in hl to ascii decimal
  212. ;
  213. DECOUT:    MVI    B,0        ; leading zero fill
  214.     LXI    D,-100
  215.     CALL    SUBTR        ; hundreds
  216.     LXI    D,-10
  217.     CALL    SUBTR        ; tens
  218.     MOV    A,L
  219.     ADI    '0'        ; ascii bias
  220.     JMP    COUT        ; print and return to caller
  221. ;
  222. ; subtract powers of 10
  223. ;
  224. SUBTR:    MVI    C,'0'-1        ; ascii count
  225. SUBT2:    INR    C
  226.     DAD    D        ; add neg number
  227.     JC    SUBT2
  228. ;
  229. ; one to many add one back
  230. ;
  231.     MOV    A,D        ; complement
  232.     CMA            ; de
  233.     MOV    D,A
  234.     MOV    A,E
  235.     CMA
  236.     MOV    E,A
  237.     INX    D
  238.     DAD    D
  239.     MOV    A,C        ; get count
  240. ;
  241. ; check for zero
  242. ;
  243.     CPI    '1'        ; less than 1?
  244.     JNC    NZERO        ; no
  245.     MOV    A,B        ; check 0 flag
  246.     ORA    A
  247.     MOV    A,C        ; restore
  248.     RZ            ; skip leading zero
  249.     JMP    COUT        ; print character
  250. ;
  251. ; set flag for non-zero character
  252. ;
  253. NZERO:    MVI    B,0FFH        ; set to zero
  254.     JMP    COUT        ; print
  255.     RET
  256. ;
  257. ; print record entry
  258. ;
  259. PRINT:    CALL    HEXADR        ; print hl as hex words
  260.     CALL    COSPAC        ; insert space
  261.     LDA    NPRINT        ; see if end of line
  262.     DCR    A
  263.     STA    NPRINT        ; update
  264.     RNZ
  265.     MVI    A,ACROSS    ; how many lines across
  266.     STA    NPRINT        ; save
  267.     CALL    COCRLF        ; start new line
  268.     RET
  269. ;
  270. ; select disk, 'e' has drive number
  271. ;
  272. FCN14:    PUSH    B
  273.     PUSH    D
  274.     PUSH    H
  275.     MVI    C,14
  276.     CALL    BDOS
  277.     POP    H
  278.     POP    D
  279.     POP    B
  280.     RET
  281. ;
  282. ; get current disk number, returns current disk in 'a'
  283. ;
  284. FCN25:    PUSH    B
  285.     PUSH    D
  286.     PUSH    H
  287.     MVI    C,25        ; no drive given, get current disk
  288.     CALL    BDOS
  289.     POP    H
  290.     POP    D
  291.     POP    B
  292.     RET
  293. ;
  294. ; get disk parameters, returns 'hl'=dpb address
  295. ;
  296. FCN31:    PUSH    B
  297.     PUSH    D
  298.     MVI    C,31        ; hl = dpb for current disk
  299.     CALL    BDOS
  300.     POP    D
  301.     POP    B
  302.     RET
  303. ;
  304. CVT2:    PUSH    H        ; display 16 bit integer
  305.     INX    H
  306.     CALL    CVT1
  307.     XTHL
  308.     CALL    CVT1
  309.     POP    H
  310.     RET
  311. ;
  312. CVT1:    MOV    A,M        ; display byte at 'hl'
  313.     INX    H
  314. CVT1A:    CALL    HEXBYT        ; a,c=ascii display
  315.     STAX    D
  316.     INX    D
  317.     MOV    A,C
  318.     STAX    D
  319.     INX    D
  320.     RET
  321. ;
  322. ; Subroutine to do an addressed dump of one line. HL point to data,
  323. ; 'B' has length
  324. ;
  325. HEXDMP:    CALL    HEXADR        ; display hl contents in hex
  326.     MVI    A,':'
  327.     CALL    COUT
  328.     CALL    COSPAC
  329. ;
  330. HEXLIN:    PUSH    B
  331.     PUSH    H
  332. HEXL2:    MOV    A,M
  333.     CALL    COHEX        ; display hl in hex
  334.     CALL    COSPAC        ; space
  335.     INX    H
  336.     DCR    B
  337.     JNZ    HEXL2
  338.     POP    H
  339.     POP    B
  340.     RET 
  341. ;
  342. ; Subroutine to print hl as an address in hex
  343. ;
  344. HEXADR    MOV    A,H
  345.     CALL    COHEX
  346.     MOV    A,L
  347.     CALL    COHEX
  348.     RET
  349. ;
  350. ; print the hex byte in 'a'
  351. ;
  352. COHEX:    PUSH    PSW        ; save byte
  353.     CALL    HEXLFT        ; get left half
  354.     CALL    COUT        ; and print
  355.     POP    PSW        ; restore byte
  356.     CALL    HEXRHT        ; right half and
  357.     CALL    COUT        ; print
  358.     RET
  359. ;
  360. HEXLFT:    RAR            ; make left nibble
  361.     RAR
  362.     RAR
  363.     RAR
  364. ;
  365. HEXRHT:    ANI    0FH        ; make right nibble
  366.     CPI    0AH
  367.     JC    HEXLR
  368.     ADI    'A'-3AH
  369. ;
  370. HEXLR:    ADI    '0'
  371.     RET
  372. ;
  373. ; suboutrine to return the hex value of 'a',
  374. ; least significant half in 'c', most significant in 'a'.
  375. ; used when ascii-hex is to be stored.
  376. ;
  377. HEXBYT:    PUSH    PSW        ; save
  378.     CALL    HEXRHT        ; get right nibble
  379.     MOV    C,A        ; save in c
  380.     POP    PSW        ; restore and get
  381.     CALL    HEXLFT        ; left nibble
  382.     RET
  383. ;
  384. ; subroutine to write 'a' to console
  385. ;
  386. COUT:    PUSH    B
  387.     PUSH    D
  388.     PUSH    H
  389.     ANI    7FH        ; strip bit 7
  390.     MOV    E,A
  391.     MVI    C,2        ; cp/m fcn 2
  392.     CALL    BDOS        ; 
  393.     POP    H
  394.     POP    D
  395.     POP    B
  396.     RET
  397. ;
  398. ; print cr,lf to the console
  399. ;
  400. COCRLF:    PUSH    PSW
  401.     MVI    A,CR        ; carriage return
  402.     CALL    COUT        ; print it
  403.     MVI    A,LF        ; line feed
  404.     CALL    COUT        ; and print it
  405.     POP    A
  406.     RET
  407. ;
  408. ; subroutine to write a space to the console
  409. ;
  410. COSPAC:    PUSH    PSW
  411.     MVI    A,SPC        ; space
  412.     CALL    COUT        ; and print it
  413.     POP    PSW
  414.     RET
  415. ;
  416. ; subroutine to write bytes addressed by hl, terminated by last byte with
  417. ; 80 bit set.
  418. ;
  419. COSTR    MOV    A,M        ; get byte
  420.     CALL    COUT        ; print
  421.     MOV    A,M        ; again and test
  422.     RLC            ; for bit 7 set
  423.     RC            ; yes, return
  424.     INX    H        ; next byte
  425.     JMP    COSTR        ; and continue
  426. ;
  427. ; bios service, offset in 'a'
  428. ;
  429. BIOS:    PUSH    B
  430.     PUSH    D
  431.     LHLD    BOOT+1        ; get warm boot address
  432.     ADD    L        ; add offset to wboot
  433.     MOV    L,A        ; to address of service
  434.     PUSH    H        ; save it
  435.     LXI    H,BIORET    ; return address
  436.     XTHL
  437.     PCHL
  438. ;
  439. BIORET:    POP    D
  440.     POP    B
  441.     RET
  442. ;
  443. ;  message strings
  444. ;
  445. DSPLAY:    
  446.     DB    'DPB table for drive '
  447. DRIVE:    DS    1
  448.     DB    ':',CR,LF
  449.     DB    'SPT:  '
  450. SPT:    DS    4
  451.     DB    'H',TAB,'Sectors per track.',cr,lf
  452.     DB    'BSH:  '
  453. BSH:    DS    2
  454.     DB    'H',TAB,'Block shift.',cr,lf
  455.     DB    'BLM:  '
  456. BLM:    DS    2
  457.     DB    'H',TAB,'Block mask.',cr,lf
  458.     DB    'EXM:  '
  459. EXM:    DS    2
  460.     DB    'H',TAB,'Extent mask.',cr,lf
  461.     DB    'DSM:  '
  462. DSM:    DS    4
  463.     DB    'H',TAB,'Disk size-1.',cr,lf
  464.     DB    'DRM:  '
  465. DRM:    DS    4
  466.     DB    'H',TAB,'Directory entries-1.',cr,lf
  467.     DB    'ASV0: '
  468. ALV0:    DS    2
  469.     DB    'H',TAB,'Directory group allocation 0.',cr,lf
  470.     DB    'ALV1: '
  471. ALV1:    DS    2
  472.     DB    'H',TAB,'Directory group allocation 1.',cr,lf
  473.     DB    'CKS:  '
  474. CKS:    DS    4
  475.     DB    'H',TAB,'Check size.',cr,lf
  476.     DB    'OFF:  '
  477. OFF:    DS    4
  478.     DB    'H',TAB,'Offset (number of reserve tracks).',cr,lf,lf
  479. ;
  480. DMPMSG:    DB    '"DPB address and hex dump of table."'
  481.     DB    CR,LF+80H
  482. ;
  483. NXLATE:    DB    BELL,'Diskette needs no translation.',cr,lf+80h
  484. ;
  485. TBLMSG:    DB    'Skew table decimal values.',cr,lf+80h
  486. ;
  487. DPH:    DB    ': (DPH address)',CR,LF+80H
  488. ; User help
  489. ;
  490. HLPMSG:    DB    'DISKPRAM.COM - <H E L P>',CR,LF,LF
  491.     DB    'Syntax:',CR,LF
  492.     DB    'A0>DISKPRAM <cr>    - DPB and SKEW table for defalt drive',CR,LF
  493.     DB    'A0>DISKPRAM d:      - Tables for selected drive',CR,LF
  494.     DB    'A0>DISKPRAM ? or /  - Displays this message',CR,LF
  495. ;
  496.     DB    CR,LF,'This program is designed to provide the user with a tool'
  497.     DB    CR,LF,'that is able to display the DPB and SKEW table of a CP/M'
  498.     DB    CR,LF,'2.2 system.  This information can be used as the decimal'
  499.     DB    CR,LF,'input for a program such as ESET.COM written for the AMPRO'
  500.     DB    CR,LF,'system.  With ESET the AMPRO''s E: drive may be used to read'
  501.     DB    CR,LF,'and write alien 5" diskette formats',CR,LF,LF+80H
  502. ;
  503. NRECS:    DS    2
  504. NPRINT:    DS    1
  505. DPHADR:    DS    2
  506. POSIT:    DS    1
  507. LAST:    DS    2
  508. ;
  509.     DS    30
  510. STACK:    EQU    $
  511. ;
  512.     END
  513.