home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / beehive / zcat / z3key14.lbr / Z3KEYRCP.ZZ0 / Z3KEYRCP.Z80
Text File  |  1991-01-31  |  18KB  |  790 lines
  1. ;  SYSTEM SEGMENT:  Z3KEY.RCP
  2. ;  WRITTEN BY:  ARNOLD BAILEY
  3.  
  4. ;
  5. ;  PROGRAM:  Z3KEYRCP.Z80
  6. ;  AUTHOR:  ARNOLD BAILEY
  7. ;  VERSION:  1.4
  8. ;  DATE:  25 JAN 86
  9. ;  PREVIOUS VERSIONS:  1.0, 1.1, 1.2, 1.3
  10.  
  11. ;  VERSION 1.4 IMPROVED INSTALLATION FOR USERS
  12.  
  13. ;  VERSION 1.3 ADDS FULL SUPERSHIFT KEY ABILITY. AND COMPILED KEY DEFINITION
  14. ;  INPUTS WITH Z3KEY.COM
  15. ;
  16. ;  VERSION 1.2 ADDS ABILITY TO DISPLAY THE KEY DEFINITIONS BY THE USE OF THE
  17. ;  KEYS COMMMAND.
  18.  
  19. ;
  20. ;  VERSION 1.1 ADDS CONTROLLED EXPANSION RATE OF MACROS TO PREVENT PROGRAMS
  21. ;  THAT CLEAR INCOMING CHARACTERS UPON ENTRY FROM THROWING AWAY THE REST OF
  22. ;  A MACRO EXPANSION.
  23. ;
  24.  
  25.  
  26. VERSION    EQU    14
  27.  
  28. ;
  29. ; ZKEYRCP IS A RESIDENT COMMAND PROCESSOR FOR ZCPR3.  IT PROVIDES THE 
  30. ; FOLLOWING FUNCTIONS:
  31. ; 
  32. ;    1. ALLOWS ON THE FLY RE-DEFINITION OF THE KEYBOARD. EVEN WHILE IN
  33. ;      A PROGRAM.
  34. ;
  35. ;    2. ALLOWS DEFINING A KEY AS THE GENERATOR OF A MACRO STRING.
  36. ;
  37. ;    3. USER DEFINIED LEADIN KEY FOR USE OF MULTI CHARACTER FUNCTION KEYS.
  38. ;
  39. ;    4. VARIABLE DELAY ALLOWS THE LEADIN KEY TO BE USED AS A SUPER SHIFT KEY.
  40. ;
  41. ;    5. CASE FLAG CAN AUTOMATICALLY UPCASE ANY CHARACTER AFTER THE LEADIN
  42. ;     CHARACTER.
  43. ;    
  44. ;    6. Z3KEY.COM UTILITY ALLOWS RE-DEFINITION OF THE ATTENTION KEY, LEADIN
  45. ;       KEY, DELAY, CASE FLAG, AND SAVING A SET OF DEFINITIONS TO A DISK FILE.
  46. ;
  47. ;
  48. ;
  49. ;  GLOBAL LIBRARY WHICH DEFINES ADDRESSES FOR ZKEYRCP
  50. ;
  51. *INCLUDE    Z3BASE.LIB        ; USE BASE ADDRESSES
  52. *INCLUDE    Z3KEYRCP.LIB        ;INITIALIZATION DEFINITIONS
  53. ;
  54. CTRLC    EQU    'C'-'@'
  55. TAB    EQU    09H
  56. LF    EQU    0AH
  57. FF    EQU    0CH
  58. CR    EQU    0DH
  59. CTRLX    EQU    'X'-'@'
  60. ;
  61. WBOOT    EQU    BASE+0000H    ; CP/M WARM BOOT ADDRESS
  62. UDFLAG    EQU    BASE+0004H    ; USER NUM IN HIGH NYBBLE, DISK IN LOW
  63. BDOS    EQU    BASE+0005H    ; BDOS FUNCTION CALL ENTRY PT
  64. TFCB    EQU    BASE+005CH    ; DEFAULT FCB BUFFER
  65. FCB1    EQU    TFCB        ; 1ST AND 2ND FCBS
  66. FCB2    EQU    TFCB+16
  67. TBUFF    EQU    BASE+0080H    ; DEFAULT DISK I/O BUFFER
  68. TPA    EQU    BASE+0100H    ; BASE OF TPA
  69. ;
  70. ;  SYSTEM ENTRY POINT
  71. ;
  72.  
  73.     ORG    RCP
  74.  
  75.     DB    'Z3RCP'        ; FLAG FOR PACKAGE LOADER
  76. ;
  77. ;  **** COMMAND TABLE FOR RCP ****
  78. ;    THIS TABLE IS RCP-DEPENDENT!
  79. ;
  80. ;    THE COMMAND NAME TABLE IS STRUCTURED AS FOLLOWS:
  81. ;
  82. ;    CTABLE:
  83. ;        DB    'CMNDNAME'    ; TABLE RECORD STRUCTURE IS
  84. ;        DW    CMNDADDRESS    ; 8 CHARS FOR NAME AND 2 BYTES FOR ADR
  85. ;        ...
  86. ;        DB    0    ; END OF TABLE
  87. ;
  88. CNSIZE    EQU    5        ; NUMBER OF CHARS IN COMMAND NAME
  89.     DB    CNSIZE        ; SIZE OF TEXT ENTRIES
  90. CTAB:
  91.     DB    'H    '        ; HELP FOR RCP
  92.     DW    CLIST
  93. CTAB1:
  94.     DB    'KEY+ '        ;CLEAR SCREEN COMMMAND
  95.     DW    KEYON
  96.  
  97.     DB    'KEY- '
  98.     DW    KEYOFF
  99.  
  100.     DB    'CASE+'
  101.     DW    CASEON
  102.  
  103.     DB    'CASE-'
  104.     DW    CASEOFF
  105.  
  106.     DB    'KSTAT'
  107.     DW    STATUS
  108.  
  109.     IF    KEYDEF
  110.  
  111.     DB    'KEYS '
  112.     DW    KEYS
  113.  
  114.     ENDIF
  115.  
  116.     DB    0
  117. ;
  118. ; THE KEY DEFINITION BUFFER AND VARIABLES MUST FOLLOW HERE SO THAT THE
  119. ; Z3KEY.COM UTILITY CAN FIND THEM PROPERLY.
  120. ;
  121.  
  122. ID    DB    'Z3KEY'        ;IDENTIFIER TO Z3KEY UTILITY
  123.  
  124. NAME    DB    '        ',0    ;NAME OF RCP STORED HERE WHEN DEFINITION SAVED
  125.  
  126. CASEFLG:            ;IF NOT ZERO THEN ALL CHAR AFTER LEADIN WILL   
  127.     DB    UPCASE        ;BE UPPERCASE                                  
  128.  
  129. DELAY:    DW    DELAYCNT    ;DELAY FOR FUNCTION KEY SECOND CHAR
  130.  
  131. INSFLG:    DB    00H        ;FLAG TO INDICATE WHETHER INSTALLED OR NOT
  132.  
  133. EXRATE:    DB    EXPRATE        ;COUNT FOR CONST CALLS BEFORE CHARACTER SENT
  134.  
  135. KTSIZE    DW    KEYTBLS        ;LENGTH OF TABLE
  136.  
  137. ATTN:                ;ATTENTION CHAR TO SIGNAL DEFINITION INPUT
  138.     DB    ATTNCHAR
  139.  
  140. LEADIN:                ;LEAD IN CHARACTER FOR FUNCTION KEYS
  141. KEYTBL:
  142.     DB    LEADCHR,LEADCHR+128,0
  143.                 ;DOUBLE CHARACTER DEFINES SINGLE LEADIN AS
  144.                 ;LEADIN CHARACTER
  145.     DS    TABLESIZE
  146.                 ;RESERVE BLANK SPACE FOR TABLE
  147.  
  148. KEYEND:
  149.  
  150.     DB    0,0        ;GUARD BYTES JUST IN CASE
  151.  
  152. KEYTBLS:    EQU    KEYEND-KEYTBL    ;KEY TABLE SIZE
  153.  
  154. ;
  155. ;  BANNER NAME OF RCP
  156. ;
  157. RCP$NAME:
  158.     DB    'Z3KEY '
  159.     DB    [VERSION/10]+'0','.',[VERSION MOD 10]+'0'
  160.     DB    RCPID,0DH,0AH,0AH
  161.     DB    ' KEY+ activates key definitions',0DH,0AH
  162.     DB    ' KEY- deactivates key definitions',0DH,0AH,0AH
  163.     DB    ' KEY- must be run before loading a new RCP',0DH,0AH
  164.     DB    0
  165.  
  166. ;
  167. ;  COMMAND LIST ROUTINE
  168. ;
  169. CLIST:
  170.     LD    HL,NAME
  171.     CALL    PRINT1
  172.     CALL    CRLF
  173.     LD    HL,RCP$NAME    ; PRINT RCP NAME
  174.     CALL    PRINT1
  175.     LD    HL,CTAB1    ; PRINT TABLE ENTRIES
  176.     LD    C,1        ; SET COUNT FOR NEW LINE
  177. CLIST1:
  178.     LD    A,(HL)        ; DONE?
  179.     OR    A
  180.     RET    Z
  181.     DEC    C        ; COUNT DOWN
  182.     JR    NZ,CLIST1A
  183.     CALL    CRLF        ; NEW LINE
  184.     LD    C,4        ; SET COUNT
  185. CLIST1A:
  186.     LD    DE,ENTRYNAME    ; COPY COMMAND NAME INTO MESSAGE BUFFER
  187.     LD    B,CNSIZE    ; NUMBER OF CHARS
  188. CLIST2:
  189.     LD    A,(HL)        ; COPY
  190.     LD    (DE),A
  191.     INC    HL        ; PT TO NEXT
  192.     INC    DE
  193.     DJNZ    CLIST2
  194.     INC    HL        ; SKIP TO NEXT ENTRY
  195.     INC    HL
  196.     PUSH    HL        ; SAVE PTR
  197.     LD    HL,ENTRYMSG    ; PRINT MESSAGE
  198.     CALL    PRINT1
  199.     POP    HL        ; GET PTR
  200.     JR    CLIST1
  201.  
  202. CRLF:    LD    A,0DH
  203.     CALL    CONOUT
  204.     LD    A,0AH
  205. ;
  206. ;  CONSOLE OUTPUT ROUTINE
  207. ;
  208. CONOUT:
  209.     PUSH    HL        ; SAVE REGS
  210.     PUSH    DE
  211.     PUSH    BC
  212.     PUSH    AF
  213.     AND    7FH        ; MASK MSB
  214.     LD    E,A        ; CHAR IN E
  215.     LD    C,2        ; OUTPUT
  216.     CALL    BDOS
  217.     POP    AF        ; GET REGS
  218.     POP    BC
  219.     POP    DE
  220.     POP    HL
  221.     RET
  222. ;
  223. ;  PRINT STRING [TERMINATED IN 0 OR MSB SET] AT RETURN ADDRESS
  224. ;
  225. PRINT:
  226.     EX    (SP),HL        ; GET ADDRESS
  227.     CALL    PRINT1
  228.     EX    (SP),HL        ; PUT ADDRESS
  229.     RET
  230. ;
  231. ;  PRINT STRING [TERMINATED IN 0 OR MSB SET] PTED TO BY HL
  232. ;
  233. PRINT1:
  234.     LD    A,(HL)        ; DONE?
  235.     INC    HL        ; PT TO NEXT
  236.     OR    A        ; 0 TERMINATOR
  237.     RET    Z
  238.     CALL    CONOUT        ; PRINT CHAR
  239.     RET    M        ; MSB TERMINATOR
  240.     JR    PRINT1
  241. ;
  242. ;  CLIST MESSAGES
  243. ;
  244. ENTRYMSG:
  245.     DB    '  '        ; COMMAND NAME PREFIX
  246. ENTRYNAME:
  247.     DS    CNSIZE        ; COMMAND NAME
  248.     DB    0        ; TERMINATOR
  249.  
  250. ;
  251. ; UCASE UPCASES CHARACTER IN A
  252. ;
  253.  
  254. UCASE:
  255.     AND    7FH        ; MASK OUT MSB
  256.     CP    'a'        ; LOWER-CASE A
  257.     RET    C
  258.     CP    'z'+1        ; GREATER THAN LOWER-CASE Z?
  259.     RET    NC
  260.     AND    5FH        ; CAPITALIZE
  261.     RET
  262. ;
  263. ;  **** RCP ROUTINES ****
  264. ;  ALL CODE FROM HERE ON IS RCP-DEPENDENT!
  265. ;
  266. ;
  267. ; MESSAGE STRINGS
  268. ;
  269.  
  270. KEYMSG:
  271.     DB    'Key: ',0    ;KEY PROMPT
  272.  
  273. EQMSG:
  274.     DB    ' = ',0        ;EQUAL STRING
  275.  
  276. FULLMSG:
  277.     DB    ' Key Table Full, Press any Key ',0    
  278.  
  279. CMESGON:
  280.     DB    '  Upcase function is on.',0DH,0AH,0
  281.  
  282. KMESGON:
  283.     DB    '  Z3KEY is active.',0DH,0AH,0
  284.  
  285. KMESGOFF:
  286.     DB    '  Z3KEY is inactive.',0DH,0AH,0
  287.  
  288. CMESGOFF:
  289.     DB    '  Upcase function is off.',0DH,0AH,0
  290.     
  291.  
  292. OLDWBOOT:
  293.     JP    0000H        ;STORAGE FOR ORIGINAL BIOS JUMP TABLE
  294. OLDCONST:
  295.     JP    0000H        
  296. OLDCONIN:
  297.     JP    0000H
  298. OLDCONOUT:
  299.     JP    0000H    
  300.  
  301.  
  302. NEWTBL:    JP    NEWCONST    ;THIS JUMP TABLE WILL BE MOVED TO
  303.     JP    NEWCONIN    ;OVERLAY AT CONST TO REDIRECT CONSOLE IO
  304.                 ;TO THE RCP
  305.  
  306. SENDFLG:            ;FLAG TO SHOW THAT A DEFINITION IS BEING SENT
  307.     DB    00H        
  308.  
  309. ENTRYPTR:            ;POINTER TO A FOUND ENTRY IN THE TABLE
  310.     DW    KEYTBL        ;USED TO CLEAR ENTRIES
  311.  
  312. DEFPTR:                ;POINTER TO NEXT CHAR TO BE SENT
  313.     DW    KEYTBL        ;INITIALLY POINTS TO THE START OF THE KEYTABLE
  314.  
  315. LNLEN    DB    0        ;STORAGE FOR DEFINITION LINE LENGTH
  316.  
  317. EXCOUNT    DB    EXPRATE        ;COUNTER FOR EXPANSION RATE
  318.  
  319. INBUFS:    EQU    5        ;SIZE OF INPUT BUFFER FOR FUNCTION KEYS
  320.  
  321. INBUF:                ;INPUT BUFFER FOR FUNCTION KEYS
  322.     DS    INBUFS      ;INITIALIZED TO ZERO
  323.  
  324.     IF    KEYDEF
  325.  
  326. KEYS:
  327.     LD    DE,KEYTBL+3
  328. KS4:    LD    B,14H
  329. KS0:    CALL    CRLF
  330. KS1:
  331.     LD    A,(DE)
  332.     OR    A
  333.     JP    M,KS2
  334.     RET    Z
  335.     CP    ' '
  336.     JR    NC,KS6
  337.     LD    A,'^'
  338.     CALL    CONOUT
  339.     LD    A,(DE)
  340.     ADD    A,40H
  341. KS6:
  342.     CALL    CONOUT
  343.     INC    DE
  344.     JR    KS1
  345. KS2:    
  346.     LD    HL,EQMSG
  347.     CALL    PRINT1
  348. KS3:    
  349.     PUSH    BC
  350.     CALL    SNDMSG
  351.     POP    BC
  352.     DJNZ    KS0    
  353. KS5:
  354.     LD    C,06H
  355.     PUSH    DE
  356.     LD    E,0FFH
  357.     CALL    BDOS
  358.     POP    DE
  359.     OR    A
  360.     JR    Z,KS5
  361.     JR    KS4
  362.  
  363.     
  364.  
  365.     ENDIF
  366.     
  367.  
  368.  
  369. KEYOFF    LD    A,(INSFLG)    ;TURNS OFF THE KEY TRANSLATION AND 
  370.     OR    A        ;UNPATCHES THE BIOS TABLE
  371.     JR    Z,KO1        ;MUST BE RUN BEFORE A NEW RCP IS LOADED
  372.     LD    DE,(WBOOT+1)    ;TO AVOID TRASHING THE BIOS POINTERS
  373.     LD    HL,OLDWBOOT
  374.     LD    BC,12
  375.     LDIR
  376.     XOR    A
  377.     LD    (INSFLG),A
  378. KO1:    LD    HL,KMESGOFF
  379.     JR    S2    
  380.  
  381. KEYON:                ;REDIRECTS CONSOLE IO TO THE RCP
  382.     LD    A,(INSFLG)    ;SEE IF ALREADY ACTIVE
  383.     OR    A
  384.     JR    NZ,KN1        ;RETURN IMMEDIATELY IF NOT 0    
  385.     LD    HL,(WBOOT+1)    ;POINT TO PRESENT BIOS TABLE
  386.     LD    DE,OLDWBOOT    ;POINT TO STORAGE AREA
  387.     LD    BC,12        ;LENGTH OF TABLE
  388.     LDIR            ;MOVE TO STORAGE
  389.     LD    HL,(WBOOT+1)    ;POINT TO PRESENT BIOS TABLE
  390.     LD    BC,3        ;ADD 3 TO POINT TO CONST
  391.     ADD    HL,BC
  392.     EX    DE,HL        ;PUT IN DE
  393.     LD    HL,NEWTBL    ;POINT TO NEW JUMP TABLE
  394.     LD    BC,6        ;LOAD LENGTH
  395.     LDIR            ;MOVE NEW TABLE TO BIOS
  396.     LD    A,0FFH        ;TURN ON INSTALLED FLAG
  397.     LD    (INSFLG),A
  398. KN1:
  399.     LD    HL,NAME        ;DISPLAY NAME OF THIS VERSION OF Z3KEY
  400.     CALL    PRINT1
  401.     CALL     CRLF
  402.     LD    HL,RCP$NAME    ;DISPLAY HELP MENU
  403.     JR    S2
  404.  
  405. CASEON:                ;TURNS ON THE CASE TRANSLATION FLAG
  406.     LD    A,0FFH
  407.     LD    (CASEFLG),A
  408.     LD    HL,CMESGON
  409.     JR    S2
  410.  
  411. CASEOFF:            ;TURNS OFF TTHE CASE TRANSLATION FLAG
  412.     XOR    A
  413.     LD    (CASEFLG),A
  414.     LD    HL,CMESGOFF
  415.     JR    S2
  416.  
  417. STATUS:                ;DISPLAYS PRESENT STATUS OF INSTALLED RCP
  418.     LD    A,(INSFLG)
  419.     OR    A
  420.     LD    HL,KMESGON
  421.     JR    NZ,S1
  422.     LD    HL,KMESGOFF
  423. S1:    CALL     PRINT1
  424.     LD    HL,CMESGON
  425.     LD    A,(CASEFLG)
  426.     OR    A
  427.     JR    NZ,S2
  428.     LD    HL,CMESGOFF
  429. S2:    JP    PRINT1
  430.  
  431. NEWCONST:            ;NEW CONSOLE STATUS ROUTINE
  432.     LD    A,(SENDFLG)    ;SEE IF FLAG SET
  433.     OR    A
  434.     JP    Z,OLDCONST    ;IF ZERO THEN CHECK THE CONSOLE
  435.     LD    A,(EXCOUNT)    ;GET EXPANSION COUNT
  436.     OR    A        ;SET FLAGS
  437.     JR    Z,NS1        ;SKIP IF ZERO
  438.     DEC    A
  439.     LD    (EXCOUNT),A     ;STORE THE NEW COUNT
  440.     XOR    A        ;ZERO A
  441.     RET            ;RET NO CHARACTER AVAILABLE YET
  442. NS1:    LD    A,0FFH        ;CHARACTER AVAILABLE HERE FIRST
  443.     RET            ;SO FLAG IT AND RETURN
  444.  
  445. NEWCONIN:            ;NEW CONSOLE INPUT ROUTINE
  446.     PUSH    HL        ;SAVE THE REGISTERS
  447.     PUSH    DE
  448.     PUSH    BC
  449.     LD    A,(SENDFLG)    ;SEE IF FLAG SET
  450.     OR    A
  451.     JR    NZ,SENDNXT    ;IF NOT ZERO THEN SEND NEXT CHAR OF DEFINITION
  452.     LD    HL,INBUF    ;POINT TO INBUF FOR GETKEY
  453.     CALL    GETKEY        ;GET THE CHARCTER OR FUNCTION KEY
  454.     LD    A,(INBUF)    ;GET FIRST CHAR
  455.     LD    BC,(ATTN)    ;GET ATTENTION CHAR    
  456.     CP     C
  457.     JP    Z,GETDEF    ;IF ATTENTION CHAR THEN GET A KEY DEFINITION
  458.     CALL    FINDKEY        ;ELSE SEARCH THE KEY TABLE RETURNS CHAR IN A
  459. NC1:
  460.     IF    KEYDEF
  461.     AND    7FH
  462.     ENDIF
  463.     POP    BC
  464.     POP    DE
  465.     POP    HL
  466.     RET
  467.  
  468. SENDNXT:            ;SENDS NEXT CHARACTER OF A MACRO KEY
  469.     LD    A,(EXRATE)    ;GET EXPANSION RATE COUNT
  470.     LD    (EXCOUNT),A    ;RESET COUNT
  471.     LD    HL,(DEFPTR)    ;GET POINTER TO NEXT CHARACTER
  472.     LD    B,(HL)        ;MOVE CHARACTER TO A
  473.     INC    HL        ;INCREMENT THE POINTER
  474.     LD    (DEFPTR),HL
  475.     LD    A,(HL)        ;GET NEXT CHAR
  476.     LD    (SENDFLG),A    ;STORE IN FLAG
  477.     LD    A,B        ;MOVE THE CHAR TO A
  478.     JR    NC1        ;AND EXIT
  479.  
  480. GETKEY:                ;GETS A KEY FROM CONSOLE AND STORES IT AT HL
  481.                 ;HL RETURNS POINTING TO 0 AT END OF STRING
  482.     PUSH    HL
  483.     CALL    OLDCONIN    ;ELSE GET CHARACTER FROM CONSOLE
  484.     POP    HL
  485.     LD    (HL),A
  486.     INC    HL
  487.     LD    BC,(LEADIN)    ;LOAD LEADIN CHARACTER TO C
  488.     CP    C        ;SEE IF CHARACTER IS LEADIN CHARACTER
  489.     CALL    Z,CHKLEADIN    ;IF SO THEN CHECK FOR REST OF CHARACTERS
  490.     LD    (HL),0        ;OTHERWISE NO NEED FOR INBUF SO 0
  491.     RET
  492.  
  493. CHKLEADIN:            ;CHECKS FOR MORE CHARACTERS AFTER A LEADIN 
  494.                 ;CHARACTER IF NONE ARRIVE WHITHIN THE PERIOD
  495.                 ;DEFINED BY DELAY IT TERMINATES THE INPUT
  496.  
  497.     LD    BC,(DELAY)    ;LOAD DELAY COUNT
  498.     XOR    A        ;ZERO A REGISTER
  499.     CP    B        ;IS B ZERO
  500.     JR    NZ,CL1        ;IF NOT THEN CONTINUE
  501.     CP    C        ;SEE IF C IS ALSO 0
  502.     JR    NZ,CL1        ;IF 0 THEN TREAT AS SUPERSHIFT KEY
  503.     PUSH    HL        ;SAVE POINTER
  504.     CALL     GETCHAR        ;GET NEXT CHARACTER
  505.     POP    HL        ;RETRIEVE POINTER
  506.     LD    (HL),A
  507.     LD    BC,(LEADIN)
  508.     CP    C
  509.     RET    Z
  510.     INC    HL
  511.     RET
  512.  
  513. CL1:
  514.     PUSH    BC        ;SAVE REGISTERS
  515.     PUSH    HL
  516.     CALL    OLDCONST    ;SEE IF NEXT CHARACTER AVAILABLE YET
  517.     OR    A        ;SET FLAGS
  518.     JR    Z,WAIT        ;IF NOT THEN WAIT A TICK
  519.     CALL    GETCHAR
  520.     POP    HL        ;RETRIEVE POINTER 
  521.     LD    (HL),A        ;STORE NEXT CHARACTER IN INBUF
  522.     INC    HL
  523.     POP    BC        ;CLEANUP STACK
  524.     JR    CHKLEADIN    ;SEE IF MORE CHARACTERS
  525.  
  526. WAIT:
  527.     POP    HL        ;RETRIEVE REGISTERS
  528.     POP    BC
  529.     DEC    BC         ;DECREMENT THE DELAY COUNT
  530.     CP    B        ;A IS ZERO SO SEE IF B IS
  531.     JR    NZ,CL1        ;IF NOT 0 THEN LOOP
  532.     CP    C        ;IF B WAS 0 SEE IF C IS
  533.     JR    NZ,CL1        ;LOOP IF NOT 0
  534.     RET
  535. ;
  536. ; GETCHAR GET A CHARACTER FROM THE OLD CONIN ROUTINE AND APPLIES THE UP CASE IF 
  537. ; THE CASE FLAG IS SET
  538. ;
  539. GETCHAR:
  540.     CALL    OLDCONIN    ;ELSE GET THE CHARACTER
  541.     LD    B,A
  542.     LD    A,(CASEFLG)
  543.     OR    A
  544.     LD    A,B
  545.     CALL    NZ,UCASE
  546.     RET
  547.  
  548.  
  549. ;
  550. ; FINDKEY LOCATES A KEY DEFINITION IN THE TABLE FROM THE STRING POINTED TO
  551. ; BY DE. RETURNS WITH THE ENTRY'S ADDRESS IN ENTRYPTR, A CONTAINS THE FIRST
  552. ; CHARACTER OF THE DEFINITION,DEFPTR POINTS TO SECOND CHARACTER OF DEFINITION
  553. ; SENDFLG IS SET IF MORE CHARACTERS TO SEND FROM THE DEFINITION
  554. ;
  555.  
  556. FINDKEY:            ;INBUF CONTAINS THE KEY CHAR TO BE MATCHED
  557.     LD    DE,INBUF
  558. SCAN:                ;ENTER HERE WITH DE PRESET
  559.     LD    BC,KEYTBLS    ;LOAD SIZE OF KEY TABLE
  560.     LD    HL,KEYTBL    ;POINT TO BEGINNING OF KEY TABLE
  561.     PUSH    DE        ;SAVE POINTER TO THE INPUT STRING
  562. KEYCOMP:
  563.     LD    A,(DE)        ;GET CHAR FROM INBUF
  564.     INC    DE        ;POINT TO NEXT INBUF CHAR
  565.     OR    A        ;END OF INBUF CHARACTERS?
  566.     JR    Z,FOUND        ;IF SO THEN FOUND
  567.     CPI            ;COMPARE INBUF CHAR WITH TABLE
  568.     JR    Z,KEYCOMP    ;IF MATCH THEN CHECK NEXT CHARACTER
  569.     POP    DE        ;IF NOT THEN GET START OF KEY
  570.     PUSH    DE        ;AND SAVE IT AGAIN
  571.     XOR    A        ;FIND A=0 WHICH BEGINS A DEFINITION
  572.     CPIR            ;SEARCH UNTIL 0 FOUND OR END OF TABLE
  573.     JP    PO,NOFIND    ;IF BC=0 THEN END OF TABLE REACHED
  574.     CP    (HL)        ;SEE IF CHARACTER AFTER THE ZERO IS ALSO A ZERO
  575.     JR    Z,NOFIND    ;DOUBLE ZERO MARKS END OF DEFINED TABLE
  576.     LD    (ENTRYPTR),HL    ;SAVE POINTER TO BEGINNING OF ENTRY
  577.     JR    KEYCOMP
  578. FOUND:    
  579.     POP    DE
  580.     LD    B,(HL)        ;GET FIRST CHARACTER
  581.     INC    HL        ;POINT TO NEXT CHAR
  582. FND1:    
  583.     LD    (DEFPTR),HL    ;STORE POINTER TO NEXT CHAR OF TRANSLATION
  584.     LD    A,(HL)        ;LOAD SECOND CHAR
  585.     LD    (SENDFLG),A    ;STORE IN FLAG IF NON ZERO THEN MORE TO SEND
  586.     LD    A,B        ;MOVE FIRST CHAR TO A
  587.     RET
  588. NOFIND:
  589.     POP    HL        ;NOT FOUND SO GET CHARACTERS FROM INPUT BUFFER
  590.     LD    B,(HL)
  591.     INC    HL
  592.     JR    FND1
  593.  
  594. PRTCHR:                ;SEND CHARACTER IN A TO CONSOLE
  595.     PUSH    HL
  596.     PUSH    DE
  597.     PUSH    BC
  598.     PUSH    AF
  599.     LD    C,A
  600.     CALL    OLDCONOUT
  601.     POP    AF
  602.     POP    BC
  603.     POP    DE
  604.     POP    HL
  605.     RET
  606.     
  607. SNDMSG:                ;SEND MESSAGE POINTED TO BY DE TO CONSOLE
  608.                 ;INCREMENTS LNLEN SO MESSAGE CAN BE ERASED
  609.  
  610.     LD    A,(DE)        ;GET CHAR
  611.  
  612.     IF    KEYDEF
  613.     AND    7FH
  614.     ENDIF
  615.  
  616.     INC    DE
  617.     OR    A        ;SET FLAGS
  618.     RET    Z        ;RETURN IF END OF STRING
  619.     CP    ' '        ;CHECK IF LESS THAN SPACE CHARACTER
  620.     JR    NC,SM1        ;JUMP IF >= TO SPACE
  621.     ADD    A,40H        ;ADD OFFSET TO PROPER CHARACTER
  622.     LD    B,A        ;SAVE CHARACTER
  623.     LD    A,'^'        ;LOAD '^' SYMBOL FOR CONTROL CHARACTERS
  624.     CALL    PRTCHR
  625.     LD    A,(LNLEN)    ;INCREMENT THE LINE LENGTH
  626.     INC    A
  627.     LD    (LNLEN),A    ;SAVE NEW VALUE BACK
  628.     LD    A,B    
  629. SM1:    
  630.     CALL    PRTCHR        ;SEND CHARACTER
  631.     LD    A,(LNLEN)    ;INCREMENT THE LINE LENGTH
  632.     INC    A
  633.     LD    (LNLEN),A
  634.     JR    SNDMSG        ;LOOP TIL DONE        
  635.  
  636.  
  637. ;
  638. ; FINDS END OF KEY TABLE. RETURNS END OF TABLE IN HL OR SENDS TABLE FULL
  639. ; MESSAGE. BC CONTAINS SPACE REMAINING IN TABLE
  640. ;
  641.  
  642. FINDEND:
  643.     LD    HL,KEYTBL    ;POINT TO BEGINNING OF TABLE
  644.     LD    BC,KEYTBLS    ;LOAD SIZE OF TABLE
  645. FE1:    XOR    A        ;SEARCH FOR 0 IN TABLE
  646.     CPIR            ;SEARCH UNTIL 0 FOUND OR END OF TABLE
  647.     JP    PO,TBLFULL    ;IF BC=0 THEN END OF TABLE REACHED
  648.     CP    (HL)        ;SEE IF CHAR AFTER THE ZERO IS ALSO A ZERO
  649.     RET    Z        ;DOUBLE ZERO MARKS END OF DEFINED TABLE
  650.     JR    FE1        ;OTHERWISE KEEP LOOKING
  651.         
  652.  
  653. ;
  654. ;GETDEF PROMPTS FOR KEY DEFINITION AND PLACES IT AT THE END OF THE TABLE
  655. ;DELETES PREVIOUS MATCHING DEFINITION IF FOUND
  656. ;
  657.  
  658. GETDEF:
  659.     XOR    A
  660.     LD    (LNLEN),A    ;ZERO LENGTH OF LINE COUNTER
  661.     LD    DE,KEYMSG    ;POINT TO KEY PROMPT
  662.     CALL    SNDMSG        ;SEND THE MESSAGE    
  663.     CALL    FINDEND        ;RETURNS WITH HL POINTING TO END OF KEY TABLE
  664.     OR    A        ;IF A ZERO THEN ROOM REMAINS IN TABLE
  665.     LD    A,0AH        ;LINEFEED
  666.     JP    NZ,NC1        ;IF NOT ZERO THEN EXIT
  667.     PUSH    HL        ;SAVE STARTING ADDRESS
  668.     CALL    GETKEY        ;GET KEY TO BE DEFINED
  669.     POP    DE        ;RETRIEVE STARTING ADDRESS
  670.     PUSH    HL        ;SAVE POINTER TO NEXT CHAR OF DEFINITION
  671.     PUSH     DE        ;SAVE STARTING ADDRESS AGAIN
  672.     LD    BC,(ATTN)    ;MOVE ATTN CHARACTER TO C REGISTER
  673.     LD    A,(DE)        ;GET FIRST CHARACTER OF KEY BEING DEFINED
  674.     CP    C        ;SEE IF IT'S THE ATTENTION CHARACTER
  675.     JR    NZ,GD3        ;IF NOT THEN SKIP NEXT
  676.     POP    DE
  677.     POP    DE        ;CLEAN UP STACK
  678.     JR    ERASE        ;ERASE AND SEND THE ATTENTION CHARACTER
  679. GD3:
  680.     CALL    SNDMSG        ;DISPLAY KEY TO BE DEFINED
  681.     LD    DE,EQMSG    ;POINT TO EQUAL MESSAGE
  682.     CALL    SNDMSG        ;SEND MESSAGE
  683.     POP    DE        ;RETRIEVE STARTING ADDRESS
  684.     PUSH    DE        ;SAVE IT AGAIN
  685.     CALL    SCAN        ;SEARCH TABLE FOR KEY POINTED TO BY DE
  686.     POP    BC        ;RETRIEVE STARTING ADDRESS OF KEY
  687.     LD    A,(ENTRYPTR)    ;GET LOW BYTE OF POINTER TO FOUND KEY DEF
  688.     CP    C        ;SEE IF ENTRY POINTER AND BC MATCH
  689.     JR    NZ,GD0        ;IF NO MATCH THEN ENTRYPTR POINTS TO PREV DEF
  690.     LD    A,(ENTRYPTR+1)    ;GET HIGH BYTE
  691.     CP    B        ;CHECK HIGH BYTE
  692. GD0:    CALL    NZ,DELDEF    ;IF NO MATCH THEN DELETE OLD DEFINITION 
  693.     POP    HL        ;IF THEY MATCH THEN THIS IS A NEW DEF 
  694. GD1:
  695.     PUSH    HL        ;SAVE POINTER TO NEXT CHAR OF DEF
  696.     CALL    GETKEY        ;GET CHAR OF DEFINITION
  697.     POP     DE        ;POP STARTING POSITION TO DE
  698.     LD    B,A
  699.  
  700.     IF    KEYDEF
  701.     OR    80H
  702.     LD    (DE),A        ;STORE CHARACTER WITH HIGH BIT SET
  703.     ENDIF
  704.  
  705.     LD    A,(ATTN)    ;GET ATTENTION CHAR
  706.     CP    B        ;SEE IF ATTENTION CHAR
  707.     LD    A,08H        ;LOAD BS TO BE RETURNED BY ERASE IF CALLED
  708.     JR    Z,ERASE        ;IF SO THEN QUIT
  709.     CALL    SNDMSG        ;DISPLAY CHAR
  710.     PUSH    HL        ;SAVE POINTER
  711.     EX    DE,HL        ;MOVE TO DE
  712.     LD    HL,KEYEND    ;LOAD END OF TABLE
  713.     CCF            ;CLEAR CARRY FLAG
  714.     SBC    HL,DE        ;CALCULATE REMAINING SPACE
  715.     POP    HL        ;RETRIEVE NEXT POSITION
  716.     JR    NC,GD1        ;SPACE REMAINS SO GET ANOTHER CHAR
  717. ;
  718. ;TBLFULL SENDS THE TABLE FULL MESSAGE WHEN CALLED
  719. ;
  720.  
  721. TBLFULL:
  722.     LD    DE,FULLMSG
  723.     CALL    SNDMSG
  724.     LD    C,07
  725.     CALL    OLDCONOUT
  726. TF2:    CALL    OLDCONST
  727.     OR    A
  728.     JR    Z,TF2
  729.     CALL     OLDCONIN
  730. ERASE:                ;ERASE A MESSAGE SENT BY SNDMSG
  731.     PUSH    AF        ;SAVE CHARACTER TO BE OUTPUT ON RETURN
  732.     LD    A,(LNLEN)
  733.     LD    B,A
  734.     PUSH    BC
  735.     LD    A,08H
  736.     CALL    SNDX
  737.     POP    BC
  738.     PUSH    BC
  739.     LD    A,' '
  740.     CALL    SNDX
  741.     POP     BC
  742.     DEC    BC
  743.     LD    A,08H
  744.     CALL    SNDX    
  745.     XOR    A
  746.     LD    (DE),A
  747.     LD    (SENDFLG),A
  748.     POP    AF        ;RETRIEVE FINAL CHARACTER 
  749.     JP    NC1        ;EXIT THROUGH END OF NEWCONIN
  750.  
  751. SNDX:
  752.     CALL    PRTCHR
  753.     DJNZ    SNDX
  754.     RET
  755.  
  756. DELDEF:                ;DELETE DEFINITION POINTED TO BY ENTRYPTR
  757.     POP    HL        ;CLEAN UP STACK
  758.     POP    DE
  759.     PUSH    HL        ;SAVE RETURN ADDRESS
  760.     LD    HL,(ENTRYPTR)    ;LOAD POSITION OF ENTRY TO DELETE
  761.     EX    DE,HL
  762.     LD    HL,KEYEND    ;LOAD ADDRESS OF TABLE END
  763.     CCF            ;CLEAR CARRY FLAG
  764.     SBC    HL,DE        ;GET LENGTH OF REMAINING TABLE
  765.     PUSH    HL        ;MOVE RESULT TO BC
  766.     POP    BC        ;SIZE OF BLOCK TO SEARCH
  767.     LD    HL,(ENTRYPTR)    ;POINT TO START OF DEFINITION TO DELETE
  768.     XOR    A        ;LOOK FOR ZERO AT END OF DEFINITION
  769.     CPIR
  770.     LD    DE,(ENTRYPTR)    ;DESTINATION OF BLOCK MOVE
  771.     LDIR            ;MOVE TABLE UP
  772.     CALL    FINDEND        ;FIND NEW END OF TABLE
  773.     DEC    HL        ;MOVE BACK ONE SPACE
  774.     INC    BC
  775.     POP    DE
  776.     PUSH    HL
  777.     PUSH    DE
  778.     RET
  779.  
  780. ;
  781. ; SIZE ERROR TEST
  782. ;
  783.     IF    [$ GT [RCP+RCPS*128]]
  784. SIZERR    EQU    NOVALUE
  785.     ENDIF
  786. ;
  787. ; END Z3KEY.RCP
  788. ;
  789.     END
  790.