home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / beehive / utilitys / rpeep12.arc / RPEEP.LIB next >
Text File  |  1991-08-11  |  20KB  |  988 lines
  1. ; RPEEP.LIB - Resident PEEP
  2. ;=============================================================================
  3. ;
  4. ;        P E E P    C O M M A N D
  5. ;
  6. ;============================================================================
  7.  
  8. ; +++++++    NOT an official RCP segment.
  9. ;        This is a hacker's module intended to work with Z33RCP.
  10.  
  11. ; Command:    PEEP
  12. ; Function:    Text File Browser and Lister
  13. ; Version:    1.2   4 Nov 1987
  14. ; Author:     Rob Friefeld, 4607 Colorado St., Long Beach, CA 213-434-7338
  15. ; Comments:    The CRT protocol has to be hard coded into this module.
  16. ;          If the TCAP were used, PEEP would not be practical.
  17. ;          See below for installation
  18. ;    Version 1.2:
  19. ;        - LF's stripped from file
  20. ;        - Bug fix, now can read file which doesn't end with 1Ah (EOF)
  21. ;        - Adds about 1100 bytes + printer init string to RCP
  22. ;          Assembly without printer code saves about 180 bytes
  23. ;----------------------------------------------------------------------------
  24. ; USAGE:    Hands rest on the home row of keys.  Left hand moves ahead,
  25. ;        right hand moves back through file. 
  26. ;                                                            ---
  27. ;                                              Go To Marker | 0 |
  28. ;                                                            ---
  29. ;                      Read More                     Init    Set    Print
  30. ;                  (if memory full)                 Printer Marker (from mark)
  31. ;                         ---                         ---    ---    ---
  32. ;                        | R |                       | I |  | O |  | P |
  33. ;                         ---                         ---    ---    ---
  34. ;    ---    ---    ---    ---    ---    ---    ---    ---    ---    ---
  35. ;   | A |  | S |  | D |  | F |  | G |  | H |  | J |  | K |  | L |  | ; |
  36. ;    ---    ---    ---    ---    ---    ---    ---    ---    ---    ---
  37. ;    End   Scan   Next   Next    Find   Rpt    Prev   Prev  R/Scan  Top
  38. ;  Screen         Line  Screen         Find   Screen  Line         Screen
  39. ;
  40. ;
  41. ;  X - Exit   <sp> - Hop 10 lines   <cr> - Next Screen (F)  </,?> - File Name
  42. ;----------------------------------------------------------------------------
  43.  
  44. ;
  45. ; PEEP EQUATES
  46. ;
  47.  
  48. ; GET WIDTH FROM ENV
  49. envwidth    equ    no    ; T = use ENV, F = use crtwid below
  50.  
  51. ; INCLUDE PRINTER CODE
  52. PEEP$LST    EQU    yes    ; Include printer related code
  53.  
  54. ;bell    equ    07h        ; If not already added to SYSDEF.LIB
  55.  
  56. ccpsz    equ    800h        ; Top mem assumes 800h CCP size
  57. textloc    equ    tpa        ; File will be read in to TPA
  58. crtrows    equ    24        ; 24 line screen
  59. scrlns    equ    crtrows-1    ; Need one line for prompts
  60. crtcols    equ    80
  61. crtwid    equ    crtcols-1    ; May be optionally taken from ENV
  62.  
  63. tabsize    equ    8        ; Tab expansion size
  64. scanspd    equ    2000h        ; Scroll rate - smaller number goes faster
  65. ovrlap    equ    1        ; Number of lines to overlap scroll (0 is OK)
  66.  
  67. ;
  68. ; STRING SEARCH BUFFER
  69. ; Set size of string to match buffer.
  70. ;     The TBUF at 80h is not used because it would prevent
  71. ;     doing a repeat FIND after reading in more of file.
  72.  
  73. findsz    equ    12        ; Size of FIND string buffer
  74.  
  75. ;
  76. ; PRINITER INITIALIZATION STRING
  77. ; If you wish to send an initialization string with the 'I' command, install
  78. ; it here.  First byte must be char count.
  79.      if    peep$lst
  80. init$str:
  81.     db    1    ; char count
  82.     db    cr
  83.      endif    ; peep$lst
  84.  
  85. ;
  86. ; CRT PROTOCOL INSTALLATION SECTION
  87. ;
  88. ; The defaults are standard for Televideo, Wyse, et al.
  89. ; 
  90.  
  91.  
  92. ; CLEAR SCREEN, HOME CURSOR
  93. clr_scr        macro
  94.     db    1ah+80h        ; Not used if CLSON is true.
  95.         endm
  96.  
  97. ; CLEAR TO END OF LINE
  98. cl_to_eol    macro
  99.     db    esc,'T'+80h
  100.         endm
  101.  
  102. ; HOME CURSOR, DO NOT CLEAR SCREEN
  103. hom_crs        macro
  104.     db    1eh+80h
  105.         endm
  106.  
  107. ; INSERT LINE
  108. ins_line    macro
  109.     db    esc,'E'+80h
  110.         endm
  111.  
  112. ; RETURN CURSOR TO START OF BOTTOM LINE OF CRT
  113. ret_crs        macro
  114.     db    esc,'=',scrlns+32,0+32+80h
  115.         endm
  116.  
  117. ; STANDOUT MODE.  MUST NOT TAKE SCREEN SPACE.  USE 0 IF NOT AVAILABLE.
  118. dim_on        macro
  119.     db    esc,')'+80h
  120.         endm
  121.  
  122. ; STANDEND
  123. dim_off        macro
  124.     db    esc,'('+80h
  125.         endm
  126.  
  127. ;
  128. ;  END OF CRT PROTOCOL INSTALLATION SECTION
  129. ;
  130.  
  131.  
  132. ;
  133. ; CRT ROUTINES USING ABOVE MACROS
  134. ;
  135.  
  136. ; INSERT BLANK LINE AT TOP OF SCREEN
  137. inslin:    call    homcrs
  138.     call    print
  139.     ins_line
  140.  
  141. ; PRINT CR AND CLREOL
  142. cr$clr:
  143. clreol:    call    print
  144.     db    cr
  145.     cl_to_eol
  146.     ret
  147.  
  148. ; HOME CURSOR
  149. homcrs:    call    print
  150.     hom_crs
  151.     ret
  152.  
  153.  
  154. ; RETURN CURSOR TO LAST LINE OF SCREEN
  155. retcrs:    call    print
  156.     ret_crs
  157.     ret
  158.  
  159. ; CLEAR SCREEN
  160.      if    [ not CLSON ]
  161. cls:    call    print
  162.     clr_scr
  163.     ret
  164.      endif
  165.  
  166. ; START STANDOUT MODE
  167. stndout:
  168.     call    print
  169.     dim_on
  170.     ret
  171.  
  172. ; END STANDOUT MODE
  173. stndend:
  174.     call    print
  175.     dim_off
  176.     ret
  177.  
  178. ;
  179. ; SWITCHING CONOUT
  180. ;
  181.      if    peep$lst
  182. plcon:    ld    a,listf        ; Switch to lst: output
  183. plcon1:    ld    (conout+8),a    ; Poke list byte at  ld  c,bdosf
  184.     ret
  185.  
  186. plcoff:    ld    a,wrconf    ; Switch to con: output
  187.     jr    plcon1
  188.      endif    ; peep$lst
  189.  
  190. ;
  191. ; SLOW DOWN SCAN FUNCTIONS
  192. ;
  193. wait:    ld    hl,scanspd
  194. wait0:    dec    hl        ; Down count to 0
  195.     ld    a,h
  196.     or    l
  197.     ret    z
  198.     jr    wait0
  199.  
  200. ;
  201. ;  UPCASE CHAR IN A
  202. ;
  203. mkupper:
  204.     cp    'a'
  205.     ret    c
  206.     cp    'z'+1
  207.     ret    nc
  208.     and    5fh
  209.     ret
  210.  
  211. ;
  212. ; MAIN PROGRAM
  213. ;
  214.  
  215. peep:    call    retsave        ; Save zcpr return
  216.  
  217. ; LOAD THE SCREEN WIDTH
  218.      if    envwidth
  219.     ld    hl,z3env+2fh    ; Offset to CRT in use
  220.     xor    a
  221.     cp    (hl)
  222.     jr    z,pinit1    ; Using CRT 0
  223.     inc    hl
  224.     inc    hl
  225.     inc    hl
  226. pinit1:    inc    hl
  227.     inc    hl
  228. pinit2:    ld    a,(hl)
  229.     dec    a
  230.     ld    (width),a
  231.      endif    ;envwidth
  232.  
  233. ; READ IN THE FILE
  234.  
  235.     call    getfil        ; Read the file into memory
  236.     call    cls
  237.  
  238. ; RESTART ENTRY FOR READING IN MORE TEXT ON "MEMORY FULL" MESSAGE
  239.  
  240. resrt:    ld    hl,textloc    ; Set Start Pointer to beginning of file
  241.     ld    (srtptr),hl
  242.     ld    (mrkptr),hl    ; Set place marker to start of text
  243.  
  244.  
  245. ;
  246. ; PRINT ONE SCREEN OF TEXT
  247. ;
  248. prnscr:    call    homcrs        ; Move cursor
  249.     call    geteos        ; Set end of screen pointer
  250.     ex    de,hl        ; Compute position relative to last screen
  251.     ld    hl,(srtptr)
  252.     push    hl        ; If near end then print entire last screen
  253.     xor    a
  254.     sbc    hl,de
  255.     pop    hl
  256.     jr    z,prn1        ; We are at or before last screen so go ahead
  257.     jp    nc,last        ; We are past last screen so back up
  258.  
  259. prn1:    ld    b,scrlns    ; Line count in B
  260. prnlp1:    call    clreol
  261.     call    prnline
  262.     djnz    prnlp1        ; Print SCRLNS lines
  263.     ld    (nxtptr),hl    ; And set Next Pointer
  264.     call    retcrs        ; Cursor to prompt line
  265.  
  266. ;
  267. ; COMMAND INPUT ROUTINE
  268. ;
  269. command:
  270.     call    getchr        ; Get command
  271.     call    case        ; Scan list of commands
  272.  
  273. ;
  274. ; COMMAND LIST: CHAR TO MATCH FOLLOWED BY ADDRESS
  275. ;
  276.     db    'A'        ; Last screen of file
  277.     dw    last
  278.     db    'D'        ; Forward a line
  279.     dw    down
  280.     db    'F'        ; Next screen
  281.     dw    next
  282.     db    'G'        ; Find string
  283.     dw    find
  284.     db    'H'        ; Find string again
  285.     dw    find0
  286.      if    peep$lst
  287.     db    'I'        ; Init printer
  288.     dw    init$prt
  289.      endif    ; peep$lst
  290.     db    'J'        ; Previous screen
  291.     dw    prev
  292.     db    'K'        ; Back a line
  293.     dw    up
  294.     db    'L'        ; Scan backward
  295.     dw    back
  296.     db    'O'        ; Set place marker
  297.     dw    mark
  298.      if    peep$lst
  299.     db    'P'        ; Print from marker
  300.     dw    list
  301.      endif
  302.     db    'R'        ; Read in more text
  303.     dw    read
  304.     db    'S'        ; Scan forward
  305.     dw    scan
  306.     db    'X'        ; Exit to CPR
  307.     dw    exit
  308.     db    ';'        ; Top of file
  309.     dw    top
  310.     db    '0'        ; Go to marker
  311.     dw    gomark0
  312.     db    20h        ; <sp> jump ahead 10 lines
  313.     dw    hop
  314.     db    cr        ; <cr> next screen
  315.     dw    next
  316.     db    '/'
  317.     dw    what        ; Show filename
  318.     db    '?'
  319.     dw    what
  320.     db    0        ; table delimiter
  321.  
  322.     jr    command        ; Loop back on invalid input
  323.  
  324. ;
  325. ; CASE - JUMP TABLE SCANNER
  326. ; FORMAT:  CALL CASE    ;CALL WITH VALUE TO MATCH IN A
  327. ;       DB    VAL1    ;FIRST VAL TO MATCH
  328. ;       DW    ADDR1    ;JUMP ADDRESS
  329. ;       ...
  330. ;       DB    0    ;END TABLE
  331. ;       ELSE NEXT INSTUCTION EXECUTES IF NO MATCH
  332. ;
  333. case:
  334.     ex    (sp),hl        ;hl -> next addr after call
  335.     ex    af,af'        ;save char
  336.     xor    a
  337. case1:
  338.     ex    af,af'        ;restore char
  339.     cp    (hl)        ;match?
  340.     inc    hl
  341.     jr    z,case0        ;if match, jump
  342.     inc    hl        ;point to next val
  343.     inc    hl
  344.     ex    af,af'        ;check for list terminator
  345.     cp    (hl)
  346.     jr    nz,case1    ;keep looking
  347.  
  348.     inc    hl        ;execute next instruction
  349. casex:    ex    (sp),hl
  350.     ret
  351.  
  352. case0:    ld    e,(hl)        ;load address
  353.     inc    hl
  354.     ld    d,(hl)
  355.     ex    de,hl
  356.     jr    casex
  357. ;
  358. ;  PRINT ONE LINE OF TEXT
  359. ;  HL -> first char on entry, next char on exit
  360. ;
  361. prnline:
  362.     push    bc        ; Preserve possible loop counter on entry
  363.     xor    a
  364.     ld    c,a        ; Char counter for CRT width and tabs
  365.     ld    d,a        ; OVFL flag
  366. prnl1:
  367.     ld    a,(hl)        ; Get char
  368.     cp    eof        ; At end?
  369.     jr    z,prnl2        ; Can occur on text smaller than one screen
  370.     inc    hl        ; Bump pointer
  371.     cp    cr        ; Are we at end of line?
  372.     jr    z,prnl2
  373.     call    prnl3        ; Print the character
  374.     jr    prnl1
  375. prnl2:    pop    bc
  376.     call    print
  377.     db    cr,lf+80h
  378.     ret            ; Exit routine
  379.  
  380. ; PRINT THE CHAR IF THE LINE IS NOT FULL
  381.  
  382. prnl3:    cp    tab
  383.     jr    nz,prnl5    ; No tab
  384.  
  385. ; TAB EXPANSION
  386.  
  387. prnl4:    ld    a,c        ; Compute char count MOD tabsize
  388.     sub    tabsize
  389.     jr    nc,$-2
  390.     neg            ; Spaces to next tab in A
  391.     ld    b,a        ; Use as loop counter
  392.     ld    a,' '        ; Print space
  393. prnl41:    call    prnl5        ; Send it out, if room, and update char count
  394.     djnz    prnl41
  395.     ret
  396.  
  397. prnl5:
  398.     ld    e,a        ; Save char
  399.     ld    a,d        ; OVFL flag
  400.     or    a
  401.     ret    nz        ; Already OVFL
  402.     inc    c        ; Bump char counter
  403.  
  404.  
  405. ; DISPLAY CONTROL CHARACTERS AS ^n
  406. ; Char in E
  407. outchr:
  408.     ld    a,7fh        ; Don't print DEL
  409.     cp    e
  410.     ret    z
  411.  
  412.      if    peep$lst
  413.     ld    a,(conout+8)    ; Listing?
  414.     cp    wrconf
  415.     jr    z,outc1        ; No, check line width before printing
  416.     ld    a,e        ; Restore char
  417.     cp    20h
  418.     jp    nc,conout    ; Not a control
  419.     call    print
  420.     db    '^'+80h
  421.     ld    a,e
  422.     add    40h        ; Make char printable
  423.     jp    conout    
  424.      endif    ;peep$lst
  425.  
  426. outc1:
  427.     ld    a,(width)    ; OVFL?
  428.     cp    c
  429.     jr    nc,outc2    ; No
  430. outc01:
  431.     dec    d        ; Now have OVFL, make d NZ
  432.     call    stndout
  433.     call    print        ; Display OVFL indicator
  434.     db    '>',bs+80h
  435.     jp    stndend        ; And quit
  436.  
  437. outc2:
  438.     ld    a,e        ; Restore char
  439.     cp    20h
  440.     jp    nc,conout    ; Not a control
  441.  
  442.     call    stndout
  443.     call    print
  444.     db    '^'+80h
  445.  
  446.     inc    c        ; Bump tab expansion count for '^' char
  447.     ld    a,(width)    ; CRT, is there still room?
  448.     cp    c
  449.     jr    c,outc01    ; OVFL
  450.     ld    a,e        ; Restore char
  451.     add    40h
  452.     call    conout
  453. outx:    jp    stndend
  454.  
  455.  
  456. ;
  457. ; PRINT NEXT SCREEN
  458. ;
  459. next:    ld    hl,(nxtptr)
  460.     ld    a,eof        ; Is there a next screen?
  461.     cp    (hl)
  462.     jr    z,hop0        ; No
  463.     ld    a,ovrlap
  464.     or    a
  465.     jr    z,next1
  466.     ld    b,a        ; Back up scroll overlap lines
  467.     call    pvline
  468.     djnz    $-3
  469. next1:    ld    (srtptr),hl    ; Next screen is new start pointer
  470.     jr    top0        ; Print the screen
  471.  
  472. ;
  473. ; PRINT FIRST SCREEN
  474. ;
  475.  
  476. top:    ld    hl,textloc    ; Start of text
  477.     ld    (srtptr),hl    ; To start pointer
  478. top0:    jp    prnscr
  479.  
  480. ;
  481. ; PRINT LAST SCREEN
  482. ;
  483. last:    call    geteos        ; Top of last screen
  484.     ld    (srtptr),hl    ; Start there
  485.     jr    top0        ; Print the screen
  486.  
  487. ;
  488. ; PRINT NEXT LINE
  489. ;
  490. down:    ld    b,1        ; Loop counter = 1 line
  491.     jr    hop1        ; Print the line
  492.  
  493. ;
  494. ; HOP FORWARD 10 LINES
  495. ;
  496. hop:    ld    b,10        ; Loop counter = 10 lines
  497. hop1:    push    bc        ; Save it
  498.     call    dnline        ; Print next line
  499.     pop    bc
  500.     djnz    hop1
  501. hop0:    jp    command
  502.  
  503. ;
  504. ; SCROLL CONTINUOUSLY AHEAD UNTIL A KEY PRESSED
  505. ;
  506. scan:    call    dnline        ; Print next line
  507.     jr    z,hop0        ; Routine returns 0 on EOF
  508.     call    scstop        ; Check for key press
  509.     jr    scan
  510.  
  511. ;
  512. ;  WAIT, THEN CHECK FOR BREAK
  513. ;
  514. scstop:
  515.     call    wait        ; Pause a few msec
  516.     ld    c,CONSTF
  517.     call    bdos
  518.     or    a
  519.     ret    z        ; No character, continue
  520.     pop    af        ; Dispose of return address
  521.     call    getchr        ; Erase screen echo and dispose of char
  522.     jr    hop0        ; Back to command list
  523.  
  524. ;
  525. ; PRINT NEXT LINE
  526. ;
  527. dnline:    ld    hl,(nxtptr)    ; Look at start of next line
  528.     ld    a,eof        ; Is it EOF?
  529.     cp    (hl)
  530.     ret    z        ; There is no next line
  531.     call    prnline        ; Print the line
  532.     ld    (nxtptr),hl    ; Advance Next Pointer
  533.     ld    hl,(srtptr)    ; Advance Start Pointer
  534.     call    nxline        ; Find start of next line
  535.     ld    (srtptr),hl    
  536.     xor    a        ; A NZ flag on successful return
  537.     dec    a
  538.     ret
  539.  
  540. ;
  541. ;  SEARCH FOR NEXT LINE OF TEXT
  542. ;  HL -> starting point
  543. ;
  544. nxline:    ld    a,(hl)        ; Look at char
  545.     cp    eof
  546.     ret    z        ; No more text
  547.     inc    hl        ; Bump pointer
  548.     cp    cr
  549.     jr    nz,nxline
  550.     ret            ; Returns HL at character after LF
  551.  
  552. ;
  553. ; PRINT PREVIOUS SCREEN
  554. ;
  555. prev:    ld    hl,(srtptr)    ; HL-> char at top of screen
  556.     ld    a,scrlns
  557.     sub    ovrlap
  558.     ld    b,a        ; Loop counter SCRLNS lines
  559. prev0:    call    pvline        ; Find start of previous line
  560.     djnz    prev0
  561.     ld    (srtptr),hl    ; Set Start Pointer
  562.     jp    prnscr        ; Print the screen
  563.  
  564. ;
  565. ;  SEARCH FOR START OF PREVIOUS LINE OF TEXT
  566. ;
  567. pvline:    push    bc        ; Save possible loop counter on entry
  568.     ld    de,textloc    ; Are we already at beginning of file?
  569.     ld    b,2
  570. prvlp:    dec    hl
  571.     xor    a
  572.     push    hl
  573.     sbc    hl,de
  574.     pop    hl
  575.     jr    c,prv0        ; Yes, so we are done
  576.     ld    a,(hl)        ; Look for last cr
  577.     cp    cr
  578.     jr    nz,prvlp    ; Haven't found cr yet
  579.     djnz    prvlp
  580. prv0:    inc    hl
  581.     pop    bc
  582.     ret
  583.  
  584. ;
  585. ;  PRINT PREVIOUS LINE
  586. ;
  587. up:    call    upline
  588. up0:    jp    command
  589.  
  590. ;
  591. ; SCAN BACKWARDS UNTIL KEY PRESS
  592. ;
  593. back:    call    upline        ; Move up a line
  594.     jr    z,up0        ; Returns Z if no more lines
  595.     call    scstop        ; Check for break
  596.     jr    back
  597.  
  598. ;
  599. ; MOVE DISPLAY UP A LINE
  600. ;
  601. upline:    ld    de,textloc    ; Are we already at start of text?
  602.     ld    hl,(srtptr)
  603.     xor    a
  604.     sbc    hl,de
  605.     ret    z        ; Yes, quit and return Z
  606.  
  607.     call    inslin        ; Home cursor and insert a blank line
  608.     ld    hl,(srtptr)    ; Back up a line
  609.     call    pvline
  610.     ld    (srtptr),hl    ; Set pointer
  611.     call    prnline        ; Print the line
  612.     ld    hl,(nxtptr)    ; Set Next Pointer
  613.     call    pvline
  614.     ld    (nxtptr),hl
  615.     call    retcrs        ; Return cursor to bottom of screen
  616.     call    cr$clr        ; Erase dead line
  617.     xor    a        ; Return NZ
  618.     dec    a
  619.     ret
  620.  
  621. ;
  622. ; FIND A STRING
  623. ;
  624. find:
  625.     call    STNDOUT
  626.     call    print        ; Find string in following pages
  627.     db    'Find ->',' '+80h
  628.     ld    de,fbuf        ; Read string to find
  629.     ld    c,RDBUFF
  630.     call    bdos
  631.     call    clrend
  632.  
  633. find0:    ld    a,(fbuf+1)    ; String length
  634.     or    a
  635.     jp    z,command    ; 0 length string ... abort
  636.     ex    af,af'        ; Save it
  637.  
  638. ; START SEARCH AT NEXT LINE
  639.  
  640.     ld    hl,(srtptr)
  641.     call    nxline        ; HL now -> next line
  642. finlp0:
  643.     ld    de,fbuf+2    ; First char
  644. finlp1:
  645.     call    fmatch        ; Compare upcase of (hl) and (de)
  646.     inc    hl        ; Bump text pointer
  647.     jr    nz,finlp1    ; No match, keep moving through text
  648.  
  649. ; AT THIS POINT, FIRST CHAR IS MATCHED
  650.  
  651.     ex    af,af'        ; Recover string length
  652.     ld    b,a
  653.     ex    af,af'
  654.     dec    b        ; We have already found 1
  655.     jr    z,findex    ; Done if only 1 char to match
  656. finlp2:
  657.     inc    de
  658.     call    fmatch
  659.     jr    nz,finlp0    ; No match ... start looking again
  660.     inc    hl        ; So far, so good
  661.     djnz    finlp2        ; Match next chars
  662.  
  663.  
  664. ; THE STRING IS IN THE CURRENT LINE, MOVE IT TO TOP OF SCREEN
  665.  
  666. findex:    call    pvline        ; Find previous line
  667.     call    nxline        ; Go to beginning of this line
  668.     ld    (srtptr),hl
  669.     jp    prnscr        ; Show the screen
  670.  
  671. ; MATCH ROUTINE
  672.  
  673. fmatch:
  674.     ld    a,(hl)
  675.     cp    eof
  676.     jr    z,finot
  677.     call    mkupper
  678.     ld    c,a
  679.     ld    a,(de)
  680.     call    mkupper
  681.     cp    c
  682.     ret
  683.  
  684. ; NO LUCK ON FIND
  685.  
  686. finot:    pop    af        ; Lift stack
  687.     call    cr$clr        ; String not found - print message
  688.     call    stndout
  689.     call    print
  690.     db    '???',' '+80h
  691. finot0:    call    stndend
  692.     jp    command
  693.  
  694.  
  695. ;
  696. ;  SHOW FILE NAME COMMAND
  697. ;
  698. what:    call    stndout
  699.     ld    hl,fcb1+1
  700.     call    prfn        ; ROUTINE ELSEWHERE IN RCP
  701.     jr    finot0        ; Finish up display
  702.  
  703. ;
  704. ; SET PLACE MARKER
  705. ;
  706. mark:
  707.     ld    hl,(srtptr)    ; Top of screen pointer is marker pointer
  708.     ld    (mrkptr),hl
  709.     call    stndout
  710.     call    print
  711.     db    'Mark',bell+80h
  712.     jr    finot0        ; Finish up display
  713.  
  714.  
  715. ;
  716. ; GO TO MARKER
  717. ;
  718. gomark0:
  719.     ld    hl,(mrkptr)
  720.     ld    (srtptr),hl
  721.     jp    prnscr
  722.  
  723.  
  724. ;
  725. ;  LIST MARKED PORTION OF FILE
  726. ;
  727.      if    peep$lst
  728. list:
  729.     ld    hl,lstmsg
  730.     call    qprompt        ; Are we serious?  (And is printer on?)
  731.     jr    z,listx        ; Abort
  732.     call    stndout
  733.     call    print
  734.     db    'Printing',' '+80h
  735. ; Compute print block size
  736.  
  737.     ld    de,(mrkptr)    ; Beginning of block
  738.     ld    hl,(nxtptr)    ; End of block
  739.     xor    a
  740.     sbc    hl,de        ; Block size now in HL
  741.     jr    c,lsterr    ; If beginning at or after end then no go
  742.     jr    z,lsterr
  743.  
  744. ; Set up pointers
  745.  
  746.     ex    de,hl        ; Block size in DE, start in HL
  747.     push    de
  748.     pop    bc        ; Block size in BC
  749.     ld    de,0        ; Count # lines in DE
  750.     ld    a,cr
  751. list1:    cpir            ; Count line feeds
  752.     inc    de
  753.     jp    po,list2    ; Loop expired at last cr
  754.     jr    list1
  755.  
  756. list2:
  757.     call    plcon        ; Switch output to list
  758.     push    de
  759.     pop    bc        ; Count to BC
  760.     ld    hl,(mrkptr)    ; Source of block
  761.  
  762. list3:    call    break        ; Exit on ^C (routine in rcpsubs.lib)
  763.     call    prnline        ; Output switched to list:
  764.     dec    bc
  765.     ld    a,b
  766.     or    c
  767.     jr    nz,list3
  768.  
  769.     call    plcoff        ; Switch output to con:
  770.  
  771. lsterr:    call    print        ; Beep on marker error or finish print
  772.     db    bell+80h
  773.     call    clrend
  774. listx:    jp    command
  775.  
  776.  
  777.  
  778. lstmsg:    db    'Print from MAR','K'+80h
  779.  
  780. ;
  781. ;  SEND INIT STRING TO PRINTER
  782. ;
  783. init$prt:
  784.     ld    hl,initmsg
  785.     call    qprompt
  786.     jr    z,listx
  787.     call    plcon        ; Switch conout to list
  788.     ld    hl,init$str    ; Send string
  789.     ld    b,(hl)        ; Char count
  790. ip1:    inc    hl
  791.     ld    a,(hl)
  792.     call    conout
  793.     djnz    ip1
  794.     call    plcoff        ; Switch conout to con
  795.     jr    listx
  796.  
  797. initmsg:
  798.     db    'Init LST',':'+80h 
  799.  
  800.       endif    ; peep$lst
  801. ;
  802. ;  READ FILE INTO TPA UNTIL FULL OR EOF
  803. ;
  804. getfil:
  805.     
  806. ; SET UP TOP OF MEMORY POINTER
  807.  
  808.     ld    hl,(bdos+1)    ; BDOS location
  809.     ld    de,-ccpsz-88h    ; CCP size + offset + cr,eof + 1 record
  810.     add    hl,de
  811.     ld    (topmem),hl    ; Store as top of memory
  812.  
  813. ; REJECT BLANK FILE SPEC
  814.  
  815. getfil1:
  816.     call    filcheck
  817.  
  818.     CALL    LOGUSR        ; ROUTINE IS IN RCPSUBS.LIB
  819.  
  820. ; OPEN THE FILE
  821.     call    opensource
  822.  
  823. ; RESET EOF FLAG (EOF NOT ENCOUNTERED)
  824.     xor    a
  825.     ld    (eoflag),a
  826.  
  827. ; FILE READ LOOP
  828. ; File read into tbuf, MSB mask, lf strip, transfer to text buffer
  829.  
  830.     ld    de,textloc    ; Start of text pointer
  831. getlp1:
  832.     ld    hl,(topmem)    ; Check memory full
  833.     xor    a
  834.     sbc    hl,de
  835.     jr    c,toobig    ; Yes
  836.  
  837.     push    de
  838.     ld    de,fcb1        ; Read a record
  839.     ld    c,readf
  840.     call    bdos
  841.     pop    de
  842.     call    loadfil        ; Load it into text buffer
  843.     jr    z,getlp1    ; Keep reading, eof not encountered
  844.  
  845. geteof:    ld    (eoflag),a    ; Set EOF flag
  846.     ret
  847.  
  848. ; MOVE RECORD INTO TEXT BUFFER
  849. loadfil:
  850.     or    a        ; Enter with BDOS read return code
  851.     jr    nz,ldfil03    ; No more to read, but no EOF char
  852.     ld    hl,tbuf
  853.     ld    b,80h
  854. ldfil01:
  855.     ld    a,(hl)
  856.     inc    hl
  857.     and    7fh        ; Mask MSB
  858.     cp    lf
  859.     jr    z,ldfil02    ; Skip lf
  860.     cp    eof
  861.     jr    z,ldfil03    ; Done, set up EOF pointers
  862.     ld    (de),a
  863.     inc    de
  864. ldfil02:
  865.     djnz    ldfil01
  866.     xor    a        ; Z = not done
  867.     ret
  868.  
  869. ldfil03:
  870.     ex    de,hl
  871.     ld    (hl),cr        ; Add a cr to the end
  872.     inc    hl
  873.     ld    (hl),eof    ; Mark end with eof
  874.     ld    (eofptr),hl    ; Save location
  875.     or    -1        ; NZ = done
  876.     ret
  877.  
  878. ; FILE HAS FILLED AVAILABLE MEMORY, PRINT WARNING
  879.  
  880. toobig:
  881.     call    print
  882.     db    'Mem',bell+80h
  883.     call    getchr        ; Wait for key press
  884.     jr    ldfil03        ; Read no more
  885.  
  886.  
  887. ;
  888. ; READ MORE TEXT COMMAND
  889. ;
  890. read:    ld    a,(eoflag)    ; Has EOF been encountered?
  891.     or    a
  892.     jr    nz,rdprompt    ; If so, send message
  893.     ld    de,textloc    ; Else, preserve some text and read more
  894.     call    geteos
  895.     ld    a,eof
  896. rdlp1:    ldi            ; Move last page to beginning of buffer
  897.     cp    (hl)        ; Check for end of file marker
  898.     jr    nz,rdlp1    ; Loop until it is reached
  899.     dec    de        ; Back up over last CR
  900.     call    getlp1        ; Fill memory with more of file
  901.     jr    readx        ; Re-initialize pointers and start
  902.  
  903.  
  904. ; PROMPT IF NO MORE TO READ
  905.  
  906. rdmsg:    db    'Restar','t'+80h
  907. rdprompt:
  908.     ld    hl,rdmsg
  909.     call    qprompt
  910.     jp    z,command    ; No
  911.  
  912.  
  913. ; STARTING OVER, ZERO FCB POSITION POINTERS
  914.  
  915. read1:
  916.     CALL    INITFCB1    ; IN RCPSUBS.LIB
  917.     ld    a,(ppusr)    ; Restore user #
  918.     ld    (fcb1+13),a
  919.     call    getfil1        ; Read the file
  920. readx:    jp    resrt        ; Restart PEEP
  921.  
  922.  
  923. ; EXAMINE COMMAND LINE FOR FILE SPEC
  924.  
  925. filcheck:
  926.     ld    a,(fcb1+13)
  927.     ld    (ppusr),a
  928.     ld    hl,fcb1+1
  929.     ld    a,' '
  930.     cp    (hl)
  931. filcx:    ret    nz
  932.     call    prfnf        ; ROUNTINE IS ELSEWHERE IN RCP
  933.     jp    exit        ; NO FILE SPEC
  934.  
  935. ; OPEN SOURCE FILE
  936.  
  937. opensource:
  938.     ld    de,fcb1
  939.     ld    c,openf
  940.     call    bdos
  941.     inc    a
  942.     jr    filcx
  943.  
  944.  
  945. ; Enter with HL -> message.  Return Z if answer = N.
  946. qprompt:
  947.     call    stndout
  948.     call    printhl
  949.     call    print
  950.     db    '? (Y/n)',' '+80h
  951. getchr:
  952.     call    conin
  953.     cp    'N'
  954. clrend:
  955.     push    af
  956.     call    stndend
  957.     call    cr$clr
  958.     pop    af
  959.     ret
  960.  
  961. ; Get pointer to start of last screen in HL
  962. geteos:
  963.     ld    hl,(eofptr)    ; Set End of Screen Pointer to beginning
  964.     ld    b,scrlns    ;   of last screen
  965.     call    pvline        ; Back up one screen from end
  966.     djnz    $-3
  967.     ret
  968.  
  969. ;
  970. ; STORAGE
  971. ;
  972. fbuf:    db    findsz        ; Find string buffer
  973.     ds    1        ; Returned char count
  974.     ds    findsz        ; Buffer
  975.  
  976. width    db    crtwid        ; Useable screen width
  977. ppusr    ds    1        ; User number
  978. eoflag    ds    1        ; EOF encountered flag
  979. srtptr    ds    2        ; Start Pointer -> top of screen
  980. nxtptr    ds    2        ; Next Pointer -> next screen
  981. eofptr    ds    2        ; End of File Pointer -> end of text
  982. topmem    ds    2        ; Top of memory pointer
  983. mrkptr:    ds    2        ; Place marker
  984.  
  985. ; End RPEEP.LIB
  986.  
  987. ; End of File Pointer -> end of text
  988. topmem    ds    2        ; Top