home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 508.lha / IO_Expansion_Board / Time / Time.asm < prev   
Assembly Source File  |  1991-05-06  |  12KB  |  427 lines
  1. *****************************************************************************
  2. * Time.asm - ©1990,91 by The Puzzle Factory
  3. *          Real-Time Clock/Calendar driver.
  4. *
  5. *   Usage: 1> Time S=SET    ;Sets clock from system date.
  6. *          1> Time R=READ    ;Sets system date from clock.
  7. * History: 01/25/88 V0.50 Created by Jeff Lavin
  8. *          11/25/90 V0.51 Converted to new syntax
  9. *
  10. * [To all: Please don't forget to bump the revision numbers if you do *any*
  11. *          modifications at all.  -Jeff]
  12. *
  13. * Notes:
  14. * There are several places in this program where small delays that are needed
  15. * by the clock chip are created by the use of one or two 'NOP' instructions.
  16. * These delays are calculated for a 7Mhz 68000 and may not work on a faster
  17. * or different processor.  If you experience problems, try doubling the
  18. * number of 'NOPs'.  I realize that this isn't good code, but I don't feel
  19. * that the extra work is warranted in this particular case.  Feel free to add
  20. * any improvements that you like.
  21. *
  22. * When setting the clock from system time, you would enter the date and time
  23. * with the 'DATE' command, and then type 'Time SET'.  Be aware that when
  24. * setting the clock, seconds are considered to be zero.  In order to get the
  25. * most accurate time, set the clock just as system time passes the minute so
  26. * that seconds really are zero.
  27. *
  28. *****************************************************************************
  29.  
  30. ;Set Tabs    |    |    |    |
  31.  
  32.     exeobj
  33.     objfile    'ram:Time'
  34.     macfile 'Includes:IOexp.i'    ;The One & Only include file
  35.  
  36. *  CLOCK / CALENDAR DRIVER PROGRAM
  37. *  for OKI MSM5832 MICROPROCESSOR
  38. *    Real-Time Clock / Calendar
  39. *
  40. * Copyright ©1990,91 The Puzzle Factory - All rights reserved
  41. * This program may not be used commercially without prior
  42. * written permission from the author.
  43. *
  44. * The clock/calendar is driven by a VIA.
  45. * The port bit assignments are as follows:
  46. *
  47. *   PORT A bits      PORT B bits
  48. * 7 6 5 4 3 2 1 0    7 6 5 4 3 2 1 0
  49. * ---------------------------------
  50. * D D D D A A A A          T|A|R|W|H
  51. * 3 2 1 0 3 2 1 0          E|D|E|R|O
  52. *          S|J|A|I|L
  53. *          T   D|T|D
  54. *            E
  55. *
  56. *              ________________________________________
  57. *             |                 |
  58. *  HOLD  _____|                 |_____
  59. *                ____________________________________
  60. *               |                   |
  61. *  READ  _______|                   |_______
  62. *        ________  _________  _________  _________  _________
  63. *                \/     \/         \/        \/
  64. *  A0-A3 ________/\_________/\_________/\_________/\_________
  65. *        __________  _________  _________  _________  _______
  66. *  Data Out        \/      \/         \/          \/
  67. *  D0-D3 __________/\_________/\_________/\_________/\_______
  68. * 
  69. *         R E A D   C Y C L E
  70. * 
  71. *              ________________________________________
  72. *             |                 |
  73. *  HOLD  _____|                 |_____
  74. *        ________  _________  _________  _________  _________
  75. *                \/     \/         \/        \/
  76. *  A0-A3 ________/\_________/\_________/\_________/\_________
  77. *        ________  _________  _________  _________  _________
  78. *  Data In       \/     \/         \/        \/
  79. *  D0-D3 ________/\_________/\_________/\_________/\_________
  80. *     _____      _____      _____
  81. *    /     \    /     \    /      \
  82. *  WRITE __________/       \__/       \__/       \___________
  83. * 
  84. *        W R I T E   C Y C L E
  85. *
  86. *
  87. * The registers assignments are:
  88. *
  89. * REG: $00 $01 $02 $03 $04 $05 $06 $07 $08 $09 $0A $0B $0C
  90. * --------------------------------------------------------
  91. * CNT: 01S 10S 01M 10M 01H 10H DoW D01 D10 M01 M10 Y01 Y10
  92. *
  93. *       5   3   6    2   9    8   2   4   2   1   0   9   8
  94. *
  95. * This example would be:  09:26:35 TUESDAY JAN 24 1989
  96. *
  97. * Bit 7 of 10H is: 0 = 12 hr format, 1 = 24 hr format
  98.  
  99. dat_Format    equ    $0C    ;Arp DateTime Structure
  100. dat_Flags    equ    $0D
  101. dat_StrDay    equ    $0E
  102. dat_StrDate    equ    $12
  103. dat_StrTime    equ    $16
  104. dat_SIZEOF    equ    $1A
  105.  
  106. LEN_DATSTRING    equ    10
  107. FORMAT_USA    equ    2
  108. DTB_FUTURE    equ    2
  109.  
  110. SECONDS_PER_DAY    equ    1440
  111. SECONDS_PER_MINUTE    equ    60
  112.  
  113. *** Begin Mainline
  114.  
  115. Time    movem.l    d0/a0,-(sp)
  116.     lea    (ArpName,pc),a1    ;Open arp.library
  117.     moveq    #34,d0    ;Version 34 or later
  118.     movea.l    (SysBase).w,a6
  119.     SYS    OpenLibrary
  120.     tst.l    d0
  121.     bne.b    OK_Go    ;Got arp, run program
  122.     lea    (DosName,pc),a1    ;Else, open dos.library
  123.     SYS    OpenLibrary
  124.     tst.l    d0
  125.     beq.b    1$
  126.     movea.l    d0,a6
  127.     SYS    Output    ; and get output filehandle
  128.     move.l    d0,d1
  129.     beq.b    1$
  130.     move.l    #alibmsg,d2
  131.     moveq    #aliblng,d3
  132.     SYS    Write    ; so we can complain
  133. 1$    addq.w    #8,SP    ; and exit.
  134.     rts
  135.  
  136. DosName    cstr    'dos.library'
  137. alibmsg    db    'you need '
  138. ArpName    db    'arp.library',0,0
  139.     db    ' V34+',10
  140. aliblng    equ    *-alibmsg
  141.  
  142. OK_Go    movea.l    d0,a6    ;ArpBase
  143.     lea    (DT),a4    ;Setup BSS base register
  144.     lea    (VIA_Base),a5    ;Setup I/O base register
  145.     movem.l    (sp)+,d0/a0
  146.     lea    (Help.msg,pc),a1
  147.     lea    (ArgArray-DT,a4),a2
  148.     lea    (Template,pc),a3
  149.     SYS    GADS
  150.     cmpi.w    #1,d0    ;Count of args, must = 1
  151.     bne.b    1$    ;Instruct & quit
  152.  
  153.     lea    (DateTime-DT,a4),a3
  154.     move.b    #FORMAT_USA,(dat_Format,a3)
  155.     bset    #DTB_FUTURE,(dat_Flags,a3)
  156.     move.l    #DayStr,(dat_StrDay,a3)
  157.     move.l    #DateStr,(dat_StrDate,a3)
  158.     move.l    #TimeStr,(dat_StrTime,a3)
  159.  
  160.     tst.l    (Arg2-DT,a4)    ;Is 'SET' argument on?
  161.     bmi.b    SetTime    ;Yes, set clock from SysTime
  162.     tst.l    (Arg1-DT,a4)    ;Is 'READ' argument on?
  163.     bmi    ReadTime    ;Yes, read clock to SysTime
  164. 1$    bra    ArgErr    ;Must be R or S, instruct & quit
  165.  
  166. *** Set Hardware Clock from System Time
  167.  
  168. SetTime    move.l    a3,d1    ;Ptr to DateTime structure
  169.     SYS    DateStamp    ;Get system time
  170.     movea.l    a3,a0
  171.     SYS    StamptoStr
  172.     tst.l    d0
  173.     bne    DateErr    ;Couldn't read DateStamp, exit
  174.  
  175.     move.b    #$FF,(DDRB,a5)    ;Set to all outputs
  176.     move.b    #$FF,(DDRA,a5)    ;Set to all outputs
  177.     move.b    #1,(ORB,a5)    ;Set HOLD high
  178.     bsr    Wait    ;150 usec HOLD setup time
  179.  
  180.     lea    (DateStr-DT,a4),a0 ;Date from StampToString
  181.     lea    (Str_order,pc),a1    ;Order of string bytes to read
  182.     lea    (Reg_order,pc),a2    ;Order of registers to write
  183.     moveq    #0,d2    ;Index
  184.     moveq    #0,d3    ;Index
  185. SetLoop    move.b    (0,a1,d3.w),d2    ;Which string byte to read
  186.     move.b    (0,a0,d2.w),d0    ;Get date/time data
  187.     lsl.b    #4,d0    ;Shift data to upper nibble
  188.     move.b    (0,a2,d3.w),d1    ;Which register to write
  189.     or.b    d1,d0    ;Combine register addr in lower nibble
  190.     move.b    d0,(ORA,a5)    ;Send the whole mess to the clock
  191.     nop        ;Data setup time
  192.     nop
  193.     move.b    #3,(ORB,a5)    ;Raise WRITE line
  194.     nop        ;WRITE pulse width
  195.     move.b    #1,(ORB,a5)    ;Lower WRITE line
  196.  
  197.     addq.w    #1,d3
  198.     cmpi.w    #12,d3
  199.     bhs.b    1$
  200.     cmpi.w    #6,d3    ;If <> 6, do next whatever
  201.     bne.b    SetLoop    ;Else, we finished the date
  202.     lea    (TimeStr-DT,a4),a0 ;So start on the time
  203.     bset.b    #3,(0,a0)    ;Mark 10 Hour for 24 hr mode
  204.     bra.b    SetLoop
  205.  
  206. 1$    lea    (Day_index,pc),a3    ;Index into table
  207.     lea    (Day_table,pc),a2    ;Table of day strings
  208.     moveq    #0,d2    ;Loop Counter & Day of Week for clock
  209. 2$    lea    (DayStr-DT,a4),a0    ;Ptr to Day of Week string (system)
  210.     moveq    #0,d1
  211.     move.b    (0,a3,d2.w),d1    ;Offset to string
  212.     lea    (0,a2,d1.w),a1    ;Ptr to Day of Week string (table)
  213.     SYS    Strcmp
  214.     beq.b    3$
  215.     addq.w    #1,d2
  216.     cmpi.w    #7,d2
  217.     blo.b    2$
  218.     bra    DateErr    ;Can't match system string
  219.  
  220. 3$    lsl.b    #4,d2    ;Shift data to upper nibble
  221.     ori.b    #6,d2    ;Combine register addr in lower nibble
  222.     move.b    d2,(ORA,a5)    ;Send the whole mess to the clock
  223.     nop        ;Data setup time
  224.     nop
  225.     move.b    #3,(ORB,a5)    ;Raise WRITE line
  226.     nop        ;WRITE pulse width
  227.     move.b    #1,(ORB,a5)    ;Lower WRITE line
  228.     nop        ;DATA hold time
  229.     move.b    #0,(ORB,a5)    ;Reset HOLD low & Fall thru
  230.  
  231. *** Read Hardware Clock and Set System Time
  232.  
  233. ReadTime    move.b    #$FF,(DDRB,a5)    ;Set to all outputs
  234.     move.b    #$0F,(DDRA,a5)    ;Hi-nibble=inputs, lo-nibble=outputs
  235.     move.b    #1,(ORB,a5)    ;Set HOLD high
  236.     bsr    Wait    ;150 usec HOLD setup time
  237.     move.b    #5,(ORB,a5)    ;Set for READ mode
  238.  
  239.     lea    (DateStr-DT,a4),a0 ;Date for StrDate
  240.     lea    (TimeStr-DT,a4),a1 ;Time for StrTime
  241.     move.b    #'-',(2,a0)    ;Initialize separators
  242.     move.b    #'-',(5,a0)
  243.     move.b    #':',(2,a1)
  244.     move.b    #':',(5,a1)
  245.  
  246.     lea    (Str_order,pc),a1    ;Order of string bytes to write
  247.     lea    (Reg_order,pc),a2    ;Order of registers to read
  248.     lea    (DataMask,pc),a3    ;Mask for unwanted bits
  249.     moveq    #0,d1    ;Index
  250.     moveq    #0,d2    ;Index
  251.  
  252. ReadLoop    move.b    (0,a2,d2.w),(ORA,a5) ;Get next register
  253.     nop        ;READ access time
  254.     moveq    #0,d0
  255.     move.b    (ORA,a5),d0    ;Get clock data
  256.     lsr.b    #4,d0    ;Shift into lower nibble
  257.     and.b    (0,a3,d2.w),d0    ;Mask off unwanted info
  258.     addi.b    #$30,d0    ;Make ASCII
  259.     move.b    (0,a1,d2.w),d1    ;Which string byte to write
  260.     move.b    d0,(0,a0,d1.w)    ;Put clock data in date/time string
  261.  
  262.     addq.w    #1,d2
  263.     cmpi.w    #12,d2
  264.     bhs.b    1$
  265.     cmpi.w    #6,d2    ;If <> 6, do next whatever
  266.     bne.b    ReadLoop    ;Else, we finished the date
  267.     lea    (TimeStr-DT,a4),a0 ;So start on the time
  268.     bra.b    ReadLoop
  269.  
  270. 1$    move.b    #6,(ORA,a5)    ;Day of Week register
  271.     nop        ;READ access time
  272.     moveq    #0,d0
  273.     move.b    (ORA,a5),d0    ;Get clock data
  274.     move.b    #0,(ORB,a5)    ;Reset HOLD low
  275.     lsr.b    #4,d0    ;Shift into lower nibble
  276.     andi.w    #%00000111,d0    ;Mask off unwanted info
  277.  
  278.     lea    (DateTime-DT,a4),a3 ;Ptr to DateTime structure
  279.     movea.l    (dat_StrDay,a3),a2
  280.     lea    (Day_table,pc),a1    ;Table of day strings
  281.     lea    (Day_index,pc),a0    ;Index into table
  282.     moveq    #0,d1
  283.     move.b    (0,a0,d0.w),d1    ;Where string[D0] starts
  284. 2$    move.b    (0,a1,d1.w),(a2)+    ;Move Day of Week string to target
  285.     addq.l    #1,a1
  286.     bne.b    2$
  287.  
  288.     tst.l    (Arg2-DT,a4)    ;Is 'SET' argument on?
  289.     bmi.b    3$    ;Yes, don't set SysTime, just print
  290.  
  291.     movea.l    a3,a0
  292.     SYS    StrtoStamp    ;Convert clock strings
  293.     bne    ConvErr    ;Can't convert DateStamp
  294.  
  295. * Formula:  (((ds_Days * 1440) + ds_Minute) * 60) + (ds_Tick / 50)
  296.  
  297.     move.l    (ds_Days,a3),d0    ;# of Days since 01/01/78
  298.     mulu.w    #SECONDS_PER_DAY,d0
  299.     add.l    (ds_Minute,a3),d0    ;# of Minutes since midnight
  300.     move.l    d0,d1
  301.     mulu.w    #SECONDS_PER_MINUTE,d1 ;Lower 16 bits
  302.     swap    d0
  303.     mulu.w    #SECONDS_PER_MINUTE,d0 ;Upper 16 bits
  304.     swap    d0
  305.     add.l    d1,d0    ;Add 'em
  306.     move.l    (ds_Tick,a3),d1    ;# of Seconds since midnight
  307.     divu.w    #TICKS_PER_SECOND,d1
  308.     ext.l    d1
  309.     add.l    d1,d0    ;# of seconds since 01/01/78
  310.     bsr.b    SetSysTime
  311.     lea    (Read.msg,pc),a0    ;Print "System Time set to..."
  312.     bra.b    4$
  313.  
  314. 3$    lea    (Set.msg,pc),a0    ;Print "Clock Time set to..."
  315. 4$    lea    (PArgs-DT,a4),a1
  316.     movea.l    a1,a2
  317.     lea    (dat_StrDay,a3),a3
  318.     move.l    (a3)+,(a2)+    ;Move ptrs to strings for Printf
  319.     move.l    (a3)+,(a2)+
  320.     move.l    (a3)+,(a2)+
  321.     moveq    #RETURN_OK,d3
  322.     moveq    #0,d2
  323.     bra    Exit
  324.  
  325. *** Subroutines
  326.  
  327. Wait    moveq    #40,d1    ;Approx. 150 usec
  328. 1$    subq.l    #1,d1
  329.     bpl.b    1$    ;So it's a cpu hog - how often do
  330.     rts        ; you read/set the clock, anyway?
  331.  
  332. SetSysTime    move.l    a6,-(sp)
  333.     movea.l    (SysBase).w,a6
  334.     moveq    #0,d2
  335.     move.l    d0,d3    ;[D0] = # of seconds
  336.     suba.w    #IOTV_SIZE,sp
  337.     movea.l    a6,a0
  338.     movea.l    (ThisTask,a0),a0
  339.     lea    (pr_MsgPort,a0),a0
  340.     move.l    a0,(MN_REPLYPORT,sp)
  341.     lea    (TimerName,pc),a0
  342.     move.l    #0,d0
  343.     movea.l    sp,a1
  344.     moveq    #0,d1
  345.     SYS    OpenDevice
  346.     tst.l    d0
  347.     bne.b    1$
  348.     move.w    #TR_SETSYSTIME,(IO_COMMAND,sp)
  349.     clr.l    (IOTV_TIME+TV_MICRO,sp)
  350.     move.l    d3,(IOTV_TIME+TV_SECS,sp)
  351.     movea.l    sp,a1
  352.     SYS    DoIO
  353.     movea.l    sp,a1
  354.     SYS    CloseDevice
  355. 1$    adda.w    #IOTV_SIZE,sp
  356.     movea.l    (sp)+,a6
  357.     rts
  358.  
  359. TimerName    cstr    'timer.device'
  360.     even
  361.  
  362. ArgErr    lea    (Help.msg,pc),a0    ;Print instructions
  363.     moveq    #RETURN_WARN,d3
  364.     moveq    #ERROR_LINE_TOO_LONG,d2
  365.     bra.b    Quit
  366.  
  367. MemErr    lea    (NoMem.msg,pc),a0    ;Print "No memory"
  368.     moveq    #RETURN_FAIL,d3
  369.     moveq    #ERROR_NO_FREE_STORE,d2
  370.     bra.b    Quit
  371.  
  372. ConvErr    lea    (Stamp1.msg,pc),a0 ;Print "Can't convert to DateStamp"
  373.     bra.b    Err.1
  374.  
  375. DateErr    lea    (Stamp2.msg,pc),a0 ;Print "Can't read system time"
  376. Err.1    moveq    #RETURN_FAIL,d3
  377.     move.l    #200,d2    ;Internal error
  378.  
  379. Quit    lea    (NULLBYT,pc),a1    ;Null arg
  380. Exit    SYS    Printf    ;Write message
  381.     move.l    d3,d0    ;D0 = ReturnCode, D2 = Fault
  382.     SYS    ArpExit
  383.  
  384. Help.msg    db    'Time V1.0 - ©1990,91 by The Puzzle Factory',10
  385.     db    'Time S/SET  sets clock from system date.',10
  386.     db    'Time R/READ sets system date from clock.',10
  387. NULLBYT    db    0
  388.  
  389. Template    cstr    'R=READ/S,S=SET/S'
  390.  
  391. NoMem.msg    cstr    'Can''t allocate memory.',10
  392. Stamp1.msg    cstr    'Can''t convert to DateStamp.',10
  393. Stamp2.msg    cstr    'Can''t read system time.',10
  394.  
  395. Set.msg    cstr    'Clock Time set to: %s %s %s',10
  396. Read.msg    cstr    'System Time set to: %s %s %s',10
  397.  
  398. ;        M10 M01 D10 D01 Y10 Y01 10H 01H 10M 01M 10S 01S
  399. Reg_order    db    $0A,$09,$08,$07,$0C,$0B,$05,$04,$03,$02,$01,$00
  400. DataMask    db    $01,$0F,$03,$0F,$0F,$0F,$03,$0F,$07,$0F,$07,$0F 
  401. Str_order    db    $00,$01,$03,$04,$06,$07,$00,$01,$03,$04,$06,$07
  402.  
  403. Day_index    db    Day0-Day0,Day1-Day0,Day2-Day0,Day3-Day0
  404.     db    Day4-Day0,Day5-Day0,Day6-Day0
  405. Day_table
  406. Day0    cstr    'Sunday'
  407. Day1    cstr    'Monday'
  408. Day2    cstr    'Tuesday'
  409. Day3    cstr    'Wednesday'
  410. Day4    cstr    'Thursday'
  411. Day5    cstr    'Friday'
  412. Day6    cstr    'Saturday'
  413.  
  414. DT
  415. ArgArray
  416. Arg1    dx.l    1
  417. Arg2    dx.l    1
  418.  
  419. PArgs    dx.l    3
  420.  
  421. DateTime    dx.b    dat_SIZEOF
  422. DayStr    dx.b    LEN_DATSTRING
  423. DateStr    dx.b    LEN_DATSTRING
  424. TimeStr    dx.b    LEN_DATSTRING
  425.  
  426.     end
  427.