home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Club Amiga de Montreal - CAM
/
CAM_CD_1.iso
/
files
/
465.lha
/
WTF
/
source
/
handler.s
< prev
next >
Wrap
Text File
|
1991-01-05
|
1KB
|
62 lines
OPT C+,L+,S-,Y+
INCDIR "DevpacAm:include/"
INCLUDE "devices/inputevent.i"
INCLUDE "exec.offsets"
INCLUDE "intuition.offsets"
ExecBase = 4
XREF _IntuitionBase
XREF _LinkerDB
XREF _Common
XDEF _KHandler
IDNT handler.a
SECTION handler,CODE
_KHandler MOVE.L A0,D0
.Again CMP.B #IECLASS_RAWMOUSE,ie_Class(A0)
BNE.B .NextEvent
CMP.W #IECODE_LBUTTON,ie_Code(A0)
BNE.B .NextEvent
MOVEM.L D0/D2-D3/A0/A4/A6,-(SP)
LEA _LinkerDB,A4
MOVE.L _IntuitionBase(A4),A6
MOVEM.L LastClick+0(A4),D0-D1
MOVEM.L ie_TimeStamp+0(A0),D2-D3
MOVEM.L D2-D3,LastClick+0(A4)
JSR _LVODoubleClick(A6)
TST.L D0
BEQ.S .NotDouble
MOVE.L ExecBase,A6
MOVE.L _Common+0(A4),A1
MOVE.B _Common+4(A4),D1
CLR.L D0
BSET D1,D0
JSR _LVOSignal(A6)
.NotDouble MOVEM.L (SP)+,D0/D2-D3/A0/A4/A6
.NextEvent MOVE.L ie_NextEvent(A0),A0
MOVE.L A0,D1
BNE.B .Again
RTS
SECTION __MERGED,DATA
LastClick DS.L 2