home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 351.lha / ontrap / c.a < prev    next >
Text File  |  1990-02-28  |  11KB  |  435 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4. * Use the following command line to make c.o
  5. * asm -u -iINCLUDE: c.a
  6. *
  7. * Use the following command line to make cres.o
  8. * asm -u -dRESIDENT -iINCLUDE: -ocres.o c.a
  9. *
  10.     INCLUDE    "exec/types.i"
  11.     INCLUDE    "exec/alerts.i"
  12.     INCLUDE    "exec/nodes.i"
  13.     INCLUDE    "exec/lists.i"
  14.     INCLUDE    "exec/ports.i"
  15.     INCLUDE    "exec/libraries.i"
  16.     INCLUDE    "exec/tasks.i"
  17.     INCLUDE    "exec/memory.i"
  18.     INCLUDE    "exec/execbase.i"
  19.     INCLUDE    "libraries/dos.i"
  20.     INCLUDE    "libraries/dosextens.i"
  21.     INCLUDE    "workbench/startup.i"
  22.     INCLUDE    "exec/funcdef.i"
  23.     INCLUDE    "exec/exec_lib.i"
  24.     INCLUDE    "libraries/dos_lib.i"
  25.  
  26. MEMFLAGS    EQU    MEMF_CLEAR+MEMF_PUBLIC
  27. AbsExecBase    EQU    4
  28.  
  29. ; some usefull macros:
  30.  
  31. callsys macro
  32.     CALLLIB _LVO\1
  33.     endm
  34.     
  35.     xdef    XCEXIT        * exit(code) is standard way to leave C.
  36.     xdef    @XCEXIT
  37.     
  38.     xref    LinkerDB    * linker defined base value
  39.     xref    _BSSBAS        * linker defined base of BSS
  40.     xref    _BSSLEN        * linker defined length of BSS
  41.     IFD    RESIDENT
  42.     xref    RESLEN
  43.     xref    RESBASE
  44.     xref    NEWDATAL
  45.     xref    _stack
  46.     ENDC
  47.     
  48. *       library references
  49.  
  50.     section text,code
  51.  
  52.     xref    _main            * Name of C program to start with.
  53.     xref    MemCleanup        * Free all allocated memory
  54.     xref    __fpinit        * initialize floating point
  55.     xref    __fpterm        * terminate floating point
  56.     
  57. start:
  58.     movem.l d1-d6/a0-a6,-(a7)
  59.  
  60.     move.l  a0,a2            * save command pointer
  61.     move.l  d0,d2            * and command length
  62.     lea     LinkerDB,a4        * load base register
  63.     move.l  AbsExecBase.W,a6
  64.  
  65.     IFND    RESIDENT
  66.     lea     _BSSBAS,a3        * get base of BSS
  67.     moveq   #0,d1
  68.     move.l  #_BSSLEN,d0        * get length of BSS in longwords
  69.     bra.s   clr_lp            * and clear for length given
  70. clr_bss move.l  d1,(a3)+
  71. clr_lp  dbf     d0,clr_bss
  72.     move.l  a7,_StackPtr(A4)       * Save stack ptr
  73.     move.l  a6,SysBase(A4)
  74.     ENDC
  75.     
  76.  
  77.     IFD    RESIDENT
  78.     movem.l    d2,-(a7)
  79.     movem.l a0-a2,-(a7)
  80.  
  81. *------ get the size of the stack, if CLI use cli_DefaultStack
  82. *------                       if WB use a7 - TC_SPLOWER
  83.     move.l    ThisTask(a6),A3
  84.     move.l  pr_CLI(A3),d1
  85.     beq.s   fromwb
  86.     lsl.l    #2,d1
  87.     move.l    d1,a0
  88.     move.l    cli_DefaultStack(a0),d1
  89.     lsl.l    #2,d1            * # longwords -> # bytes
  90.     bra.s    dostack
  91.  
  92. fromwb:
  93.     move.l    a7,d1             
  94.     sub.l    TC_SPLOWER(a3),d1     
  95. dostack:
  96.     moveq    #0,d2            * use d2 as flag for newstack or not
  97.     move.l    #RESLEN,d0
  98.     cmp.l    _stack(a4),d1        * This a4 is in the original 
  99.                     * set of data
  100.     bcc.s    nochange    
  101.     move.l    _stack(a4),d1
  102.     add.l    d1,d0            * increase size of mem for new stack
  103.     moveq    #1,d2            * set flag
  104.         
  105. nochange:
  106.     move.l    d1,a3            * save stacksize to set up stack checking
  107.     move.l    #MEMFLAGS,d1
  108.     callsys AllocMem
  109.     tst.l    d0
  110.     bne.s    ok1
  111.     movem.l    (a7)+,d2/a0-a2
  112.     rts
  113.  
  114. ok1:    move.l    d0,a0
  115.     move.l    d0,a2
  116.  
  117. ;a2 now has difference
  118.     move.l    d0,a1
  119.     move.l    #NEWDATAL,d0
  120.     sub.l    #RESBASE,a4
  121. ;copy data over
  122. cpy:    move.l    (a4)+,(a0)+
  123.     subq.l    #1,d0
  124.     bne.s    cpy
  125. ;a4 now points at number of relocs
  126.     move.l    (a4)+,d0
  127. reloc:  beq.s    nreloc
  128.     move.l    a1,a0
  129.     add.l    (a4)+,a0        * a0 now has add of reloc
  130.     add.l    (a0),a2
  131.     move.l    a2,(a0) 
  132.     move.l    a1,a2            * restore offset
  133.     subq.l    #1,d0
  134.     bra.s    reloc
  135.     
  136. nreloc: move.l    a1,a4            * set up new base register
  137.     add.l    #RESBASE,a4
  138.  
  139.     move.l    #RESLEN,realdatasize(a4)
  140.     movem.l (a7)+,a0-a2
  141.  
  142.     move.l  a6,SysBase(A4)
  143.     tst.b    d2
  144.     movem.l    (a7)+,d2        * restore d2 
  145.     movem.l a7,_StackPtr(A4)    * Save stack ptr (movem doesn't
  146.                     * change flags
  147.     beq.s    nochg2
  148.  
  149. *------ set up new stack
  150.     move.l    a4,d0
  151.     sub.l    #RESBASE,d0
  152.     add.l    #RESLEN,d0
  153.     add.l    _stack(a4),d0        * here a4 will be pointing at the
  154.                     * new data, but _stack will be the
  155.                     * same if all goes well
  156.                     
  157.     sub.l    #128,d0            * 128 down for good measure
  158.     move.l    d0,a7
  159.     move.l    _stack(a4),d0
  160.     move.l    d0,4(a7)        * fill in size of new stack    
  161.     add.l    d0,realdatasize(a4)     * need to know how much to free later
  162.  
  163. nochg2:
  164. *------ Set _base for stack checking
  165.     move.l    a7,d1
  166.     sub.l    a3,d1            * get top of stack
  167.     add.l   #128,D1            * allow for parms overflow
  168.     move.l  D1,_base(A4)        * save for stack checking
  169.  
  170.     ENDC
  171.  
  172. clrwb:
  173.     clr.l   WBenchMsg(A4)
  174.  
  175. *JVP--- get the address of our task
  176.     move.l    ThisTask(a6),A3
  177.  
  178. *JVP--- set up for my very own trap handler
  179.     move.l    TC_TRAPCODE(a3),oldTrapCode(a4)    * save the old trap code
  180.     lea    trapcode,a0        * do something a little less
  181.     move.l    a0,TC_TRAPCODE(a3)    * drastic.
  182.  
  183. *-----  clear any pending signals
  184.     moveq    #0,d0
  185.     move.l    #$00003000,d1
  186.     callsys    SetSignal
  187.     
  188.  
  189. *------ attempt to open DOS library:
  190.     lea     DOSName(PC),A1
  191.     moveq.l #0,D0
  192.     callsys OpenLibrary
  193.     move.l  D0,DOSBase(A4)
  194.     bne.s    ok2
  195.     moveq.l #100,d0
  196.     bra.w   exit2
  197.  
  198. ok2:
  199. *------ are we running as a son of Workbench?
  200.     move.l    ThisTask(a6),A3
  201.     move.l  pr_CurrentDir(A3),curdir(A4)
  202.     tst.l   pr_CLI(A3)
  203.     beq.s  fromWorkbench
  204.     
  205. *=======================================================================
  206. *====== CLI Startup Code ===============================================
  207. *=======================================================================
  208. *
  209. * Entry: D2 = command length
  210. *    A2 = Command pointer
  211. fromCLI:
  212.     ifnd    RESIDENT    * we need to set _base if not resident
  213.         move.l  a7,D0           * get top of stack
  214.         sub.l   4(a7),D0        * compute bottom 
  215.         add.l   #128,D0         * allow for parms overflow
  216.         move.l  D0,_base(A4)    * save for stack checking
  217.     endc
  218.     
  219. *------ find command name:
  220.     move.l  pr_CLI(a3),a0
  221.     add.l   a0,a0       * bcpl pointer conversion
  222.     add.l   a0,a0
  223.     move.l  cli_CommandName(a0),a1
  224.     add.l   a1,a1       * bcpl pointer conversion
  225.     add.l   a1,a1
  226.  
  227. *------ collect parameters:
  228.     move.l  d2,d0           * get command line length
  229.     moveq.l #0,d1
  230.     move.b  (a1)+,d1
  231.     move.l  a1,_ProgramName(A4)
  232.     add.l   d1,d0           * add length of command name
  233.     addq.l  #1,d0           * allow for space after command 
  234.  
  235.     clr.w   -(A7)           * set null terminator for command line
  236.     addq.l  #1,D0           * force to even number of bytes
  237.     andi.w  #$fffe,D0           *(round up)
  238.     sub.l   D0,A7           * make room on stack for command line
  239.     subq.l  #2,D0
  240.     clr.w   0(A7,D0)
  241.  
  242. *------ copy command line onto stack
  243.     move.l  d2,d0           * get command line length
  244.     subq.l  #1,d0
  245.     add.l   d1,d2
  246.  
  247. copy_line:
  248.     move.b  0(A2,D0.W),0(A7,D2.W)   * copy command line to stack
  249.     subq.l  #1,d2
  250.     dbf     d0,copy_line
  251.     move.b  #' ',0(a7,d2.w)     * add space between command and parms
  252.     subq.l  #1,d2
  253.  
  254. copy_cmd:
  255.     move.b  0(a1,d2.w),0(a7,d2.w)   * copy command name to stack
  256.     dbf     d2,copy_cmd
  257.     move.l  A7,A1
  258.     move.l  A1,-(A7)        * push command line address
  259.     bra.s   main            * call C entrypoint
  260.  
  261. *=======================================================================
  262. *====== Workbench Startup Code =========================================
  263. *=======================================================================
  264.  
  265. fromWorkbench:
  266.  
  267.     ifnd    RESIDENT    * we need to set _base if not resident
  268.         move.l  TC_SPLOWER(a3),_base(A4) * set base of stack
  269.     moveq   #127,d0
  270.     addq.l    #1,d0                    * Efficient way of getting in 128
  271.         add.l   d0,_base(A4)             * allow for parms overflow
  272.     endc
  273.  
  274. *------ we are now set up.  wait for a message from our starter
  275.     lea     pr_MsgPort(A3),a0       * our process base
  276.     callsys WaitPort
  277.     lea     pr_MsgPort(A3),a0       * our process base
  278.     callsys GetMsg
  279.     move.l  d0,WBenchMsg(a4)
  280.     move.l  d0,-(SP)
  281. *
  282.     move.l  d0,a2           * get first argument
  283.     move.l  sm_ArgList(a2),d0
  284.     beq.s   do_cons
  285.     move.l  DOSBase(a4),a6
  286.     move.l  d0,a0
  287.     move.l  wa_Lock(a0),d1
  288.     move.l  d1,curdir(A4)
  289.     callsys CurrentDir
  290. do_cons:
  291.     move.l  sm_ToolWindow(a2),d1    * get the window argument
  292.     beq.s   do_main
  293.     move.l  #MODE_OLDFILE,d2
  294.     callsys Open
  295.     move.l  d0,stdin(a4)
  296.     beq.s   do_main
  297.     lsl.l   #2,d0
  298.     move.l  d0,a0
  299.     move.l  fh_Type(a0),pr_ConsoleTask(A3)
  300. do_main:
  301.     move.l  WBenchMsg(A4),a0    * get address of workbench message
  302.     move.l  a0,-(a7)        * push argv
  303.     pea     NULL(a4)        * push argc
  304.     move.l  sm_ArgList(a0),a0       * get address of arguments
  305.     move.l  wa_Name(a0),_ProgramName(A4)       * get name of program
  306.  
  307. *=============================================
  308. *------ common code --------
  309. *=============================================
  310.  
  311. main    jsr     __fpinit(PC)        * Initialize floating point
  312.     jsr     _main(PC)           * call C entrypoint
  313.     moveq.l #0,d0           * set successful status
  314.     bra.s   exit2
  315. *
  316.  
  317. XCEXIT:
  318.     move.l  4(SP),d0        * extract return code
  319. @XCEXIT:
  320. exit2:
  321.     move.l  d0,-(a7)
  322.     move.l  _ONEXIT(A4),d0      * exit trap function?
  323.     beq.s   exit3
  324.     move.l  d0,a0
  325.     jsr     (a0)
  326. exit3   jsr     MemCleanup(PC)      * cleanup leftover memory alloc.
  327.     move.l  AbsExecBase.W,a6
  328.     move.l  DOSBase(A4),a1
  329.     callsys CloseLibrary        * close Dos library
  330.  
  331.     jsr     __fpterm(PC)        * clean up any floating point
  332.  
  333. done_1c:
  334. *------ if we ran from CLI, skip workbench cleanup:
  335.     tst.l   WBenchMsg(A4)
  336.     beq.s   exitToDOS
  337.     move.l  stdin(a4),d1
  338.     beq.s   done_4
  339.     callsys Close
  340. done_4:
  341.  
  342. *------ return the startup message to our parent
  343. *       we forbid so workbench can't UnLoadSeg() us
  344. *       before we are done:
  345.     move.l  AbsExecBase.W,A6
  346.     callsys Forbid
  347.     move.l  WBenchMsg(a4),a1
  348.     callsys ReplyMsg
  349.  
  350. *------ this rts sends us back to DOS:
  351. exitToDOS:
  352. *JVP--- restore original TC_TRAPCODE leaving the shell as it was.
  353.     move.l    ThisTask(a6),a1
  354.     move.l    oldTrapCode(a4),TC_TRAPCODE(a1)    * politely restore this guy.
  355.     IFD    RESIDENT
  356.     move.l    realdatasize(a4),d0
  357.     move.l  a4,a1
  358.     sub.l   #RESBASE,a1
  359.     move.l  AbsExecBase.W,a6
  360.         move.l  (A7)+,d6
  361.         movea.l _StackPtr(a4),a5
  362.     callsys FreeMem
  363.         move.l   d6,d0
  364.         movea.l  a5,sp
  365.         ELSE
  366.     move.l  (A7)+,D0
  367.     movea.l _StackPtr(a4),SP    * restore stack ptr
  368.     ENDC
  369.     
  370.     movem.l (a7)+,d1-d6/a0-a6
  371.     rts
  372.  
  373. *JVP---------------------------------------------------------------------
  374. *  Trap handler. Helps avoid the GURU.
  375.  
  376. trapcode:
  377.         move.l    (sp)+,d0    ; get the trap code off the supervisor stack
  378.                 andi    #$DFFF,SR    ; switch back to Usermode
  379.                 lea     LinkerDB,A4    ; load linker defined base register
  380.                 move.l    d0,_TRAPCODE(A4) ; Make the trap code available to C functions
  381.         move.l    _ONTRAP(A4),d0    ; get the new trap vector
  382.         beq    1$        ; skip C routine call if not supplied
  383.         move.l    d0,a0        ; make it a funtion address
  384.                 jsr     (a0)        ; Let C code clean up.
  385. 1$:        move.l    _TRAPCODE(A4),d0    ; use the trap code as the return code
  386.         add.l    #1000,d0    ; give it an offset to force exit message
  387.                 jmp     exit2        ; exit this error prone program.
  388.  
  389.  
  390. DOSName     dc.b    'dos.library',0
  391.  
  392.     section __MERGED,BSS
  393. *
  394.     xref    DOSBase
  395.  
  396.     xdef    NULL,SysBase,WBenchMsg
  397.     xdef    curdir,_mbase,_mnext,_msize,_tsize
  398.     xdef    _oserr,_OSERR,_FPERR,_SIGFPE,_ONERR,_ONEXIT,_ONBREAK
  399.     xdef    _SIGINT
  400.     xdef    _ProgramName,_StackPtr,_base
  401.  
  402. *JVP--- ontrap externals
  403.     xdef    _ONTRAP,_TRAPCODE
  404. *
  405.     ifd    RESIDENT
  406. realdatasize    ds.b    4    * size of memory allocated for data +
  407.                 * possible stack
  408.     endc
  409.     
  410. NULL        ds.b    4    *
  411. _base        ds.b    4    * base of stack
  412. _mbase        ds.b    4    * base of memory pool
  413. _mnext        ds.b    4    * next available memory location
  414. _msize        ds.b    4    * size of memory pool
  415. _tsize        ds.b    4    * total size?
  416. _oserr        equ     *
  417. _OSERR        ds.b    4
  418. _FPERR        ds.b    4
  419. _SIGFPE        ds.b    4
  420. _SIGINT        ds.b    4
  421. _ONERR        ds.b    4
  422. _ONEXIT        ds.b    4
  423. _ONBREAK    ds.b    4
  424. curdir         ds.b    4
  425. SysBase        ds.b    4
  426. WBenchMsg    ds.b    4
  427. _StackPtr    ds.b    4
  428. stdin        ds.b    4
  429. _ProgramName    ds.b    4
  430. *JVP--- ontrap storage
  431. _ONTRAP         ds.b    4        * my trap handler vector
  432. _TRAPCODE    ds.b    4
  433. oldTrapCode     ds.b    4
  434.         END
  435.