home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 326.lha / requester.library_v1.3 / Test.asm < prev    next >
Assembly Source File  |  1989-12-30  |  20KB  |  572 lines
  1.  ;====Uncomment these directives for MANX asm only!!
  2.  ; far   code ;so that we can use register a4, and no limit on program size.
  3.  ; far   data
  4.  
  5.  SMALLOBJ ;CAPE PC relative addressing substituted for absolute
  6.  
  7.  INCLUDE  "rad:FileIO.i"
  8.  
  9.  ;======Amiga Library routines======
  10.    XREF    _LVOCloseLibrary,_LVOCloseScreen,_LVOCloseWindow,_LVOSetMenuStrip
  11.    XREF    _LVOOpenWindow,_LVOOpenScreen,_LVOOpenLibrary
  12.    XREF    _LVOGetMsg,_LVOReplyMsg,_LVOWait,_LVOMove,_LVOText
  13.    XREF    _LVOSetAPen,_LVOSetBPen,_LVOSetDrMd
  14.  
  15.  ;======From the startup code======
  16.    XREF    _SysBase,_DOSBase
  17.  
  18.  ;======From dissidents utilities lib
  19.    XREF up_to_low_case_str,append
  20.  
  21. ; This program opens and utilizes the requester library in order to obtain
  22. ; a full pathname string from the user. When the user clicks the right mouse
  23. ; button, the program calls TestFileIO which calls the library routine that
  24. ; does the entire requester operation. A menu is included in order to enable
  25. ; certain features such as:
  26. ; EXTENSION - Sets the FileIO's EXTENSION_MATCH flag so that only filenames
  27. ;             that end in a specified extension are matched. I have allowed
  28. ;             the user to type in the extension he wishes via the FileIO's
  29. ;             PromptUserEntry function (extension must be specified in lower
  30. ;             case).
  31. ; WORKBENCH - Gives workbench pattern matching (i.e. only .info files are
  32. ;             displayed but without the .info) A file not ending in .info is
  33. ;             ignored.
  34. ; DEVICE    - Uses device names (i.e. DF0:) instead of the disk's real name.
  35. ; CUSTOM    - Inserts a custom handler for the requester's StartUpHandler
  36. ;             which just displays an autorequester message.
  37. ; TYPENAME  - Uses the lib function TypeFilename to completely bypass the
  38. ;             file requester, and uses the titlebar instead.
  39.  
  40. ; Any or all of these can be set simultaneously, but you should enable one
  41. ; at a time to see the actual effect.
  42. ; If running this program from the CLI and you specify any argument on the
  43. ; command (i.e.  1> TestFileIO blort ), then the window will open on a hires
  44. ; screen. You can then see what the requester looks like in hires.
  45.  
  46. LIB_VERSION equ 33
  47.  
  48. ;  For Manx,   ln -o TestFileIO  ManxStartUp.o  main.o  cl32.lib
  49. ;
  50. ;  For Others, Blink StartUp.o main.o amiga.lib NODEBUG to TestFileIO
  51.  
  52. ExtBufSize equ 21  ;(30-1)-PromptLen
  53.  
  54.    SECTION FileIOTestCode,CODE
  55.  
  56.    XDEF   _main
  57. _main:
  58.     movem.l   d2-d7/a2-a6,-(sp)
  59.     movea.l   _SysBase,a6
  60. ;======Open The Intuition Library=======
  61.     moveq     #LIB_VERSION,d0
  62.     lea       IntuitionName,a1
  63.     jsr       _LVOOpenLibrary(a6)
  64.     lea       _IntuitionBase,a4
  65.     move.l    d0,(a4)+
  66.     beq       C7
  67. ;======Open The Graphics Library========
  68.     moveq     #LIB_VERSION,d0
  69.     lea       GfxName,a1
  70.     jsr       _LVOOpenLibrary(a6)
  71.     move.l    d0,(a4)+
  72.     beq       C6
  73. ;*******Open the "Brand New, Improved, Exciting" Requester library*********
  74.     moveq     #0,d0            ;any version (for now)
  75.     lea       RequesterName,a1
  76.     jsr       _LVOOpenLibrary(a6)
  77.     move.l    d0,(a4)+
  78.     beq       C5
  79. ;=====If started from WBench, then don't open a CUSTOM screen
  80.     movea.l   _IntuitionBase,a6
  81.     move.l    52(sp),d0
  82.     beq.s     .9
  83. ;=====If opened from CLI with any argument, then open CUSTOM screen
  84.     subq.l    #2,48(sp)
  85.     bcs.s     .9
  86.     lea       newScreen,a0
  87.     jsr       _LVOOpenScreen(a6)
  88.     lea       newWindow,a0
  89.    ;-----Window's Screen = ScreenPtr
  90.     move.l    d0,30(a0)
  91.     beq.s     .9A             ;If an error, forget the screen!
  92.    ;-----Window's Type = CUSTOMSCREEN
  93.     move.w    #15,46(a0)
  94. ;=========Open the FileIO window==========
  95. .9  lea       newWindow,a0
  96. .9A jsr       _LVOOpenWindow(a6)
  97.     move.l    d0,(a4)+
  98.     beq       C2
  99.     movea.l   d0,a3
  100.    ;---Get Window's RastPort
  101.     move.l    50(a3),(a4)
  102. ;====Attach our menu to the window======
  103.     lea       ProjectMenu,a1
  104.     movea.l   a3,a0
  105.      ;  _IntuitionBase,a6
  106.     jsr       _LVOSetMenuStrip(a6)
  107. ;-----Get a FileIO structure
  108. E1  movea.l   _RequesterBase,a6
  109.     jsr       _LVOGetFileIO(a6)
  110.     movea.l   d0,a4
  111.     move.l    d0,d1
  112.     beq       IOe          ;If NULL, then error, so exit this test program.
  113. ;---Set Colors and DrawMode
  114.     moveq     #1,d0
  115.     move.b    d0,FILEIO_DRAWMODE(a4)
  116.     movea.l   RastPort,a2
  117.     movea.l   a2,a1
  118.     movea.l   _GfxBase,a6
  119.     jsr       _LVOSetDrMd(a6)
  120.     moveq     #2,d0
  121.     move.b    d0,FILEIO_PENA(a4)
  122.     movea.l   a2,a1
  123.     jsr       _LVOSetAPen(a6)
  124.     moveq     #0,d0
  125.     move.b    d0,FILEIO_PENB(a4)
  126.     movea.l   a2,a1
  127.     jsr       _LVOSetBPen(a6)
  128. ;====Set up custom handlers for the FileIO but don't enable the flag yet===
  129.     move.l    #HandlerBlock,FILEIO_CUSTOM(a4) ;the address of our handler vectors
  130. ;====Set up the XY co-ordinates of where the requester will open====
  131. ; If we used DoFileIOWindow(), we wouldn't need to set co-ordinates.
  132.     moveq     #6,d0
  133.     move.w    d0,FILEIO_X(a4)  ;x position
  134.     moveq     #11,d0
  135.     move.w    d0,FILEIO_Y(a4)  ;y position
  136.  ;---Get the buffer where the complete Path will be stored
  137.     move.l   #buffer,FILEIO_BUFFER(a4)
  138.  ;---Set up EXTENTION in case the user wants to enable it via function key 4
  139.  ;   If we allow this feature, we must supply a buffer of at least 30 bytes
  140.  ;   If we don't want the user to utilize this feature, then FILEIO_EXTENTION
  141.  ;   field must be zeroed and EXTENTION_MATCH flag cleared whenever we
  142.  ;   aren't using this feature.
  143.     lea      ExtMatch,a0
  144.     move.l   a0,FILEIO_EXTENSION(a4)
  145. ;====Create a mask of the Window's UserPort's mp_Sigbit=====
  146. E3  movea.l   86(a3),a0
  147.     move.b    15(a0),d0
  148.     moveq     #0,d7
  149.     Bset.l    d0,d7
  150. ;=====Get the message that arrived at our UserPort====
  151. E4  movea.l   86(a3),a0
  152.     movea.l   _SysBase,a6
  153.     jsr       _LVOGetMsg(a6)
  154.     move.l    d0,d1
  155.     bne.s     E7
  156. ;===Check if we are ready to exit the program=====
  157. E5  Btst.b    #0,Quit
  158.     beq       E15
  159. ;----Print out "Click Mouse to start demo....
  160.     movea.l   RastPort,a2
  161.     moveq     #5,d0
  162.     moveq     #75,d1
  163.     movea.l   a2,a1           ;our window's RastPort
  164.     move.l    a6,-(sp)        ;save _SysBase
  165.     movea.l   _GfxBase,a6
  166.     jsr       _LVOMove(a6)
  167.     moveq     #36,d0          ;# of bytes to output.
  168.     lea       Click,a0
  169.     movea.l   a2,a1
  170.     jsr       _LVOText(a6)
  171.     movea.l   (sp)+,a6        ;restore _SysBase
  172. ;===Wait for a message sent to our Window (from Intuition)===
  173. E6  move.l    d7,d0
  174.     jsr       _LVOWait(a6)
  175.     bra.s     E4
  176. ;====Copy all the info we want from the IntuiMessage====
  177. E7  movea.l   d0,a1
  178.     lea       20(a1),a0  ;get the address of the first field to copy.
  179.     move.l    (a0)+,d6   ;Copy the Class field to d6
  180.     move.w    (a0)+,d5   ;Copy the Code field to d5
  181.     move.w    (a0)+,d4   ;Copy the qualifier field to d4
  182.     movea.l   (a0)+,a2   ;Copy the IAddress field to a2
  183.     move.w    (a0)+,d3   ;Copy MouseX position to d3
  184.     move.w    (a0)+,d2   ;Copy MouseY position to d2
  185. ;====Now reply to the message so Intuition can dispose of it
  186. E8  ;Address of the message is in a1.
  187.     jsr       _LVOReplyMsg(a6)
  188. ;========switch (class)=========
  189.     Bclr.l    #9,d6  ;CLOSEWINDOW
  190.     bne       CW
  191.     Bclr.l    #8,d6  ;MENUPICK
  192.     bne.s     MU
  193.     Bclr.l    #3,d6  ;MOUSEBUTTONS
  194.     beq       E4
  195. ;---Make sure that it's an UP select if MOUSEBUTTONS
  196.     subi.b    #$68,d5
  197.     beq       E4     ;ignore down
  198. ;===The FOLLOWING ROUTINE IS OUR TEST CALL. WHEN THE USER IS DONE (in FileIO lib)
  199. ;===HE WILL SELECT EITHER THE CANCEL OR OK! GADGET. IF CANCEL, TestFileIO
  200. ;===DOES NOTHING. IF OK!, TestFileIO JUSTS PRINTS THE SELECTED FILENAME.
  201. E2  bsr       TestFileIO
  202.   ;If TestFileIO returns a 1, then we should CLEAR the NO_CARE_REDRAW
  203.   ;flag in any FileIOs that had it SET. We aren't using this feature though
  204.   ;because another application might change the disks unbeknowst to us.
  205.   ;NO_CARE_REDRAW is only SET when you don't care if the list of names
  206.   ;displayed is updated to include any recent changes by another task.
  207.   ;We probably should clear it though, just in case the user set it.
  208.     bra     E4
  209. ;=========case MENUPICK:===============
  210. ; Actually, if the user selects some of these flags via the function keys,
  211. ; our menu checkmarks won't accurately reflect the real state of the
  212. ; option. We really should set the menuitem's CHECKED flag depending on the
  213. ; toggled state of the FileIO flag. This is just a simple example though.
  214. ; Normally, you wouldn't need to have menus for these options since in the
  215. ; case of CUSTOM handlers it should be invisible to the user. For things
  216. ; like INFO_SUPPRESS, let the user set it himself with the function keys.
  217.   ;------Determine which item
  218. MU lsr.w   #5,d5         ;Shift the item # bits into lowest bits of reg.
  219.    andi.w  #$3F,d5       ;Isolate the Item # from the Menu and subitem #.
  220.    beq.s   G4            ;branch if Item #0 (Extension)
  221.    subq.w  #1,d5
  222.    beq     G3            ;branch if Item #1 (WB)
  223.    subq.w  #1,d5
  224.    beq     G5            ;branch if Item #2 (Device)
  225.    subq.w  #1,d5
  226.    beq     G1            ;branch if Item #3 (Custom)
  227.    subq.w  #1,d5
  228.    beq     G6            ;branch if Item #4 (No Info)
  229.    subq.w  #1,d5
  230.    beq     AB            ;branch if Item #5 (About)
  231.    subq.w  #1,d5
  232.    bne     E4            ;branch if not Item #6 (TypeName)
  233. ;---We deliberately call TypeFilename instead of DoFileIO
  234.    bchg.b  #0,Flag
  235.    bra     E4
  236. ;---Display Info about this program
  237. AB movem.l a2/a3,-(sp)
  238.    movea.l a3,a0         ;window
  239.    lea     Msg1,a1
  240.    lea     Msg2,a2
  241.    lea     Msg3,a3
  242.    movea.l _RequesterBase,a6
  243.    jsr     _LVOAutoPrompt3(a6)
  244.    movem.l (sp)+,a2/a3
  245.    bra     E4
  246. G6 Bchg.b  #INFO_SUPPRESS,1(a4)  ;toggle the INFO_SUPPRESS flag ON/OFF
  247.    bra     E4
  248. G1 Bchg.b  #1,(a4)       ;toggle the CUSTOM_HANDLERS flag ON/OFF
  249.    bra     E4
  250. G4 Bchg.b  #EXTENSION_MATCH,1(a4) ;toggle the EXTENSION_MATCH flag ON/OFF
  251.    bne     E4
  252.  ;WARNING: Must have RAWKEY set in order to call PromptUserEntry or UserEntry
  253.  ;---get the user's choice of extention
  254.    lea     ExtPrompt,a0
  255.    moveq   #ExtBufSize,d0
  256.    lea     ExtMatch,a1  ;display the previous extention
  257.    movea.l a4,a2
  258.    ;window in a3
  259.    movea.l _RequesterBase,a6
  260.    jsr     _LVOPromptUserEntry(a6)
  261.  ;---Did he enter anything?
  262.    move.l  d0,d1    ;buffer
  263.    bne     MF
  264.    Bclr.b  #EXTENSION_MATCH,1(a4) ;turn it back off
  265.    bra     E4
  266.  ;---Set the FileIO match string and size of string
  267.  ;---Now we copy buffer to ExtMatch buffer, converting to all lower case
  268.  ;   since the library needs to see the match string in lower case ONLY.
  269. MF movea.l d0,a1
  270.    lea     ExtMatch,a0
  271.    jsr     up_to_low_case_str
  272.    move.w  d0,FILEIO_EXTSIZE(a4) ;size of extension (don't count NULL)
  273.    bra     E4
  274. G3 Bchg.b  #WBENCH_MATCH,1(a4) ;toggle the WBENCH_MATCH
  275.    bra     E4
  276. G5 Bchg.b  #USE_DEVICE_NAMES,1(a4) ;toggle USE_DEVICE_NAMES
  277.    bra     E4
  278. ;=========case CLOSEWINDOW:============
  279. CW  Bclr.b    #0,Quit
  280.     bra       E4
  281. ;======if an error, indicate NO_MEMORY. This is a FileIO routine
  282. ;======and is callable even if GetFileIO() fails
  283. IOe movea.l   a3,a0
  284.     moveq     #0,d0
  285.     movea.l   _RequesterBase,a6
  286.     jsr       _LVOAutoFileMessage(a6)
  287. ;========NOW BEGINS OUR EXIT ROUTINE=========
  288. E15 movea.l   a4,a1                ;If the pointer to FileIO was NULL, then
  289.     movea.l   _RequesterBase,a6    ;ReleaseFileIO just returns, so it's safe to
  290.     jsr       _LVOReleaseFileIO(a6) ;always release any return value of GetFileIO.
  291. ;=====Close the Window and Screen======
  292. C1  movea.l   _IntuitionBase,a6
  293.     movea.l   a3,a0
  294.     jsr       _LVOCloseWindow(a6)
  295. C2  move.l    ScreenPtr,d0
  296.     beq.s     C3            ;check if we specified a screen
  297.     movea.l   d0,a0
  298.     ; _IntuitionBase in a6
  299.     jsr       _LVOCloseScreen(a6)
  300. ;=====Close Whichever Libs are Open (_SysBase in a6 for ALL calls)=====
  301. C3  movea.l  _SysBase,a6
  302.     movea.l  _RequesterBase,a1
  303.     jsr      _LVOCloseLibrary(a6)
  304. C5  movea.l  _GfxBase,a1
  305.     jsr      _LVOCloseLibrary(a6)
  306. C6  movea.l  _IntuitionBase,a1
  307.     jsr      _LVOCloseLibrary(a6)
  308. C7  movem.l  (sp)+,d2-d7/a2-a6
  309.     rts
  310.  
  311. ;*******************************************
  312. ; This just calls the DoFileIO library routine and displays a msg on return.
  313. ; (GetFileIO must have been called with success first).
  314. ; The DoFileIO routine returns -1 if the user selected CANCEL,
  315. ; or returns the address of the Pathname string if OK! was selected. At this
  316. ; point, we could call a load or save operation using this filename string,
  317. ; but instead, we simply display the chosen name.
  318. ;   TestFileIO(FileIO, window)
  319. ;                a4      a3
  320.  
  321. typename:
  322. ;--This shows what would happen (automatically) if the lib was in use on a
  323. ;  call to DoFileIO(), or the requester couldn't open.
  324.    jsr       _LVOTypeFilename(a6)
  325.    bra.s     cex
  326.    XDEF TestFileIO
  327. TestFileIO:
  328.     movea.l  _RequesterBase,a6
  329.  ;-----DoFileIO(FileIO, window, Buffer)
  330.     movea.l  a3,a1
  331.     movea.l  a4,a0
  332.     Btst.b   #0,Flag
  333.     bne.s    typename
  334.     jsr      _LVODoFileIO(a6)
  335. cex move.l   d0,d1
  336.     beq.s    .error 
  337.  ;must have been an error. If we were using DoFileIOWindow(), the window
  338.  ;might not have opened. For DoFileIO(), we shouldn't see a 0 return.
  339.  ;We could check the FileIO's ERRNO field to see what the specific error
  340.  ;was.
  341.     addq.l   #1,d1
  342.     beq.s    .can        ;If -1, user must have selected CANCEL
  343.  ;-----AutoMessage(buffer, window) Display our path.
  344.     ;buffer in d0
  345.     movea.l  a3,a0
  346.     jsr      _LVOAutoMessage(a6)
  347. ; Now we could check the FileIO's Filename field to see if the user entered
  348. ; a file, or just a drawer or disk name alone. If not NULL, we have a filename.
  349. ; Next we would check the FILEIO_FILESIZE field. If this is 0, then
  350. ; the user must have typed in a filename that doesn't yet exist. We could
  351. ; create it now. Otherwise, this field tells us how large the selected file is.
  352.     move.b   FILEIO_FILENAME(a4),d0
  353.     beq.s    dirdisk
  354.     move.l   FILEIO_FILESIZE(a4),d0
  355.     bne.s    exists
  356.     move.l   #NoExist,d0
  357.     movea.l  a3,a0
  358.     jsr      _LVOAutoMessage(a6)
  359. ;----Clear the DISK_HAS_CHANGED flag. If it was SET, return 1. Else return 0.
  360. ; (i.e. return d0=1 if the user swapped disks during DoFileIO() else 0)
  361. ; We only need to bother with this if we had SET the NO_CARE_REFRESH flag
  362. ; (or the user did via function key 6).
  363. exists:
  364.     moveq    #1,d0
  365.     Bclr.b   #5,(a4)
  366.     bne.s    .32
  367.   ;---Otherwise, return 0
  368.     moveq    #0,d0
  369. .32 rts
  370. .error: move.l  #errmsg,d0
  371. prt     movea.l a3,a0
  372.         jsr     _LVOAutoMessage(a6)
  373.         bra.s   exists
  374. .can    move.l  #cancel,d0
  375.         bra.s   prt
  376. dirdisk move.l  #just,d0
  377.         bra.s   prt
  378.  
  379. start_msg: ;a custom handler for requester's REQSET
  380.     movea.l  window,a0
  381.     move.l   #MSG,d0
  382.     move.l   a6,-(sp)        ;must save a6 (non-scratch) here
  383.     movea.l  _RequesterBase,a6
  384.     jsr      _LVOAutoMessage(a6)  ;depending on if the user selects OK or
  385.     movea.l  (sp)+,a6             ;NO, the internal library's startup handler
  386.     rts                           ;will be executed or skipped.
  387.  
  388.   ; SECTION MainData,DATA  ;Not needed for CAPE PC relative addressing!!
  389.  
  390.    XDEF _IntuitionBase,_GfxBase,ScreenPtr
  391.    XDEF _RequesterBase
  392.  ;must be in this order
  393. _IntuitionBase dc.l 0
  394. _GfxBase       dc.l 0
  395. _RequesterBase dc.l 0
  396. window         dc.l 0
  397. RastPort       dc.l 0
  398.  
  399.    XDEF   newScreen
  400. newScreen:
  401.    dc.w   0,0         ;LeftEdge, TopEdge
  402.    dc.w   640,400     ;Width, Height
  403.    dc.w   2           ;Depth
  404.    dc.b   0,1         ;Detail, Block pens
  405.    dc.w   -32764      ;ViewPort Modes HIRES|LACE (must set/clr HIRES as needed)
  406.    dc.w   15          ;CUSTOMSCREEN
  407.    dc.l   TextAttr    ;Font
  408.    dc.l   ScrTitle
  409.    dc.l   0           ;Gadgets
  410.    dc.l   0           ;CustomBitmap
  411.  
  412.    XDEF   newWindow
  413. newWindow:
  414.           dc.w   30,30
  415.           dc.w   306,145
  416.           dc.b   0,1
  417.  ;IDCMP = MOUSEBUTTONS|CLOSEWINDOW|MENUPICK|RAWKEY
  418.  ;Must have RAWKEY set in order to call PromptUserEntry,UserEntry,GetString
  419.           dc.l   $708
  420.  ;WindowFlags = WINDOWDRAG|WINDOWDEPTH|SMART_REFRESH|ACTIVATE|WINDOWSIZE
  421.  ;(no FOLLOWMOUSE allowed as that messes up the requester when using
  422.  ;DoFileIO(). If you need FOLLOWMOUSE, then use DoFileIOWindow() to open
  423.  ;the req in its own window.)
  424.           dc.l   $100F
  425.           dc.l   0
  426.           dc.l   0
  427.           dc.l   WINTITLE
  428. ScreenPtr dc.l   0
  429.           dc.l   0
  430.           dc.w   306,145
  431.           dc.w   600,240
  432.           dc.w   1         ;WBENCHSCREEN
  433.  
  434. ;==========THE PROJECT MENU===========
  435.  
  436. ProjectMenu:
  437.    dc.l 0
  438.    dc.w 0,0
  439.    dc.w 90,0
  440.    dc.w 1
  441.    dc.l ProjectTitle
  442.    dc.l ExtItem
  443.    dc.w 0,0,0,0
  444.  
  445. ;======The Items in Menu0========
  446.  ;These are MenuItem structures for the preceding Menu Structure.
  447. ExtItem   dc.l WBItem
  448.           dc.w 0,0
  449.           dc.w 200,10
  450.           dc.w $5F
  451.           dc.l 0
  452.           dc.l ExtText
  453.           dc.l 0
  454.           dc.b 'E'
  455.           dc.b 0
  456.           dc.l 0
  457.           dc.w 0
  458. WBItem    dc.l DevItem
  459.           dc.w 0,10,200,10
  460.           dc.w $5F
  461.           dc.l 0,WBText,0
  462.           dc.b 'W'
  463.           dc.b 0
  464.           dc.l 0
  465.           dc.w 0
  466. DevItem   dc.l CusItem
  467.           dc.w 0,20,200,10,$5F
  468.           dc.l 0,DevText,0
  469.           dc.b 'D',0
  470.           dc.l 0
  471.           dc.w 0
  472. CusItem   dc.l InfoItem
  473.           dc.w 0,30,200,10,$5F
  474.           dc.l 0,CusText,0
  475.           dc.b 'C',0
  476.           dc.l 0
  477.           dc.w 0
  478. InfoItem  dc.l AboutItem
  479.           dc.w 0,40,200,10,$5F
  480.           dc.l 0,InfoText,0
  481.           dc.b 'I',0
  482.           dc.l 0
  483.           dc.w 0
  484. AboutItem dc.l TypeItem
  485.           dc.w 0,50,200,10,86
  486.           dc.l 0,AboutText,0
  487.           dc.b 'A',0
  488.           dc.l 0
  489.           dc.w 0
  490. TypeItem  dc.l 0
  491.           dc.w 0,60,200,10,$5F
  492.           dc.l 0,TypeText,0
  493.           dc.b 'T',0
  494.           dc.l 0
  495.           dc.w 0
  496. ExtText   dc.b 0,1,1,0
  497.           dc.w 19,0
  498.           dc.l TextAttr,ExtString,0
  499. WBText    dc.b 0,1,1,0
  500.           dc.w 19,0
  501.           dc.l TextAttr,WBString,0
  502. DevText   dc.b 0,1,1,0
  503.           dc.w 19          ;allow room for the checkmark
  504.           dc.w 0
  505.           dc.l TextAttr,DevString,0
  506. CusText   dc.b 0,1,1,0
  507.           dc.w 19,0
  508.           dc.l TextAttr,CusString,0
  509. InfoText  dc.b 0,1,1,0
  510.           dc.w 19,0
  511.           dc.l TextAttr,NoInfoString,0
  512. AboutText dc.b 0,1,1,0
  513.           dc.w 19,0
  514.           dc.l TextAttr,AboutString,0
  515. TypeText dc.b 0,1,1,0
  516.           dc.w 19,0
  517.           dc.l TextAttr,TypeString,0
  518.  
  519. TextAttr:        ;Topaz 8 is a ROM font so doesn't need to be opened
  520.    dc.l   FONTNAME
  521.    dc.w   8      ;TOPAZ_EIGHTY
  522.    dc.b   0,0
  523.  
  524. HandlerBlock: ;these are the addresses of my custom handlers for the requester's
  525.               ;REQSET, GADGETUP and GADGETDOWN, DISKINSERTED, RAWKEY, and
  526.               ;MOUSEMOVE respectively. Note that I only installed a StartUp
  527.               ;handler. The rest are NULL because I don't care about them.
  528.    dc.l   start_msg     ;StartUpHandler
  529.    dc.l   $0000         ;GadgetHandler
  530.    dc.l   $0000         ;NewDiskHandler
  531.    dc.l   $0000         ;KeyHandler
  532.    dc.l   $0000         ;MouseMoveHandler
  533.  
  534. Quit dc.b 1  ;When this is a 0, the user wants to exit.
  535.  
  536. ScrTitle      dc.b 'Example FileIO Program Screen',0
  537. WINTITLE      dc.b 'Example FileIO Program Window',0
  538. Click         dc.b 'Click mouse for demo or CLOSEWINDOW.',0
  539. IntuitionName dc.b 'intuition.library',0
  540. IconName      dc.b 'icon.library',0
  541. DOSName       dc.b 'dos.library',0
  542. GfxName       dc.b 'graphics.library',0
  543. RequesterName dc.b 'requester.library',0
  544. FONTNAME      dc.b 'topaz.font',0
  545. errmsg        dc.b 'Error in accessing the requester',0
  546. cancel        dc.b 'The CANCEL gadget was selected.',0
  547. ExtString     dc.b 'Extension',0
  548. CusString     dc.b 'Custom',0
  549. WBString      dc.b 'WorkBench',0
  550. DevString     dc.b 'Device',0
  551. NoInfoString  dc.b 'No Info',0
  552. AboutString   dc.b 'About',0
  553. TypeString    dc.b 'Type Name',0
  554. MSG           dc.b 'This is my custom handler',0
  555. ProjectTitle  dc.b 'Project',0
  556. NoExist       dc.b 'This file does not yet exist',0
  557. Msg1   dc.b 'An example of using the FileIO lib',0
  558. Msg2   dc.b 'written by Jeff Glatt',0
  559. Msg3   dc.b '< dissidents >',0
  560. Flag   dc.b 0
  561. just   dc.b 'This is a drawer or disk, not a file.',0
  562.  
  563. PromptLen  equ  7
  564. ExtPrompt  dc.b 'Match >',0
  565.  
  566. buffer    ds.b 202  ;for the complete pathname
  567. ExtMatch  ds.b 30   ;for extension match, must be big enough for extension
  568.                     ;and ExtPrompt because of the way PromptUserEntry works.
  569.  
  570.  
  571.    END
  572.