home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 182.lha / Ls_v2.1 / lssup.a < prev   
Encoding:
Text File  |  1988-04-28  |  21.4 KB  |  835 lines
  1. * --------------------------------------------------------------------- *
  2. * LSSUP.A    - Assembly support routines for ls.c            *
  3. * Copyright © 1988 by Justin V. McCormick. All Rights Reserved.        *
  4. * --------------------------------------------------------------------- *
  5.     IDNT    "lssup.a"
  6.  
  7.     include "asm:inc/macros.i"
  8.  
  9. ; Assembler options for CAPE
  10.     BASEREG    B
  11.     SMALLOBJ
  12. ;    OPTIMON
  13. ;    ADDSYM
  14. ;    DEBUG
  15.  
  16. ; Equates
  17. fib_FileName    equ    $8
  18. fib_Size    equ    $7C
  19. fib_NumBlocks    equ    $80
  20. fib_DateStamp    equ    $84
  21.  
  22. ds_Days        equ    $0
  23. ds_Minute    equ    $4
  24. ds_Tick        equ    $8
  25.  
  26. _LVOAddPort    equ    $FFFFFE9E
  27. _LVOAllocMem    equ    $FFFFFF3A
  28. _LVOAllocSignal    equ    $FFFFFEB6
  29. _LVODebug    equ    $FFFFFF8E
  30. _LVOFindTask    equ    $FFFFFEDA
  31. _LVOFreeMem    equ    $FFFFFF2E
  32. _LVOFreeSignal    equ    $FFFFFEB0
  33. _LVOGetMsg    equ    $FFFFFE8C
  34. _LVOPutMsg    equ    $FFFFFE92
  35. _LVORawDoFmt    equ    $FFFFFDF6
  36. _LVORemPort    equ    $FFFFFE98
  37. _LVORead    equ    $FFFFFFD6
  38. _LVOWaitPort    equ    $FFFFFE80
  39. _LVOWrite    equ    $FFFFFFD0
  40.  
  41. pr_ConsoleTask        EQU    $A4 
  42. MEMF_CLEAR        EQU    $10000 
  43. MEMF_PUBLIC        EQU    $1 
  44. sp_Msg            EQU    $0 
  45. sp_Pkt            EQU    $14 
  46. sp_SIZEOF        EQU    $44 
  47. dp_Link            EQU    $0 
  48. dp_Port            EQU    $4 
  49. dp_Arg1            EQU    $14 
  50. dp_Type            EQU    $8 
  51. ACTION_SCREEN_MODE    EQU    $3E2 
  52. LN_NAME            EQU    $A 
  53. LN_PRI            EQU    $9 
  54. LN_TYPE            EQU    $8 
  55. MP_FLAGS        EQU    $E 
  56. MP_MSGLIST        EQU    $14 
  57. MP_SIGBIT        EQU    $F 
  58. MP_SIGTASK        EQU    $10 
  59. MP_SIZE            EQU    $22 
  60. NT_MSGPORT        EQU    $4 
  61. PA_SIGNAL        EQU    $0 
  62.  
  63. * External constants
  64.     XREF    _DOSBase
  65.     XREF    _Out
  66.     XREF    _In
  67. * --------------------------------------------------------------------- *
  68.     SECTION    lssup,CODE
  69.  
  70. * ------------------------------------------------------------------------- *
  71. * void asprintf(wstr, formatstring, args)
  72. *   char *wstr;
  73. *   char *formatstring;
  74. *   char **args;
  75. * 
  76. * Synopsis: Given formatstring and args to format, formats output to wstr.
  77. * Similar to sprintf(), except doesn't handle floats.
  78. * ------------------------------------------------------------------------- *
  79.     XDEF    _asprintf
  80. _asprintf:
  81.     link    a5,#0
  82.     movem.l    d0-d2/a0-a3,-(sp)    ;Save everything we might clobber
  83.  
  84. * Call format function to convert fmtstring and args to buffer on the stack
  85.     movea.l    12(a5),a0        ;Grab format string
  86.     lea    16(a5),a1        ;Grab EA of arguments
  87.     lea    kput1,a2        ;Grab EA of output subroutine
  88.     movea.l    8(a5),a3        ;Grab EA of dest workspace
  89.     SYS    RawDoFmt,4        ;Format it into workspace
  90.  
  91.     movem.l    (sp)+,d0-d2/a0-a3    ;Restore registers
  92.     unlk    a5            ;And stack frame
  93.     rts
  94.  
  95. * ------------------------------------------------------------------------- *
  96. * RawDoFmt() output routine for xprintf, called for each formatted char.
  97. * Takes byte in d0 and puts in buffer pointed to by a3, then increments a3.
  98. * ------------------------------------------------------------------------- *
  99.     XDEF    kput1
  100. kput1:
  101.     move.b    d0,(a3)+
  102.     rts
  103.  
  104. * --------------------------------------------------------------------- *
  105. * void GetWinBounds(width, height)
  106. *   long *width, *height;
  107. *
  108. * Find current console window, determine width and height
  109. * in terms of current font, update width and height VPARMS passed.
  110. * --------------------------------------------------------------------- *
  111. rpstr    equ    -32
  112. rpport    equ    -12
  113. packet    equ    -8
  114. conid    equ    -4
  115.  
  116. width    equ    8
  117. height    equ    12
  118.  
  119.     XDEF    _GetWinBounds
  120. _GetWinBounds:
  121.     link    a5,#-32
  122.     movem.l    d2-d4/a2,-(sp)
  123.  
  124.     suba.l    a1,a1
  125.     SYS    FindTask,4        ;d0 = FindTask(0L), our process
  126.     movea.l    d0,a0            ;Transfer to address reg
  127.     move.l    pr_ConsoleTask(a0),conid(a5) ;Save proc->pr_ConsoleTask
  128.  
  129.     moveq    #0,d4            ;Clear our success status register
  130.  
  131.     moveq    #0,d0
  132.     movea.l    d0,a0
  133.     bsr.w    CreatePort
  134.     move.l    d0,rpport(a5)        ;rpport = CreatePort(0L, 0L)
  135.      beq.w    gwbdone            ;Oops, no signals or ram available!
  136.     move.l    #MEMF_PUBLIC+MEMF_CLEAR,d1
  137.     moveq    #sp_SIZEOF,d0
  138.     SYS    AllocMem
  139.     move.l    d0,packet(a5)        ;packet = AllocMem(sizeof(*packet),MEMF_PUBLIC|MEMF_CLEAR)
  140.      beq.w    gwbfreeport        ;Oops, no ram, free up port
  141.  
  142. * Okay, we got our process id, reply port, and packet
  143. * Now toggle the console into raw mode
  144.     movea.l    rpport(a5),a2
  145.     movea.l    d0,a1
  146.     movea.l    conid(a5),a0
  147.     moveq    #1,d0
  148.     bsr.w    SetConsoleType        ;SetConsoleType(1L, conid, packet, rpport)
  149.  
  150. * Request a window bounds report
  151.     moveq    #4,d3
  152.     lea    gwbrstr(a4),a0
  153.     move.l    a0,d2
  154.     move.l    _Out(a4),d1
  155.     SYS    Write,_DOSBase(a4)    ;Write(Output(), "\2330 q", 4L);
  156.     cmpi.l    #$0004,d0        ;Did the console choke on it?
  157.      bne.w    gwbsetcook        ;hmmm, see if we can back out gracefully
  158.  
  159. * Read the report string into stack buffer
  160.     moveq    #16,d3            ;Don't let it get longer than 16 characters
  161.     lea    rpstr(a5),a0        ;Point to input string area
  162.     move.l    a0,d2
  163.     move.l    _In(a4),d1
  164.     SYS    Read            ;Read(Input(), rpstr, 16L)
  165.     move.l    d0,d4            ;Save read length while we close shop
  166.  
  167. * Turn the console back to cooked mode pronto to avoid cursor blink
  168. gwbsetcook:
  169.     movea.l    rpport(a5),a2
  170.     movea.l    packet(a5),a1
  171.     movea.l    conid(a5),a0
  172.     moveq    #0,d0
  173.     bsr.w    SetConsoleType        ;SetConsoleType(0L, conid, packet, rpport)
  174.  
  175. * Release resources we borrowed
  176. gwbfreepack:
  177.     move.l    packet(a5),d0        ;Did we allocate a packet?
  178.      beq.b    gwbfreeport        ;nay, check for port to free
  179.     movea.l    d0,a1
  180.     moveq    #sp_SIZEOF,d0
  181.     SYS    FreeMem            ;Else FreeMem(packet, sizeof(*packet))
  182.  
  183. gwbfreeport:
  184.     move.l    rpport(a5),d0        ;if (rpport)...
  185.      beq.w    gwbdone            ;nope
  186.     bsr.w    DeletePort        ;Else DeletePort(rpport)
  187.  
  188. * Finally, sanity check window bounds report string
  189. * d4 = length of report string according to Read()
  190.     cmpi.l    #9,d4            ;Less than 8 characters returned?
  191.      ble.w    gwbdone            ;hmmm, phonky bounds report from DOS?
  192.     lea    rpstr(a5),a2        ;a2 = rpstr
  193.     cmpi.b    #';',4(a2)        ;Matches a typical report template?
  194.      bne.w    gwbdone            ;nope, got some weird junk back?
  195.     cmpi.b    #'r',-1(a2,d4.w)    ;Last byte is 'r' for report?
  196.      bne.w    gwbdone            ;Nope, message fubar!
  197.  
  198. * Parse the height and width variables from the field now
  199. * Our report format looks like this in hex:
  200. *     9b 31 3b 31 3b y2 y1 3b x2 x1 20 72
  201. * Or in ascii:
  202. *    <0x9b>1;1;20;77 r
  203. * Which would indicate a width of 77 cols and a height of 20 rows for
  204. * the current console device
  205. *
  206. * REGS:    a2 points to beginning of 'r' terminated string
  207.  
  208.     lea    5(a2),a2        ;Point to first char of Y size
  209.     moveq    #0,d1            ;Clear out work reg
  210.  
  211. * Convert ascii rows value to LONG, update host data
  212.     move.b    (a2)+,d1        ;Grab a Y
  213.     subi.w    #'0',d1            ;Less ascii offset
  214.     cmpi.b    #';',(a2)        ;Any more Y digits?
  215.      beq.b    1$            ;Nope
  216.     mulu    #10,d1            ;Else shift by 10
  217.     add.b    (a2)+,d1        ;Add least significant Y digit
  218.     subi.b    #'0',d1            ;Less ascii offset
  219.     cmpi.b    #';',(a2)        ;Any more Y digits?
  220.      beq.b    1$            ;Nope
  221.     mulu    #$000a,d1        ;Else shift by 10
  222.     add.b    (a2)+,d1        ;Add least significant Y digit
  223.     subi.b    #'0',d1            ;Less ascii offset
  224.                     ;We'll assume screen height < 999 rows    
  225. 1$
  226. * Convert ascii columns value to LONG, update host data
  227.     addq.w    #1,a2            ;Move past the ';' separator
  228.     moveq    #0,d2            ;Zap work reg
  229.     move.b    (a2)+,d2        ;Grab msd of X
  230.     cmpi.b    #' ',d2            ;Premature end?
  231.      beq.w    gwbdone            ;Huh, must be garbage - don't update VPARMS
  232.     cmpi.b    #';',d2            ;Also a possible error
  233.      beq.w    gwbdone
  234.     cmpi.b    #'r',d2            ;And what about this?
  235.      beq.w    gwbdone
  236.  
  237.     subi.b    #'0',d2            ;Okay, adjust ascii offset
  238.     cmpi.b    #' ',(a2)        ;Hit end of report?
  239.      beq.b    2$            ;Yep
  240.     mulu    #$000a,d2        ;Else shift by 10
  241.     add.b    (a2)+,d2        ;Add next digit
  242.     subi.b    #'0',d2            ;Ascii adjust
  243.     cmpi.b    #' ',(a2)        ;Hit end of report?
  244.      beq.b    2$            ;Yep
  245.     mulu    #$000a,d2        ;Else shift by 10
  246.     add.b    (a2),d2            ;Add next digit
  247.     subi.b    #'0',d2            ;Ascii adjust
  248.  
  249. 2$
  250. * Finally, update parameters by reference
  251.     movea.l    height(a5),a0        ;Grab height VPARM
  252.     move.l    d1,(a0)            ;*height = d1
  253.     movea.l    width(a5),a0        ;Grab width VPARM
  254.     move.l    d2,(a0)            ;*width = d2
  255.  
  256. gwbdone:
  257.     movem.l    (sp)+,d2-d4/a2
  258.     unlk    a5
  259.     rts
  260.  
  261. * --------------------------------------------------------------------- *
  262. * void __asm SetConsoleType(flag, id, packet, port)
  263. *   register __d0 long flag;
  264. *   register __a0 struct Process *id;
  265. *   register __a1 struct StandardPacket *packet;
  266. *   register __a2 struct MsgPort *port;
  267. *
  268. * Flag = 1L -- Raw mode
  269. *      = 0L -- Cooked mode
  270. * --------------------------------------------------------------------- *
  271.     XDEF    SetConsoleType
  272. SetConsoleType:
  273.     movem.l    a3/a5,-(sp)
  274.  
  275.     movea.l    a0,a3            ;Copy process pointer
  276.     movea.l    a1,a5            ;Copy packet pointer
  277.     lea    sp_Pkt(a5),a0        ;a0 = &packet->sp_Pkt
  278.     move.l    a0,sp_Msg+LN_NAME(a5)    ;p->sp_Msg.mn_Node.ln_Name = &p->sp_Pkt
  279.     lea    sp_Msg(a5),a0        ;a0 = &packet->sp_Msg
  280.     move.l    a0,sp_Pkt+dp_Link(a5)    ;p->sp_Pkt.dp_Link = &p->sp_Msg
  281.     move.l    a2,sp_Pkt+dp_Port(a5)    ;p->sp_Pkt.dp_Port = replyport
  282.     move.l    #ACTION_SCREEN_MODE,sp_Pkt+dp_Type(a5)    ;Set function
  283.  
  284.     tst.w    d0            ;On or Off?
  285.      beq.w    1$
  286.     move.l    #-1,sp_Pkt+dp_Arg1(a5)    ;RAW ON
  287.     bra.b    2$
  288. 1$
  289.     clr.l    sp_Pkt+dp_Arg1(a5)    ;RAW OFF
  290. 2$
  291.     movea.l    a3,a0
  292.     movea.l    a5,a1
  293.     SYS    PutMsg,4        ;PutMsg(proc, packet)
  294.  
  295.     movea.l    a2,a0
  296.     SYS    WaitPort        ;WaitPort(port)
  297.     movea.l    a2,a0
  298.     SYS    GetMsg            ;(void)GetMsg(port)
  299.  
  300.     movem.l    (sp)+,a3/a5
  301.     rts
  302.  
  303. * ------------------------------------------------------------------------- *
  304. * struct MsgPort *CreatePort(name, pri) (a0/d0)
  305. * ------------------------------------------------------------------------- *
  306.     XDEF    CreatePort
  307. CreatePort:
  308.     movem.l    d5/d7/a2/a5,-(sp)
  309.  
  310.     move.l    a0,a5            ;Save Name
  311.     move.l    d0,d5            ;Save Pri
  312.  
  313. * Allocate a free signal, crap out if we can't
  314.     moveq    #-1,d0
  315.     SYS    AllocSignal,4
  316.     cmp.l    #-1,d0            ;Did we get a signal?
  317.      bne.b    cpgotsig        ;Yep
  318.     moveq    #0,d0            ;Otherwise return NULL
  319.     bra.w    cpdone
  320.  
  321. cpgotsig:
  322.     move.l    d0,d7            ;Save our signal
  323.  
  324. * Allocate memory for MsgPort
  325.     moveq.l    #MP_SIZE,d0        ;Size of MsgPort
  326.     move.l    #MEMF_PUBLIC!MEMF_CLEAR,d1    ;Type of memory
  327.     SYS    AllocMem        ;Allocate it
  328.     tst.l    d0            ;Did we get it?
  329.      bne.b    cpgotport        ;Yep
  330.  
  331.     move.l    d7,d0            ;Otherwise crap out, free signal
  332.     SYS    FreeSignal
  333.     moveq    #0,d0            ;Return NULL
  334.     bra.w    cpdone
  335.  
  336. cpgotport:
  337.     move.l    d0,a2            ;This is our new port!
  338.     move.l    a5,LN_NAME(a2)        ;port->mp_Node.ln_Name = name
  339.     move.b    d5,LN_PRI(a2)        ;port->mp_Node.ln_Pri = priority
  340.     move.b    #NT_MSGPORT,LN_TYPE(a2) ;port->mp_Node.ln_Type = NT_MSGPORT
  341.     move.b    #PA_SIGNAL,MP_FLAGS(a2) ;port->mp_Flags = PA_SIGNAL
  342.     move.b    d7,MP_SIGBIT(a2)    ;port->mp_SIGBIT = sigBit
  343.     suba.l    a1,a1
  344.     SYS    FindTask
  345.     move.l    d0,MP_SIGTASK(a2)    ;port->mp_SIGTASK = FindTask(0L)
  346.     
  347.     cmpa.l    #0,a5            ;Is this a new name?
  348.     beq.b    cpnoname        ;Nope, add it to the msg list
  349.  
  350.     movea.l    a2,a1
  351.     SYS    AddPort            ;Otherwise add this port
  352.     move.l    a2,d0            ;Return port pointer
  353.     bra.b    cpdone
  354.  
  355. cpnoname:
  356. * Initialized New List head
  357.     lea    MP_MSGLIST(a2),a0     ;a0 = &port->mp_MsgList
  358.     move.l    a0,(a0)            ;list->lh_Head = list
  359.     addq.l    #4,(a0)            ;list->lh_Head += 4L
  360.     clr.l    4(a0)            ;list->lh_Tail = 0L
  361.     move.l    a0,8(a0)        ;list->lh_TailPred = list
  362.     move.l    a2,d0            ;Return port pointer
  363.  
  364. cpdone:
  365.     movem.l    (sp)+,d5/d7/a2/a5
  366.     rts
  367.  
  368. * ------------------------------------------------------------------------- *
  369. * DeletePort(port)(d0)
  370. * ------------------------------------------------------------------------- *
  371.     XDEF    DeletePort
  372. DeletePort:
  373.     move.l    a5,-(sp)
  374.  
  375.     move.l    d0,a5
  376.     tst.l    LN_NAME(a5)        ;Is there a name?
  377.     beq.s    dpnoname
  378.     
  379.     move.l    d0,a1
  380.     SYS    RemPort,4        ;RemPort(port)
  381.     
  382. dpnoname:
  383.     move.b    #$ff,LN_TYPE(a5)     ;port->mp_Node.ln_Type = 0xff
  384.     move.l    #-1,MP_MSGLIST(a5)     ;port->mp_MsgList.lh_Head = -1L
  385.  
  386.     moveq    #0,d0
  387.     move.b    MP_SIGBIT(a5),d0    ;d0 = port->mp_SigBit
  388.     SYS    FreeSignal,4        ;FreeSignal(d0)
  389.  
  390.     moveq    #MP_SIZE,d0
  391.     move.l    a5,a1
  392.     SYS    FreeMem            ;FreeMem(port, sizeof(*port))
  393.  
  394.     move.l    (sp)+,a5
  395.     rts
  396.  
  397. * ------------------------------------------------------------------------
  398. * char *FibFileDate(fib_date)
  399. *   register struct DateStamp *fib_date;
  400. *
  401. *   Calculate date based on DateStamp structure and return a pointer
  402. * to the formatted date string.
  403. * ------------------------------------------------------------------------
  404.     XDEF    _FibFileDate
  405. _FibFileDate:
  406.     link    a5,#0
  407.     movem.l    d3-d7/a4,-(sp)
  408.  
  409.     movea.l    8(a5),a1        ;Grab datestamp pointer
  410.     moveq    #78,d7            ;Initial year = 1978
  411.  
  412.     move.l    (a1),d5            ;days = fib_date->ds_Days
  413.      blt.w    ffdbaddate        ;Hey! you can't be negative! Invalid date...
  414.  
  415. * Determine what year it is
  416.     divu    #1461,d5
  417.     move.l    d5,d0            ;Stash it
  418.     ext.l    d5
  419.     lsl.l    #2,d5
  420.     add.l    d5,d7            ;year += (days / 1461) * 4
  421.  
  422. * Count how many months into that year
  423. ffdgetmo:
  424.     swap    d0            ;days %= 1461
  425.     move.w    d0,d5
  426.  
  427. 1$    tst.w    d5            ;Out of days yet?
  428.      beq.b    3$            ;Yep, done here
  429.  
  430.     move.w    #365,d6            ;Else month_days = 365
  431.     move.w    d7,d0            ;Grab year
  432.     andi.w    #3,d0            ;if (year & 3) == 0 Leap year?
  433.      bne.b    2$            ;Nope
  434.     addq.w    #1,d6            ;Otherwise bump month_days
  435.  
  436. 2$    cmp.w    d6,d5            ;is day < month_days?
  437.      blt.b    3$            ;yep, done here
  438.     sub.w    d6,d5            ;otherwise day -= month_days
  439.  
  440.     addq.l    #1,d7            ; year++
  441.     bra.b    1$
  442. 3$
  443.  
  444. * Count how many days into that month of that year
  445. ffdgetday:
  446. ;for (i = 0, day++; i < 12; i++)
  447.     moveq    #0,d4            ;current month = 0
  448.     moveq    #0,d6            ;Zap hinybs
  449.     addq.w    #1,d5
  450.     lea    _dayspermonth(a4),a0
  451.  
  452. 1$
  453.     move.b    0(a0,d4.w),d6        ;month_days = dayspermonth[i]
  454.  
  455.     cmpi.w    #1,d4            ;if (i == 1 && (year & 3) == 0)
  456.      bne.b    2$
  457.     move.w    d7,d0
  458.     andi.w    #3,d0
  459.      bne.b    2$
  460.     addq.w    #1,d6            ;month_days++
  461.  
  462. 2$    cmp.w    d6,d5            ;if (day <= month_days)
  463.      ble.b    4$            ;Break out, found the right month
  464.  
  465.     sub.w    d6,d5            ;Else, day -= month_days
  466.  
  467.     addq.w    #1,d4            ;i++
  468. 3$    cmpi.w    #12,d4            ;Done all months yet?
  469.      blt.b    1$            ;Nope
  470.  
  471. 4$
  472. ffdprint:
  473. 1$    cmpi.l    #99,d7            ;while (year >= 100)
  474.      ble.b    2$
  475.     subi.l    #100,d7            ;year -= 100
  476.     bra.b    1$
  477. 2$
  478. ;asprintf(datestr, "%02d-%02d-%02d %02d:%02d:%02d", i + 1, day, year, hour, min, sec)
  479.     move.l    8(a1),d0        ;sec = fib_date->ds_Tick / 50;
  480.     divu    #50,d0
  481.     move.w    d0,-(sp)        ;Push secs
  482.  
  483.     moveq    #0,d0            ;Zap reg
  484.     move.w    6(a1),d0        ;min = fib_date->ds_Minute
  485.     move.w    d0,d1            ;Clone it
  486.     divu    #60,d0
  487.     move.w    d0,d3            ;hour = min / 60
  488.     mulu    #60,d0
  489.     sub.w    d0,d1            ;min -= hour * 60
  490.     move.w    d1,-(sp)        ;Push mins
  491.  
  492.     move.w    d3,-(sp)        ;Push hours
  493.     addq.w    #1,d4            ;Push day of month (offset by 1!)
  494.     move.w    d5,-(sp)        ;Push month
  495.     move.w    d4,-(sp)
  496.     move.w    d7,-(sp)        ;Push year
  497.     pea    _datepat(a4)        ;Push the format pattern
  498.     pea    _datestr(a4)        ;Push destination buffer
  499.     jsr    _asprintf    
  500.     lea    20(sp),sp
  501.     lea    _datestr(a4),a0
  502.     move.l    a0,d0            ;return((char *)&datestr[0])
  503.  
  504. ffddone:
  505.     movem.l    (sp)+,d3-d7/a4
  506.     unlk    a5
  507.     rts
  508.  
  509. ffdbaddate:
  510.     lea    _baddatestr(a4),a0    ;return (" <Invalid Date> ");
  511.     move.l    a0,d0
  512.     bra.b    ffddone
  513.  
  514. *----------------------------------------------------------------------
  515. * LONG iswild(name)
  516. *   char *name;
  517. *
  518. * Search a string for wild characters, return 1 if found
  519. *----------------------------------------------------------------------
  520.     XDEF    _iswild
  521. _iswild:
  522.     movea.l    4(sp),a0        ;Grab string pointer
  523.     moveq    #0,d0            ;Clear out our character register
  524. ischk1:
  525.     move.b    (a0)+,d0        ;Grab a char
  526.      beq.b    iwdone            ;Might be end of string?
  527.     cmpi.b    #'*',d0            ;Is it *?
  528.      beq.b    iswdone            ;yep, is wild
  529.     cmpi.b    #'?',d0            ;Is it a qmark
  530.      bne.b    ischk1            ;Nope, check next character
  531.  
  532. iswdone:
  533.     moveq    #1,d0
  534. iwdone:
  535.     rts
  536.  
  537.  
  538. * ------------------------------------------------------------------------
  539. ; Compare a wild card name with a normal name
  540. ; LONG wildmatch (name, wild)
  541. ;   char *name, *wild;
  542. * ------------------------------------------------------------------------
  543.     XDEF    _wildmatch
  544. _wildmatch:
  545.     link    a5,#-64
  546.     movem.l    d3/a2-a3,-(sp)
  547.  
  548.     movea.l    8(a5),a2        ;Grab name
  549.     movea.l    12(a5),a3        ;Grab pattern
  550.     lea    -64(a5),a0        ;back[0][0]
  551.     lea    -60(a5),a1        ;back[0][1]
  552.  
  553.     moveq    #0,d3            ;bi = 0
  554.  
  555. wmloop1:
  556.     tst.b    (a2)            ;End of name?
  557.      bne.b    wmnoteon
  558.     tst.b    (a3)            ;End of pattern?
  559.      beq.w    wmmatched        ;Yep, we matched
  560.  
  561. wmnoteon:
  562.     cmpi.b    #'*',(a3)        ;Is it a splat?
  563.      bne.b    wmnotstar        ;Nope, maybe '?'
  564.  
  565.     cmpi.w    #64,d3            ;Have we hit max expression depth?
  566.      beq.w    wmnomatch        ;Yep, ran out of room in recursion table
  567.  
  568. ;back[bi][0] = w
  569.     move.l    a3,0(a0,d3.w)        ;Stash pointer to this '*' in table
  570.  
  571. ;back[bi][1] = n
  572.     move.l    a2,0(a1,d3.w)
  573.  
  574.     addq.w    #8,d3            ;++bi
  575.     addq.w    #1,a3            ;++w
  576.     bra.b    wmloop1            ;Check next
  577.  
  578. wmgoback:
  579.     subq.w    #8,d3            ;--bi
  580.     move.l    a0,d0
  581. wmback1:
  582.     tst.w    d3            ;while (bi >= 0 && *back[bi][1] == '\x0')
  583.      blt.b    wmbacked
  584.     movea.l    0(a1,d3.l),a0
  585.     tst.b    (a0)
  586.      bne.b    wmbacked
  587.  
  588.     subq.w    #8,d3            ;--bi
  589.     bra.b    wmback1
  590.  
  591. wmbacked:
  592.     tst.w    d3            ;if (bi < 0)
  593.      blt.b    wmnomatch        ;return (0)
  594.  
  595.     movea.l    d0,a0
  596.     movea.l    0(a0,d3.w),a3        ;w = back[bi][0] + 1
  597.     addq.w    #1,a3    
  598.  
  599.     addq.l    #1,0(a1,d3.w)
  600.     movea.l    0(a1,d3.l),a2        ;n = ++back[bi][1]
  601.  
  602.     addq.w    #8,d3            ;++bi
  603.     bra.b    wmloop1
  604.  
  605. wmnotstar:
  606.     cmpi.b    #'?',(a3)        ;Is it '?'
  607.      bne.b    wmnotqmark
  608.  
  609.     tst.b    (a2)            ;Reached end of string?
  610.      bne.b    wmincpoint        ;Nope, move on to next char
  611.  
  612.     tst.w    d3            ;Are we at top level of expression?
  613.      beq.b    wmnomatch        ;Yep, expression didn't match
  614.     bra.b    wmgoback        ;Otherwise pop a level and try to match
  615.  
  616. wmnotqmark:
  617.     move.b    (a2),d0            ;Grab a char from bstr
  618.     cmpi.b    #$40,d0            ;less than @ character?
  619.      bls.b    1$            ;Yep
  620.     cmpi.b    #$5a,d0            ;Greater than Z?
  621.      bhi.b    1$            ;Yep
  622.     addi.b    #$20,d0
  623. 1$
  624.     move.b    (a3),d1            ;Grab a char from bstr
  625.     cmpi.b    #$40,d1            ;less than @ character?
  626.      bls.b    2$            ;Yep
  627.     cmpi.b    #$5a,d1            ;Greater than Z?
  628.      bhi.b    2$            ;Yep
  629.     addi.b    #$20,d1
  630. 2$
  631.     cmp.b    d0,d1            ;*n = *w?
  632.      beq.b    wmincpoint        ;Yep, move on past
  633.  
  634.     tst.w    d3            ;Are we at top expression level?
  635.      beq.b    wmnomatch        ;Yep, they didn't match
  636.     bra.b    wmgoback        ;Nope, process next part
  637.  
  638. wmincpoint:
  639.     tst.b    (a2)            ;Done with name?
  640.      beq.b    wmnamend        ;Yep
  641.     addq.w    #1,a2            ;Otherwise increment name pointer
  642.  
  643. wmnamend:
  644.     tst.b    (a3)            ;End of pattern?
  645.      beq.b    wmmatched        ;Yep, we matched
  646.     addq.w    #1,a3            ;Otherwise inc wild pointer, match next char
  647.     bra.w    wmloop1
  648.  
  649. wmmatched:
  650.     moveq    #1,d0
  651.     bra.b    wmdone
  652.  
  653. wmnomatch:
  654.     moveq    #0,d0
  655.  
  656. wmdone:
  657.     movem.l    (sp)+,d3/a2-a3
  658.     unlk    a5
  659.     rts
  660.  
  661. * --------------------------------------------------------------------- *
  662. * void SortFibs (keytype, direction, fibheadp)
  663. *           d0       d1         a0
  664. *  int keytype;
  665. *  struct FibEntry *fibheadp;
  666. *
  667. * Selection sort a linked list of FibEntrys based on a keycode         *
  668. * --------------------------------------------------------------------- *
  669.     XDEF    _SortFibs
  670. _SortFibs:
  671.     link    a5,#0
  672.     movem.l    d2-d4/a2-a3/a6,-(sp)
  673.  
  674.     movem.l    8(a5),d0-d1/a0
  675.  
  676.     move.l    d0,d2            ;Save keytype
  677.     move.l    d1,d4            ;Save direction of sort
  678.     movea.l    a0,d3            ;Save fibheadp
  679.     movea.l    a0,a2            ;a2 = a0 = i
  680.  
  681. sfILoop:
  682.     cmp.l    (a2),d3            ;i->NextFib != fibheadp?
  683.      beq.b    sfdone            ;Nope, wrapped around to start
  684.     movea.l    a2,a6            ;k = i
  685.     movea.l    (a2),a3            ;j = i->NextFib
  686.  
  687. sfJLoop:
  688.     cmp.l    a3,d3            ;j != fibheadp?
  689.      beq.b    sfJdone            ;Nope compared them all, see if swapped any
  690.     movea.l    8(a6),a0        ;a0 = k->Fibp
  691.     movea.l    8(a3),a1        ;a1 = j->Fibp
  692.     move.l    d2,d0            ;d0 = keytype
  693.     jsr    _CompFibs        ;d0 = CompFibs(keytype, k->Fibp, j->Fibp)
  694.     tst.w    d4            ;Reverse sort?
  695.      beq.b    1$            ;Nope
  696.     bchg.l    #0,d0            ;Else reverse sense of return
  697. 1$
  698.     tst.l    d0            ;Return != 0?
  699.      beq.b    sfNextJ            ;Nope, these two are in order
  700.     movea.l    a3,a6            ;else k = j, this is new swap
  701.  
  702. sfNextJ:
  703.     movea.l    (a3),a3            ;j = j->NextFib
  704.     bra.b    sfJLoop            ;Check bounds
  705.  
  706. sfJdone:
  707.     cmpa.l    a6,a2            ;k != i, did we swap?
  708.      beq.b    sfNextI            ;Nope, i was in correct position already
  709.     move.l    8(a6),d0
  710.     move.l    8(a2),8(a6)
  711.     move.l    d0,8(a2)        ;Else SwapFibs (k, i)
  712.  
  713. sfNextI:
  714.     movea.l    (a2),a2            ;i = i->NextFib
  715.     bra.b    sfILoop            ;Check bounds
  716.  
  717. sfdone:
  718.     movem.l    (sp)+,d2-d4/a2-a3/a6
  719.     unlk    a5
  720.     rts
  721.  
  722. * --------------------------------------------------------------------- *
  723. * int CompFibs (keytype, a, b)
  724. *         d0     a0 a1
  725. *   int keytype;
  726. *   struct FileInfoBlock *a, *b;
  727. *
  728. * Used by SortFibs to determine precedence of Fibs.
  729. * --------------------------------------------------------------------- *
  730.     XDEF    _CompFibs
  731. _CompFibs:
  732.     tst.w    d0            ;Alphabetize?
  733.      bne.b    cfnalpha        ;Nope
  734.  
  735. * Compare lexigraphically, ignoring case differences
  736. cfalpha:
  737.     lea    fib_FileName(a0),a0    ;a = &Fipb->fib_FileName
  738.     lea    fib_FileName(a1),a1    ;b = &Fipb->fib_FileName
  739.  
  740. ;  for(; *a && tolower(*a) == tolower(*b); a++, b++);
  741. lccstart:
  742.     tst.b    (a0)            ;Is there a char here at source?
  743.      beq.b    lcceostr        ;Nope, fell off the end
  744.  
  745.     move.b    (a1)+,d1        ;Grab a char from bstr
  746.     cmpi.b    #$40,d1            ;less than @ character?
  747.      bls.b    1$            ;Yep
  748.     cmpi.b    #$5a,d1            ;Greater than Z?
  749.      bhi.b    1$            ;Yep
  750.     addi.b    #$20,d1
  751. 1$
  752.     move.b    (a0)+,d0        ;Grab a char from astr
  753.     cmpi.b    #$40,d0            ;less than @ character?
  754.      bls.b    2$            ;Yep
  755.     cmpi.b    #$5a,d0            ;Greater than Z?
  756.      bhi.b    2$            ;Yep
  757.     addi.b    #$20,d0
  758. 2$
  759.     cmp.b    d0,d1            ;are they the same?
  760.      beq.b    lccstart        ;Yep, compare next pair of chars
  761.  
  762. lcceostr:
  763.     sub.b    d1,d0            ;return(tolower(*astr) - tolower(*bstr))
  764.      bgt.b    cftrue            ; > 0?, return TRUE
  765.     bra.b    cffalse            ;Else return FALSE
  766.  
  767. cfnalpha:
  768.     subq.w    #1,d0            ;Size?
  769.      bne.b    cfnsize            ;Nope
  770.  
  771. * Compare fib_Sizes
  772.     move.l    fib_Size(a1),d0        ;d0 = bfib->fib_Size
  773.     cmp.l    fib_Size(a0),d0        ;a->fib_Size > b->fib_Size?
  774.      blt.b    cftrue            ;Yep, return TRUE
  775.      bgt.b    cffalse            ;<, return FALSE
  776.     bra.b    cfalpha            ;Else it's a tie, alphabetize
  777.  
  778. cfnsize:
  779.     subq.w    #1,d0            ;Time?
  780.      bne.b    cffalse            ;Nope, an error!
  781.  
  782. * Compare fib_DateStamps
  783.     lea    fib_DateStamp(a0),a0    ;a = &afib->fib_DateStamp
  784.     lea    fib_DateStamp(a1),a1    ;b = &bfib->fib_DateStamp
  785.     move.l    ds_Days(a1),d0        ;d0 = bdate->ds_Days
  786.     cmp.l    ds_Days(a0),d0        ;a->ds_Days > b->ds_Days?
  787.      blt.b    cftrue            ;Yep, a is older
  788.      bgt.b    cffalse            ;Else if a < b, b is older
  789.                     ;Else they are the same day, check min/tick
  790.     move.l    ds_Minute(a0),d0
  791.     sub.l    ds_Minute(a1),d0    ;d0 = amin - bmin
  792.     muls    #3000,d0        ;     * 3000
  793.     add.l    ds_Tick(a0),d0
  794.     sub.l    ds_Tick(a1),d0        ;     + atick - btick
  795.      bgt.b    cftrue            ;Hey, a > b
  796.      blt.b    cffalse            ;a < b, return false
  797.     bra.b    cfalpha            ;Else its the same date, alphabetize
  798.  
  799. cftrue:
  800.     moveq    #1,d0
  801.     rts
  802. cffalse:
  803.     moveq    #0,d0
  804.     rts
  805.  
  806. * --------------------------------------------------------------------- *
  807.     SECTION    __MERGED,DATA
  808. * --------------------------------------------------------------------- *
  809.     XDEF    _dayspermonth
  810. _dayspermonth:
  811.     dc.b    31,28,31,30,31,30,31,31,30,31,30,31
  812.     XDEF    _datepat
  813. _datepat:
  814.     dc.b    '%02d-%02d-%02d %02d:%02d:%02d',0
  815.     CNOP    0,2
  816.     XDEF    _baddatestr
  817. _baddatestr:
  818.     dc.b    '00-00-00 00:00:00',0
  819.     CNOP    0,2
  820.  
  821.     XDEF    gwbrstr
  822. gwbrstr:
  823.     dc.b    $9b,'0 q'
  824.  
  825. * --------------------------------------------------------------------- *
  826.     SECTION    __MERGED,BSS
  827. * --------------------------------------------------------------------- *
  828.     XDEF    _datestr
  829. _datestr:
  830.     ds.b    40
  831.  
  832. * --------------------------------------------------------------------- *
  833.     END
  834. * --------------------------------------------------------------------- *
  835.