home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 109.lha / PD_C / lib / xprintf.asm < prev   
Assembly Source File  |  1986-11-20  |  2KB  |  63 lines
  1. ;XPRINTF.ASM 
  2. ; 
  3. ;  Handles formatted printing to xstdio file pointers w/ xprintf 
  4. ;  Handles formatted printing to Amiga file handles   w/ fprintf 
  5.  
  6.       xdef  _xprintf 
  7.       xdef  _fprintf 
  8.       xref  _xwrite 
  9.       xref  _Write 
  10.       xref  _LVORawDoFmt 
  11.       xref  _SysBase 
  12.  
  13. _xprintf 
  14.       jsr      xformat           ;RawDoFmt to buffer and write setup 
  15.       jsr      _xwrite 
  16.       bra      done 
  17. _fprintf 
  18.       jsr      xformat           ;same thing 
  19.       jsr      _Write 
  20. done 
  21.       lea.l    268(A7),A7 
  22.       rts 
  23.  
  24.       ;XFORMAT takes a Xprintf(xx, cs, arg, arg...)  where xx is any 
  25.       ;integer and returns (xx, buf, bytes) on the stack suitable for an 
  26.       ;immediate call to xwrite() or Write().  The caller must deallocate 
  27.       ;268 bytes from the stack when done. 
  28.       ; 
  29.       ;                                     (oret) 
  30.       ;  A2 A3 A4 A5 A6 RET FI BUF NUM <thebuffer> printfret fi cs args 
  31.       ;  ^               ^                     ^ 
  32.       ;  1               2                     3 
  33.  
  34.  
  35. xformat 
  36.       move.l   A7,A0             ;sp now at pos. #3      A0 = pos #3 
  37.       sub.l    #268,A7           ;sp now at pos. #2      SP = pos #2 
  38.       move.l   (A0),(A7)         ;copy return address 
  39.       move.l   8(A0),4(A7)       ;copy fi or fh  to FI 
  40.       lea.l    16(A7),A1         ;address of buffer 
  41.       move.l   A1,8(A7)          ;place in          BUF 
  42.       movem.l  A2-A6,-(A7)       ;save regs              SP = pos #1 
  43.       move.l   A1,A3             ;A3 = buffer pointer 
  44.       lea.l    16(A0),A1         ;A1 = lea of printf arg list 
  45.       move.l   12(A0),A0         ;A0 = control string 
  46.       move.l   #_xc,A2           ;A2 = call vector 
  47.  
  48.       move.l   _SysBase,A6       ;exec library call 
  49.       jsr      _LVORawDoFmt(A6) 
  50.  
  51.       move.l   28(A7),A3         ;buffer start 
  52. loop  tst.b    (A3)+             ;find end of string 
  53.       bne      loop 
  54.       sub.l    28(A7),A3         ;get string length 
  55.       subq.l   #1,A3 
  56.       move.l   A3,32(A7)         ;place in          NUM 
  57.       movem.l  (A7)+,A2-A6       ;restore registers used 
  58.       rts 
  59.  
  60. _xc 
  61.       move.b   D0,(A3)+ 
  62.       rts 
  63.