home *** CD-ROM | disk | FTP | other *** search
/ Carousel Volume 2 #1 / carousel.iso / comdore / 64apps / dirprint (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1987-08-08  |  2.3 KB  |  96 lines
  1. 10 CLR:DIMT$(68)
  2. 20 HC$=CHR$(147):RT$=CHR$(13):RV$=CHR$(18):RF$=CHR$(146)
  3. 90 PRINT HC$
  4. 95 PRINT SPC(9);CHR$(129)"DISK DIRECTORY PRINT"
  5. 96 GOSUB5500
  6. 100 PRINT"INSERT DISKETTE IN DRIVE"
  7. 110 PRINT"PRESS RETURN TO CONTINUE"
  8. 120 GETC$:IFC$=""THEN 120
  9. 130 IFC$<>CHR$(13)GOTO 120
  10. 150 OPEN15,8,15,"I0"
  11. 160 INPUT#15,EN$,EM$,ET$,ES$
  12. 170 IFEN$="00"GOTO210
  13. 180 PRINT:PRINT;RV$;""EN$", "EM$","ET$","ES$;RF$
  14. 190 CLOSE15
  15. 200 END
  16. 210 PRINTHC$
  17. 215 OPEN1,8,2,"$"
  18. 216 FORX=1TO141:GET#1,A$:NEXT
  19. 217 T$(0)="DEL ":T$(1)="SEQ ":T$(2)="PRG ":T$(3)="USR ":T$(4)="REL "
  20. 218 T$(64)="DEL<":T$(65)="SEQ<":T$(66)="PRG<":T$(67)="USR<":T$(68)="REL<"
  21. 220 PRINT:PRINT:PRINT:PRINT
  22. 230 PQ$="Y":INPUT"  FILE NAMES ONLY? Y/N";PQ$
  23. 240 PRINTHC$
  24. 250 PRINT:PRINT:PRINT:PRINT
  25. 260 PRINTSPC(2);"1-COMPRESSED PRINT":PRINT
  26. 270 PRINTSPC(2);"2-SUPERCOMPRESSED PRINT":PRINT
  27. 280 PRINTSPC(2);"3-NORMAL PRINT":PRINT
  28. 290 PRINT:PRINT"  ENTER DESIRED FUNCTION"
  29. 300 GETC$:IFC$=""THEN300
  30. 310 V=VAL(C$):IFV<1ORV>3THEN5990
  31. 320 OPEN4,4,5:LF$="":ONV GOSUB5600,5800,5950
  32. 330 PRINT:PRINTCHR$(129)"  OK"CHR$(5)
  33. 400 J=17:GOSUB5000
  34. 500 N$=B$
  35. 600 J=2
  36. 700 GOSUB5000
  37. 800 I$=B$
  38. 850 GET#1,A$
  39. 851 B$=""
  40. 852 PRINT#15,"M-R"CHR$(250)CHR$(2)CHR$(3)
  41. 853 GET#15,B$
  42. 854 L=ASC(B$+CHR$(0))
  43. 855 GET#15,B$
  44. 856 GET#15,B$
  45. 857 H=ASC(B$+CHR$(0))
  46. 858 BF=L+(H*256)
  47. 900 J=2
  48. 1000 GOSUB5000
  49. 1100 O$=B$
  50. 1200 FORL=1TO88
  51. 1300 GET#1,A$
  52. 1400 NEXT
  53. 1550 PRINTHC$
  54. 1600 PRINTCHR$(129)"DISK NAME:  "CHR$(5)N$:PRINTCHR$(129)"ID:         "CHR$(5)I$
  55. 1601 PRINTCHR$(129)"BLKS FREE: "CHR$(5)BF
  56. 1603 PRINT#4,"NAME: "N$LF$:PRINT#4,"ID:   "I$LF$:PRINT#4,"BLKS FREE: "BF;LF$
  57. 1605 GOSUB5500
  58. 1610 PRINT: PRINT"LENGTH","TYPE","NAME"
  59. 1612 PRINT#4,LF$
  60. 1620 PRINT"----------------------------------------"
  61. 1630 PRINT#4,"----------------------------"LF$
  62. 1650 FORP=1TO8
  63. 1700 GET#1,T$,A$,A$
  64. 1800 IFT$=""THENT$=CHR$(128)
  65. 1900 J=15
  66. 2000 GOSUB5000
  67. 2100 N$=B$
  68. 2200 GET#1,A$,A$,A$,A$,A$,A$,A$,A$,A$,L$,H$
  69. 2250 L=ASC(L$+CHR$(0))+256*ASC(H$+CHR$(0)):IFL=0THEN2600
  70. 2251 H$=RIGHT$("  "+RIGHT$(STR$(L),LEN(STR$(L))-1),3)
  71. 2265 IFSTTHENCLOSE1
  72. 2270 IFSTTHENPRINT#4,"----------------------------"LF$:PRINT#4,LF$:PRINT#4,LF$:GOTO6020
  73. 2300 PRINTH$,T$(ASC(T$)-128),N$
  74. 2375 IFPQ$="Y"THEN2450
  75. 2400 PRINT#4," "H$"   "T$(ASC(T$)-128)"   ";
  76. 2450 PRINT#4,N$;LF$
  77. 2500 IFP<8THENGET#1,A$,A$
  78. 2600 NEXTP:GOTO1650
  79. 5000 B$=""
  80. 5100 FORL=0TOJ
  81. 5200 GET#1,A$
  82. 5300 IFA$<>CHR$(96)THENIFA$<>CHR$(160)THENB$=B$+A$
  83. 5400 NEXT
  84. 5500 POKE53280,0:POKE53281,0:POKE646,1:RETURN
  85. 5600 LF$=CHR$(27)+CHR$(74)+CHR$(30)
  86. 5700 PRINT#4,CHR$(27);CHR$(15):RETURN
  87. 5800 LF$=CHR$(27)+CHR$(74)+CHR$(20)
  88. 5900 PRINT#4,CHR$(27);CHR$(15);CHR$(27);CHR$(83);CHR$(0):RETURN
  89. 5950 LF$=CHR$(10):RETURN
  90. 5990 PRINTHC$""
  91. 6000 PRINT:PRINTCHR$(129)"       PICK ONLY ONE PRINT STYLE"CHR$(5)
  92. 6005 PRINT:PRINT"             PRESS RETURN"
  93. 6010 CLOSE1:CLOSE4:CLOSE15:GOTO120
  94. 6020 PRINT#4,CHR$(27);CHR$(84);CHR$(18)
  95. 6030 CLOSE1:CLOSE4:CLOSE15:END
  96.