home *** CD-ROM | disk | FTP | other *** search
/ Carousel Volume 2 #1 / carousel.iso / comdore / 64apps / budgplan.prg (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1987-07-18  |  7.0 KB  |  223 lines
  1. 1 PRINT"ô"
  2. 100 DEV=8:GOTO1850
  3. 110 PRINTHM$;LEFT$(X$,X);LEFT$(Y$,Y);:RETURN
  4. 120 A=ABS(X)+.005-.5*(DP=0):A1=INT(A):A$=MID$(STR$(A1),2):IFX<0THENA$="-"+A$
  5. 130 IFDPTHEN A2$=MID$(STR$(INT((A-A1)*100)),2):IFLEN(A2$)<2THENA2$="0"+A2$
  6. 140 IFDPTHENA$=A$+"."+A2$
  7. 150 A$=RIGHT$(SP$+A$,F):RETURN
  8. 160 A$=LEFT$(SP$,(X-LEN(A$))/2)+A$:RETURN
  9. 170 FORI=1TONW:A=0:FORJ=0TONR-1:A=A+TB(J,I):NEXT:TB(NR,I)=A:TB(0,I+1)=A:NEXT
  10. 180 FORI=1TONW:MM=0:IFTB(NR,I)<0THENMM=-1:I=NW
  11. 190 NEXT:RETURN
  12. 200 A$=RIGHT$(SP$+"WEEK"+STR$(CW),F-2):X=2:Y=3:GOSUB110:PRINT A$;:RETURN
  13. 210 A$="BUDGET PLANNER"+STR$(YR):X=40:GOSUB160
  14. 220 PRINTCL$;FG$;A$:PRINTD$:PRINTEA$:EA$=""
  15. 230 GOSUB280:FORI=0TONR:IFMMANDI=NRTHENPRINTDEBT$;
  16. 240 PRINTHM$;LEFT$(Y$,I+5);:A$=TB$(I):GOSUB150:PRINTA$;FG$;
  17. 250 FORJ=WTOW+2:IFI=NRANDTB(I,J)<0THENPRINTDEBT$;
  18. 260 X=TB(I,J):GOSUB120:PRINTA$;FG$;
  19. 270 NEXT:NEXT:RETURN
  20. 280 GOSUB200:A=D:B=M:C=YR
  21. 290 FORZ=1TO3
  22. 300 A$=STR$(D)+MNTH$(M):GOSUB150:PRINTA$;
  23. 310 GOSUB580:NEXT
  24. 320 D=A:M=B:YR=C
  25. 330 PRINT"├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├"
  26. 340 RETURN
  27. 350 GOSUB200:X=TB(CR,CW):GOSUB120:B$=RV$+A$+NV$:X=CC*10:Y=CR+5:GOSUB110
  28. 360 PRINTB$;
  29. 370 GETC$:IFC$=""THEN370
  30. 380 IFC$="+"ORC$="-"ORC$="."OR(C$>="0"ANDC$<="9")THEN740
  31. 390 IFC$=UP$THEN610
  32. 400 IFC$=DN$THEN640
  33. 410 IFC$=LF$THEN660
  34. 420 IFC$=RT$THEN700
  35. 430 IFC$=CR$THENRETURN
  36. 440 IFC$=BK$THENIFLEN(D$)<>0THENC$="":D$=LEFT$(D$,LEN(D$)-1):GOTO740
  37. 450 GOSUB110:PRINTA$;
  38. 460 IFASC(C$)>132ANDASC(C$)<141THEN760
  39. 470 IFC$="═"THEN1650
  40. 480 IFC$="─"THENDP=NOTDP:GOSUB210:GOTO350
  41. 490 IFC$="┼"THEN1730
  42. 500 IFC$="╞"THEN1790
  43. 510 IFC$="╫"THEN1630
  44. 520 IFC$="╘"THENDEV=1:EA$="TAPE SELECTEDÆ":GOSUB210:GOTO350
  45. 530 IFC$="╤"THENDEV=8:EA$="DISK SELECTEDÆ":GOSUB210:GOTO350
  46. 540 GOSUB110:PRINTB$:GOTO370
  47. 550 D=D-7:IFD>=1THENRETURN
  48. 560 M=M-1:IFM>=1THEND=D+MNTH(M):RETURN
  49. 570 YR=YR-1:M=12:D=D+MNTH(M):RETURN
  50. 580 D=D+7:IFD<=MNTH(M)THENRETURN
  51. 590 D=D-MNTH(M):M=M+1:IFM<13THENRETURN
  52. 600 YR=YR+1:M=1:RETURN
  53. 610 IFCR=0THEN370
  54. 620 CR=CR-1
  55. 630 GOSUB110:PRINTA$;:GOTO350
  56. 640 IFCR<>NR-1THENCR=CR+1:GOTO630
  57. 650 GOTO370
  58. 660 IFCC<>1THENCC=CC-1:CW=CW-1:GOTO630
  59. 670 IFCW=1THEN370
  60. 680 CW=CW-1:W=W-1:GOSUB550
  61. 690 GOSUB210:GOTO350
  62. 700 IFCC<>3THENCC=CC+1:CW=CW+1:GOTO630
  63. 710 IFCW=NWTHEN370
  64. 720 CW=CW+1:W=W+1:GOSUB580
  65. 730 GOSUB210:GOTO350
  66. 740 IFLEN(D$)<10THEND$=D$+C$:PRINTHM$;DN$;D$;LEFT$(SP$,10-LEN(D$)):GOTO370
  67. 750 GOTO370
  68. 760 PRINT HM$;DN$;SP$:PRINTSP$
  69. 770 ONASC(C$)-132GOSUB780,870,980,1090,1100,1250,1330,1400:GOTO350
  70. 780 X=0:Y=0:GOSUB110:PRINTWH$;"<F1>HELP   <F2>GOTO  <E>ND OF MONTH "
  71. 790 Y=Y+1:GOSUB110:PRINTWH$;"<F3>LOADáá <F4>SAVE  <F>IND NEG     "
  72. 800 Y=Y+1:GOSUB110:PRINTWH$;"<F5>+ROWáá <F6>-ROW  <M>ONTHLY EXP  "
  73. 810 Y=Y+1:GOSUB110:PRINTWH$;"<F7>CALCáá <F8>PRNT  <W>EEKLY EXP   "
  74. 820 Y=Y+1:GOSUB110:PRINTWH$;"<Q>DISK    <T>APE    <D>ECIMAL      "
  75. 830 Y=Y+1:GOSUB110:PRINT"<PRESS ANY KEY>   "
  76. 840 GETA$:IFA$=""THEN840
  77. 850 PRINTFG$;
  78. 860 GOSUB210:RETURN
  79. 870 X=0:Y=0:GOSUB110:PRINTWH$;"*LOAD*Æ"
  80. 880 Y=Y+1:GOSUB110:F$="":INPUT"FILENAME";F$:IFF$=""THEN1210
  81. 890 IFDE=8THEN910
  82. 900 OPEN2,1,0,F$:GOTO920
  83. 910 OPEN15,8,15:OPEN2,8,2,F$+",S,R":GOSUB2300:IFEATHENGOSUB210:GOTO970
  84. 920 PRINTCL$;DN$;"LOADING ";F$
  85. 930 INPUT#2,NR,NW,D,M,YR:M0=M:D0=D:Y0=YR:CC=1:CR=1:CW=1:W=1:GOSUB2140
  86. 940 IFDE=8THENGOSUB2300:IFEATHEN970
  87. 950 FORI=0TONR:INPUT#2,TB$(I):FORJ=0TONW:INPUT#2,TB(I,J):NEXTJ,I
  88. 960 GOSUB170:GOSUB210
  89. 970 CLOSE2:CLOSE15:RETURN
  90. 980 X=0:Y=0:GOSUB110:PRINTWH$;"*+ROW*Æ"
  91. 990 IFNR=18THENY=Y+1:GOSUB110:PRINT"-NO MORE ROOM-":GOTO830
  92. 1000 N$="":Y=Y+1:GOSUB110:INPUT"NAME";N$
  93. 1010 IFN$=""THEN1080
  94. 1020 Y=Y+1:GOSUB110:I$="E":INPUT"(I/E)";I$
  95. 1030 A=-1:IFI$="I"THENA=1
  96. 1040 CR=CR+1
  97. 1050 FORI=NRTOCRSTEP-1:TB$(I+1)=TB$(I):FORJ=0TONW:TB(I+1,J)=TB(I,J):NEXTJ,I
  98. 1060 FORI=1TONW:TB(CR,I)=0:NEXT:TB$(CR)=LEFT$(N$,10)
  99. 1070 NR=NR+1:TB(CR,0)=A
  100. 1080 GOSUB210:RETURN
  101. 1090 GOSUB110:PRINTA$;:GOSUB170:GOSUB210:RETURN
  102. 1100 X=0:Y=0:GOSUB110:PRINTWH$;"*GOTO*Æ"
  103. 1110 Y=Y+1:GOSUB110:W$="":INPUT"WEEK";W$
  104. 1120 A=INT(VAL(W$))
  105. 1130 IFLEFT$(W$,1)="-"ORLEFT$(W$,1)="+"THENA=CW+A
  106. 1140 IFA=WTHEN1200
  107. 1150 IFA>50THENA=50
  108. 1160 IFA<=0THEN1210
  109. 1170 IFA>WTHEN1220
  110. 1180 W=W-1:GOSUB550
  111. 1190 IFA<WTHEN1180
  112. 1200 CW=W:CC=1
  113. 1210 GOSUB210:RETURN
  114. 1220 W=W+1:GOSUB580
  115. 1230 IFA>WTHEN1220
  116. 1240 GOTO1200
  117. 1250 X=0:Y=0:GOSUB110:PRINTWH$;"*SAVE*Æ"
  118. 1260 Y=Y+1:GOSUB110:F$="":INPUT"FILENAME";F$:IFF$=""THEN1210
  119. 1270 IFDE=8THEN1290
  120. 1280 OPEN2,1,2,F$:GOTO1300
  121. 1290 OPEN15,8,15:OPEN2,8,2,"@0:"+F$+",S,W":GOSUB2300:IFEATHEN1320
  122. 1300 PRINT#2,NR;",";NW;",";D0;",";M0;",";Y0
  123. 1310 FORI=0TONR:PRINT#2,TB$(I):FORJ=0TONW:PRINT#2,TB(I,J):NEXTJ,I
  124. 1320 CLOSE15:CLOSE2:GOSUB170:GOSUB210:RETURN
  125. 1330 X=0:Y=0:GOSUB110:PRINTWH$;"*-ROW*Æ"
  126. 1340 IFCR=0THENY=Y+1:GOSUB110:PRINT"ILLEGAL ROW":GOTO830
  127. 1350 Y=Y+1:GOSUB110:N$="":INPUT"SURE";N$
  128. 1360 IFLEFT$(N$,1)<>"Y"THEN1210
  129. 1370 NR=NR-1
  130. 1380 FORI=CRTONR:TB$(I)=TB$(I+1):FORJ=0TONW:TB(I,J)=TB(I+1,J):NEXTJ,I
  131. 1390 CR=CR-1:GOTO1210
  132. 1400 Q$="":PRINTHM$;WH$;"<PRNT>":INPUT"FROM";Q$:IFQ$=""THEN1210
  133. 1410 Q1$="":INPUT"TO  ";Q1$:IFQ1$=""THENQ1$=Q$
  134. 1420 Q$="-"+Q$:M1=0:FORI=1TO12:IFMNTH$(I)=Q$THENM1=I:I=12
  135. 1430 NEXT:M2=0:Q1$="-"+Q1$:FORI=1TO12:IFMN$(I)=Q1$THENM2=I:I=12
  136. 1440 NEXT:IFM1=0ORM2=0THENEA$="ILLEGAL MONTH":GOTO1210
  137. 1450 OPEN4,4:CMD4:X=79:A$="BUDGET PLANNER"+STR$(Y0)
  138. 1460 PRINT"                    "A$:PRINT:M=M0:Y=Y0:D=D0:Q=1
  139. 1470 M2=M2+1:IFM2=13THENM2=1
  140. 1480 IFM<>M1THENGOSUB580:Q=Q+1:GOTO1480
  141. 1490 PRINTTAB(10);:N=1
  142. 1500 A$=STR$(D)+MNTH$(M):GOSUB150:PRINTA$;
  143. 1510 A=M:GOSUB580:IFA=MTHENN=N+1:GOTO1500
  144. 1520 PRINT:FORI=0TON:PRINT"├├├├├├├├├├";:NEXT:PRINT
  145. 1530 FORI=0TONR:A$=TB$(I):GOSUB150
  146. 1540 IFI=NRANDMMTHENPRINTRV$;A$;NV$;:GOTO1560
  147. 1550 PRINTA$;
  148. 1560 QQ=Q+N-1:IFQQ>52THENQQ=52
  149. 1570 FORJ=QTOQQ:X=TB(I,J):GOSUB120
  150. 1580 IFI=NRANDX<0THENPRINTRV$;A$;NV$;:GOTO1600
  151. 1590 PRINTA$;
  152. 1600 NEXTJ:PRINT:NEXTI
  153. 1610 PRINT:PRINT:Q=Q+N:IFQ<53ANDM<>M2THEN1490
  154. 1620 M=M0:D=D0:YR=Y0:W=1:CW=1:CC=1:CR=0:PRINT#4:CLOSE4:GOTO1210
  155. 1630 IFD$=""THENRETURN
  156. 1640 A=TB(CR,0)*VAL(D$):FORI=CWTONW:TB(CR,I)=A:NEXTI:D$="":GOSUB210:GOTO350
  157. 1650 IFD$=""THENRETURN
  158. 1660 A=D:B=M:C=YR:Q=W:X=M
  159. 1670 IFW<>CWTHENGOSUB580:W=W+1:GOTO1670
  160. 1680 X=M
  161. 1690 GOSUB580:W=W+1:IFX=MTHEN1690
  162. 1700 X=M:W=W-1:GOSUB550:IFW>52THEND=A:M=B:YR=C:W=Q:D$="":GOTO1720
  163. 1710 TB(CR,W)=TB(CR,0)*VAL(D$):GOTO1690
  164. 1720 GOSUB210:GOTO350
  165. 1730 IFW<>CWTHENW=W+1:GOSUB580:GOTO1730
  166. 1740 A=D:B=M:C=YR:W=W+1:GOSUB580:X=M:FL=0
  167. 1750 GOSUB580:W=W+1:IFX=MTHEN1750
  168. 1760 GOSUB550:W=W-1:IFW>50THENFL=-1:GOTO1760
  169. 1770 CC=1:CW=W:IFFLTHENCC=3:CW=52
  170. 1780 GOSUB210:GOTO350
  171. 1790 IFW<>CWTHENW=W+1:GOSUB580:GOTO1790
  172. 1800 A=D:B=M:C=YR:Q=W
  173. 1810 GOSUB580:W=W+1:IFTB(NR,W)>=0ANDW<>50THEN1810
  174. 1820 IFTB(NR,W)>=0THEND=A:M=B:YR=C:W=Q:GOTO350
  175. 1830 CC=1:CW=W
  176. 1840 GOSUB210:GOTO350
  177. 1850 DIMTB(18,53),TB$(18),MN$(12),MN(12)
  178. 1860 DEBT$=CHR$(28):FG$=CHR$(159):HM$=CHR$(19):CL$=CHR$(147):UP$=CHR$(145)
  179. 1870 DN$=CHR$(17):LF$=CHR$(157):RT$=CHR$(29):CR$=CHR$(13):BK$=CHR$(20)
  180. 1880 RV$=CHR$(18):NV$=CHR$(146):WH$=CHR$(5)+RV$
  181. 1890 POKE53280,3:POKE53281,0:PRINTFG$
  182. 1900 REM FOR PLUS 4, PRIOR LINE IS COLOR 0,4,0:COLOR 4,4,7
  183. 1910 PRINTFG$:FORI=1TO12:READMNT$(I),MNT(I):NEXT
  184. 1920 DATA -JAN,31,-FEB,28,-MAR,31,-APR,30
  185. 1930 DATA -MAY,31,-JUN,30,-JUL,31,-AUG,31
  186. 1940 DATA -SEP,30,-OCT,31,-NOV,30,-DEC,31
  187. 1950 W=1:F=10:DP=-1:NW=52
  188. 1960 SP$="                                       "
  189. 1970 X$="":FORI=1TO40:X$=X$+RT$:NEXT
  190. 1980 Y$="":FORI=1TO24:Y$=Y$+DN$:NEXT
  191. 1990 A=FRE(X)
  192. 2000 NR=1:CW=1:CR=0:CC=1
  193. 2010 TB$(0)="PREVBAL":TB(0,0)=1
  194. 2020 TB$(1)="TOTAL"
  195. 2030 GOSUB2070
  196. 2040 GOSUB350
  197. 2050 IFD$=""THEN2040
  198. 2060 TB(CR,CW)=TB(CR,0)*VAL(D$):D$="":X=0:Y=1:GOSUB110:PRINTSP$:GOTO2040
  199. 2070 A$="BUDGET PLANNER":X=39:GOSUB160:PRINT"ô";FG$;A$
  200. 2080 PRINT:PRINTEA$:F$="":EA$=""
  201. 2090 INPUT"ENTER FILENAME";F$
  202. 2100 IFF$=""THEN2170
  203. 2110 GOSUB890
  204. 2120 IFEATHEN2070
  205. 2130 RETURN
  206. 2140 X=Y0:MNTH(2)=28:IFM0>2THENX=X+1
  207. 2150 IFINT(X/4)=X/4THENMN(2)=29
  208. 2160 RETURN
  209. 2170 A$="BUDGET PLANNER":X=39:GOSUB160:PRINT "ô";FG$;A$
  210. 2180 PRINTD$:INPUT"DAY   ";DD$:D=VAL(DD$)
  211. 2190 INPUT"MONTH ";MM$:MM$="-"+MM$
  212. 2200 INPUT"YEAR  ";YR$:YR=VAL(YR$):Y0=YR
  213. 2210 M=0:FORI=1TO12:IFMN$(I)=MM$THENM=I
  214. 2220 NEXT:IFM=0THEN2280
  215. 2230 IFYR<1910ORYR>1999THEN2290
  216. 2240 GOSUB2140
  217. 2250 IFD<1ORD>MNTH(M)THEN2270
  218. 2260 D$="":GOSUB210:M0=M:D0=D:Y0=YR:RETURN
  219. 2270 D$="ILLEGAL DAY VALUE TRY AGAINÆ":GOTO2170
  220. 2280 D$="ILLEGAL MONTH - USE 3-CHAR ABREVIATIONÆ":GOTO2170
  221. 2290 D$="ILLEGAL YEAR - (1910-1999 ONLY)Æ":GOTO2170
  222. 2300 INPUT#15,EA,EA$,A,A:EA=(EA<>0):RETURN
  223.