home *** CD-ROM | disk | FTP | other *** search
/ Computer Club Elmshorn Atari PD / CCE_PD.iso / pc / 0600 / CCE_0690.ZIP / CCE_0690.PD / YANNIS / RGRUPPER.MF < prev    next >
Text File  |  1993-11-01  |  29KB  |  615 lines
  1. % This file is a rearrangement of code in Computer Modern's romanu.mf
  2. % It contains definitions for Greek capitals.
  3.  
  4. cmchar "Uppercase alpha";
  5. beginchar("A",13u#,cap_height#,0);
  6. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  7. numeric left_stem,right_stem,outer_jut,alpha;
  8. right_stem=cap_stem-stem_corr;
  9. left_stem=min(cap_hair if hefty: -3stem_corr fi,right_stem);
  10. outer_jut=.8cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
  11. x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
  12. alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
  13. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  14. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  15. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  16. if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
  17.  fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  18.   --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  19.   ...{up}z0+.5left--cycle; %  left and right diagonals
  20. else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  21.   --diag_end(2l,1l,1,1,1r,0)--cycle; fi %  left and right diagonals
  22. penpos5(whatever,angle(z2-z1)); z5=whatever[z1,z2];
  23. penpos6(whatever,angle(z3-z4)); z6=whatever[z3,z4]; y6=y5;
  24. if hefty: y5r else: y5 fi =5/12y0;
  25. y5r-y5l=y6r-y6l=cap_band; penstroke z5e--z6e; %  bar line
  26. if serifs: numeric inner_jut; pickup tiny.nib;
  27.  prime_points_inside(1,2); prime_points_inside(4,3);
  28.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  29.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  30.  dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark);  %  left serif
  31.  dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi  %  right serif
  32. penlabels(0,1,2,3,4,5,6); endchar;
  33.  
  34. cmchar "Uppercase beta";
  35. beginchar("B",12.5u#,cap_height#,0);
  36. italcorr .75cap_height#*slant-.5u#;
  37. adjust_fit(cap_serif_fit#,0);
  38. numeric left_stem,right_curve,middle_weight;
  39. left_stem=cap_stem-hround 2stem_corr; middle_weight=.6vair+.5;
  40. pickup tiny.nib; pos1(left_stem,0); pos2(left_stem,0);
  41. lft x1l=lft x2l=hround max(2u,3u-.5left_stem); top y1=h; bot y2=0;
  42. filldraw stroke z1e--z2e; %  stem
  43. penpos3(cap_band,90); penpos4(cap_band,90);
  44. penpos6(middle_weight,-90); penpos7(middle_weight,-90);
  45. penpos8(middle_weight,90); penpos9(middle_weight,90);
  46. penpos5(right_curve-stem_corr,0); penpos10(right_curve,0);
  47. penpos11(cap_band,-90); penpos12(cap_band,-90);
  48. z3r=top z1; y4=y3; y5=.5[y4,y6]; y6=y7; y7l-y8l=vair;
  49. z12r=bot z2; y11=y12; y10=.5[y11,y9]; y8=y9; .5[y7l,y8l]=.52h;
  50. x4=x6; x9=x11=x4+.5u; x7=x8=x1; x9l:=x4+.25u;
  51. x5r=hround(w-1.5u); x10r=hround(w-u);
  52. if serifs: right_curve=cap_curve-stem_corr; x4=.5[x1,w-1.5u];
  53. else: right_curve=cap_curve-3stem_corr; x4=.5[x1,w-2.5u];
  54.  x4l:=x4l-.5u; x9l:=x9l-.5u; fi
  55. x6l:=x6l-.5u; x11l:=x11l-.5u;
  56. fill stroke z3e..super_arc.e(4,5) & super_arc.e(5,6)..z7e;  %  upper lobe
  57. fill stroke z8e..super_arc.e(9,10) & super_arc.e(10,11)..z12e;  %  lower lobe
  58. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  %  upper serif
  59.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  %  lower serif
  60. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
  61.  
  62. cmchar "Uppercase epsilon";
  63. beginchar("E",12u#-width_adj#,cap_height#,0);
  64. italcorr cap_height#*slant-beak_jut#-.5u#;
  65. adjust_fit(cap_serif_fit#,0);
  66. h:=vround(h-stem_corr);
  67. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  68. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  69. filldraw stroke z1e--z2e; %  stem
  70. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  71. top y3r=h; x3=x1; rt x4r=hround(w-u); y4=good.y(y3l-beak)-eps;
  72. arm(3,4,e,beak_darkness,beak_jut);  %  upper arm and beak
  73. pos5(cap_bar,-90); pos6(hair,0);
  74. top y5l=vround(.52[y2,y1]+.5cap_bar); x5=x1;
  75. pos0(cap_bar,90); pos7(hair,0);
  76. z0=z5; x6=x7; y6-y5l=y0l-y7;
  77. if serifs: rt x6r=hround(w-4.4u+.5hair); y6=good.y(y5l+.6beak)+eps;
  78.  rt x9r=hround(w-.5u);
  79. else: rt x6r=hround(w-1.5u); y6=y5l+eps; rt x9r=hround(w-.75u); fi
  80. arm(5,6,f,beak_darkness,0); arm(0,7,g,beak_darkness,0);  %  middle arm and seri
  81. pos8(slab if not serifs:+2stem_corr fi,-90); pos9(hair,0);
  82. bot y8r=0; x8=x2; y9=good.y(y8l+7/6beak)+eps;
  83. arm(8,9,h,beak_darkness,1.5beak_jut);  %  lower arm and beak
  84. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  %  upper serif
  85.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi  %  lower serif
  86. math_fit(0,.5ic#); penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  87.  
  88. cmchar "Uppercase eta";
  89. beginchar("H",13u#+width_adj#,cap_height#,0);
  90. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  91. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  92. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  93. pos3(cap_stem,0); pos4(cap_stem,0);
  94. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
  95. top y1=top y3=h; bot y2=bot y4=0;
  96. filldraw stroke z1e--z2e; %  left stem
  97. filldraw stroke z3e--z4e; %  right stem
  98. penpos5(cap_bar,90); penpos6(cap_bar,90);
  99. x5=x1; x6=x3; y5=y6=.52h;
  100. fill stroke z5e--z6e;  %  bar
  101. if serifs: numeric inner_jut;
  102.  if rt x1r+cap_jut+.5u+1<=lft x3l-cap_jut: inner_jut=cap_jut;
  103.  else: rt x1r+inner_jut+.5u+1=lft x3l-inner_jut; fi
  104.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,inner_jut);  %  upper left serif
  105.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,inner_jut); %  lower left serif
  106.  dish_serif(3,4,e,1/3,inner_jut,f,1/3,cap_jut);  %  upper left serif
  107.  dish_serif(4,3,g,1/3,inner_jut,h,1/3,cap_jut); fi  %  lower left serif
  108. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  109.  
  110. cmchar "Uppercase iota";
  111. beginchar("I",max(6u#,4u#+cap_stem#),cap_height#,0);
  112. italcorr cap_height#*slant-.25u#;
  113. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  114. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  115. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  116. filldraw stroke z1e--z2e; %  stem
  117. if serifs: dish_serif(1,2,a,1/3,1.05cap_jut,b,1/3,1.05cap_jut);  %  upper serif
  118.  dish_serif(2,1,c,1/3,1.05cap_jut,d,1/3,1.05cap_jut);  fi %  lower serif
  119. math_fit(0,.5ic#); penlabels(1,2); endchar;
  120.  
  121. cmchar "Uppercase kappa";
  122. beginchar("K",13.5u#,cap_height#,0);
  123. italcorr cap_height#*slant-.5u#;
  124. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  125. numeric right_jut,stem[],alpha[];
  126. if serifs: right_jut=.6cap_jut;
  127. else: right_jut=.4tiny; fi
  128. pickup tiny.nib; pos1(fudged.cap_stem,0); pos2(fudged.cap_stem,0);
  129. lft x1l=lft x2l=hround max(2u,3u-.5fudged.cap_stem); top y1=h; bot y2=0;
  130. filldraw stroke z1e--z2e; %  stem
  131. stem2=max(tiny.breadth,fudged.cap_stem-3stem_corr);
  132. stem1=max(tiny.breadth,fudged.hair if hefty:-3stem_corr fi);
  133. top y3=h; rt x3r=hround(r-letter_fit-u-right_jut);
  134. bot y6=0; rt x6r=hround(r-letter_fit-.75u-right_jut);
  135. x4=x1; y4=1/3h;
  136. alpha1=diag_ratio(1,.5(stem1-tiny),y3-y4,x3r-x4);
  137. penpos3(alpha1*(stem1-tiny),0); penpos4(whatever,-90);
  138. alpha2=diag_ratio(1,.5(stem2-tiny),y1-y6,x6r-x1);
  139. penpos6(alpha2*(stem2-tiny),0);
  140. forsuffixes $=l,r: y3'$=h; y6'$=0; z4$=z3'$+whatever*(z3-z4);
  141.  z5$=z6'$+whatever*(z1-z6)=whatever[z3,z4]; endfor
  142. z5=.5[z5l,z5r];
  143. z3'r=z3r+penoffset z3-z4 of currentpen+whatever*(z3-z4);
  144. %  we have also |z3'l=z3l+penoffset z4-z3 of currentpen+whatever*(z3-z4)|;\]
  145. z6'r=z6r+penoffset z1-z6 of currentpen+whatever*(z1-z6);
  146. z6'l=z6l+penoffset z6-z1 of currentpen+whatever*(z1-z6);
  147. fill z4r--diag_end(4r,3'r,1,.5,3'l,4l)--z4l--cycle;  %  upper diagonal
  148. fill z5l--diag_end(5l,6'l,.5,1,6'r,5r)--z5r--cycle;  %  lower diagonal
  149. if serifs: numeric inner_jut;
  150.  if rt x2r+cap_jut+.5u+1<=lft x6l-cap_jut: inner_jut=cap_jut;
  151.  else: rt x2r+cap_jut+.5u+1=lft x6l-inner_jut; fi
  152.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,cap_jut); %  upper stem serif
  153.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut);  %  lower stem serif
  154.  dish_serif(3,4,e,2/3,1.2cap_jut,f,1/2,right_jut)(dark); %  upper diagonal seri
  155.  dish_serif(6,5,g,1/2,inner_jut,h,1/3,right_jut)(dark);fi %  lower diagonal ser
  156. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  157.  
  158. cmchar "Uppercase mu";
  159. beginchar("M",16u#+width_adj#,cap_height#,0);
  160. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  161. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  162. numeric stem[]; %  thicknesses of the four strokes
  163. stem1=hround(fudged.hair+stem_corr);
  164. stem2=hround(fudged.cap_stem-4stem_corr);
  165. stem3=hround(fudged.hair-stem_corr);
  166. stem4=hround(fudged.cap_stem-3stem_corr);
  167. if stem4<stem1: stem4:=stem1; fi
  168. pickup tiny.nib; pos1(stem1,0); pos2(stem1,0);
  169. pos3(stem4,0); pos4(stem4,0);
  170. x1=x2; x3=x4; x1l=w-x3r; rt x3r=hround min(w-2u,w-3u+.5stem4);
  171. top y1=top y3=h; bot y2=bot y4=0;
  172. filldraw stroke z1e--z2e; %  left stem
  173. filldraw stroke z3e--z4e; %  right stem
  174. penpos5(stem2,0); penpos6(stem2,0); penpos7(stem3,0); penpos8(stem3,0);
  175. x5l=x1; x6l=x7l; x8=lft x3l; x6-x5=x8-x7; y5=y8=h; y6=y7;
  176. if hefty: y6=if monospace: vround 1/3h else: o fi;
  177.  numeric upper_notch,lower_notch;
  178.  upper_notch=h-cap_notch_cut; lower_notch=y6+cap_notch_cut;
  179.  x1'=rt x1r; z1'=whatever[z5l,z6l]; x3'=lft x3l; z3'=whatever[z7r,z8r];
  180.  z0=whatever[z5r,z6r]=whatever[z7l,z8l];
  181.  fill z5l..
  182.   if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
  183.   {z6-z5}diag_in(5l,6l,1,6r)..diag_out(7l,1,7r,8r){z8-z7}
  184.   if y3'<upper_notch: ...{up}(x3'-1,upper_notch){right} fi
  185.   ..z8r--diag_out(8r,1,8l,7l){z7-z8}
  186.   if y0<=lower_notch: ..{z7-z8}z0{z5-z6}..
  187.   else: ...{down}(x0+.5,lower_notch)--(x0-.5,lower_notch){up}... fi
  188.   {z5-z6}diag_in(6r,5r,1,5l)--cycle;  %  diagonals
  189. else: y6=0; z0=whatever[z5r,z6r]=whatever[z7l,z8l];
  190.  fill z5l..{z6-z5}diag_in(5l,6l,1,6r)..diag_out(7l,1,7r,8r){z8-z7}
  191.   ..z8r--diag_out(8r,1,8l,7l){z7-z8}..{z7-z8}z0{z5-z6}
  192.   ..{z5-z6}diag_in(6r,5r,1,5l)--cycle; fi  %  diagonals
  193. if serifs: serif(1,2,a,1/3,-cap_jut);  %  upper left serif
  194.  dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); %  lower left serif
  195.  serif(3,4,d,1/3,cap_jut); %   upper right serif
  196.  dish_serif(4,3,e,1/3,cap_jut,f,1/3,cap_jut); fi  %  lower right serif
  197. math_fit(0,max(.5ic#-.5u#,0));
  198. penlabels(0,1,1',2,3,3',4,5,6,7,8); endchar;
  199.  
  200. cmchar "Uppercase nu";
  201. beginchar("N",13u#+width_adj#,cap_height#,0);
  202. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  203. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  204. numeric thin_stem; thin_stem=hround(fudged.hair+stem_corr);
  205. pickup tiny.nib; pos1(thin_stem,0); pos2(thin_stem,0);
  206. pos3(thin_stem,0); pos4(thin_stem,0);
  207. pickup tiny.nib; top y1=top y3=h; bot y2=bot y4=0;
  208. x1=x2; x3=x4; x1l=w-x3r;
  209. rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
  210. filldraw stroke z1e--z2e; %  left stem
  211. filldraw stroke z3e--z4e; %  right stem
  212. if hefty: penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
  213.  x5l=x1; x6r=x4; y5=h; y6=0;
  214.  numeric upper_notch,lower_notch;
  215.  upper_notch=h-cap_notch_cut; lower_notch=cap_notch_cut;
  216.  x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l; z4'=whatever[z5r,z6r];
  217.  fill z5l..
  218.   if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
  219.   {z6-z5}diag_in(5l,6l,1,6r)--z6r..
  220.   if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
  221.   {z5-z6}diag_in(6r,5r,1,5l)--cycle;  %  diagonal
  222. else: penpos5(whatever,0); penpos6(whatever,90);
  223.  z5l=z1l; z6l=z4l;
  224.  z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
  225.  z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
  226.  filldraw stroke z5e..z6e; fi  %  diagonal
  227. if serifs: if hefty: serif(1,2,a,1/3,-cap_jut); %  upper left serif
  228.  else: serif(5,6,a,1/3,-cap_jut); fi  %  upper left serif
  229.  dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); %  lower left serif
  230.  dish_serif(3,4,e,1/2,cap_jut,f,1/2,cap_jut)(dark); fi  %  upper right serif
  231. math_fit(0,max(.5ic#-.5u#,0)); penlabels(1,1',2,3,4,4',5,6,7); endchar;
  232.  
  233. cmchar "Uppercase omicron";
  234. beginchar("O",14u#-width_adj#,cap_height#,0);
  235. italcorr .7cap_height#*slant-.5u#;
  236. adjust_fit(0,0);
  237. penpos1(vair',90); penpos3(vround(vair+1.5vair_corr),-90);
  238. penpos2(cap_curve,180); penpos4(cap_curve,0);
  239. if monospace: x2r=hround 1.5u;
  240.  interim superness:=sqrt superness;  %  make |"O"|, not |"0"|
  241. else: x2r=hround u; fi
  242. x4r=w-x2r; x1=x3=.5w; y1r=h+o; y3r=-o;
  243. y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  244. penstroke pulled_super_arc.e(1,2)(.5superpull)
  245.  & pulled_super_arc.e(2,3)(.5superpull)
  246.  & pulled_super_arc.e(3,4)(.5superpull)
  247.  & pulled_super_arc.e(4,1)(.5superpull) & cycle;  %  bowl
  248. math_fit(-.3cap_height#*slant-.5u#,ic#-.5u#); penlabels(1,2,3,4); endchar;
  249.  
  250. cmchar "Uppercase rho";
  251. beginchar("R",12u#,cap_height#,0);
  252. italcorr .75cap_height#*slant-.5u#;
  253. adjust_fit(cap_serif_fit#,0);
  254. pickup tiny.nib; penpos1(cap_stem'-tiny,0); penpos2(cap_stem-tiny,0);
  255. pos0(cap_stem',0); pos0'(cap_stem,0);
  256. lft x1l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
  257. x1l=x2l=x0l=x0'l; y0=y0'=y7;
  258. penpos3(cap_band,90); penpos4(cap_band,90);
  259. penpos5(cap_curve if hefty:-3stem_corr fi,0);
  260. penpos6(.5[vair,cap_band],-90); penpos7(.5[vair,cap_band],-90);
  261. z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
  262. x7=x2; y7l=vround .5h; x4=x6=.5w+.75u; x5r=hround(w-u);
  263. x4l:=x6l:=x4-.25cap_curve;
  264. filldraw stroke z1e--z0e--z0'e--z2e; %  stem
  265. fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  %  lobe
  266. if serifs: dish_serif(1,0,a,1/3,cap_jut,b,1/3,.5cap_jut);  %  upper serif
  267.  dish_serif(2,0',c,1/3,cap_jut,d,1/3,cap_jut); fi  %  lower serif
  268. math_fit(0,ic#-2.5u#); penlabels(0,1,2,3,4,5,6,7); endchar;
  269.  
  270. cmchar "Uppercase tau";
  271. beginchar("T",13u#-width_adj#,cap_height#,0);
  272. italcorr cap_height#*slant-beak_jut#-.25u#;
  273. adjust_fit(0,0);
  274. h:=vround(h-2stem_corr);
  275. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  276. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  277. filldraw stroke z1e--z2e; %  stem
  278. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  279. top y3r=h; x3=x1; rt x4r=hround(w-.65u); y4=good.y(y3l-beak)-eps;
  280. arm(3,4,e,beak_darkness,.7beak_jut);  %  right arm and beak
  281. pos5(hair,180); x5=w-x4; y5=y4;
  282. arm(3,5,f,beak_darkness,-.7beak_jut);  %  left arm and beak
  283. if serifs: dish_serif(1,2,a,1/3,.5cap_jut,b,1/3,.5cap_jut);  %  upper bracketin
  284.  dish_serif(2,1,c,1/3,1.414cap_jut,d,1/3,1.414cap_jut); fi  %  lower serif
  285. math_fit(-.75cap_height#*slant,ic#-2.5u#); penlabels(1,2,3,4,5,6); endchar;
  286.  
  287. cmchar "Uppercase chi";
  288. beginchar("Q",13u#,cap_height#,0);
  289. italcorr cap_height#*slant-.25u#;
  290. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  291. numeric stem[],outer_jut,xjut,alpha[];
  292. stem1=cap_stem-2stem_corr; stem2=min(cap_hair,stem1);
  293. outer_jut=.75cap_jut; xjut= if serifs: (stem1-stem2)/4 else: 0 fi;
  294. x1l=l+letter_fit+.5u+outer_jut; x2r=r-letter_fit-u-outer_jut-xjut;
  295. x3l=l+letter_fit+.25u+outer_jut+xjut; x4r=r-letter_fit-.25u-outer_jut;
  296. y1=y2=h; y3=y4=0;
  297. alpha1=diag_ratio(1,stem1,h,x4r-x1l);
  298. alpha2=diag_ratio(1,stem2,h,x2r-x3l);
  299. penpos1(alpha1*stem1,0); penpos2(alpha2*stem2,0);
  300. penpos3(alpha2*stem2,0); penpos4(alpha1*stem1,0);
  301. if hefty: z0=whatever[z1,z4]=whatever[z2,z3];
  302.  x12=x34=x0; y13=y24=y0;
  303.  z12=whatever[z2l,z3l]; z13=whatever[z2l,z3l];
  304.  z24=whatever[z2r,z3r]; z34=whatever[z2r,z3r];
  305.  forsuffixes $=13,24,34: z$'=.1[z$,z0]; endfor
  306.  fill diag_end(12,1r,.5,1,1l,13')--z13'--diag_end(13',3l,1,.5,3r,34')--z34'
  307.   --diag_end(34',4l,.5,1,4r,24')--z24'
  308.   --diag_end(24',2r,1,.5,2l,12)--z12--cycle; %  diagonals
  309. else: fill diag_end(4r,1r,.5,1,1l,4l)
  310.   --diag_end(1l,4l,.5,1,4r,1r)--cycle; %  left diagonal
  311.  fill diag_end(2l,3l,.5,1,3r,2r)
  312.   --diag_end(3r,2r,.5,1,2l,3l)--cycle; fi  %  right diagonal
  313. if serifs: numeric inner_jut[]; pickup tiny.nib;
  314.  prime_points_inside(1,4); prime_points_inside(2,3);
  315.  prime_points_inside(3,2); prime_points_inside(4,1);
  316.  if rt x1'r+cap_jut+.5u+1<=lft x2'l-cap_jut-xjut: inner_jut1=cap_jut;
  317.  else: rt x1'r+inner_jut1+.5u+1=lft x2'l-inner_jut1-xjut; fi
  318.  if rt x3'r+cap_jut+.5u+1<=lft x4'l-cap_jut-xjut: inner_jut2=cap_jut;
  319.  else: rt x3'r+inner_jut2+.5u+1=lft x4'l-inner_jut2-xjut; fi
  320.  dish_serif(1',4,a,1/3,outer_jut,b,2/3,inner_jut1);  %  upper left serif
  321.  dish_serif(4',1,c,2/3,inner_jut2,d,1/3,outer_jut);  %  lower right serif
  322.  dish_serif(2',3,e,2/3,inner_jut1+xjut,
  323.   f,1/2,outer_jut+xjut)(dark);  %  upper right serif
  324.  dish_serif(3',2,g,1/2,outer_jut+xjut,
  325.   h,2/3,inner_jut2+xjut)(dark); fi  %  lower left serif
  326. math_fit(0,.5ic#); penlabels(0,1,2,3,4,12,13,24,34); endchar;
  327.  
  328. cmchar "Uppercase zeta";
  329. beginchar("Z",11u#,cap_height#,0);
  330. italcorr cap_height#*slant-.5u#;
  331. adjust_fit(0,0);
  332. numeric arm_thickness[],z_stem;
  333. if hefty: arm_thickness1=Vround(slab-vair_corr); arm_thickness2=slab;
  334.  z_stem=.8[vair,cap_stem];
  335. else: arm_thickness1=slab; arm_thickness2=vround(slab+vair_corr);
  336.  z_stem=.9[vair,cap_stem]; fi
  337. pickup tiny.nib; x3l=x4l=w-x1r=w-x2r; lft x3l=hround u;
  338. top y1=h; y2=min(y1,h-2/3arm_thickness1);
  339. bot y4=0; y3=max(y4,2/3arm_thickness2);
  340. numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l);
  341. penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
  342. penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
  343. pair delta; delta=penoffset z3-z2 of currentpen;
  344. fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
  345.  ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
  346.  ---cycle;  %  diagonal
  347. pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
  348. top y5r=h; x5=x1; lft x6r=hround 1.25u; y6=good.y(y5l-beak)-eps;
  349. arm(5,6,a,beak_darkness**.8,-.4beak_jut);  %  upper arm and beak
  350. pos7(arm_thickness2,-90); pos8(hair,0);
  351. bot y7r=0; x7=x4; rt x8r=hround(w-.9u); y8=good.y(y7l+1.2beak)+eps;
  352. arm(7,8,b,beak_darkness**.9,.6beak_jut);  %  lower arm and beak
  353. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8); endchar;
  354.  
  355. cmchar "Uppercase gamma";
  356. beginchar("G",11u#-width_adj#,cap_height#,0);
  357. italcorr cap_height#*slant-beak_jut#-.25u#;
  358. adjust_fit(cap_serif_fit#,0);
  359. h:=vround(h-stem_corr);
  360. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  361. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
  362. filldraw stroke z1e--z2e; %  stem
  363. pickup crisp.nib; pos3(slab,90); pos4(hair,0);
  364. top y3r=h; x3=x1; rt x4r=hround(w-.75u); y4=good.y(y3l-beak)-eps;
  365. arm(3,4,e,beak_darkness,beak_jut);  %  arm and beak
  366. if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut);  %  upper serif
  367.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,1.25cap_jut); fi  %  lower serif
  368. math_fit(0,ic#-2.5u#); penlabels(1,2,3,4); endchar;
  369.  
  370. cmchar "Uppercase delta";
  371. beginchar("D",15u#,cap_height#,0);
  372. adjust_fit(0,0);
  373. numeric left_stem,alpha;
  374. left_stem=cap_hair if hefty: -3stem_corr fi;
  375. x1l=w-x4r=.75u; y1=y4=0;
  376. x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
  377. alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
  378. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  379. penpos3(alpha*cap_stem,0); penpos4(alpha*cap_stem,0);
  380. fill diag_end(2l,1l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)--cycle;  %  triangle
  381. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  382. y5=y6=cap_vstem; z5=whatever[z1r,z2r]; z6=whatever[z3l,z4l];
  383. if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
  384.  unfill z0+.5right{down}...{z4-z3}z6--z5{z2-z1}
  385.   ...{up}z0+.5left--cycle; %  counter
  386. else: unfill z0--z5--z6--cycle; fi  %  counter
  387. penlabels(0,1,2,3,4,5,6); endchar;
  388.  
  389. cmchar "Uppercase theta";
  390. beginchar("J",14u#,cap_height#,0);
  391. italcorr .7cap_height#*slant-.5u#;
  392. adjust_fit(0,0);
  393. numeric light_curve; light_curve=hround(cap_curve-2stem_corr);
  394. penpos1(vair,90); penpos3(vround(vair+.5vair_corr),-90);
  395. penpos2(light_curve,180); penpos4(light_curve,0);
  396. if monospace: x2r=hround 1.5u;
  397.  interim superness:=sqrt superness;  %  make |"O"|, not |"0"|
  398. else: x2r=hround u; fi
  399. x4r=w-x2r; x1=x3=.5w; y1r=h+o; y2=y4=.5h-vair_corr; y3r=-o;
  400. penstroke pulled_super_arc.e(1,2)(.5superpull)
  401.  & pulled_super_arc.e(2,3)(.5superpull)
  402.  & pulled_super_arc.e(3,4)(.5superpull)
  403.  & pulled_super_arc.e(4,1)(.5superpull) & cycle;  %  bowl
  404. pickup crisp.nib; pos5(cap_vstem,90); pos6(cap_vstem,90);
  405. lft x5=w-rt x6=hround(x2l+u)+1; y5=y6=.5[y1l,y3l];
  406. filldraw stroke z5e--z6e;  %  bar
  407. if serifs: pos7(hair,0); pos8(hair,0); pos9(hair,0); pos10(hair,0);
  408.  x7l=x8l=x5; x9r=x10r=x6;
  409.  y7-y5r=y9-y6r=y5l-y8=y6l-y10=vround .05h;
  410.  filldraw stroke z7e--z8e;  %  left serif
  411.  filldraw stroke z9e--z10e; fi  %  right serif
  412. math_fit(-.3cap_height#*slant-.5u#,ic#-.5u#);
  413. penlabels(1,2,3,4,5,6,7,8,9,10); endchar;
  414.  
  415. cmchar "Uppercase lambda";
  416. beginchar("L",12u#,cap_height#,0);
  417. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  418. numeric left_stem,outer_jut,alpha;
  419. left_stem=cap_hair if hefty: -3stem_corr fi;
  420. outer_jut=.7cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
  421. x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
  422. alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
  423. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  424. penpos3(alpha*cap_stem,0); penpos4(alpha*cap_stem,0);
  425. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  426. if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
  427.   fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  428.     --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  429.     ...{up}z0+.5left--cycle; %  left and right diagonals
  430. else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  431.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi %  left and right diagonals
  432. if serifs: numeric inner_jut; pickup tiny.nib;
  433.  prime_points_inside(1,2); prime_points_inside(4,3);
  434.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  435.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  436.  dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark);  %  left serif
  437.  dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi  %  right serif
  438. penlabels(0,1,2,3,4,5,6); endchar;
  439.  
  440. cmchar "Uppercase xi";
  441. beginchar("X",12u#,cap_height#,0);
  442. italcorr cap_height#*slant-.35u#;
  443. adjust_fit(0,0);
  444. h:=vround(h-2stem_corr);
  445. numeric shaved_stem; shaved_stem=hround .9[vair,.85cap_stem];
  446. pickup crisp.nib; pos1(shaved_stem,90); pos2(hair,0);
  447. top y1r=h; x1=.5w; rt x2r=hround(w-.85u); y2=good.y(y1l-4/9beak)-eps;
  448. arm(1,2,a,.4beak_darkness,.3beak_jut);  %  upper right arm and beak
  449. pos3(hair,180); x3=w-x2; y3=y2;
  450. arm(1,3,b,.4beak_darkness,-.3beak_jut);  %  upper left arm and beak
  451. pos4(shaved_stem,-90); pos5(hair,0);
  452. bot y4r=0; x4=.5w; rt x5r=hround(w-.75u); y5=good.y(y4l+.5beak)+eps;
  453. arm(4,5,c,.4beak_darkness,.3beak_jut);  %  lower right arm and beak
  454. pos6(hair,180); x6=w-x5; y6=y5;
  455. arm(4,6,d,.4beak_darkness,-.3beak_jut);  %  lower left arm and beak
  456. pos7(shaved_stem,90); pos8(shaved_stem,90);
  457. lft x7=w-rt x8=hround if serifs: 2.5 else: 2 fi\\ u;
  458. top y7r=top y8r=vround(.52h+.5shaved_stem);
  459. filldraw stroke z7e--z8e;  %  middle bar
  460. if serifs: numeric xjut;
  461.  if bot y2>top y7r+.75cap_jut: xjut=.5cap_jut;
  462.  else: bot y2=top y7r+1.5xjut; fi
  463.  pos11(hair,0); pos12(hair,0); y11=y12;
  464.  pos13(hair,0); pos14(hair,0); y13=y14;
  465.  lft x11l=lft x13l=w-rt x12r=w-rt x14r=hround 2.5u;
  466.  top y11-bot y13=shaved_stem+2xjut; .5[y11,y13]=y7;
  467.  filldraw stroke z11e--z13e; filldraw stroke z12e--z14e; fi  %  middle serifs
  468. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,11,12,13,14); endchar;
  469.  
  470. cmchar "Uppercase pi";
  471. beginchar("P",13u#+width_adj#,cap_height#,0);
  472. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  473. adjust_fit(cap_serif_fit#,cap_serif_fit#); pickup tiny.nib;
  474. h:=vround(h-stem_corr);
  475. pos1(cap_stem,0); pos2(cap_stem,0); pos3(cap_stem,0); pos4(cap_stem,0);
  476. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
  477. top y1=top y3=h; bot y2=bot y4=0;
  478. filldraw stroke z1e--z2e; %  left stem
  479. filldraw stroke z3e--z4e; %  right stem
  480. penpos5(cap_bar,90); penpos6(cap_bar,90);
  481. x5=x1; x6=x3; y5r=y6r=h;
  482. fill stroke z5e--z6e;  %  bar
  483. if serifs: numeric inner_jut;
  484.  if rt x1r+cap_jut+.5u+1<=lft x3l-cap_jut: inner_jut=cap_jut;
  485.  else: rt x1r+inner_jut+.5u+1=lft x3l-inner_jut; fi
  486.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,eps);  %  upper left serif
  487.  dish_serif(2,1,c,1/3,cap_jut,d,1/3,inner_jut); %  lower left serif
  488.  dish_serif(3,4,e,1/3,eps,f,1/3,cap_jut);  %  upper left serif
  489.  dish_serif(4,3,g,1/3,inner_jut,h,1/3,cap_jut); fi  %  lower left serif
  490. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  491.  
  492. cmchar "Uppercase sigma";
  493. beginchar("S",13u#,cap_height#,0);
  494. italcorr cap_height#*slant-beak_jut#-.5u#;
  495. adjust_fit(0,0);
  496. numeric bot_arm_thickness;
  497. bot_arm_thickness=Vround .25[slab,cap_vstem];
  498. pickup tiny.nib; lft x1l=hround u; x1l=x2l=x4l;
  499. top y1=h; bot y2=h-slab; bot y4=0; x3l-x1l=4/11(w-2u); y3=.5h;
  500. numeric alpha[]; alpha1=((x3l-x1l)++(y2-y3))/(y2-y3);
  501. penpos1(alpha1*(cap_stem-tiny),0); penpos2(alpha1*(cap_stem-tiny),0);
  502. penpos3(alpha1*(cap_stem-tiny),0);
  503. alpha2=diag_ratio(1,cap_hair-tiny,y3-y4,x3r-x4l);
  504. penpos4(alpha2*(cap_hair-tiny),0);
  505. z0=whatever[z2l,z3l]=z4l+whatever*(z3r-z4r);
  506. filldraw z1l--z2l--z0--z4l--z4r--z3r--z2r--z1r--cycle;  %  diagonals
  507. pickup crisp.nib; pos5(slab,90); pos6(hair,0);
  508. top y5r=h; x5=x1; rt x6r=hround(w-u); y6=good.y(y5l-beak)-eps;
  509. arm(5,6,a,beak_darkness,beak_jut);  %  upper arm and beak
  510. pos7(bot_arm_thickness,-90); pos8(hair,0);
  511. bot y7r=0; z7l=whatever[z4,z3]; x7r:=x4; x8=x6; y8=good.y(y7l+beak)+eps;
  512. arm(7,8,b,beak_darkness,beak_jut);  %  lower arm and beak
  513. math_fit(0,.5ic#); penlabels(0,1,2,3,4,5,6,7,8); endchar;
  514.  
  515. cmchar "Uppercase upsilon";
  516. beginchar("U",13u#,cap_height#,0);
  517. italcorr cap_height#*slant+.45u#;
  518. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  519. numeric left_stem,right_stem,outer_jut,dy,alpha;
  520. left_stem=cap_stem-stem_corr;
  521. right_stem=min(cap_hair if hefty:-2stem_corr fi,left_stem);
  522. outer_jut=.75cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.05u;
  523. x2l=x5l=hround(.5w-.5left_stem); x3r=x5r; y1=y4=h; y2=y3=y5=.4h;
  524. dy=y1-y2; alpha=((x2l-x1l)++dy)/dy;
  525. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  526. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  527. penpos5(left_stem,0); penpos6(left_stem,0); x5=x6; y6=0;
  528. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  529. if y0>y2+cap_notch_cut: y0:=y2+cap_notch_cut;
  530.   fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)--z5r
  531.     --diag_end(5r,6r,1,1,6l,5l)--z5l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  532.     ...{down}z0+.5left--cycle; % diagonals and stem
  533. else: fill z0--diag_end(0,4l,1,1,4r,3r)--z5r
  534.     --diag_end(5r,6r,1,1,6l,5l)--z5l
  535.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi  % diagonals and stem
  536. if serifs: numeric inner_jut; pickup tiny.nib;
  537.  prime_points_inside(1,2); prime_points_inside(4,3); prime_points_inside(6,5);
  538.  if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
  539.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  540.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);  % upper left serif
  541.  dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark);  % upper right serif
  542.  dish_serif(6',5,e,1/3,cap_jut,f,1/3,cap_jut); fi  % lower serif
  543. math_fit(.5u#-cap_height#*slant,ic#-4u#);
  544. penlabels(0,1,2,3,4,5,6); endchar;
  545.  
  546. cmchar "Uppercase phi";
  547. beginchar("F",13u#,cap_height#,0);
  548. italcorr .5cap_height#*slant-.5u#;
  549. adjust_fit(0,0);
  550. numeric shaved_stem,light_curve;
  551. shaved_stem=cap_stem-hround 2stem_corr;
  552. light_curve=cap_curve-hround stem_corr;
  553. pickup tiny.nib; pos1(shaved_stem,0); pos2(shaved_stem,0);
  554. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  555. filldraw stroke z1e--z2e; %  stem
  556. penpos3(vair,90); penpos5(vair,-90);
  557. penpos4(light_curve,180); penpos6(light_curve,0);
  558. x4r=hround u; x6r=w-x4r; x3=x5=.5w;
  559. y3r=vround(.85h if serifs:-slab fi); y4=y6=.5[y3,y5];
  560. y5r=vround(.15h if serifs:+slab fi);
  561. penstroke pulled_arc.e(3,4) & pulled_arc.e(4,5)
  562.  & pulled_arc.e(5,6) & pulled_arc.e(6,3) & cycle;  %  bowl
  563. if serifs: dish_serif(1,2,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut);  %  upper serif
  564.  dish_serif(2,1,c,1/3,1.25cap_jut,d,1/3,1.25cap_jut); fi  %  lower serif
  565. math_fit(-.5cap_height#*slant-.5u#,ic#); penlabels(1,2,3,4,5,6); endchar;
  566.  
  567. cmchar "Uppercase psi";
  568. beginchar("Y",14u#,cap_height#,0);
  569. italcorr .8cap_height#*slant-.5u#;
  570. adjust_fit(0,0);
  571. numeric shaved_stem;
  572. shaved_stem=cap_stem-hround 2stem_corr;
  573. pickup tiny.nib; pos1(shaved_stem,0); pos2(shaved_stem,0);
  574. lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
  575. filldraw stroke z1e--z2e; %  stem
  576. pos3(shaved_stem,-180); pos4(shaved_stem,-180);
  577. pos5(vair,-90); x5=x1; bot y5r=vround(.15h if serifs:+slab fi);
  578. pos6(shaved_stem,0); pos7(shaved_stem,0);
  579. lft x3r=hround u; x7=w-x3; lft x4r=hround(3u-.5shaved_stem); x6=w-x4;
  580. pos3'(vair,90); pos7'(vair,90); z3'r=z3r; z7'r=z7r;
  581. y3=y7; y4=y6=.6h; y3=good.y(y3+.84h if serifs:-slab fi-y3');
  582. interim superness:=more_super;
  583. filldraw z3'l{right}...z4r{down} & super_arc.r(4,5)
  584.  & super_arc.r(5,6) & z6r{up}...z7'l{right}
  585.  --z7r---z7l...z6l{down} & super_arc.l(6,5)
  586.  & super_arc.l(5,4) & z4l{up}...z3l---z3r--cycle;  %  stroke
  587. if serifs: dish_serif(1,2,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut);  %  upper serif
  588.  dish_serif(2,1,c,1/3,1.25cap_jut,d,1/3,1.25cap_jut); fi  %  lower serif
  589. math_fit(-.8cap_height#*slant-.5u#,.4cap_height#*slant-1.25u#);
  590. penlabels(1,2,3,4,5,6,7); endchar;
  591.  
  592. cmchar "Uppercase omega";
  593. beginchar("W",13u#,cap_height#,0);
  594. italcorr .75cap_height#*slant-.5u#;
  595. adjust_fit(0,0);
  596. pickup tiny.nib; pos1(vair,90); pos2(cap_curve,180);
  597. pos3(vair,180); pos4(cap_curve,0); pos5(vair,0);
  598. x1=.5w; top y1r=h+o; lft x2r=hround u; y2=y4=2/3h; x4=w-x2;
  599. rt x3l=hround(1/3(w+.5u)+.5hair); bot y3=bot y5=0; x5=w-x3;
  600. filldraw stroke z3e{up}...{up}z2e
  601.  & pulled_super_arc.e(2,1)(.5superpull)
  602.  & pulled_super_arc.e(1,4)(.5superpull)
  603.  & z4e{down}...{down}z5e;  %  bowl
  604. numeric arm_thickness; path p; p=z3{up}...{up}z2;
  605. arm_thickness=Vround(if hefty:slab+2stem_corr else:.75[slab,cap_vstem] fi);
  606. pickup crisp.nib; pos6(arm_thickness,-90); pos7(fudged.hair,-180);
  607. bot y6r=0; x6=x3; lft x7r=hround .8u; y7=good.y(y6l+.5beak)+eps;
  608. (x,y)=p intersectionpoint((0,y6l)--(w,y6l)); x6l:=x;
  609. arm(6,7,a,.5beak_darkness,-1.2beak_jut);  %  left arm and beak
  610. pos8(arm_thickness,-90); pos9(fudged.hair,0);
  611. y8=y6; y9=y7; x8+x6=x9+x7=w; x8l:=w-x6l;
  612. arm(8,9,b,.5beak_darkness,1.2beak_jut);  %  right arm and beak
  613. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
  614.  
  615.