home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Computer Club Elmshorn Atari PD
/
CCE_PD.iso
/
pc
/
0600
/
CCE_0616.ZIP
/
CCE_0616.PD
/
TERM2000.2_5
/
DEMO
/
VT52DEMO.BAS
< prev
next >
Wrap
BASIC Source File
|
1991-05-01
|
2KB
|
74 lines
10 "C":WAIT 0:REM Komplexometrie
20 REM Variablenbedeutung:
30 REM A=Re(1)
40 REM B=Im(1)
50 REM C=Re(2)
60 REM D=Im(2)
70 REM E=Re(Ergebnis)
80 REM F=Im(Ergebnis)
90 REM Y=Betrag(POL (E,F))
100 REM Z=Winkel(POL (E,F))
110 U1$="##.###^":U2$="####.##"
120 PRINT "Re(1) = ":CALL &80CA:INPUT A
130 PRINT "Im(1) = ":CALL &80CA:INPUT B
140 "C LOOP"
150 PRINT "Komplexe Operation : ":CALL &80CA:INPUT I$
160 IF ASC (I$)=252THEN LET I$="SQR":REM Wurzelzeichen in "SQR" wandeln
170 IF I$="SQR"GOSUB "SQR"
180 IF I$="SQR"GOTO "ERG"
190 IF ASC (I$)=130THEN LET I$="POL":REM Taste POLAR in "POL" wandeln
200 IF I$="POL"GOSUB "POL"
210 IF I$="POL"GOTO "END"
220 IF ASC (I$)=135THEN LET I$="RCP":REM Taste 1/X in "RCP" wandeln
230 IF I$="RCP"GOSUB "RCP"
240 IF I$="RCP"GOTO "ERG"
250 IF I$<>"+"AND I$<>"-"AND I$<>"*"AND I$<>"/"GOTO "C LOOP"
260 PRINT "Re(2) = ":CALL &80CA:INPUT C
270 PRINT "Im(2) = ":CALL &80CA:INPUT D
280 IF I$="+"GOSUB "ADD"
290 IF I$="-"GOSUB "SUB"
300 IF I$="*"GOSUB "MUL"
310 IF I$="/"GOSUB "DIV"
320 "ERG"
330 REM AusgabeinKomplex
340 PRINT USING U1$;MDF (E);" +j ";MDF (F):CALL &80CA
350 "END"
360 PRINT "Weiter / Neu ? ":CALL &80CA:INPUT I$
370 IF I$="W"LET A=E
380 IF I$="W"LET B=F
390 IF I$="W"GOTO "C LOOP"
400 IF I$="N"GOTO "C"
410 GOTO "END"
420 REM EndedesHauptprogrammes---------------
430 "ADD"
440 E=A+C:F=B+D
450 RETURN
460 "SUB"
470 E=A-C:F=B-D
480 RETURN
490 "MUL"
500 E=A*C-B*D:F=A*D+C*B
510 RETURN
520 "DIV"
530 E=(A*C+B*D)/(C*C+D*D)
540 F=(-A*D+C*B)/(C*C+D*D)
550 RETURN
560 "SQR"
570 AA=A*A:BB=B*B
580 E=SQR ((SQR (AA+BB)+A)/2)
590 F=SQR ((SQR (AA+BB)-A)/2)*SGN (B)
600 WAIT 150
610 PRINT "SQR ==> +/- !"
620 WAIT
630 RETURN
640 "POL"
650 REM UmwandlungundAusgabeinPolar
660 PAUSE "Polar :"
670 PRINT USING U1$;POL (A,B),USING U2$;Z
680 RETURN
690 "RCP"
700 E=A/(A*A+B*B)
710 F=-B/(A*A+B*B)
720 RETURN
730 END :REM EndederUnterprogramme---------