home *** CD-ROM | disk | FTP | other *** search
/ Computer Club Elmshorn Atari PD / CCE_PD.iso / pc / 0600 / CCE_0616.ZIP / CCE_0616.PD / TERM2000.2_5 / DEMO / VT52DEMO.BAS < prev    next >
BASIC Source File  |  1991-05-01  |  2KB  |  74 lines
  1. 10 "C":WAIT 0:REM Komplexometrie
  2. 20 REM Variablenbedeutung:
  3. 30 REM A=Re(1)
  4. 40 REM B=Im(1)
  5. 50 REM C=Re(2)
  6. 60 REM D=Im(2)
  7. 70 REM E=Re(Ergebnis)
  8. 80 REM F=Im(Ergebnis)
  9. 90 REM Y=Betrag(POL (E,F))
  10. 100 REM Z=Winkel(POL (E,F))
  11. 110 U1$="##.###^":U2$="####.##"
  12. 120 PRINT "Re(1) = ":CALL &80CA:INPUT A
  13. 130 PRINT "Im(1) = ":CALL &80CA:INPUT B
  14. 140 "C LOOP"
  15. 150 PRINT "Komplexe Operation : ":CALL &80CA:INPUT I$
  16. 160 IF ASC (I$)=252THEN LET I$="SQR":REM Wurzelzeichen in "SQR" wandeln
  17. 170 IF I$="SQR"GOSUB "SQR"
  18. 180 IF I$="SQR"GOTO "ERG"
  19. 190 IF ASC (I$)=130THEN LET I$="POL":REM Taste POLAR in "POL" wandeln
  20. 200 IF I$="POL"GOSUB "POL"
  21. 210 IF I$="POL"GOTO "END"
  22. 220 IF ASC (I$)=135THEN LET I$="RCP":REM Taste 1/X in "RCP" wandeln
  23. 230 IF I$="RCP"GOSUB "RCP"
  24. 240 IF I$="RCP"GOTO "ERG"
  25. 250 IF I$<>"+"AND I$<>"-"AND I$<>"*"AND I$<>"/"GOTO "C LOOP"
  26. 260 PRINT "Re(2) = ":CALL &80CA:INPUT C
  27. 270 PRINT "Im(2) = ":CALL &80CA:INPUT D
  28. 280 IF I$="+"GOSUB "ADD"
  29. 290 IF I$="-"GOSUB "SUB"
  30. 300 IF I$="*"GOSUB "MUL"
  31. 310 IF I$="/"GOSUB "DIV"
  32. 320 "ERG"
  33. 330 REM AusgabeinKomplex
  34. 340 PRINT USING U1$;MDF (E);" +j ";MDF (F):CALL &80CA
  35. 350 "END"
  36. 360 PRINT "Weiter / Neu ? ":CALL &80CA:INPUT I$
  37. 370 IF I$="W"LET A=E
  38. 380 IF I$="W"LET B=F
  39. 390 IF I$="W"GOTO "C LOOP"
  40. 400 IF I$="N"GOTO "C"
  41. 410 GOTO "END"
  42. 420 REM EndedesHauptprogrammes---------------
  43. 430 "ADD"
  44. 440 E=A+C:F=B+D
  45. 450 RETURN 
  46. 460 "SUB"
  47. 470 E=A-C:F=B-D
  48. 480 RETURN 
  49. 490 "MUL"
  50. 500 E=A*C-B*D:F=A*D+C*B
  51. 510 RETURN 
  52. 520 "DIV"
  53. 530 E=(A*C+B*D)/(C*C+D*D)
  54. 540 F=(-A*D+C*B)/(C*C+D*D)
  55. 550 RETURN 
  56. 560 "SQR"
  57. 570 AA=A*A:BB=B*B
  58. 580 E=SQR ((SQR (AA+BB)+A)/2)
  59. 590 F=SQR ((SQR (AA+BB)-A)/2)*SGN (B)
  60. 600 WAIT 150
  61. 610 PRINT "SQR ==> +/-  !"
  62. 620 WAIT 
  63. 630 RETURN 
  64. 640 "POL"
  65. 650 REM UmwandlungundAusgabeinPolar
  66. 660 PAUSE "Polar :"
  67. 670 PRINT USING U1$;POL (A,B),USING U2$;Z
  68. 680 RETURN 
  69. 690 "RCP"
  70. 700 E=A/(A*A+B*B)
  71. 710 F=-B/(A*A+B*B)
  72. 720 RETURN
  73. 730 END :REM EndederUnterprogramme---------
  74.