home *** CD-ROM | disk | FTP | other *** search
/ Complete Linux / Complete Linux.iso / docs / system / mail / mailhand / metamail.z / metamail / bin / metasend < prev    next >
Encoding:
Text File  |  1992-05-05  |  5.8 KB  |  207 lines
  1. #!/bin/csh -f
  2. # Copyright (c) 1991 Bell Communications Research, Inc. (Bellcore)
  3. # 
  4. # Permission to use, copy, modify, and distribute this material 
  5. # for any purpose and without fee is hereby granted, provided 
  6. # that the above copyright notice and this permission notice 
  7. # appear in all copies, and that the name of Bellcore not be 
  8. # used in advertising or publicity pertaining to this 
  9. # material without the specific, prior written permission 
  10. # of an authorized representative of Bellcore.  BELLCORE 
  11. # MAKES NO REPRESENTATIONS ABOUT THE ACCURACY OR SUITABILITY 
  12. # OF THIS MATERIAL FOR ANY PURPOSE.  IT IS PROVIDED "AS IS", 
  13. # WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES.
  14. #
  15.  
  16. set MustDelete=0
  17. set batchmode=0
  18. set splitsize = 100000
  19. while ($#argv > 0)
  20.     switch ($1)
  21.         case "-S":
  22.             shift
  23.             if ($#argv == 0) then
  24.                 echo "-S requires a following argument, the SPLIT threshhold"
  25.                 exit
  26.             endif
  27.             set splitsize=$1
  28.             shift
  29.             breaksw
  30.         case "-b":
  31.             # Batch mode -- ALL args must be on command line
  32.             set batchmode = 1
  33.             shift
  34.             breaksw
  35.         case "-c":
  36.             shift
  37.             if ($#argv == 0) then
  38.                 echo "-c requires a following argument, the CC address"
  39.                 exit
  40.             endif
  41.             set cc=$1
  42.             shift
  43.             breaksw
  44.         case "-s":
  45.             shift
  46.             if ($#argv == 0) then
  47.                 echo "-s requires a following argument, the SUBJECT"
  48.                 exit
  49.             endif
  50.             set subject="$1"
  51.             shift
  52.             breaksw
  53.         case "-t":
  54.             shift
  55.             if ($#argv == 0) then
  56.                 echo "-t requires a following argument, the TO address"
  57.                 exit
  58.             endif
  59.             set to="$1"
  60.             shift
  61.             breaksw
  62.         case "-e":
  63.             shift
  64.             if ($#argv == 0) then
  65.                 echo "-e requires a following argument, the ENCODING value"
  66.                 exit
  67.             endif
  68.             set encode=$1
  69.             shift
  70.             breaksw
  71.         case "-f":
  72.             shift
  73.             if ($#argv == 0) then
  74.                 echo "-f requires a following argument, the DATA FILE"
  75.                 exit
  76.             endif
  77.             set datafile=$1
  78.             shift
  79.             breaksw
  80.         case "-m":
  81.             shift
  82.             if ($#argv == 0) then
  83.                 echo "-m requires a following argument, the MIME CONTENT-TYPE"
  84.                 exit
  85.             endif
  86.             set ctype=$1
  87.             shift
  88.             breaksw
  89.         case "-z":
  90.             set MustDelete=1
  91.             shift
  92.             breaksw
  93.         default:
  94.             echo UNRECOGNIZED METASEND OPTION: $1
  95.             exit
  96.     endsw
  97. end
  98.  
  99. if ($batchmode == 0) then
  100.     if (! $?to) then
  101.         echo -n "To: "
  102.         set to = $<
  103.     endif
  104.     if (! $?subject) then
  105.         echo -n "Subject: "
  106.         set subject = $<
  107.     endif
  108.     if (! $?cc) then
  109.         echo -n "CC: "
  110.         set cc = $<
  111.     endif
  112.     if (! $?ctype) then
  113.         echo -n "Content-type: "
  114.         set ctype = $<
  115.     endif
  116.     if (! $?datafile) then
  117.         getfile:
  118.         echo -n "Name of file containing $ctype data: "
  119.         set datafile = $<
  120.         if (! -e  $datafile) then
  121.             echo The file $datafile does not exist.
  122.             goto getfile
  123.         endif
  124.     endif
  125.     if (! $?encode) then
  126.         retry:
  127.         echo "Do you want to encode this data for sending through the mail?"
  128.         echo "  1 -- No, it is already in 7 bit ASCII"
  129.         echo "  2 -- Yes, encode in base64 (most efficient)"
  130.         echo "  3 -- Yes, encode in quoted-printable (less efficient, more readable)"
  131.         echo "  4 -- Yes, encode it using uuencode (not standard, being phased out)"
  132.         set encode=$<
  133.         switch ("$encode")
  134.             case 1:
  135.                 set encodingprog = cat
  136.       set encode = 7bit
  137.                 breaksw
  138.             case 2:
  139.                 set encodingprog = "mmencode -b"
  140.       set encode = base64
  141.                 breaksw
  142.             case 3:
  143.                 set encodingprog = "mmencode -q"
  144.       set encode = quoted-printable
  145.                 breaksw
  146.             case 4:
  147.                 set encodingprog = "uuencode $datafile"
  148.       set encode = x-uue
  149.                 breaksw
  150.             default:
  151.                 echo Unrecognized answer, please try again.
  152.                 goto retry
  153.         endsw
  154.     endif
  155. else
  156.     if (! $?to || ! $?subject || ! $?ctype || ! $?datafile) then
  157.         echo metasend: in batch mode, -t, -s, -f, and -m are all required
  158.         exit
  159.     endif
  160.     if (! -e  $datafile) then
  161.         echo metasend:  The file $datafile does not exist
  162.         exit
  163.     endif
  164.     if (! $?cc) set cc=""
  165.     if (! $?encode) then
  166.         if ("$ctype" =~ text*) then
  167.     set encodingprog = "mmencode -q"
  168.     set encode = "quoted-printable"
  169.         else
  170.             set encodingprog = "mmencode -b"
  171.             set encode = base64
  172.         endif
  173.     else if ($encode == "base64") then
  174.         set encodingprog = "mmencode -b"
  175.     else if ($encode == "x-uue") then
  176.         set encodingprog = "uuencode mail-body"
  177.     else if ($encode == "7bit") then
  178.         set encodingprog = cat
  179.     else
  180.         set encodingprog = "mmencode -q"
  181.         set encode = "quoted-printable"
  182.     endif
  183. endif
  184.  
  185. set fname = /tmp/metasend.$$
  186. echo "To: " "$to" > $fname
  187. echo "Subject: " "$subject" >> $fname
  188. echo "CC: " "$cc" >> $fname
  189. echo "MIME-Version: 1.0" >> $fname
  190. echo "Content-type: " $ctype >> $fname
  191. echo "Content-Transfer-Encoding: " $encode >> $fname
  192. echo  "" >> $fname
  193. $encodingprog < $datafile >> $fname
  194. # Ensure last line has trailing carraige return
  195. echo "" >> $fname
  196.  
  197. splitmail -s $splitsize -d $fname
  198. if (! $status) then
  199.     rm $fname
  200. else if ($MustDelete == 1) then
  201.     echo Mail delivery failed
  202.     rm $fname
  203. else
  204.     echo Mail delivery failed, draft mail is in $fname
  205. endif
  206.  
  207.