home *** CD-ROM | disk | FTP | other *** search
/ CLIX - Fazer Clix Custa Nix / CLIX-CD.cdr / mac / lib / Safe.pm < prev    next >
Text File  |  1998-04-04  |  17KB  |  556 lines

  1. package Safe;
  2.  
  3. use 5.003_11;
  4. use strict;
  5. use vars qw($VERSION);
  6.  
  7. $VERSION = "2.06";
  8.  
  9. use Carp;
  10.  
  11. use Opcode 1.01, qw(
  12.     opset opset_to_ops opmask_add
  13.     empty_opset full_opset invert_opset verify_opset
  14.     opdesc opcodes opmask define_optag opset_to_hex
  15. );
  16.  
  17. *ops_to_opset = \&opset;   # Temporary alias for old Penguins
  18.  
  19.  
  20. my $default_root  = 0;
  21. my $default_share = ['*_']; #, '*main::'];
  22.  
  23. sub new {
  24.     my($class, $root, $mask) = @_;
  25.     my $obj = {};
  26.     bless $obj, $class;
  27.  
  28.     if (defined($root)) {
  29.     croak "Can't use \"$root\" as root name"
  30.         if $root =~ /^main\b/ or $root !~ /^\w[:\w]*$/;
  31.     $obj->{Root}  = $root;
  32.     $obj->{Erase} = 0;
  33.     }
  34.     else {
  35.     $obj->{Root}  = "Safe::Root".$default_root++;
  36.     $obj->{Erase} = 1;
  37.     }
  38.  
  39.     # use permit/deny methods instead till interface issues resolved
  40.     # XXX perhaps new Safe 'Root', mask => $mask, foo => bar, ...;
  41.     croak "Mask parameter to new no longer supported" if defined $mask;
  42.     $obj->permit_only(':default');
  43.  
  44.     # We must share $_ and @_ with the compartment or else ops such
  45.     # as split, length and so on won't default to $_ properly, nor
  46.     # will passing argument to subroutines work (via @_). In fact,
  47.     # for reasons I don't completely understand, we need to share
  48.     # the whole glob *_ rather than $_ and @_ separately, otherwise
  49.     # @_ in non default packages within the compartment don't work.
  50.     $obj->share_from('main', $default_share);
  51.     return $obj;
  52. }
  53.  
  54. sub DESTROY {
  55.     my $obj = shift;
  56.     $obj->erase if $obj->{Erase};
  57. }
  58.  
  59. sub erase {
  60.     my $obj= shift;
  61.     my $pkg = $obj->root();
  62.     my ($stem, $leaf);
  63.  
  64.     no strict 'refs';
  65.     $pkg = "main::$pkg\::"; # expand to full symbol table name
  66.     ($stem, $leaf) = $pkg =~ m/(.*::)(\w+::)$/;
  67.  
  68.     # The 'my $foo' is needed! Without it you get an
  69.     # 'Attempt to free unreferenced scalar' warning!
  70.     my $stem_symtab = *{$stem}{HASH};
  71.  
  72.     #warn "erase($pkg) stem=$stem, leaf=$leaf";
  73.     #warn " stem_symtab hash ".scalar(%$stem_symtab)."\n";
  74.     # ", join(', ', %$stem_symtab),"\n";
  75.  
  76.     delete $stem_symtab->{$leaf};
  77.  
  78. #    my $leaf_glob   = $stem_symtab->{$leaf};
  79. #    my $leaf_symtab = *{$leaf_glob}{HASH};
  80. #    warn " leaf_symtab ", join(', ', %$leaf_symtab),"\n";
  81. #    %$leaf_symtab = ();
  82.     #delete $leaf_symtab->{'__ANON__'};
  83.     #delete $leaf_symtab->{'foo'};
  84.     #delete $leaf_symtab->{'main::'};
  85. #    my $foo = undef ${"$stem\::"}{"$leaf\::"};
  86.  
  87.     $obj->share_from('main', $default_share);
  88.     1;
  89. }
  90.  
  91.  
  92. sub reinit {
  93.     my $obj= shift;
  94.     $obj->erase;
  95.     $obj->share_redo;
  96. }
  97.  
  98. sub root {
  99.     my $obj = shift;
  100.     croak("Safe root method now read-only") if @_;
  101.     return $obj->{Root};
  102. }
  103.  
  104.  
  105. sub mask {
  106.     my $obj = shift;
  107.     return $obj->{Mask} unless @_;
  108.     $obj->deny_only(@_);
  109. }
  110.  
  111. # v1 compatibility methods
  112. sub trap   { shift->deny(@_)   }
  113. sub untrap { shift->permit(@_) }
  114.  
  115. sub deny {
  116.     my $obj = shift;
  117.     $obj->{Mask} |= opset(@_);
  118. }
  119. sub deny_only {
  120.     my $obj = shift;
  121.     $obj->{Mask} = opset(@_);
  122. }
  123.  
  124. sub permit {
  125.     my $obj = shift;
  126.     # XXX needs testing
  127.     $obj->{Mask} &= invert_opset opset(@_);
  128. }
  129. sub permit_only {
  130.     my $obj = shift;
  131.     $obj->{Mask} = invert_opset opset(@_);
  132. }
  133.  
  134.  
  135. sub dump_mask {
  136.     my $obj = shift;
  137.     print opset_to_hex($obj->{Mask}),"\n";
  138. }
  139.  
  140.  
  141.  
  142. sub share {
  143.     my($obj, @vars) = @_;
  144.     $obj->share_from(scalar(caller), \@vars);
  145. }
  146.  
  147. sub share_from {
  148.     my $obj = shift;
  149.     my $pkg = shift;
  150.     my $vars = shift;
  151.     my $no_record = shift || 0;
  152.     my $root = $obj->root();
  153.     croak("vars not an array ref") unless ref $vars eq 'ARRAY';
  154.     no strict 'refs';
  155.     # Check that 'from' package actually exists
  156.     croak("Package \"$pkg\" does not exist")
  157.     unless keys %{"$pkg\::"};
  158.     my $arg;
  159.     foreach $arg (@$vars) {
  160.     # catch some $safe->share($var) errors:
  161.     croak("'$arg' not a valid symbol table name")
  162.         unless $arg =~ /^[\$\@%*&]?\w[\w:]*$/
  163.             or $arg =~ /^\$\W$/;
  164.     my ($var, $type);
  165.     $type = $1 if ($var = $arg) =~ s/^(\W)//;
  166.     # warn "share_from $pkg $type $var";
  167.     *{$root."::$var"} = (!$type)       ? \&{$pkg."::$var"}
  168.               : ($type eq '&') ? \&{$pkg."::$var"}
  169.               : ($type eq '$') ? \${$pkg."::$var"}
  170.               : ($type eq '@') ? \@{$pkg."::$var"}
  171.               : ($type eq '%') ? \%{$pkg."::$var"}
  172.               : ($type eq '*') ?  *{$pkg."::$var"}
  173.               : croak(qq(Can't share "$type$var" of unknown type));
  174.     }
  175.     $obj->share_record($pkg, $vars) unless $no_record or !$vars;
  176. }
  177.  
  178. sub share_record {
  179.     my $obj = shift;
  180.     my $pkg = shift;
  181.     my $vars = shift;
  182.     my $shares = \%{$obj->{Shares} ||= {}};
  183.     # Record shares using keys of $obj->{Shares}. See reinit.
  184.     @{$shares}{@$vars} = ($pkg) x @$vars if @$vars;
  185. }
  186. sub share_redo {
  187.     my $obj = shift;
  188.     my $shares = \%{$obj->{Shares} ||= {}};
  189.     my($var, $pkg);
  190.     while(($var, $pkg) = each %$shares) {
  191.     # warn "share_redo $pkg\:: $var";
  192.     $obj->share_from($pkg,  [ $var ], 1);
  193.     }
  194. }
  195. sub share_forget {
  196.     delete shift->{Shares};
  197. }
  198.  
  199. sub varglob {
  200.     my ($obj, $var) = @_;
  201.     no strict 'refs';
  202.     return *{$obj->root()."::$var"};
  203. }
  204.  
  205.  
  206. sub reval {
  207.     my ($obj, $expr, $strict) = @_;
  208.     my $root = $obj->{Root};
  209.  
  210.     # Create anon sub ref in root of compartment.
  211.     # Uses a closure (on $expr) to pass in the code to be executed.
  212.     # (eval on one line to keep line numbers as expected by caller)
  213.     my $evalcode = sprintf('package %s; sub { eval $expr; }', $root);
  214.     my $evalsub;
  215.  
  216.     if ($strict) { use strict; $evalsub = eval $evalcode; }
  217.     else         {  no strict; $evalsub = eval $evalcode; }
  218.  
  219.     return Opcode::_safe_call_sv($root, $obj->{Mask}, $evalsub);
  220. }
  221.  
  222. sub rdo {
  223.     my ($obj, $file) = @_;
  224.     my $root = $obj->{Root};
  225.  
  226.     my $evalsub = eval
  227.         sprintf('package %s; sub { do $file }', $root);
  228.     return Opcode::_safe_call_sv($root, $obj->{Mask}, $evalsub);
  229. }
  230.  
  231.  
  232. 1;
  233.  
  234. __DATA__
  235.  
  236. =head1 NAME
  237.  
  238. Safe - Compile and execute code in restricted compartments
  239.  
  240. =head1 SYNOPSIS
  241.  
  242.   use Safe;
  243.  
  244.   $compartment = new Safe;
  245.  
  246.   $compartment->permit(qw(time sort :browse));
  247.  
  248.   $result = $compartment->reval($unsafe_code);
  249.  
  250. =head1 DESCRIPTION
  251.  
  252. The Safe extension module allows the creation of compartments
  253. in which perl code can be evaluated. Each compartment has
  254.  
  255. =over 8
  256.  
  257. =item a new namespace
  258.  
  259. The "root" of the namespace (i.e. "main::") is changed to a
  260. different package and code evaluated in the compartment cannot
  261. refer to variables outside this namespace, even with run-time
  262. glob lookups and other tricks.
  263.  
  264. Code which is compiled outside the compartment can choose to place
  265. variables into (or I<share> variables with) the compartment's namespace
  266. and only that data will be visible to code evaluated in the
  267. compartment.
  268.  
  269. By default, the only variables shared with compartments are the
  270. "underscore" variables $_ and @_ (and, technically, the less frequently
  271. used %_, the _ filehandle and so on). This is because otherwise perl
  272. operators which default to $_ will not work and neither will the
  273. assignment of arguments to @_ on subroutine entry.
  274.  
  275. =item an operator mask
  276.  
  277. Each compartment has an associated "operator mask". Recall that
  278. perl code is compiled into an internal format before execution.
  279. Evaluating perl code (e.g. via "eval" or "do 'file'") causes
  280. the code to be compiled into an internal format and then,
  281. provided there was no error in the compilation, executed.
  282. Code evaulated in a compartment compiles subject to the
  283. compartment's operator mask. Attempting to evaulate code in a
  284. compartment which contains a masked operator will cause the
  285. compilation to fail with an error. The code will not be executed.
  286.  
  287. The default operator mask for a newly created compartment is
  288. the ':default' optag.
  289.  
  290. It is important that you read the Opcode(3) module documentation
  291. for more information, especially for detailed definitions of opnames,
  292. optags and opsets.
  293.  
  294. Since it is only at the compilation stage that the operator mask
  295. applies, controlled access to potentially unsafe operations can
  296. be achieved by having a handle to a wrapper subroutine (written
  297. outside the compartment) placed into the compartment. For example,
  298.  
  299.     $cpt = new Safe;
  300.     sub wrapper {
  301.         # vet arguments and perform potentially unsafe operations
  302.     }
  303.     $cpt->share('&wrapper');
  304.  
  305. =back
  306.  
  307.  
  308. =head1 WARNING
  309.  
  310. The authors make B<no warranty>, implied or otherwise, about the
  311. suitability of this software for safety or security purposes.
  312.  
  313. The authors shall not in any case be liable for special, incidental,
  314. consequential, indirect or other similar damages arising from the use
  315. of this software.
  316.  
  317. Your mileage will vary. If in any doubt B<do not use it>.
  318.  
  319.  
  320. =head2 RECENT CHANGES
  321.  
  322. The interface to the Safe module has changed quite dramatically since
  323. version 1 (as supplied with Perl5.002). Study these pages carefully if
  324. you have code written to use Safe version 1 because you will need to
  325. makes changes.
  326.  
  327.  
  328. =head2 Methods in class Safe
  329.  
  330. To create a new compartment, use
  331.  
  332.     $cpt = new Safe;
  333.  
  334. Optional argument is (NAMESPACE), where NAMESPACE is the root namespace
  335. to use for the compartment (defaults to "Safe::Root0", incremented for
  336. each new compartment).
  337.  
  338. Note that version 1.00 of the Safe module supported a second optional
  339. parameter, MASK.  That functionality has been withdrawn pending deeper
  340. consideration. Use the permit and deny methods described below.
  341.  
  342. The following methods can then be used on the compartment
  343. object returned by the above constructor. The object argument
  344. is implicit in each case.
  345.  
  346.  
  347. =over 8
  348.  
  349. =item permit (OP, ...)
  350.  
  351. Permit the listed operators to be used when compiling code in the
  352. compartment (in I<addition> to any operators already permitted).
  353.  
  354. =item permit_only (OP, ...)
  355.  
  356. Permit I<only> the listed operators to be used when compiling code in
  357. the compartment (I<no> other operators are permitted).
  358.  
  359. =item deny (OP, ...)
  360.  
  361. Deny the listed operators from being used when compiling code in the
  362. compartment (other operators may still be permitted).
  363.  
  364. =item deny_only (OP, ...)
  365.  
  366. Deny I<only> the listed operators from being used when compiling code
  367. in the compartment (I<all> other operators will be permitted).
  368.  
  369. =item trap (OP, ...)
  370.  
  371. =item untrap (OP, ...)
  372.  
  373. The trap and untrap methods are synonyms for deny and permit
  374. respectfully.
  375.  
  376. =item share (NAME, ...)
  377.  
  378. This shares the variable(s) in the argument list with the compartment.
  379. This is almost identical to exporting variables using the L<Exporter(3)>
  380. module.
  381.  
  382. Each NAME must be the B<name> of a variable, typically with the leading
  383. type identifier included. A bareword is treated as a function name.
  384.  
  385. Examples of legal names are '$foo' for a scalar, '@foo' for an
  386. array, '%foo' for a hash, '&foo' or 'foo' for a subroutine and '*foo'
  387. for a glob (i.e.  all symbol table entries associated with "foo",
  388. including scalar, array, hash, sub and filehandle).
  389.  
  390. Each NAME is assumed to be in the calling package. See share_from
  391. for an alternative method (which share uses).
  392.  
  393. =item share_from (PACKAGE, ARRAYREF)
  394.  
  395. This method is similar to share() but allows you to explicitly name the
  396. package that symbols should be shared from. The symbol names (including
  397. type characters) are supplied as an array reference.
  398.  
  399.     $safe->share_from('main', [ '$foo', '%bar', 'func' ]);
  400.  
  401.  
  402. =item varglob (VARNAME)
  403.  
  404. This returns a glob reference for the symbol table entry of VARNAME in
  405. the package of the compartment. VARNAME must be the B<name> of a
  406. variable without any leading type marker. For example,
  407.  
  408.     $cpt = new Safe 'Root';
  409.     $Root::foo = "Hello world";
  410.     # Equivalent version which doesn't need to know $cpt's package name:
  411.     ${$cpt->varglob('foo')} = "Hello world";
  412.  
  413.  
  414. =item reval (STRING)
  415.  
  416. This evaluates STRING as perl code inside the compartment.
  417.  
  418. The code can only see the compartment's namespace (as returned by the
  419. B<root> method). The compartment's root package appears to be the
  420. C<main::> package to the code inside the compartment.
  421.  
  422. Any attempt by the code in STRING to use an operator which is not permitted
  423. by the compartment will cause an error (at run-time of the main program
  424. but at compile-time for the code in STRING).  The error is of the form
  425. "%s trapped by operation mask operation...".
  426.  
  427. If an operation is trapped in this way, then the code in STRING will
  428. not be executed. If such a trapped operation occurs or any other
  429. compile-time or return error, then $@ is set to the error message, just
  430. as with an eval().
  431.  
  432. If there is no error, then the method returns the value of the last
  433. expression evaluated, or a return statement may be used, just as with
  434. subroutines and B<eval()>. The context (list or scalar) is determined
  435. by the caller as usual.
  436.  
  437. This behaviour differs from the beta distribution of the Safe extension
  438. where earlier versions of perl made it hard to mimic the return
  439. behaviour of the eval() command and the context was always scalar.
  440.  
  441. Some points to note:
  442.  
  443. If the entereval op is permitted then the code can use eval "..." to
  444. 'hide' code which might use denied ops. This is not a major problem
  445. since when the code tries to execute the eval it will fail because the
  446. opmask is still in effect. However this technique would allow clever,
  447. and possibly harmful, code to 'probe' the boundaries of what is
  448. possible.
  449.  
  450. Any string eval which is executed by code executing in a compartment,
  451. or by code called from code executing in a compartment, will be eval'd
  452. in the namespace of the compartment. This is potentially a serious
  453. problem.
  454.  
  455. Consider a function foo() in package pkg compiled outside a compartment
  456. but shared with it. Assume the compartment has a root package called
  457. 'Root'. If foo() contains an eval statement like eval '$foo = 1' then,
  458. normally, $pkg::foo will be set to 1.  If foo() is called from the
  459. compartment (by whatever means) then instead of setting $pkg::foo, the
  460. eval will actually set $Root::pkg::foo.
  461.  
  462. This can easily be demonstrated by using a module, such as the Socket
  463. module, which uses eval "..." as part of an AUTOLOAD function. You can
  464. 'use' the module outside the compartment and share an (autoloaded)
  465. function with the compartment. If an autoload is triggered by code in
  466. the compartment, or by any code anywhere that is called by any means
  467. from the compartment, then the eval in the Socket module's AUTOLOAD
  468. function happens in the namespace of the compartment. Any variables
  469. created or used by the eval'd code are now under the control of
  470. the code in the compartment.
  471.  
  472. A similar effect applies to I<all> runtime symbol lookups in code
  473. called from a compartment but not compiled within it.
  474.  
  475.  
  476.  
  477. =item rdo (FILENAME)
  478.  
  479. This evaluates the contents of file FILENAME inside the compartment.
  480. See above documentation on the B<reval> method for further details.
  481.  
  482. =item root (NAMESPACE)
  483.  
  484. This method returns the name of the package that is the root of the
  485. compartment's namespace.
  486.  
  487. Note that this behaviour differs from version 1.00 of the Safe module
  488. where the root module could be used to change the namespace. That
  489. functionality has been withdrawn pending deeper consideration.
  490.  
  491. =item mask (MASK)
  492.  
  493. This is a get-or-set method for the compartment's operator mask.
  494.  
  495. With no MASK argument present, it returns the current operator mask of
  496. the compartment.
  497.  
  498. With the MASK argument present, it sets the operator mask for the
  499. compartment (equivalent to calling the deny_only method).
  500.  
  501. =back
  502.  
  503.  
  504. =head2 Some Safety Issues
  505.  
  506. This section is currently just an outline of some of the things code in
  507. a compartment might do (intentionally or unintentionally) which can
  508. have an effect outside the compartment.
  509.  
  510. =over 8
  511.  
  512. =item Memory
  513.  
  514. Consuming all (or nearly all) available memory.
  515.  
  516. =item CPU
  517.  
  518. Causing infinite loops etc.
  519.  
  520. =item Snooping
  521.  
  522. Copying private information out of your system. Even something as
  523. simple as your user name is of value to others. Much useful information
  524. could be gleaned from your environment variables for example.
  525.  
  526. =item Signals
  527.  
  528. Causing signals (especially SIGFPE and SIGALARM) to affect your process.
  529.  
  530. Setting up a signal handler will need to be carefully considered
  531. and controlled.  What mask is in effect when a signal handler
  532. gets called?  If a user can get an imported function to get an
  533. exception and call the user's signal handler, does that user's
  534. restricted mask get re-instated before the handler is called?
  535. Does an imported handler get called with its original mask or
  536. the user's one?
  537.  
  538. =item State Changes
  539.  
  540. Ops such as chdir obviously effect the process as a whole and not just
  541. the code in the compartment. Ops such as rand and srand have a similar
  542. but more subtle effect.
  543.  
  544. =back
  545.  
  546. =head2 AUTHOR
  547.  
  548. Originally designed and implemented by Malcolm Beattie,
  549. mbeattie@sable.ox.ac.uk.
  550.  
  551. Reworked to use the Opcode module and other changes added by Tim Bunce
  552. E<lt>F<Tim.Bunce@ig.co.uk>E<gt>.
  553.  
  554. =cut
  555.  
  556.