home *** CD-ROM | disk | FTP | other *** search
/ CLIX - Fazer Clix Custa Nix / CLIX-CD.cdr / mac / lib / DynaLoader.pm < prev    next >
Text File  |  1998-04-04  |  25KB  |  725 lines
  1. package DynaLoader;
  2.  
  3. #   And Gandalf said: 'Many folk like to know beforehand what is to
  4. #   be set on the table; but those who have laboured to prepare the
  5. #   feast like to keep their secret; for wonder makes the words of
  6. #   praise louder.'
  7.  
  8. #   (Quote from Tolkien sugested by Anno Siegel.)
  9. #
  10. # See pod text at end of file for documentation.
  11. # See also ext/DynaLoader/README in source tree for other information.
  12. #
  13. # Tim.Bunce@ig.co.uk, August 1994
  14.  
  15. use vars qw($VERSION);
  16.  
  17. $VERSION = "1.02";
  18.  
  19. require Carp;
  20. require Config;
  21.  
  22. require AutoLoader;
  23. *AUTOLOAD = \&AutoLoader::AUTOLOAD;
  24.  
  25. # enable debug/trace messages from DynaLoader perl code
  26. $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  27.  
  28. #
  29. # Flags to alter dl_load_file behaviour.  Assigned bits:
  30. #   0x01  make symbols available for linking later dl_load_file's.
  31. #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  32. #         (ignored under VMS; effect is built-in to image linking)
  33. #
  34. # This is called as a class method $module->dl_load_flags.  The
  35. # definition here will be inherited and result on "default" loading
  36. # behaviour unless a sub-class of DynaLoader defines its own version.
  37. #
  38.  
  39. sub dl_load_flags { 0x00 }
  40.  
  41. # 
  42.  
  43. ($dl_dlext, $dlsrc)
  44.         = @Config::Config{'dlext', 'dlsrc'};
  45.  
  46. # Some systems need special handling to expand file specifications
  47. # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  48. # See dl_expandspec() for more details. Should be harmless but
  49. # inefficient to define on systems that don't need it.
  50. $do_expand = $Is_VMS = $^O eq 'VMS';
  51. $Is_MacOS = $^O eq 'MacOS';
  52.  
  53. @dl_require_symbols = ();       # names of symbols we need
  54. @dl_resolve_using   = ();       # names of files to link with
  55. @dl_library_path    = ();       # path to look for files
  56. @dl_librefs         = ();       # things we have loaded
  57. @dl_modules         = ();       # Modules we have loaded
  58.  
  59. # This is a fix to support DLD's unfortunate desire to relink -lc
  60. @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  61.  
  62. # Initialise @dl_library_path with the 'standard' library path
  63. # for this platform as determined by Configure
  64. push(@dl_library_path, split(' ',$Config::Config{'libpth'}));
  65.  
  66. # Add to @dl_library_path any extra directories we can gather from
  67. # environment variables. So far LD_LIBRARY_PATH is the only known
  68. # variable used for this purpose. Others may be added later.
  69. if ($Is_MacOS) {
  70.     push(@dl_library_path, split(/,/, $ENV{LD_LIBRARY_PATH}))
  71.         if $ENV{LD_LIBRARY_PATH};
  72. } else {
  73.     push(@dl_library_path, split(/:/, $ENV{LD_LIBRARY_PATH}))
  74.         if $ENV{LD_LIBRARY_PATH};
  75. }
  76.  
  77. # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
  78. boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader);
  79.  
  80.  
  81. if ($dl_debug) {
  82.     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
  83.     print STDERR "DynaLoader not linked into this perl\n"
  84.             unless defined(&boot_DynaLoader);
  85. }
  86.  
  87. 1; # End of main code
  88.  
  89.  
  90. # The bootstrap function cannot be autoloaded (without complications)
  91. # so we define it here:
  92.  
  93. sub bootstrap {
  94.     # use local vars to enable $module.bs script to edit values
  95.     local(@args) = @_;
  96.     local($module) = $args[0];
  97.     local(@dirs, $file);
  98.  
  99.     Carp::confess("Usage: DynaLoader::bootstrap(module)") unless $module;
  100.  
  101.     # A common error on platforms which don't support dynamic loading.
  102.     # Since it's fatal and potentially confusing we give a detailed message.
  103.     Carp::croak("Can't load module $module, dynamic loading not available in this perl.\n".
  104.         "  (You may need to build a new perl executable which either supports\n".
  105.         "  dynamic loading or has the $module module statically linked into it.)\n")
  106.         unless defined(&dl_load_file);
  107.  
  108.     my @modparts = split(/::/,$module);
  109.     my $modfname = $modparts[-1];
  110.  
  111.     # Some systems have restrictions on files names for DLL's etc.
  112.     # mod2fname returns appropriate file base name (typically truncated)
  113.     # It may also edit @modparts if required.
  114.     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
  115.  
  116.     my $modpname = join(($Is_MacOS ? ':' : '/'),@modparts);
  117.  
  118.     if ($Is_MacOS) {
  119.         print STDERR "DynaLoader::bootstrap for $module ",
  120.             "(:auto:$modpname:$modfname)\n" if $dl_debug;
  121.     } else {
  122.         print STDERR "DynaLoader::bootstrap for $module ",
  123.             "(auto/$modpname/$modfname.$dl_dlext)\n" if $dl_debug;
  124.     }
  125.  
  126.     foreach (@INC) {
  127.         chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
  128.         if ($Is_MacOS) {
  129.             chop $_ if /:$/;
  130.         }
  131.         my $dir = ($Is_MacOS) ? "$_:auto:$modpname" : "$_/auto/$modpname";
  132.         next unless -d $dir; # skip over uninteresting directories
  133.  
  134.         # check for common cases to avoid autoload of dl_findfile
  135.         if ($Is_MacOS) {
  136.             last if -f ($file="$dir:$modfname");
  137.         } else {
  138.             last if ($file=_check_file("$dir/$modfname.$dl_dlext"));
  139.         }
  140.         
  141.         # no luck here, save dir for possible later dl_findfile search
  142.         push(@dirs, "-L$dir");
  143.     }
  144.     # last resort, let dl_findfile have a go in all known locations
  145.     $file = dl_findfile(@dirs, map("-L$_",@INC), $modfname) unless $file;
  146.  
  147.     Carp::croak("Can't find loadable object for module $module in \@INC (@INC)")
  148.         unless $file;
  149.  
  150.     my $bootname = "boot_$module";
  151.     $bootname =~ s/\W/_/g;
  152.     @dl_require_symbols = ($bootname);
  153.  
  154.     # Execute optional '.bootstrap' perl script for this module.
  155.     # The .bs file can be used to configure @dl_resolve_using etc to
  156.     # match the needs of the individual module on this architecture.
  157.     my $bs = $file;
  158.     $bs =~ s/(\.\w+)?$/\.bs/; # look for .bs 'beside' the library
  159.     if (-s $bs) { # only read file if it's not empty
  160.         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
  161.         eval { do $bs; };
  162.         warn "$bs: $@\n" if $@;
  163.     }
  164.  
  165.     # Many dynamic extension loading problems will appear to come from
  166.     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
  167.     # Often these errors are actually occurring in the initialisation
  168.     # C code of the extension XS file. Perl reports the error as being
  169.     # in this perl code simply because this was the last perl code
  170.     # it executed.
  171.  
  172.     my $libref = dl_load_file($file, $module->dl_load_flags) or
  173.         Carp::croak("Can't load '$file' for module $module: ".dl_error()."\n");
  174.  
  175.     push(@dl_librefs,$libref);  # record loaded object
  176.  
  177.     my @unresolved = dl_undef_symbols();
  178.     Carp::carp("Undefined symbols present after loading $file: @unresolved\n")
  179.         if @unresolved;
  180.  
  181.     my $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
  182.          Carp::croak("Can't find '$bootname' symbol in $file\n");
  183.  
  184.     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
  185.  
  186.     push(@dl_modules, $module); # record loaded module
  187.  
  188.     # See comment block above
  189.     &$xs(@args);
  190. }
  191.  
  192.  
  193. sub _check_file {   # private utility to handle dl_expandspec vs -f tests
  194.     my($file) = @_;
  195.     return $file if (!$do_expand && -f $file); # the common case
  196.     return $file if ( $do_expand && ($file=dl_expandspec($file)));
  197.     return undef;
  198. }
  199.  
  200.  
  201. # Let autosplit and the autoloader deal with these functions:
  202. __END__
  203.  
  204.  
  205. sub dl_findfile {
  206.     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
  207.     # This function does not automatically consider the architecture
  208.     # or the perl library auto directories.
  209.     my (@args) = @_;
  210.     my (@dirs,  $dir);   # which directories to search
  211.     my (@found);         # full paths to real files we have found
  212.     my $dl_ext= $Config::Config{'dlext'}; # suffix for perl extensions
  213.     my $dl_so = $Config::Config{'so'};  # suffix for shared libraries
  214.  
  215.     print STDERR "dl_findfile(@args)\n" if $dl_debug;
  216.  
  217.     # accumulate directories but process files as they appear
  218.     arg: foreach(@args) {
  219.         #  Special fast case: full filepath requires no search
  220.         if ($Is_VMS && m%[:>/\]]% && -f $_) {
  221.             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
  222.             last arg unless wantarray;
  223.             next;
  224.         }
  225.         elsif ($Is_MacOS && m/:/ && -f $_) {
  226.             push(@found,$_);
  227.             last arg unless wantarray;
  228.             next;
  229.         }
  230.         elsif (m:/: && -f $_ && !$do_expand) {
  231.             push(@found,$_);
  232.             last arg unless wantarray;
  233.             next;
  234.         }
  235.  
  236.         # Deal with directories first:
  237.         #  Using a -L prefix is the preferred option (faster and more robust)
  238.         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
  239.  
  240.         if ($Is_MacOS) {
  241.              #  Otherwise we try to try to spot directories by a heuristic
  242.              #  (this is a more complicated issue than it first appears)
  243.              if (m/:/ && -d $_) {   push(@dirs, $_); next; }
  244.  
  245.             #  Only files should get this far...
  246.             my(@names, $name);    # what filenames to look for
  247.             if (m:-l: ) {          # convert -lname to appropriate library name
  248.                 s/-l//;
  249.                 push(@names,"$_");
  250.             } else {                # Umm, a bare name. Try various alternatives:
  251.                 push(@names, $_);
  252.             }
  253.             foreach $dir (@dirs, @dl_library_path) {
  254.                 next unless -d $dir;
  255.                 $dir =~ s/:$//;
  256.                 $dir =~ s/^([^:]+)$/:$1/;
  257.                 foreach $name (@names) {
  258.                     my($file) = "$dir:$name";
  259.                     print STDERR " checking in $dir for $name\n" if $dl_debug;
  260.                     if (-f $file) {
  261.                         push(@found, $file);
  262.                         next arg; # no need to look any further
  263.                     }
  264.                 }
  265.             }
  266.         } else {
  267.             #  Otherwise we try to try to spot directories by a heuristic
  268.             #  (this is a more complicated issue than it first appears)
  269.             if (m:/: && -d $_) {   push(@dirs, $_); next; }
  270.  
  271.             #  Only files should get this far...
  272.             my(@names, $name);    # what filenames to look for
  273.             if (m:-l: ) {          # convert -lname to appropriate library name
  274.                 s/-l//;
  275.                 push(@names,"lib$_.$dl_so");
  276.                 push(@names,"lib$_.a");
  277.            } else {                # Umm, a bare name. Try various alternatives:
  278.                 # these should be ordered with the most likely first
  279.                 push(@names,"$_.$dl_ext")    unless m/\.$dl_ext$/o;
  280.                 push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
  281.                 push(@names,"lib$_.$dl_so")  unless m:/:;
  282.                 push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
  283.                 push(@names, $_);
  284.             }
  285.             foreach $dir (@dirs, @dl_library_path) {
  286.                 next unless -d $dir;
  287.                 chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
  288.                 foreach $name (@names) {
  289.                     my($file) = "$dir/$name";
  290.                     print STDERR " checking in $dir for $name\n" if $dl_debug;
  291.                     $file = _check_file($file);
  292.                     if ($file) {
  293.                         push(@found, $file);
  294.                         next arg; # no need to look any further
  295.                     }
  296.                 }
  297.             }
  298.         }
  299.     }
  300.     if ($dl_debug) {
  301.         foreach(@dirs) {
  302.             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
  303.         }
  304.         print STDERR "dl_findfile found: @found\n";
  305.     }
  306.     return $found[0] unless wantarray;
  307.     @found;
  308. }
  309.  
  310.  
  311. sub dl_expandspec {
  312.     my($spec) = @_;
  313.     # Optional function invoked if DynaLoader.pm sets $do_expand.
  314.     # Most systems do not require or use this function.
  315.     # Some systems may implement it in the dl_*.xs file in which case
  316.     # this autoload version will not be called but is harmless.
  317.  
  318.     # This function is designed to deal with systems which treat some
  319.     # 'filenames' in a special way. For example VMS 'Logical Names'
  320.     # (something like unix environment variables - but different).
  321.     # This function should recognise such names and expand them into
  322.     # full file paths.
  323.     # Must return undef if $spec is invalid or file does not exist.
  324.  
  325.     my $file = $spec; # default output to input
  326.  
  327.     if ($Is_VMS) { # dl_expandspec should be defined in dl_vms.xs
  328.         Carp::croak("dl_expandspec: should be defined in XS file!\n");
  329.     } else {
  330.         return undef unless -f $file;
  331.     }
  332.     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
  333.     $file;
  334. }
  335.  
  336. sub dl_find_symbol_anywhere
  337. {
  338.     my $sym = shift;
  339.     my $libref;
  340.     foreach $libref (@dl_librefs) {
  341.         my $symref = dl_find_symbol($libref,$sym);
  342.         return $symref if $symref;
  343.     }
  344.     return undef;
  345. }
  346.  
  347. =head1 NAME
  348.  
  349. DynaLoader - Dynamically load C libraries into Perl code
  350.  
  351. dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_find_symbol(), dl_find_symbol_anywhere(), dl_undef_symbols(), dl_install_xsub(), dl_load_flags(), bootstrap() - routines used by DynaLoader modules
  352.  
  353. =head1 SYNOPSIS
  354.  
  355.     package YourPackage;
  356.     require DynaLoader;
  357.     @ISA = qw(... DynaLoader ...);
  358.     bootstrap YourPackage;
  359.  
  360.     # optional method for 'global' loading
  361.     sub dl_load_flags { 0x01 }     
  362.  
  363.  
  364. =head1 DESCRIPTION
  365.  
  366. This document defines a standard generic interface to the dynamic
  367. linking mechanisms available on many platforms.  Its primary purpose is
  368. to implement automatic dynamic loading of Perl modules.
  369.  
  370. This document serves as both a specification for anyone wishing to
  371. implement the DynaLoader for a new platform and as a guide for
  372. anyone wishing to use the DynaLoader directly in an application.
  373.  
  374. The DynaLoader is designed to be a very simple high-level
  375. interface that is sufficiently general to cover the requirements
  376. of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
  377.  
  378. It is also hoped that the interface will cover the needs of OS/2, NT
  379. etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
  380.  
  381. It must be stressed that the DynaLoader, by itself, is practically
  382. useless for accessing non-Perl libraries because it provides almost no
  383. Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
  384. library function or supplying arguments.  It is anticipated that any
  385. glue that may be developed in the future will be implemented in a
  386. separate dynamically loaded module.
  387.  
  388. DynaLoader Interface Summary
  389.  
  390.   @dl_library_path
  391.   @dl_resolve_using
  392.   @dl_require_symbols
  393.   $dl_debug
  394.   @dl_librefs
  395.   @dl_modules
  396.                                                   Implemented in:
  397.   bootstrap($modulename)                               Perl
  398.   @filepaths = dl_findfile(@names)                     Perl
  399.   $flags = $modulename->dl_load_flags                  Perl
  400.   $symref  = dl_find_symbol_anywhere($symbol)          Perl
  401.  
  402.   $libref  = dl_load_file($filename, $flags)           C
  403.   $symref  = dl_find_symbol($libref, $symbol)          C
  404.   @symbols = dl_undef_symbols()                        C
  405.   dl_install_xsub($name, $symref [, $filename])        C
  406.   $message = dl_error                                  C
  407.  
  408. =over 4
  409.  
  410. =item @dl_library_path
  411.  
  412. The standard/default list of directories in which dl_findfile() will
  413. search for libraries etc.  Directories are searched in order:
  414. $dl_library_path[0], [1], ... etc
  415.  
  416. @dl_library_path is initialised to hold the list of 'normal' directories
  417. (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
  418. ensure portability across a wide range of platforms.
  419.  
  420. @dl_library_path should also be initialised with any other directories
  421. that can be determined from the environment at runtime (such as
  422. LD_LIBRARY_PATH for SunOS).
  423.  
  424. After initialisation @dl_library_path can be manipulated by an
  425. application using push and unshift before calling dl_findfile().
  426. Unshift can be used to add directories to the front of the search order
  427. either to save search time or to override libraries with the same name
  428. in the 'normal' directories.
  429.  
  430. The load function that dl_load_file() calls may require an absolute
  431. pathname.  The dl_findfile() function and @dl_library_path can be
  432. used to search for and return the absolute pathname for the
  433. library/object that you wish to load.
  434.  
  435. =item @dl_resolve_using
  436.  
  437. A list of additional libraries or other shared objects which can be
  438. used to resolve any undefined symbols that might be generated by a
  439. later call to load_file().
  440.  
  441. This is only required on some platforms which do not handle dependent
  442. libraries automatically.  For example the Socket Perl extension
  443. library (F<auto/Socket/Socket.so>) contains references to many socket
  444. functions which need to be resolved when it's loaded.  Most platforms
  445. will automatically know where to find the 'dependent' library (e.g.,
  446. F</usr/lib/libsocket.so>).  A few platforms need to be told the
  447. location of the dependent library explicitly.  Use @dl_resolve_using
  448. for this.
  449.  
  450. Example usage:
  451.  
  452.     @dl_resolve_using = dl_findfile('-lsocket');
  453.  
  454. =item @dl_require_symbols
  455.  
  456. A list of one or more symbol names that are in the library/object file
  457. to be dynamically loaded.  This is only required on some platforms.
  458.  
  459. =item @dl_librefs
  460.  
  461. An array of the handles returned by successful calls to dl_load_file(),
  462. made by bootstrap, in the order in which they were loaded.
  463. Can be used with dl_find_symbol() to look for a symbol in any of
  464. the loaded files.
  465.  
  466. =item @dl_modules
  467.  
  468. An array of module (package) names that have been bootstrap'ed.
  469.  
  470. =item dl_error()
  471.  
  472. Syntax:
  473.  
  474.     $message = dl_error();
  475.  
  476. Error message text from the last failed DynaLoader function.  Note
  477. that, similar to errno in unix, a successful function call does not
  478. reset this message.
  479.  
  480. Implementations should detect the error as soon as it occurs in any of
  481. the other functions and save the corresponding message for later
  482. retrieval.  This will avoid problems on some platforms (such as SunOS)
  483. where the error message is very temporary (e.g., dlerror()).
  484.  
  485. =item $dl_debug
  486.  
  487. Internal debugging messages are enabled when $dl_debug is set true.
  488. Currently setting $dl_debug only affects the Perl side of the
  489. DynaLoader.  These messages should help an application developer to
  490. resolve any DynaLoader usage problems.
  491.  
  492. $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
  493.  
  494. For the DynaLoader developer/porter there is a similar debugging
  495. variable added to the C code (see dlutils.c) and enabled if Perl was
  496. built with the B<-DDEBUGGING> flag.  This can also be set via the
  497. PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
  498. higher for more.
  499.  
  500. =item dl_findfile()
  501.  
  502. Syntax:
  503.  
  504.     @filepaths = dl_findfile(@names)
  505.  
  506. Determine the full paths (including file suffix) of one or more
  507. loadable files given their generic names and optionally one or more
  508. directories.  Searches directories in @dl_library_path by default and
  509. returns an empty list if no files were found.
  510.  
  511. Names can be specified in a variety of platform independent forms.  Any
  512. names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
  513. an appropriate suffix for the platform.
  514.  
  515. If a name does not already have a suitable prefix and/or suffix then
  516. the corresponding file will be searched for by trying combinations of
  517. prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
  518. and "$name".
  519.  
  520. If any directories are included in @names they are searched before
  521. @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
  522. names are treated as filenames to be searched for.
  523.  
  524. Using arguments of the form C<-Ldir> and C<-lname> is recommended.
  525.  
  526. Example: 
  527.  
  528.     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
  529.  
  530.  
  531. =item dl_expandspec()
  532.  
  533. Syntax:
  534.  
  535.     $filepath = dl_expandspec($spec)
  536.  
  537. Some unusual systems, such as VMS, require special filename handling in
  538. order to deal with symbolic names for files (i.e., VMS's Logical Names).
  539.  
  540. To support these systems a dl_expandspec() function can be implemented
  541. either in the F<dl_*.xs> file or code can be added to the autoloadable
  542. dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
  543. more information.
  544.  
  545. =item dl_load_file()
  546.  
  547. Syntax:
  548.  
  549.     $libref = dl_load_file($filename, $flags)
  550.  
  551. Dynamically load $filename, which must be the path to a shared object
  552. or library.  An opaque 'library reference' is returned as a handle for
  553. the loaded object.  Returns undef on error.
  554.  
  555. The $flags argument to alters dl_load_file behaviour.  
  556. Assigned bits:
  557.  
  558.  0x01  make symbols available for linking later dl_load_file's.
  559.        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  560.        (ignored under VMS; this is a normal part of image linking)
  561.  
  562. (On systems that provide a handle for the loaded object such as SunOS
  563. and HPUX, $libref will be that handle.  On other systems $libref will
  564. typically be $filename or a pointer to a buffer containing $filename.
  565. The application should not examine or alter $libref in any way.)
  566.  
  567. This is the function that does the real work.  It should use the
  568. current values of @dl_require_symbols and @dl_resolve_using if required.
  569.  
  570.     SunOS: dlopen($filename)
  571.     HP-UX: shl_load($filename)
  572.     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
  573.     NeXT:  rld_load($filename, @dl_resolve_using)
  574.     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
  575.  
  576. (The dlopen() function is also used by Solaris and some versions of
  577. Linux, and is a common choice when providing a "wrapper" on other
  578. mechanisms as is done in the OS/2 port.)
  579.  
  580. =item dl_loadflags()
  581.  
  582. Syntax:
  583.  
  584.     $flags = dl_loadflags $modulename;
  585.  
  586. Designed to be a method call, and to be overridden by a derived class
  587. (i.e. a class which has DynaLoader in its @ISA).  The definition in
  588. DynaLoader itself returns 0, which produces standard behavior from
  589. dl_load_file().
  590.  
  591. =item dl_find_symbol()
  592.  
  593. Syntax:
  594.  
  595.     $symref = dl_find_symbol($libref, $symbol)
  596.  
  597. Return the address of the symbol $symbol or C<undef> if not found.  If the
  598. target system has separate functions to search for symbols of different
  599. types then dl_find_symbol() should search for function symbols first and
  600. then other types.
  601.  
  602. The exact manner in which the address is returned in $symref is not
  603. currently defined.  The only initial requirement is that $symref can
  604. be passed to, and understood by, dl_install_xsub().
  605.  
  606.     SunOS: dlsym($libref, $symbol)
  607.     HP-UX: shl_findsym($libref, $symbol)
  608.     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
  609.     NeXT:  rld_lookup("_$symbol")
  610.     VMS:   lib$find_image_symbol($libref,$symbol)
  611.  
  612.  
  613. =item dl_find_symbol_anywhere()
  614.  
  615. Syntax:
  616.  
  617.     $symref = dl_find_symbol_anywhere($symbol)
  618.  
  619. Applies dl_find_symbol() to the members of @dl_librefs and returns
  620. the first match found.
  621.  
  622. =item dl_undef_symbols()
  623.  
  624. Example
  625.  
  626.     @symbols = dl_undef_symbols()
  627.  
  628. Return a list of symbol names which remain undefined after load_file().
  629. Returns C<()> if not known.  Don't worry if your platform does not provide
  630. a mechanism for this.  Most do not need it and hence do not provide it,
  631. they just return an empty list.
  632.  
  633.  
  634. =item dl_install_xsub()
  635.  
  636. Syntax:
  637.  
  638.     dl_install_xsub($perl_name, $symref [, $filename])
  639.  
  640. Create a new Perl external subroutine named $perl_name using $symref as
  641. a pointer to the function which implements the routine.  This is simply
  642. a direct call to newXSUB().  Returns a reference to the installed
  643. function.
  644.  
  645. The $filename parameter is used by Perl to identify the source file for
  646. the function if required by die(), caller() or the debugger.  If
  647. $filename is not defined then "DynaLoader" will be used.
  648.  
  649.  
  650. =item bootstrap()
  651.  
  652. Syntax:
  653.  
  654. bootstrap($module)
  655.  
  656. This is the normal entry point for automatic dynamic loading in Perl.
  657.  
  658. It performs the following actions:
  659.  
  660. =over 8
  661.  
  662. =item *
  663.  
  664. locates an auto/$module directory by searching @INC
  665.  
  666. =item *
  667.  
  668. uses dl_findfile() to determine the filename to load
  669.  
  670. =item *
  671.  
  672. sets @dl_require_symbols to C<("boot_$module")>
  673.  
  674. =item *
  675.  
  676. executes an F<auto/$module/$module.bs> file if it exists
  677. (typically used to add to @dl_resolve_using any files which
  678. are required to load the module on the current platform)
  679.  
  680. =item *
  681.  
  682. calls dl_load_flags() to determine how to load the file.
  683.  
  684. =item *
  685.  
  686. calls dl_load_file() to load the file
  687.  
  688. =item *
  689.  
  690. calls dl_undef_symbols() and warns if any symbols are undefined
  691.  
  692. =item *
  693.  
  694. calls dl_find_symbol() for "boot_$module"
  695.  
  696. =item *
  697.  
  698. calls dl_install_xsub() to install it as "${module}::bootstrap"
  699.  
  700. =item *
  701.  
  702. calls &{"${module}::bootstrap"} to bootstrap the module (actually
  703. it uses the function reference returned by dl_install_xsub for speed)
  704.  
  705. =back
  706.  
  707. =back
  708.  
  709.  
  710. =head1 AUTHOR
  711.  
  712. Tim Bunce, 11 August 1994.
  713.  
  714. This interface is based on the work and comments of (in no particular
  715. order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
  716. Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
  717.  
  718. Larry Wall designed the elegant inherited bootstrap mechanism and
  719. implemented the first Perl 5 dynamic loader using it.
  720.  
  721. Solaris global loading added by Nick Ing-Simmons with design/coding
  722. assistance from Tim Bunce, January 1996.
  723.  
  724. =cut
  725.