home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 5
/
FREESOFT.BIN
/
mopterm
/
fapx405b
/
fapxview.plp
< prev
Wrap
Text File
|
1992-08-19
|
22KB
|
917 lines
/* 全てのメモをクローズする */
%CloseAllMemo{
case(@mlast!=0 && @mcheck==0,{Yes},{mopen(1)});
case(@mcheck!=0,{Yes},{loop({mclose(2);im(@mcheck!=0)})});
};
/* 指定ディレクトリのサブディレクトリ名を返す */
%subdir {
[dir,sdir]
case (@nochar(dir)==3,
{Yes}, {im(dir|sdir)},
{No}, {im(dir|{\}|sdir)}
);
};
%ViewLOG{
[logdir,memono]
/* 1ログファイルの表示処理 */
%Select1{
%LineNo @xlinenum;
%MemoLine @nolmemo(memono);
%line1 @case (LineNo>MemoLine,
{Yes},{im(@memo(memono,MemoLine,1))},
{No},
{case(LineNo<=0,
{Yes},{im(@memo(memono,1,1))},
{No},{im(@memo(memono,LineNo,1))})
});
case (@body(line1,{<},{>})={DIR},
{Yes},
{ViewLOG(@subdir(logdir,
@head(@getchar(line1,1,8),{ })),
memono+1)},
{No},
{
case (@getchar(line1,10,3),
{LZH},
{ViewLZH(@subdir(logdir,
@head(@getchar(line1,1,8),{ })),
memono+1)},
{NAP},
{ViewNAP(@subdir(logdir,@head(@getchar
(line1,1,8),{ })|{.NAP}),
memono)},
{NPB},
{ViewNAP(@subdir(logdir,@head(@getchar
(line1,1,8),{ })|{.NAP}),
memono)},
,
{
case (@getchar(line1,10,3)<>{ },
{Yes},
{LOGFILE:=@subdir(logdir,
@head(@getchar(line1,1,8),{ })|
{.}|
@head(@getchar(line1,10,3),{ }))
},
{No},
{LOGFILE:=@subdir(logdir,
@head(@getchar(line1,1,8),{ }))
}
);
%m1 memono+1;
CloseAllMemo;
case(@mlast>=m1,{Yes},{mclear(m1)});
mread(LOGFILE,m1);
mopen(m1,0,21,639,459,{w});
loop ({
footnote({終了削除更新コメント},{b});
waitx();
case (@xtype,
101,
{CloseAllMemo;footnote({});
im({No})},
201,
{CloseAllMemo;footnote({});
im({No})},
102,delLOG, 202,delLOG,
103,updLOG, 203,updLOG,
104,{COMMENT(m1)},
204,{COMMENT(m1)},
m1,{COMMENT(m1)},
,{im({Yes})});
});
});
});
im({Yes});
};
/* ログファイル名の変更処理 */
%Rename1{
footnote({ファイル名を変更しています});
%LineNo @xlinenum;
%MemoLine @nolmemo(memono);
%line1 @case (LineNo>MemoLine,
{Yes},{im(@memo(memono,MemoLine,1))},
{No},
{case(LineNo<=0,
{Yes},{im(@memo(memono,1,1))},
{No},{im(@memo(memono,LineNo,1))})
});
case (@body(line1,{<},{>})={DIR},
{Yes},
{display({ディレクトリ名は変更できません\n})},
{No},
{
var file [64];
case (@getchar(line1,10,3)<>{ },
{Yes},
{file:=@subdir(logdir,
@head(@getchar(line1,1,8),{ })|
{.}|@head(@getchar(line1,10,3),{ }))
},
{No},
{file:=@subdir(logdir,
@head(@getchar(line1,1,8),{ }))
}
);
SNDMSG({nyuryo_f.snd});
footnote({新しいファイル名を入力して下さい});
%file2 @input({新しいファイル名を入力して下さい},,
@tail(file,{\}));
footnote({ファイル名を変更しています});
dispoff({Yes});
command({rename }|file|{ }|file2);
command({dir }|logdir|{>}|TEMP2|{_mopdir.tmp});
dispoff({No});
case(@mlast>=memono,{Yes},{mclear(memono)});
madd(memono,@read(TEMP2|{_mopdir.tmp},7,lineno-9));
mopen(memono,0,21,639,459,{r});
});
im({Yes});
};
/* ログファイルの複写処理 */
%Copy1 {
footnote({ファイルを複写します});
%LineNo @xlinenum;
%MemoLine @nolmemo(memono);
%line1 @case (LineNo>MemoLine,
{Yes},{im(@memo(memono,MemoLine,1))},
{No},
{case(LineNo<=0,
{Yes},{im(@memo(memono,1,1))},
{No},{im(@memo(memono,LineNo,1))})
});
case (@body(line1,{<},{>})={DIR},
{Yes},
{display({ディレクトリは複写できません\n})},
{No},
{
case (@getchar(line1,10,3)<>{ },
{Yes},
{LOGFILE:=@subdir(logdir,
@head(@getchar(line1,1,8),{ })|
{.}|@head(@getchar(line1,10,3),{ }))
},
{No},
{LOGFILE:=@subdir(logdir,
@head(@getchar(line1,1,8),{ }))
}
);
SNDMSG({erande_f.snd});
footnote({複写先のファイルを指定して下さい});
%file2 @filesel;
footnote({ファイルを複写します});
dispoff({Yes});
command({copy }|LOGFILE|{ }|file2);
dispoff({No});
mopen(memono,0,21,639,459,{r});
});
im({Yes});
};
/* ディレクトリ表示と選択処理 */
%viewlog1{
case(@mlast>=memono,{Yes},{mclear(memono)});
madd(memono,@read(TEMP2|{_mopdir.tmp},7,lineno-9));
mopen(memono,0,21,639,459,{r});
SNDMSG({erande_f.snd});
footnote({終了選択改名複写},{b});
waitx(60);
case (@xtype,
memono,Select1,
101,{im({No})}, 201,{im({No})},
102,Select1, 202,Select1,
103,Rename1, 203,Rename1,
104,Copy1, 204,Copy1,
,{im({Yes})});
};
/* ViewLOG のメイン処理 */
fn:=@tail(logdir,{\});
loop ({
CloseAllMemo;
dispoff({Yes});
command({dir }|logdir|{>}|TEMP2|{_mopdir.tmp});
dispoff({No});
%lineno @noline(@read(TEMP2|{_mopdir.tmp}));
case (lineno>9,
{Yes},viewlog1,
{No},{display(logdir|{ は空です\n});im({No})});
});
/* ログ参照に使用したメモの削除処理 */
CloseAllMemo;
loop ({
case (@mlast>=memono,
{Yes},{mopen(@mlast);mclose(3);im({Yes})},
{No},{im({No})});
});
setcdir(CDIR);
};
/* 圧縮ファイルの表示処理 */
%ViewLZH{
[lzhfile,memono]
/* 1ログファイルの表示処理 */
%select1{
%LineNo @xlinenum;
%MemoLine @nolmemo(memono);
%line1 @case (LineNo>MemoLine,
{Yes},{im(@memo(memono,MemoLine,1))},
{No},
{case(LineNo<=0,
{Yes},{im(@memo(memono,1,1))},
{No},{im(@memo(memono,LineNo,1))})
});
%lzhfile1 @getchar(line1,3,12);
setcdir(TEMP);
dispoff({Yes});
command({del }|lzhfile1);
command(ARCHIVER|{ E }|lzhfile|{ }|lzhfile1);
dispoff({No});
case (@body(lzhfile1,{.}),
{NAP},{ViewNAP(TEMP2|lzhfile1,memono)},
{NPB},{ViewNAP(TEMP2|lzhfile1,memono)},
,
{
%m1 memono+1;
CloseAllMemo;
case(@mlast>=m1,{Yes},{mclear(m1)});
LOGFILE:=TEMP2|lzhfile1;
mread(lzhfile1,m1);
mopen(m1,0,21,639,459,{w});
loop ({
footnote({終了削除更新コメント},{b});
waitx();
case (@xtype,
101,{CloseAllMemo;im({No})},
201,{CloseAllMemo;im({No})},
102,delLZH, 202,delLZH,
103,updLZH, 203,updLZH,
104,{COMMENT(m1)},204,{COMMENT(m1)},
m1,{COMMENT(m1)},
,{im({Yes})});
});
footnote({});
setcdir(TEMP);
dispoff({Yes});
command({del }|lzhfile1);
dispoff({No});
im({Yes});
});
};
/* ログファイル名の変更処理 */
%rename1{
footnote({ファイル名を変更します});
%LineNo @xlinenum;
%MemoLine @nolmemo(memono);
%line1 @case (LineNo>MemoLine,
{Yes},{im(@memo(memono,MemoLine,1))},
{No},
{case(LineNo<=0,
{Yes},{im(@memo(memono,1,1))},
{No},{im(@memo(memono,LineNo,1))})
});
var file [64];
file:=@head(@getchar(line1,3,12),{ });
SNDMSG({nyuryo_f.snd});
footnote({新しいファイル名を入力して下さい});
%file2 @input({新しいファイル名を入力して下さい},,
@tail(file,{\}));
footnote({ファイル名を変更します});
case (file2<>{},{Yes},
{
setcdir(TEMP);
dispoff({Yes});
command(ARCHIVER|{ e }|lzhfile|{ }|file);
command({rename }|file|{ }|file2);
command(ARCHIVER|{ a }|lzhfile|{ }|file2);
command(ARCHIVER|{ d }|lzhfile|{ }|file);
command({del }|file2);
command(ARCHIVER|{ }|lzhfile|{>}|TEMP2|{_lzhdir.tmp});
dispoff({No});
});
CloseAllMemo;
case(@mlast>=memono,{Yes},{mclear(memono)});
madd(memono,@read(TEMP2|{_lzhdir.tmp},6,lineno-8));
mopen(memono,0,21,639,459,{r});
im({Yes});
};
/* ログファイルの解凍処理 */
%copy1 {
footnote({ファイルを解凍します});
%LineNo @xlinenum;
%MemoLine @nolmemo(memono);
%line1 @case (LineNo>MemoLine,
{Yes},{im(@memo(memono,MemoLine,1))},
{No},
{case(LineNo<=0,
{Yes},{im(@memo(memono,1,1))},
{No},{im(@memo(memono,LineNo,1))})
});
var file [64];
file:=@head(@getchar(line1,3,12),{ });
SNDMSG({erande_f.snd});
footnote({解凍先のファイルを指定して下さい});
%file2 @filesel;
footnote({ファイルを解凍します});
case(file2<>{},{Yes},
{
dispoff({Yes});
command(ARCHIVER|{ e }|lzhfile|{ }|file);
case (file<>file2 && file2<>{*.*} && file2<>{},
{Yes},{command({ren }|file|{ }|file2)});
dispoff({No});
});
im({Yes});
};
/* 圧縮ファイル内容の表示と選択処理 */
%viewlzh1{
case(@mlast>=memono,{Yes},{mclear(memono)});
madd(memono,@read(TEMP2|{_lzhdir.tmp},6,lineno-8));
mopen(memono,0,21,639,459,{r});
SNDMSG({erande_f.snd});
footnote({終了選択改名解凍},{b});
waitx(60);
case (@xtype,
memono,select1,
101,{im({No})}, 201,{im({No})},
102,select1, 202,select1,
103,rename1, 203,rename1,
104,copy1, 204,copy1,
,{im({Yes})});
};
/* ViewLZHのメイン処理 */
fn:=@tail(lzhfile,{\},{.});
loop ({
dispoff({Yes});
command(ARCHIVER|{ }|lzhfile|{>}|TEMP2|{_lzhdir.tmp});
dispoff({No});
%lineno @noline(@read(TEMP2|{_lzhdir.tmp}));
CloseAllMemo;
case (lineno>8,
{Yes},viewlzh1,
{No},{display(lzhfile|{ はありません\n});im({No})});
});
CloseAllMemo;
};
/* 非圧縮ログファイルの削除処理 */
%delLOG {
footnote({ログファイルを削除します});
SNDMSG({kaknin_f.snd});
select ({現在表示しているログファイルを削除します},
Wtime4,{im({Yes})},
{ 削除する },
{
CloseAllMemo;
dispoff({Yes});
command({del }|LOGFILE);
dispoff({No});
im({No});
},
{ 削除しない },
{im({Yes})}
);
};
/* 非圧縮ログファイルの更新処理 */
%updLOG {
footnote({ログファイルを更新します});
SNDMSG({kaknin_f.snd});
select ({現在表示しているログファイルを更新します},
Wtime4,{im({Yes})},
{ 更新する },
{
CloseAllMemo;
dispoff({Yes});
command({del }|LOGFILE);
mwrite(file,memono+1);
command({dir }|logdir|{>}|TEMP2|{_mopdir.tmp});
dispoff({No});
im({No});
},
{ 更新しない },
{im({Yes})}
);
};
/* 圧縮モードのログファイルを削除する */
%delLZH {
footnote({ログファイルを削除します});
SNDMSG({kaknin_f.snd});
select({現在表示しているログファイルを削除します},
Wtime4,{im({Yes})},
{ 削除する },
{
CloseAllMemo;
dispoff({Yes});
command(ARCHIVER|{ d }|lzhfile|{ }|lzhfile1);
dispoff({No});
im({No});
},
{ 削除しない },
{im({Yes})}
);
};
/* 圧縮モードのログファイルを更新する */
%updLZH {
footnote({ログファイルを更新します});
SNDMSG({kaknin_f.snd});
select ({現在表示しているログファイルを更新します},
Wtime4,{im({Yes})},
{ 更新する },
{
CloseAllMemo;
dispoff({Yes});
command({del }|lzhfile1);
mwrite(lzhfile1,memono+1);
command(ARCHIVER|{ u }|lzhfile|{ }|lzhfile1);
command(ARCHIVER|{ }|lzhfile|{>}|TEMP2|{_lzhdir.tmp});
dispoff({No});
im({No});
},
{ 更新しない },
{im({Yes})}
);
};
/* コメント作成処理の振り分け */
%COMMENT{
[memono]
%LineNo @xlinenum;
%MemoLine @nolmemo(memono);
case (LineNo>=MemoLine,
{Yes},{l1:=@memo(memono,MemoLine-1,1)},
{No},
{case (LineNo<=0,
{Yes},{l1:=@memo(memono,1,1)},
{No},{l1:=@memo(memono,LineNo,1)})
});
case (LineNo>MemoLine,
{Yes},{l2:=@memo(memono,MemoLine,1)},
{No},
{case (LineNo<=1,
{Yes},{l2:=@memo(memono,2,1)},
{No},{l2:=@memo(memono,LineNo+1,1)})
});
case (@getchar(l1,4,1)={/}&&@getchar(l2,1,1)={(},
{Yes}, {resMES(memono)},
{No}, {
case (@getchar(l1,1,3)={- F}&&@getchar(l2,4,1)={/},
{Yes}, {sayMES(memono)},
{No}, {
case (@getchar(l2,5,6)={題名:},
{Yes}, {resMAIL(memono)},
{No}, {
case (@getchar(l1,18,1)={/}&&@getchar(l1,21,1)={/},
{Yes}, {downDLIB},
{No}, {
case (@getchar(l1,4,3)={ [}&&@getchar(l1,9,1)={/},
{Yes}, {resHP(memono)},
{No}, {footnote({カーソルをタイトル行に置いてください});
wait(2)}
) }
) }
) }
) }
);
im({Yes});
};
/* アップ用文書作成用メモをオープンする */
%OpenMemo{
[memono]
CloseAllMemo;
mopen(memono,0,21,639,240,{w});
mclose(1);
madd(memono+1,{\n});
mclear(memono+1);
mopen(memono+1,0,241,639,459,{w});
};
/* アップ文書作成をキャンセルする */
%cancel {
[memono]
case(@mcheck!=memono+1,{Yes},{mopen(memono+1)});
mclose(3);
CloseAllMemo;
mopen(memono,0,21,639,459,{w});
im({No});
};
/* アップ用文書を清書する */
%rewrite{
[memono]
footnote({メモ}|memono+1|{を清書しています});
CloseAllMemo;
dispoff({Yes});
%cdir @getcdir;
setcdir(CDIR);
command({del }|TEMP2|{_moptext.tmp});
command({del }|TEMP2|{_moptext});
mwrite(TEMP2|{_moptext.tmp},memono+1);
command({txf -i }|TEMP2|{_moptext.tmp -o }|TEMP2|{_moptext }|
{-mr 72 -l 76 -r -q});
dispoff({No});
case (@filechk(TEMP2|{_moptext}),
{Yes},
{
mclear(memono+1);
mread(TEMP2|{_moptext},memono+1);
mopen(memono,0,21,639,240,{w});
mclose(1);
mopen(memono+1,0,241,639,459,{w});
},
{No},
{
display({清書機能には TXF.EXE がパスの通った}|
{ディレクトリに必要です\n});
wait(2);
mopen(memono,0,21,639,240,{w});
mclose(1);
mopen(memono+1,0,241,639,459,{w});
});
setcdir(cdir);
im({Yes});
};
/* 会議室へのコメント作成処理 */
%resMES {
[memono]
%savememo{
[memono]
%c1 @case (@nochar(l1)-38<=0,
{Yes},{im(1)},
{No},{im(@nochar(l1)-38)});
SNDMSG({nyuryo_f.snd});
%a @plane( {cフォーラムの会議室へのコメント\n}|
{t フォーラム名 /xxxxxxxx\n}|
{t 会議室番号 /xx\n}|
{tコメント元番号/xxx\n}|
{t タイトル /xxxxxxxxxxxxxxxxxxxx}|
{xxxxxxxxxxxxxxxxxxxx\n}|
{s / 登録 / 取消 \n},
fn,
@getchar(l2,2,2),
@getchar(l1,1,3),
{re:}|@head(@getchar(l1,39,c1),{\n})
);
%forum @head(@getline(a,1,1),{\n});
%mes @head(@getline(a,2,1),{\n});
%reply @head(@getline(a,3,1),{\n});
%title @head(@getline(a,4,1),{\n});
%ok @head(@getline(a,5,1),{\n});
case (ok==1,{Yes},
{
footnote({会議室へのコメントを作成します});
mkdir2(TEMP);
%file1 @crefile(TEMP,{res});
case(@mcheck!=0,{Yes},{mclose(1)});
mwrite(TEMP2|file1,memono+1);
mopen(memono+1,0,241,639,459,{w});
%res1 {forum=}|forum|{;}| {mes=}|mes|{;}|
{reply=}|reply|{;}| {title=}|title|{;}|
{file=}|TEMP2|file1|{;\n};
write(TEMP2|{_mopres.ctl},res1);
case(@mcheck!=memono+1,{Yes},{mopen(memono+1)});
mclose(3);
CloseAllMemo;
mopen(memono,0,21,639,459,{w});
im({No});
},
{No},
{im({Yes})}
);
};
footnote({会議室へのコメントを作成します});
OpenMemo(memono);
loop ({
footnote({終了取消清書},{b});
waitx();
case (@xtype,
101,{savememo(memono)}, 201,{savememo(memono)},
102,{cancel(memono)}, 202,{cancel(memono)},
103,{rewrite(memono)}, 203,{rewrite(memono)},
,{im({Yes})}
);
});
im({Yes});
};
/* 会議室へのコメント作成処理 */
%sayMES {
[memono]
%savememo{
[memono]
%c1 @case (@nochar(l1)-38<=0,
{Yes},{im(1)},
{No},{im(@nochar(l1)-38)});
SNDMSG({nyuryo_f.snd});
%a @plane( {cフォーラムの会議室への新規発言\n}|
{t フォーラム名 /xxxxxxxx\n}|
{t 会議室番号 /xx\n}|
{t タイトル /xxxxxxxxxxxxxxxxxxxx}|
{xxxxxxxxxxxxxxxxxxxx\n}|
{s / 登録 / 取消 \n},
fn,,
);
%forum @head(@getline(a,1,1),{\n});
%mes @head(@getline(a,2,1),{\n});
%title @head(@getline(a,3,1),{\n});
%ok @head(@getline(a,4,1),{\n});
case (ok==1,{Yes},
{
footnote({会議室への新規発言を作成します});
mkdir2(TEMP);
%file1 @crefile(TEMP,{res});
case(@mcheck!=0,{Yes},{mclose(1)});
mwrite(TEMP2|file1,memono+1);
mopen(memono+1,0,241,639,459,{w});
%res1 {forum=}|forum|{;}| {mes=}|mes|{;}|
{reply=;}| {title=}|title|{;}|
{file=}|TEMP2|file1|{;\n};
write(TEMP2|{_mopres.ctl},res1);
case(@mcheck!=memono+1,{Yes},{mopen(memono+1)});
mclose(3);
CloseAllMemo;
mopen(memono,0,21,639,459,{w});
im({No});
},
{No},
{im({Yes})}
);
};
footnote({会議室への新規発言を作成します});
OpenMemo(memono);
loop ({
footnote({終了取消清書},{b});
waitx();
case (@xtype,
101,{savememo(memono)}, 201,{savememo(memono)},
102,{cancel(memono)}, 202,{cancel(memono)},
103,{rewrite(memono)}, 203,{rewrite(memono)},
,{im({Yes})}
);
});
im({Yes});
};
/* メールへの返信作成処理 */
%resMAIL{
[memono]
%savememo{
[memono]
%c1 @case (@nochar(l2)-10<=0,
{Yes},{im(1)},
{No},{im(@nochar(l2)-10)});
SNDMSG({nyuryo_f.snd});
%a @plane( {cメールの返信\n}|
{t メール宛先 /xxxxxxxx\n}|
{t タイトル /xxxxxxxxxxxxxxxxxxxx}|
{xxxxxxxxxxxxxxxxxxxx\n}|
{s / 登録 / 取消 \n},
@getchar(l1,23,8),
{re:}|@head(@getchar(l2,11,c1),{\n})
);
%mail @head(@getline(a,1,1),{\n});
%title @head(@getline(a,2,1),{\n});
%ok @head(@getline(a,3,1),{\n});
case (ok==1,
{Yes},
{
footnote({メールの返信を作成します});
mkdir2(TEMP);
%file1 @crefile(TEMP,{res});
case(@mcheck!=0,{Yes},{mclose(1)});
mwrite(TEMP2|file1,memono+1);
mopen(memono+1,0,241,639,459,{w});
%res1 {mail=}|mail|{;}| {title=}|title|{;}|
{file=}|TEMP2|file1|{;}|{date=;\n};
write(TEMP2|{_mopres.ctl},res1);
case(@mcheck!=memono+1,{Yes},{mopen(memono+1)});
mclose(3);
CloseAllMemo;
mopen(memono,0,21,639,459,{w});
im({No});
},
{No},
{im({Yes})}
);
};
footnote({メールの返信を作成します});
OpenMemo(memono);
loop ({
footnote({終了取消清書},{b});
waitx();
case (@xtype,
101,{savememo(memono)}, 201,{savememo(memono)},
102,{cancel(memono)}, 202,{cancel(memono)},
103,{rewrite(memono)}, 203,{rewrite(memono)},
,{im({Yes})}
);
});
im({Yes});
};
/* HPへの書き込み文書作成処理 */
%resHP {
[memono]
%savememo{
[memono]
%c1 @case (@nochar(l1)-37<=0,
{Yes},{im(1)},
{No},{im(@nochar(l1)-37)});
SNDMSG({nyuryo_f.snd});
%a @plane( {cHPへの新規発言\n}|
{t HPのID /xxxxxxxx\n}|
{t パスワード /xxxxxxxx\n}|
{t タイトル /xxxxxxxxxxxxxxxxxxxx}|
{xxxxxxxxxxxxxxxxxxxx\n}|
{s / 登録 / 取消 \n},
fn,
@tail(NIFTY,{/}|fn|{/},{/}),
{re:}|@head(@getchar(l1,38,c1),{\n})
);
%hpid @head(@getline(a,1,1),{\n});
%hppass @head(@getline(a,2,1),{\n});
%title @head(@getline(a,3,1),{\n});
%ok @head(@getline(a,4,1),{\n});
case (ok==1,
{Yes},
{
footnote({HPへのアップ文書を作成します});
mkdir2(TEMP);
%file1 @crefile(TEMP,{res});
case(@mcheck!=0,{Yes},{mclose(1)});
mwrite(TEMP2|file1,memono+1);
mopen(memono+1,0,241,639,459,{w});
%res1 {hp=}|hpid|{;}| {pass=}|hppass|{;}|
{title=}|title|{;}|{file=}|TEMP2|file1|{;\n};
write(TEMP2|{_mopres.ctl},res1);
case(@mcheck!=memono+1,{Yes},{mopen(memono+1)});
mclose(3);
CloseAllMemo;
mopen(memono,0,21,639,459,{w});
im({No});
},
{No},
{im({Yes})}
);
};
footnote({HPへのアップ文書を作成します});
OpenMemo(memono);
loop ({
footnote({終了取消清書},{b});
waitx();
case (@xtype,
101,{savememo(memono)}, 201,{savememo(memono)},
102,{cancel(memono)}, 202,{cancel(memono)},
103,{rewrite(memono)}, 203,{rewrite(memono)},
,{im({Yes})}
);
});
im({Yes});
};
/* DLIBからのダウンロード制御文作成処理 */
%downDLIB{
var forum [8];
var libno [2];
var datano [3];
var docfile [64];
var datafile[64];
var ok [2];
%LineNo @xlinenum;
dispoff({Yes});
command({del }|TEMP2|{_mopdlib.tmp});
command({txf -dlib -i }|LOGFILE|{ }|LineNo|{ > }|TEMP2|{_mopdlib.tmp});
dispoff({No});
%dlib @read(TEMP2|{_mopdlib.tmp},1,1);
forum:= @tail(dlib,{forum=},{;});
libno:= @tail(dlib,{libno=},{;});
datano:= @tail(dlib,{datano=},{;});
datafile:= LOG2|{FREESOFT\}|@tail(dlib,{datafile=},{\n});
docfile:= LOG2|{FREESOFT\}|@tail(dlib,{docfile=},{;});
loop ({
SNDMSG({nyuryo_f.snd});
%a @plane( {cライブラリからのダウンロード\n}|
{t フォーラム名 /xxxxxxxx\n}|
{tライブラリ番号/xx\n}|
{t データ番号 /xxx\n}|
{tデータファイル/\n}|
{s ファイル一覧 / 選択 \n}|
{t 概要ファイル /\n}|
{s ファイル一覧 / 選択 \n}|
{s / 登録 / 取消 \n},
forum,libno,datano,datafile,docfile);
forum:= @head(@getline(a,1,1),{\n});
libno:= @head(@getline(a,2,1),{\n});
datano:= @head(@getline(a,3,1),{\n});
datafile:= @head(@getline(a,4,1),{\n});
%sel1 @head(@getline(a,5,1),{\n});
docfile:= @head(@getline(a,6,1),{\n});
%sel2 @head(@getline(a,7,1),{\n});
ok:= @head(@getline(a,8,1),{\n});
case (sel1==1,{Yes},
{datafile:=@FILEsel1;
docfile:=@body(datafile,,{.})|{.ggg};im({Yes})});
case (sel2==1,{Yes},{docfile:=@FILEsel1;im({Yes})});
});
case (ok==1,{Yes},
{
%res1 {forum=}|forum|{;}| {libno=}|libno|{;}|
{datano=}|datano|{;}| {docfile=}|docfile|{;}|
{datafile=}|datafile|{;\n};
write(TEMP2|{_mopdlib.ctl},res1);
case(@mcheck!=memono,{Yes},{mopen(memono)});
});
im({Yes});
};
/* ダウンロードファイル指定処理 */
%FILEsel1{
var dnfile [64];
SNDMSG({erande_f.snd});
dnfile:=@filesel;
case (dnfile,
{},{im({})},
,
{
case (@nochar(@getcdir)=3,
{Yes}, {dnfile:=@getcdir|dnfile},
{No}, {dnfile:=@getcdir|{\}|dnfile}
)
}
);
im(dnfile);
};
/* NAPLPSファイル表示処理 */
%ViewNAP{
[file,memono]
CloseAllMemo;
naplps(file);
footnote({終了},{b});
loop ({
waitx(300);
case (@xtype,
101,
{
napend;
CloseAllMemo;
footnote({});
mopen(memono,0,21,639,459,{w});
im({No});
},
201,
{
napend;
CloseAllMemo;
footnote({});
mopen(memono,0,21,639,459,{w});
im({No});
},
,{im({Yes})}
);
});
im({Yes});
};
/* 受信ログ参照処理メイン */
var fn [8];
var l1 [82];
var l2 [82];
var DOCFILE [64];
var DATAFILE[64];
var LOGFILE [64];
footnote({受信ログを参照します});
%memono @mlast+1;
case (memono>5,
{No},{ViewLOG(LOG,memono)},
{Yes},
{
SNDMSG ({kaknin_f.snd});
select ({メモ5-9の内容が消去されます よろしいですか?},
Wtime4,,{ は い },{ViewLOG(LOG,5)},{ いいえ },);
});