home *** CD-ROM | disk | FTP | other *** search
/ FM Towns: Free Software Collection 5 / FREESOFT.BIN / fb386 / tonedial / tone.bas < prev    next >
BASIC Source File  |  1992-08-19  |  2KB  |  41 lines
  1. 1000 ' ＴＯＷＮＳトーンダイアラー　データ利用法サンプルプログラム
  2. 1010 '                                 Jan.09,1992     by s.kamio
  3. 1020 '
  4. 1030 ' このプログラムでは、トーンデータを一気に読み取り、その後にテンキー
  5. 1040 ' または数字のキーを入力して、トーンを発信させるものです。
  6. 1050 ' ただ、私はプログラムのテストをしていないので、実用になるかどうか
  7. 1060 ' 怪しいものですが、タウンズのスピーカに電話を近づけて発信させれば
  8. 1070 ' 多分電話が掛かると思います（トーン回線に限る）。
  9. 1080 ' テンキー使用時に便利なように、「＃」の代わりに「．」が使用できま
  10. 1090 ' す。
  11. 1100 '
  12. 1110 CLEAR ,,,256*1024
  13. 1120 DIM G%(100*1024-1),F%(16*1024-1)
  14. 1130 SCREEN@ 2:COLOR 7,0,7,0:PALETTE:CLS
  15. 1140 ' データ読み込み ----------------------------------------------------
  16. 1150 ' ＢＡＳＩＣにはブロック転送命令がないので、ＰＵＴ＠Ａ文で代用して
  17. 1160 ' います（かなり、速いです）。
  18. 1170 FOR I=0 TO 11
  19. 1180 IF I=10 THEN LOAD@ "tasta.snd",F%:GOTO 1210:'　「＊」
  20. 1190 IF I=11 THEN LOAD@ "tnumb.snd",F%:GOTO 1210:'　「＃」
  21. 1200 LOAD@ "t"+HEX$(I)+".snd",F%
  22. 1210 PUT@A (0,0)-(511,15),F%
  23. 1220 GET@A (0,0)-(511,15),G%,I*8*1024/2
  24. 1230 NEXT I
  25. 1240 LINE (0,0)-(511,15),PSET,0,BF
  26. 1250 ' プログラム終了はブレークキーを押すしかありません。-----------------
  27. 1260 WHILE 1
  28. 1270 SYMBOL (380,400),"数字キーを押してください。",1,1
  29. 1280 I$=INPUT$ (1)
  30. 1290 S=VAL (I$)-(I$="*")*10-(I$="#")*11-(I$=".")*11
  31. 1300 PUT@A (0,0)-(511,15),G%,PSET,1,1,,S*8*1024/2
  32. 1310 GET@A (0,0)-(511,15),F%
  33. 1320 LINE (0,0)-(511,15),PSET,0,BF
  34. 1330 PCMPLAY F%,127
  35. 1340 LINE (100,100)-(639,479),PSET,0,BF
  36. 1350 SYMBOL (100,100),KMID$ ("０１２３４５６７８９＊＃",S+1,1),12,12
  37. 1360 WHILE PLAY (2)
  38. 1370 WEND
  39. 1380 WEND
  40. 1390 END
  41.