home *** CD-ROM | disk | FTP | other *** search
/ Celestin Apprentice 5 / Apprentice-Release5.iso / Environments / PowerMacOberon feb96 / Source / Edit.Mod (.txt) < prev    next >
Encoding:
Oberon Text  |  1995-07-17  |  21.0 KB  |  501 lines  |  [TEXT/.Ob4]
  1. Syntax10.Scn.Fnt
  2. Syntax10i.Scn.Fnt
  3. Syntax12.Scn.Fnt
  4. Syntax10b.Scn.Fnt
  5. MODULE Edit;    (** CAS/MH/HM 12.10.1993 / mah 29.8.94 **)
  6.     IMPORT
  7.         Modules, Oberon, Files, Display, Viewers, MenuViewers, Fonts, Printer,
  8.         Texts, TextFrames, ParcElems, TextPrinter;
  9.     CONST
  10.         Menu = "System.Close  System.Copy  System.Grow  Edit.Search  Edit.Replace  Edit.Parcs  Edit.Store ";
  11.         mm = TextFrames.mm; unit = TextFrames.Unit; Unit = TextPrinter.Unit;
  12.         Scale = mm DIV 10;    (*unit of user setable attributes is 1/10 mm*)
  13.         headerX = 15 * mm DIV Unit;
  14.         headerW = 165 * mm DIV Unit;
  15.         bodyX = 15 * mm DIV Unit; bodyY = 15 * mm DIV Unit;
  16.         bodyW = 165 * mm DIV Unit; bodyMaxW = 180 * mm DIV Unit;
  17.         MaxPat = 128;
  18.         CR = 0DX;
  19.         R: Texts.Reader;
  20.         W: Texts.Writer;
  21.         mnam: ARRAY 12*3 + 1 OF CHAR;
  22.         find: RECORD
  23.             time, len: LONGINT;
  24.             buf: ARRAY MaxPat OF CHAR
  25.         END;
  26.         repl: RECORD
  27.             time: LONGINT;
  28.             buf: Texts.Buffer
  29.         END;
  30.     PROCEDURE Ch (ch: CHAR);
  31.     BEGIN Texts.Write(W, ch); Texts.Append(Oberon.Log, W.buf)
  32.     END Ch;
  33.     PROCEDURE Str (s: ARRAY OF CHAR);
  34.     BEGIN Texts.WriteString(W, s); Texts.Append(Oberon.Log, W.buf)
  35.     END Str;
  36.     PROCEDURE Int (n: LONGINT);
  37.     BEGIN Texts.Write(W, " "); Texts.WriteInt(W, n, 0); Texts.Append(Oberon.Log, W.buf)
  38.     END Int;
  39.     PROCEDURE Ln;
  40.     BEGIN Texts.WriteLn(W); Texts.Append(Oberon.Log, W.buf)
  41.     END Ln;
  42.     PROCEDURE Min (x, y: LONGINT): LONGINT;
  43.     BEGIN
  44.         IF x < y THEN RETURN x ELSE RETURN y END
  45.     END Min;
  46.     PROCEDURE AppendNum (VAR s: ARRAY OF CHAR; VAR i: INTEGER; n: LONGINT);
  47.         VAR j: INTEGER; digits: ARRAY 16 OF CHAR;
  48.     BEGIN j := 0;
  49.         REPEAT digits[j] := CHR(n MOD 10 + 30H); INC(j); n := n DIV 10 UNTIL n = 0;
  50.         REPEAT DEC(j); s[i] := digits[j]; INC(i) UNTIL j = 0;
  51.         s[i] := 0X
  52.     END AppendNum;
  53.     PROCEDURE AppendDate (VAR s: ARRAY OF CHAR);    (*s := s & "   (dd mmm yy)"*)
  54.         VAR time, date: LONGINT; i, j, k, m: INTEGER;
  55.     BEGIN Oberon.GetClock(time, date); i := 0;
  56.         WHILE s[i] # 0X DO INC(i) END;
  57.         s[i] := " "; s[i + 1] := " "; s[i + 2] := " "; s[i + 3] := "("; INC(i, 4);
  58.         AppendNum(s, i, date MOD 20H); s[i] := " "; INC(i);
  59.         m := SHORT((date DIV 20H) MOD 10H); k := m * 3; j := k - 3;
  60.         REPEAT s[i] := mnam[j]; INC(i); INC(j) UNTIL j = k;
  61.         s[i] := " "; INC(i); AppendNum(s, i, (date DIV 200H) MOD 100);
  62.         s[i] := ")"; s[i + 1] := 0X
  63.     END AppendDate;
  64.     PROCEDURE ShowAliens (t: Texts.Text);
  65.         VAR R: Texts.Reader; identify: Texts.IdentifyMsg;
  66.     BEGIN
  67.         Texts.OpenReader(R, t, 0); Texts.ReadElem(R);
  68.         WHILE ~R.eot DO identify.mod[31] := 0X; R.elem.handle(R.elem, identify);
  69.             IF identify.mod[31] = 1X THEN Ln; Str("pos"); Int(Texts.Pos(R) - 1);
  70.                 Str("  unknown element allocator: "); Str(identify.mod); Ch("."); Str(identify.proc)
  71.             END;
  72.             Texts.ReadElem(R)
  73.         END;
  74.         IF W.buf.len > 0 THEN Ln; Texts.Append(Oberon.Log, W.buf) END
  75.     END ShowAliens;
  76.     (* view support *)
  77.     PROCEDURE ShowPos (F: TextFrames.Frame; pos: LONGINT);
  78.         VAR beg, end, delta: LONGINT;
  79.     BEGIN delta := 200;
  80.         LOOP beg := F.org; end := TextFrames.Pos(F, F.X + F.W, F.Y);
  81.             IF (beg <= pos) & (pos < end) OR (delta = 0) THEN EXIT END;
  82.             TextFrames.Show(F, pos - delta); delta := delta DIV 2
  83.         END
  84.     END ShowPos;
  85.     PROCEDURE SetCaret (F: TextFrames.Frame; pos: LONGINT);
  86.     BEGIN Oberon.PassFocus(Viewers.This(F.X, F.Y)); TextFrames.SetCaret(F, pos)
  87.     END SetCaret;
  88.     PROCEDURE NewView (name: ARRAY OF CHAR; class: INTEGER;
  89.             T: Texts.Text; org: LONGINT): TextFrames.Frame;
  90.         VAR V: MenuViewers.Viewer; F, M: TextFrames.Frame; buf: Texts.Buffer; i, x, y: INTEGER;
  91.     BEGIN
  92.         IF class = Texts.String THEN i := 0;
  93.             WHILE name[i] # 0X DO INC(i) END;
  94.             name[i] := 22X; INC(i); name[i] := 0X;
  95.             WHILE i >= 0 DO name[i+1] := name[i]; DEC(i) END;
  96.             name[0] := 22X
  97.         END;
  98.         F := TextFrames.NewText(T, org);
  99.          M := TextFrames.NewMenu(name, "^Edit.Menu.Text");
  100.         Oberon.AllocateUserViewer(Oberon.Mouse.X, x, y);
  101.         V := MenuViewers.New(M, F, TextFrames.menuH, x, y);
  102.         ShowPos(F, org);
  103.         RETURN F
  104.     END NewView;
  105.     (* search & replace *)
  106.     PROCEDURE Find (T: Texts.Text; beg: LONGINT; VAR end: LONGINT);
  107.         VAR i, j, b, e: INTEGER; ch: CHAR; ref: ARRAY MaxPat OF CHAR;    (*ref [b..e) is readback buffer*)
  108.     BEGIN
  109.         Texts.OpenReader(R, T, beg); Texts.Read(R, ch); i := 0; ref[0] := ch; j := 0; b := 0; e := 1;
  110.         WHILE ~R.eot & (i < find.len) DO
  111.             IF (find.buf[i] = ch)
  112.                 OR (find.buf[i] = 0FFX)
  113.                     & ((ch < "0") OR (ch > "9") & (ch < "A") OR (ch > "Z") & (ch < "a") OR (ch > "z"))
  114.                         THEN INC(i); j := (j + 1) MOD MaxPat
  115.             ELSE i := 0; b := (b + 1) MOD MaxPat; j := b
  116.             END;
  117.             IF j # e THEN ch := ref[j]
  118.             ELSE Texts.Read(R, ch); ref[j] := ch; e := (e + 1) MOD MaxPat; INC(beg);
  119.             END
  120.         END;
  121.         IF i = find.len THEN end := beg ELSE end := -1 END
  122.     END Find;
  123.     PROCEDURE Check (T: Texts.Text; beg: LONGINT): BOOLEAN;
  124.         VAR ch: CHAR; i: INTEGER;
  125.     BEGIN i := 0;
  126.         IF (beg >= 0) & (find.len > 0) THEN Texts.OpenReader(R, T, beg); Texts.Read(R, ch);
  127.             WHILE ~R.eot & (i < find.len) & (ch = find.buf[i]) DO Texts.Read(R, ch); INC(i) END;
  128.         END;
  129.         RETURN i = find.len
  130.     END Check;
  131.     PROCEDURE SetReplBuf;
  132.         VAR T: Texts.Text; B: Texts.Buffer; beg, end, time: LONGINT;
  133.     BEGIN Oberon.GetSelection(T, beg, end, time);
  134.         IF time > repl.time THEN repl.time := time;
  135.             Texts.OpenBuf(repl.buf); Texts.Save(T, beg, end, repl.buf)
  136.         END
  137.     END SetReplBuf;
  138.     PROCEDURE Subst (T: Texts.Text; beg: LONGINT; VAR end: LONGINT);
  139.     BEGIN
  140.         Texts.Delete(T, beg, beg + find.len);
  141.         end := beg + repl.buf.len;
  142.         IF repl.buf.len > 0 THEN
  143.             Texts.Insert(T, beg, repl.buf); Texts.Save(T, beg, end, repl.buf)
  144.         END
  145.     END Subst;
  146.     (* arguments *)
  147.     PROCEDURE MarkedFrame (): TextFrames.Frame;
  148.         VAR V: Viewers.Viewer;
  149.     BEGIN V := Oberon.MarkedViewer();
  150.         IF (V # NIL) & (V IS MenuViewers.Viewer) & (V.dsc.next IS TextFrames.Frame) THEN
  151.             RETURN V.dsc.next(TextFrames.Frame)
  152.         ELSE RETURN NIL
  153.         END
  154.     END MarkedFrame;
  155.     PROCEDURE FocusFrame (): TextFrames.Frame;
  156.         VAR V: Viewers.Viewer; f: Display.Frame;
  157.     BEGIN V := Oberon.FocusViewer;
  158.         IF (V # NIL) & (V IS MenuViewers.Viewer) & (V.dsc # NIL) THEN f := V.dsc.next;
  159.             IF (f # NIL) & (f IS TextFrames.Frame) THEN RETURN f(TextFrames.Frame) ELSE RETURN NIL END
  160.         ELSE RETURN NIL
  161.         END
  162.     END FocusFrame;
  163.     PROCEDURE TargetFrame (): TextFrames.Frame;    (*body frame or focus frame*)
  164.         VAR f: Display.Frame;
  165.     BEGIN
  166.         IF Oberon.Par.vwr.dsc = Oberon.Par.frame THEN f := Oberon.Par.frame.next;
  167.             IF (f # NIL) & (f IS TextFrames.Frame) THEN RETURN f(TextFrames.Frame) ELSE RETURN NIL END
  168.         ELSE RETURN FocusFrame()
  169.         END
  170.     END TargetFrame;
  171.     PROCEDURE GetMainArg (VAR S: Texts.Scanner; VAR end: LONGINT); (*takes recent selection if ^*)
  172.         VAR text: Texts.Text; beg, time: LONGINT;
  173.     BEGIN Texts.Scan(S); end := MAX(LONGINT);
  174.         IF (S.class = Texts.Char) & (S.c = "^") THEN Oberon.GetSelection(text, beg, end, time);
  175.             IF time >= 0 THEN Texts.OpenScanner(S, text, beg); Texts.Scan(S) END
  176.         END;
  177.         IF S.line # 0 THEN S.class := Texts.Inval END
  178.     END GetMainArg;
  179.     PROCEDURE GetArg (VAR S: Texts.Scanner); (*takes selection in command frame if ^*)
  180.         VAR F: TextFrames.Frame;
  181.     BEGIN Texts.OpenScanner(S, Oberon.Par.text, Oberon.Par.pos); Texts.Scan(S);
  182.         IF (S.class = Texts.Char) & (S.c = "^") THEN F := Oberon.Par.frame(TextFrames.Frame);
  183.             IF F.hasSel THEN Texts.OpenScanner(S, F.text, F.selbeg.pos); Texts.Scan(S); F.time := 0 END
  184.         END
  185.     END GetArg;
  186.     PROCEDURE Change (sel: SET);
  187.         VAR S: Texts.Scanner; fnt: Fonts.Font; text: Texts.Text; beg, end, time: LONGINT; col, off: SHORTINT;
  188.     BEGIN GetArg(S); Oberon.GetSelection(text, beg, end, time);
  189.         IF time >= 0 THEN
  190.             IF (sel = {0}) & (S.class IN {Texts.Name, Texts.String}) THEN fnt := Fonts.This(S.s)
  191.             ELSIF (sel = {1}) & (S.class = Texts.Int) & (0 <= S.i) & (S.i < 16) THEN col := SHORT(SHORT(S.i))
  192.             ELSIF (sel = {2}) & (S.class = Texts.Int) & (-128 <= S.i) & (S.i < 128) THEN off := SHORT(SHORT(S.i))
  193.             ELSE sel := {}
  194.             END;
  195.             IF sel # {} THEN Texts.ChangeLooks(text, beg, end, sel, fnt, col, off) END
  196.         END
  197.     END Change;
  198.     (* commands *)
  199.     PROCEDURE Locate*;
  200.         VAR S: Texts.Scanner; F: TextFrames.Frame; text: Texts.Text; beg, end, time: LONGINT;
  201.     BEGIN F := MarkedFrame(); Oberon.GetSelection(text, beg, end, time);
  202.         IF time > 0 THEN Texts.OpenScanner(S, text, beg); Texts.Scan(S);
  203.             WHILE (S.class # Texts.Int) & (S.line = 0) & ~S.eot DO Texts.Scan(S) END;
  204.             IF (F # NIL) & (S.class = Texts.Int) & (S.line = 0) THEN ShowPos(F, S.i); SetCaret(F, S.i) END
  205.         END;
  206.     END Locate;
  207.     PROCEDURE Search*;
  208.         VAR F: TextFrames.Frame; T: Texts.Text; i, beg, end, time: LONGINT; ch: CHAR;
  209.     BEGIN Oberon.GetSelection(T, beg, end, time); F := TargetFrame();
  210.         IF time > find.time THEN find.time := time; find.len := Min(end - beg, MaxPat);
  211.             Texts.OpenReader(R, T, beg); i := 0;
  212.             REPEAT Texts.Read(R, find.buf[i]); INC(i) UNTIL i = find.len
  213.         END;
  214.         IF F # NIL THEN
  215.             IF F.hasCar THEN beg := F.carloc.pos ELSE beg := 0 END;
  216.             Find(F.text, beg, end);
  217.             IF end >= 0 THEN ShowPos(F, end); SetCaret(F, end)
  218.             ELSE TextFrames.RemoveCaret(F)
  219.             END;
  220.             TextFrames.RemoveSelection(F)
  221.         END
  222.     END Search;
  223.     PROCEDURE Show*;
  224.         VAR S: Texts.Scanner; R: Texts.Reader; F: TextFrames.Frame; text: Texts.Text;
  225.             i, j, beg, end, time: LONGINT; ch: CHAR;
  226.             name: ARRAY LEN(Modules.ModuleName) + 4 OF CHAR;
  227.     BEGIN text := Oberon.Par.text; beg := Oberon.Par.pos; end := Oberon.Par.text.len; time := Oberon.Time();
  228.         Texts.OpenScanner(S, text, beg); Texts.Scan(S);
  229.         IF (S.class = Texts.Char) & (S.c = "^") OR (S.line > 0) THEN Oberon.GetSelection(text, beg, end, time);
  230.             IF time >= 0 THEN Texts.OpenScanner(S, text, beg); Texts.Scan(S) END
  231.         END;
  232.         IF (time >= 0) & (S.class = Texts.Name) THEN i := 0;
  233.             WHILE (S.s[i] # 0X) & (S.s[i] # ".") DO name[i] := S.s[i]; INC(i) END;
  234.             IF i < LEN(Modules.ModuleName) THEN
  235.                 name[i] := "."; name[i+1] := "M"; name[i+2] := "o"; name[i+3] := "d"; name[i+4] := 0X;
  236.                 find.len := 0; j := i + 1; 
  237.                 WHILE S.s[j] # 0X DO find.buf[find.len] := S.s[j]; INC(find.len); INC(j) END;
  238.                 find.buf[find.len] := 0FFX; INC(find.len);
  239.                 find.time := time;
  240.                 text := TextFrames.Text(name);
  241.                 Find(text, 0, end); IF end < 0 THEN end := 0 END;
  242.                 F := NewView(name, Texts.Name, text, end);
  243.                 IF end > 0 THEN SetCaret(F, end) END
  244.             END
  245.         END
  246.     END Show;
  247.     PROCEDURE Recall*;
  248.         VAR B: Texts.Buffer; copyover: Oberon.CopyOverMsg;
  249.     BEGIN Texts.Recall(B);
  250.         IF B # NIL THEN copyover.beg := 0; copyover.end := B.len;
  251.             copyover.text := TextFrames.Text(""); Texts.Append(copyover.text, B);
  252.             Oberon.FocusViewer.handle(Oberon.FocusViewer, copyover)
  253.         END
  254.     END Recall;
  255.     PROCEDURE ClearReplaceBuffer*;
  256.     BEGIN Texts.OpenBuf(repl.buf)
  257.     END ClearReplaceBuffer;
  258.     PROCEDURE Replace*;
  259.         VAR F: TextFrames.Frame; T: Texts.Text; beg, end: LONGINT;
  260.     BEGIN F := TargetFrame(); SetReplBuf;
  261.         IF (F # NIL) & F.hasCar THEN T := F.text; end := F.carloc.pos; beg := end - find.len;
  262.             TextFrames.RemoveSelection(F);
  263.             IF Check(T, beg) THEN Subst(T, beg, end) END;
  264.             Find(T, end, beg);
  265.             IF beg >= 0 THEN ShowPos(F, beg); SetCaret(F, beg)
  266.             ELSE TextFrames.RemoveCaret(F)
  267.             END
  268.         END
  269.     END Replace;
  270.     PROCEDURE ReplaceAll*;
  271.         VAR F: TextFrames.Frame; T: Texts.Text; beg, end: LONGINT;
  272.     BEGIN F := TargetFrame(); SetReplBuf;
  273.         IF (F # NIL) & F.hasCar THEN T := F.text; end := F.carloc.pos; beg := end - find.len;
  274.             TextFrames.RemoveSelection(F);
  275.             IF Check(T, beg) THEN Subst(T, beg, end) END;
  276.             LOOP Find(T, end, beg);
  277.                 IF beg < 0 THEN EXIT END;
  278.                 Subst(T, beg - find.len, end)
  279.             END
  280.         END
  281.     END ReplaceAll;
  282.     PROCEDURE ChangeFont*;
  283.     BEGIN Change({0})
  284.     END ChangeFont;
  285.     PROCEDURE ChangeColor*;
  286.     BEGIN Change({1})
  287.     END ChangeColor;
  288.     PROCEDURE ChangeOffset*;
  289.     BEGIN Change({2})
  290.     END ChangeOffset;
  291.     PROCEDURE ChangeBackgroundColor*;
  292.         VAR F: TextFrames.Frame; m: MenuViewers.ModifyMsg; S: Texts.Scanner; H: INTEGER;
  293.     BEGIN F := MarkedFrame();
  294.         IF F # NIL THEN GetArg(S);
  295.             IF S.class = Texts.Int THEN
  296.                 F.col := SHORT(SHORT(S.i)); m.id := MenuViewers.extend; m.Y := F.Y; H := F.H;
  297.                 m.H := 0; F.handle(F, m); (*suspend*)
  298.                 m.H := H; F.handle(F, m) (*extend*)
  299.             END
  300.         END
  301.     END ChangeBackgroundColor;
  302.     PROCEDURE InsertParc*;
  303.         VAR copy: Texts.CopyMsg; insert: TextFrames.InsertElemMsg;
  304.     BEGIN
  305.         TextFrames.defParc.handle(TextFrames.defParc, copy); insert.e := copy.e;
  306.         Oberon.FocusViewer.handle(Oberon.FocusViewer, insert)
  307.     END InsertParc;
  308.     PROCEDURE Parcs*;
  309.         VAR S: Texts.Scanner; R: Texts.Reader; V: Viewers.Viewer; F: TextFrames.Frame;
  310.             um: TextFrames.UpdateMsg; m: Oberon.ControlMsg;
  311.     BEGIN
  312.         IF Oberon.Par.frame # Oberon.Par.vwr.dsc THEN Texts.OpenScanner(S, Oberon.Par.text, Oberon.Par.pos);
  313.             Texts.Scan(S);
  314.             IF (S.class = Texts.Char) & (S.line = 0) & (S.c = "*") THEN V := Oberon.MarkedViewer() ELSE V := NIL END
  315.         ELSE V := Oberon.Par.vwr
  316.         END;
  317.         IF (V # NIL) & (V IS MenuViewers.Viewer) & (V.dsc.next IS TextFrames.Frame) THEN
  318.             F := V.dsc.next(TextFrames.Frame); F.showsParcs := ~ F.showsParcs;
  319.             m.id := Oberon.neutralize; F.handle(F, m);
  320.             Texts.OpenReader(R, F.text, F.org); Texts.ReadElem(R);
  321.             WHILE (Texts.Pos(R) <= TextFrames.Pos(F, F.X + F.W, F.Y)) & (R.elem # NIL) DO
  322.                 IF R.elem IS TextFrames.Parc THEN
  323.                     um.id := Texts.replace; um.text := F.text; um.end := Texts.Pos(R); um.beg := um.end - 1;
  324.                     F.handle(F, um)
  325.                 END;
  326.                 Texts.ReadElem(R)
  327.             END
  328.         END
  329.     END Parcs;
  330.     PROCEDURE Open*;
  331.         VAR S: Texts.Scanner; F: TextFrames.Frame; end: LONGINT;
  332.     BEGIN Texts.OpenScanner(S, Oberon.Par.text, Oberon.Par.pos); GetMainArg(S, end);
  333.         IF (S.class = Texts.Name) OR (S.class = Texts.String) THEN
  334.             F := NewView(S.s, S.class, TextFrames.Text(S.s), 0);
  335.             ShowAliens(F.text)
  336.         END
  337.     END Open;
  338.     PROCEDURE Store*;
  339.         VAR S: Texts.Scanner; R: Texts.Reader; V: Viewers.Viewer; T: Texts.Text; ch: CHAR;
  340.     BEGIN
  341.         IF Oberon.Par.frame = Oberon.Par.vwr.dsc THEN V := Oberon.Par.vwr
  342.         ELSIF Oberon.Pointer.on THEN  V := Oberon.MarkedViewer()
  343.         END;
  344.         IF (V # NIL) & (V IS MenuViewers.Viewer) & (V.dsc IS TextFrames.Frame) & (V.dsc.next IS TextFrames.Frame) THEN
  345.             Texts.OpenScanner(S, V.dsc(TextFrames.Frame).text, 0); Texts.Scan(S);
  346.             IF (S.class = Texts.Name) OR (S.class = Texts.String) THEN
  347.                 Str("Edit.Store "); Str(S.s); T := V.dsc.next(TextFrames.Frame).text;
  348.                 Texts.Close(T, S.s); Int(T.len); Ln;
  349.                 T := V.dsc(TextFrames.Frame).text;
  350.                 Texts.OpenReader(R, T, T.len - 1); Texts.Read(R, ch);
  351.                 IF ch = "!" THEN Texts.Delete(T, T.len - 1, T.len) END
  352.             END
  353.         END
  354.     END Store;
  355.     PROCEDURE Set*;
  356.         VAR S: Texts.Scanner; R: Texts.Reader; text: Texts.Text; P: TextFrames.Parc; pos, beg, end, time: LONGINT;
  357.             msg: ParcElems.StateMsg;
  358.     BEGIN GetArg(S); Oberon.GetSelection(text, beg, end, time);
  359.         IF time >= 0 THEN Texts.OpenReader(R, text, beg); 
  360.             REPEAT Texts.ReadElem(R); pos := Texts.Pos(R);
  361.                 IF ~R.eot & (pos <= end) & (R.elem IS TextFrames.Parc) THEN
  362.                     msg.id := ParcElems.set; msg.pos := pos - 1; msg.frame := NIL; msg.par := S; msg.log := Oberon.Log;
  363.                     P := R.elem(TextFrames.Parc); P.handle(P, msg);
  364.                 END
  365.             UNTIL R.eot OR (pos > end)
  366.         ELSE Str("Edit.Set failed (no parc selected)"); Ln
  367.         END
  368.     END Set;
  369.     PROCEDURE Get*;
  370.         VAR S: Texts.Scanner; R: Texts.Reader; text: Texts.Text; P: TextFrames.Parc; pos, beg, end, time: LONGINT;
  371.             msg: ParcElems.StateMsg;
  372.     BEGIN GetArg(S); Oberon.GetSelection(text, beg, end, time); Str("Edit.Get ");
  373.         IF time >= 0 THEN
  374.             Texts.OpenReader(R, text, beg); Texts.ReadElem(R); pos := Texts.Pos(R);
  375.             IF ~R.eot & (pos <= end) & (R.elem IS TextFrames.Parc) THEN
  376.                 msg.id := ParcElems.get; msg.pos := pos - 1; msg.frame := NIL; msg.par := S; msg.log := Oberon.Log;
  377.                 P := R.elem(TextFrames.Parc); P.handle(P, msg)
  378.             ELSE Str("failed (no parc selected)")
  379.             END
  380.         ELSE Str("failed (no parc selected)")
  381.         END;
  382.     END Get;
  383.     PROCEDURE Print*;
  384.         VAR S, S1: Texts.Scanner; V: Viewers.Viewer; F: TextFrames.Frame; end: LONGINT; draft: BOOLEAN;
  385.         PROCEDURE PrintText(VAR S: Texts.Scanner; T: Texts.Text; name: ARRAY OF CHAR; draft: BOOLEAN);
  386.             CONST headerLen = 128;
  387.             VAR pos, len: LONGINT; ch: CHAR;
  388.                 hx, hy, hw, bx, by, bw, bh, i, k: INTEGER;
  389.                 nofcopies, pno, first, last, arab: INTEGER;
  390.                 fnt: Fonts.Font; label, labelfirst, alt: BOOLEAN;
  391.                 header: ARRAY headerLen OF CHAR;
  392.         BEGIN hx := headerX; hw := headerW;
  393.             hy := SHORT((LONG(Printer.PageHeight) * Unit - 17 * mm) DIV Unit);
  394.             bx := bodyX; by := bodyY; bw := bodyW;
  395.             bh := SHORT((LONG(Printer.PageHeight) * Unit - 37 * mm) DIV Unit);
  396.             nofcopies := 1; pno := 0; first := 0; last := 10000; arab := 1;
  397.             label := TRUE; labelfirst := TRUE; alt := FALSE;
  398.             header[0] := 0X; fnt := Fonts.Default;
  399.             Texts.Scan(S);
  400.             WHILE (S.class = Texts.Char) & (S.c = "/") DO
  401.                 Texts.Scan(S);
  402.                 IF S.class = Texts.Name THEN ch := CAP(S.s[0]);
  403.                     IF ch # "H" THEN Texts.Scan(S) END;
  404.                     IF ch = "A" THEN alt := TRUE
  405.                     ELSIF (ch = "C") & (S.class = Texts.Int) & (1 <= S.i) & (S.i < 10) THEN nofcopies := SHORT(S.i); Texts.Scan(S)
  406.                     ELSIF (ch = "F") & (S.class = Texts.Name) THEN fnt := Fonts.This(S.s); Texts.Scan(S)
  407.                     ELSIF ch = "H" THEN
  408.                         REPEAT Texts.Read(S, ch) UNTIL (ch > " ") OR S.eot;
  409.                         IF ch = 22X THEN i := 0; (* read string *)
  410.                             REPEAT Texts.Read(S, ch); header[i] := ch; INC(i) UNTIL (ch = 22X) OR (ch = CR);
  411.                             header[i-1] := 0X; Texts.Read(S, ch);
  412.                             (*COPY(S.s, header); Texts.Scan(S)*)
  413.                         ELSE COPY(name, header); AppendDate(header)
  414.                         END;
  415.                         S.nextCh := ch; Texts.Scan(S);
  416.                     ELSIF ch = "M" THEN    (*margin options*)
  417.                         IF S.class = Texts.Name THEN ch := CAP(S.s[0]); Texts.Scan(S); i := 0;
  418.                             WHILE (S.class = Texts.Int) & (0 <= S.i) DO
  419.                                 k := SHORT(S.i * Scale DIV TextPrinter.Unit); INC(i); Texts.Scan(S);
  420.                                 IF ch = "H" THEN
  421.                                     IF i = 1 THEN hx := k ELSIF i = 2 THEN hy := k ELSIF i = 3 THEN hw := k END
  422.                                 ELSIF ch = "B" THEN
  423.                                     IF i = 1 THEN bx := k ELSIF i = 2 THEN by := k
  424.                                     ELSIF i = 3 THEN bw := k ELSIF i = 4 THEN bh := k
  425.                                     END
  426.                                 END
  427.                             END
  428.                         END
  429.                     ELSIF ch = "P" THEN    (*page numbering options*)
  430.                         IF (S.class = Texts.Int) & (0 <= S.i) THEN pno := SHORT(S.i); first := pno; Texts.Scan(S)
  431.                         ELSIF S.class = Texts.Name THEN ch := CAP(S.s[0]); Texts.Scan(S);
  432.                             IF ch = "F" THEN labelfirst := FALSE
  433.                             ELSIF ch = "N" THEN label := FALSE
  434.                             ELSIF ch = "R" THEN arab := -1;
  435.                                 IF first = 0 THEN pno := 1; first := 1 END
  436.                             END
  437.                         END
  438.                     ELSIF (ch = "S") & (S.class = Texts.Int) & (0 <= S.i) THEN first := SHORT(S.i); Texts.Scan(S);
  439.                         IF (S.class = Texts.Int) & (0 <= S.i) THEN last := SHORT(S.i); Texts.Scan(S) ELSE last := first END
  440.                     END
  441.                 END
  442.             END;
  443.             Int(nofcopies); Ch(" ");
  444.             IF draft THEN TextPrinter.PrintDraft(T, name, nofcopies)
  445.             ELSE pos := 0; len:=T.len;
  446.                 WHILE (pos < len) & (pno <= last) & (Printer.res = 0) DO
  447.                     IF (first <= pno) & label & labelfirst THEN
  448.                         TextPrinter.PlaceHeader(hx, hy, hw, arab*pno, fnt, header, alt)
  449.                     END;
  450.                     TextPrinter.PlaceBody(bx, by, bw, bh, T, pos, pno, (first <= pno) & (pno <= last));
  451.                     IF first <= pno THEN Printer.Page(nofcopies); Ch(".") ELSE Ch("'") END;
  452.                     INC(pno); labelfirst := TRUE
  453.                 END
  454.             END;
  455.             Ln
  456.         END PrintText;
  457.     BEGIN Str("Edit.Print "); Texts.OpenScanner(S, Oberon.Par.text, Oberon.Par.pos); Texts.Scan(S);
  458.         IF ((S.class = Texts.Name) OR (S.class = Texts.String)) & (S.line = 0) THEN Str(S.s);
  459.             Printer.Open(S.s, Oberon.User, Oberon.Password);
  460.             IF Printer.res = 0 THEN GetMainArg(S, end); TextPrinter.InitFonts; 
  461.                 IF (S.class = Texts.Char) & (S.c = "%") THEN draft := TRUE; Texts.Scan(S) ELSE draft := FALSE END;
  462.                 IF Oberon.Par.frame = Oberon.Par.vwr.dsc THEN
  463.                     F := Oberon.Par.frame(TextFrames.Frame);
  464.                     IF (F.next # NIL) & (F.next IS TextFrames.Frame) THEN
  465.                         Texts.OpenScanner(S1, F.text, 0); Texts.Scan(S1);
  466.                         PrintText(S, F.next(TextFrames.Frame).text, S1.s, draft)
  467.                     END
  468.                 ELSIF (S.class = Texts.Char) & (S.c = "*") THEN V := Oberon.MarkedViewer();
  469.                     IF (V # NIL) & (V IS MenuViewers.Viewer)
  470.                     & (V.dsc IS TextFrames.Frame) & (V.dsc.next IS TextFrames.Frame) THEN
  471.                         Texts.OpenScanner(S1, V.dsc(TextFrames.Frame).text, 0); Texts.Scan(S1);
  472.                         IF S1.class # Texts.Name THEN S1.s[0] := "*"; S1.s[1] := 0X END;
  473.                         Ch(" "); Str(S1.s);
  474.                         PrintText(S, V.dsc.next(TextFrames.Frame).text, S1.s, draft)
  475.                     ELSE Str(" failed (bad * marker)"); Ln
  476.                     END
  477.                 ELSIF S.class = Texts.Name THEN
  478.                     REPEAT Ch(" "); Str(S.s);
  479.                         PrintText(S, TextFrames.Text(S.s), S.s, draft)
  480.                     UNTIL S.eot OR (S.class # Texts.Name) OR (Texts.Pos(S) > end)
  481.                 ELSE Ln
  482.                 END;
  483.                 Printer.Close
  484.             ELSE Str(" failed (");
  485.                 IF Printer.res = 1 THEN Str("no such printer)")
  486.                 ELSIF Printer.res = 2 THEN Str("no link)")
  487.                 ELSIF Printer.res = 3 THEN Str("printer not ready)")
  488.                 ELSIF Printer.res = 4 THEN Str("no permission)")
  489.                 ELSE Str("res ="); Int(Printer.res); Str(" ?)")
  490.                 END;
  491.                 Ln
  492.             END
  493.         ELSE Str("failed (no printer specified)"); Ln
  494.         END
  495.     END Print;
  496. BEGIN Texts.OpenWriter(W);
  497.     mnam := "JanFebMarAprMayJunJulAugSepOctNovDec";
  498.     find.time := -1; find.len := 0;
  499.     repl.time := -1; NEW(repl.buf); Texts.OpenBuf(repl.buf)
  500. END Edit.
  501.