home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
C64'er
/
C64'er.iso
/
85xx
/
8506.d64
/
gcr-hex
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
51 lines
10 REM PROGRAMM ZUR KONVERTIERUNG
20 REM VON FUENF GCR-BYTES IN DIE
30 REM VIER ENTSPRECHENDEN
40 REM HEX-AEQUIVALENTE
50 REM
60 REM
70 REM
80 REM (W) 1985 BY KARSTEN SCHRAMM
90 REM
100 A$="0123456789ABCDEF":DIMG$(15):E$=""
110 G$(0)="01010"
120 G$(1)="01011"
130 G$(2)="10010"
140 G$(3)="10011"
150 G$(4)="01110"
160 G$(5)="01111"
170 G$(6)="10110"
180 G$(7)="10111"
190 G$(8)="01001"
200 G$(9)="11001"
210 G$(10)="11010"
220 G$(11)="11011"
230 G$(12)="01101"
240 G$(13)="11101"
250 G$(14)="11110"
260 G$(15)="10101"
270 PRINT"[147]GCR - HEX - KONVERTIERUNG":PRINT
280 PRINT:PRINT"GEBEN SIE JETZT 5 GCR-BYTES EIN":PRINT
290 INPUT"";H$:GC$=""
300 X$="":FORX=1TOLEN(H$)
310 IFMID$(H$,X,1)<>" "THENX$=X$+MID$(H$,X,1)
320 NEXT
330 H$=X$
340 FORX=1TO10
350 X$=MID$(H$,X,1)
360 XX=VAL(X$):IFXX=0ANDX$<>"0"THENXX=ASC(X$)-55
370 FORY=0TO3
380 YY=INT(XX/2^(3-Y)):XX=XX-YY*2^(3-Y)
390 IFYYTHENGC$=GC$+"1":GOTO410
400 GC$=GC$+"0"
410 NEXTY,X
420 HC$="":FORX=1TO8
430 X$=MID$(GC$,X*5-4,5)
440 FORY=0TO15
450 IFX$<>G$(Y)THENNEXTY
460 :
470 HC$=HC$+MID$(A$,Y+1,1)
480 IFINT(X/2)=X/2THENHC$=HC$+" "
490 NEXTX
500 PRINT:PRINT:PRINT"HEX: ";HC$