home *** CD-ROM | disk | FTP | other *** search
/ Fresh Fish 8 / FreshFishVol8-CD1.bin / useful / dev / c / rkrm / printer / epsonx / init.asm < prev    next >
Assembly Source File  |  1992-09-03  |  5KB  |  169 lines
  1. *
  2. * Copyright (c) 1992 Commodore-Amiga, Inc.
  3. * 
  4. * This example is provided in electronic form by Commodore-Amiga, Inc. for 
  5. * use with the "Amiga ROM Kernel Reference Manual: Devices", 3rd Edition, 
  6. * published by Addison-Wesley (ISBN 0-201-56775-X).
  7. * 
  8. * The "Amiga ROM Kernel Reference Manual: Devices" contains additional 
  9. * information on the correct usage of the techniques and operating system 
  10. * functions presented in these examples.  The source and executable code 
  11. * of these examples may only be distributed in free electronic form, via 
  12. * bulletin board or as part of a fully non-commercial and freely 
  13. * redistributable diskette.  Both the source and executable code (including 
  14. * comments) must be included, without modification, in any copy.  This 
  15. * example may not be published in printed form or distributed with any
  16. * commercial product.  However, the programming techniques and support
  17. * routines set forth in these examples may be used in the development
  18. * of original executable software products for Commodore Amiga computers.
  19. * 
  20. * All other rights reserved.
  21. * 
  22. * This example is provided "as-is" and is subject to change; no
  23. * warranties are made.  All use is at your own risk. No liability or
  24. * responsibility is assumed.
  25. *
  26. **********************************************************************
  27. *
  28. *       printer device functions
  29. *
  30. **********************************************************************
  31.  
  32.         SECTION         printer
  33.  
  34. *------ Included Files -----------------------------------------------
  35.  
  36.         INCLUDE         "exec/types.i"
  37.         INCLUDE         "exec/nodes.i"
  38.         INCLUDE         "exec/lists.i"
  39.         INCLUDE         "exec/memory.i"
  40.         INCLUDE         "exec/ports.i"
  41.         INCLUDE         "exec/libraries.i"
  42.  
  43.         INCLUDE         "macros.i"
  44.  
  45. *------ Imported Functions -------------------------------------------
  46.  
  47.         XREF_EXE        CloseLibrary
  48.         XREF_EXE        OpenLibrary
  49.         XREF            _AbsExecBase
  50.  
  51.  
  52.         XREF            _PEDData
  53.  
  54.  
  55. *------ Exported Globals ---------------------------------------------
  56.  
  57.         XDEF            _Init
  58.         XDEF            _Expunge
  59.         XDEF            _Open
  60.         XDEF            _Close
  61.         XDEF            _PD
  62.         XDEF            _PED
  63.         XDEF            _SysBase
  64.         XDEF            _DOSBase
  65.         XDEF            _GfxBase
  66.         XDEF            _IntuitionBase
  67.  
  68.  
  69. **********************************************************************
  70.         SECTION         printer,DATA
  71. _PD             DC.L    0
  72. _PED            DC.L    0
  73. _SysBase        DC.L    0
  74. _DOSBase        DC.L    0
  75. _GfxBase        DC.L    0
  76. _IntuitionBase  DC.L    0
  77.  
  78.  
  79. **********************************************************************
  80.         SECTION         printer,CODE
  81. _Init:
  82.                 MOVE.L  4(A7),_PD
  83.                 LEA     _PEDData(PC),A0
  84.                 MOVE.L  A0,_PED
  85.                 MOVE.L  A6,-(A7)
  86.                 MOVE.L  _AbsExecBase,A6
  87.                 MOVE.L  A6,_SysBase
  88.  
  89. *           ;------ open the dos library
  90.                 LEA     DLName(PC),A1
  91.                 MOVEQ   #0,D0
  92.                 CALLEXE OpenLibrary
  93.                 MOVE.L  D0,_DOSBase
  94.                 BEQ     initDLErr
  95.  
  96.  
  97. *           ;------ open the graphics library
  98.                 LEA     GLName(PC),A1
  99.                 MOVEQ   #0,D0
  100.                 CALLEXE OpenLibrary
  101.                 MOVE.L  D0,_GfxBase
  102.                 BEQ     initGLErr
  103.  
  104. *           ;------ open the intuition library
  105.                 LEA     ILName(PC),A1
  106.                 MOVEQ   #0,D0
  107.                 CALLEXE OpenLibrary
  108.                 MOVE.L  D0,_IntuitionBase
  109.                 BEQ     initILErr
  110.  
  111.                 MOVEQ   #0,D0
  112. pdiRts:
  113.                 MOVE.L  (A7)+,A6
  114.                 RTS
  115.  
  116. initPAErr:
  117.                 MOVE.L  _IntuitionBase,A1
  118.                 LINKEXE CloseLibrary
  119.  
  120. initILErr:
  121.                 MOVE.L  _GfxBase,A1
  122.                 LINKEXE CloseLibrary
  123.  
  124. initGLErr:
  125.                 MOVE.L  _DOSBase,A1
  126.                 LINKEXE CloseLibrary
  127.  
  128. initDLErr:
  129.                 MOVEQ   #-1,D0
  130.                 BRA.S   pdiRts
  131.  
  132. ILName:
  133.                 DC.B    'intuition.library'
  134.                 DC.B    0
  135. DLName:
  136.                 DC.B    'dos.library'
  137.                 DC.B    0
  138. GLName:
  139.                 DC.B    'graphics.library'
  140.                 DC.B    0
  141.                 DS.W    0
  142.  
  143.  
  144. *---------------------------------------------------------------------
  145. _Expunge:
  146.                 MOVE.L  _IntuitionBase,A1
  147.                 LINKEXE CloseLibrary
  148.  
  149.                 MOVE.L  _GfxBase,A1
  150.                 LINKEXE CloseLibrary
  151.  
  152.                 MOVE.L  _DOSBase,A1
  153.                 LINKEXE CloseLibrary
  154.  
  155.  
  156. *---------------------------------------------------------------------
  157. _Open:
  158.                 MOVEQ   #0,D0
  159.                 RTS
  160.  
  161.  
  162.  
  163. *---------------------------------------------------------------------
  164. _Close:
  165.                 MOVEQ   #0,D0
  166.                 RTS
  167.  
  168.                 END
  169.