home *** CD-ROM | disk | FTP | other *** search
/ Fresh Fonts 1 / freshfonts1.bin / bbs / programs / amiga / metafont.lha / MF / INPUTS / MANUAL / HALFTONE.MF < prev    next >
Text File  |  1993-11-28  |  969b  |  46 lines
  1. % halftone font with 65 levels of gray, characters "0" (white) to "p" (black)
  2.  
  3. pair p[]; % the pixels in order (first p0 becomes black, then p1, etc)
  4. p0=(1,1);
  5. p8=(2,0);
  6. p16=(1,0);
  7. p24=(0,0);
  8. p32=(3,-1);
  9. p40=(2,-1);
  10. p48=(1,-1);
  11. p56=(2,-2);
  12. transform r; r=identity rotatedaround ((1.5,1.5),90);
  13.  
  14. for i=0 step 8 until 56:
  15.  p[i+2]=p[i] transformed r;
  16.  p[i+6]=p[i+2] transformed r;
  17.  p[i+5]=p[i+6] transformed r;
  18.  p[i+1]=p[i] shifted (4,4);
  19.  p[i+3]=p[i+2] shifted (4,4);
  20.  p[i+7]=p[i+6] shifted (4,4);
  21.  p[i+4]=p[i+5] shifted (4,4);
  22.  endfor
  23.  
  24. for i=32 step 1 until 63:
  25.  p[i] := (xpart p[i] mod 8, ypart p[i] mod 8);
  26. endfor
  27.  
  28. mode_setup;
  29. designsize:=64/pt; % that's 64 pixels
  30.  
  31. def makebox(text t)= enddef; % shut off boxes
  32.  
  33. picture prevchar;
  34.  
  35. prevchar=nullpicture;
  36. for i=0 upto 64:
  37.  beginchar(i+ASCII"0",designsize/8,designsize/8,0);
  38.  currentpicture:=prevchar;
  39.  if i>0: fill unitsquare shifted p[i-1]; fi
  40.  prevchar:=currentpicture;
  41.  endchar;
  42.  endfor
  43.  
  44. font_quad=designsize/8;
  45. end
  46.