home *** CD-ROM | disk | FTP | other *** search
/ The Business Master (3rd Edition) / The Business Master (3rd Edition).iso / files / utilstem / util2 / colon.asm < prev    next >
Encoding:
Assembly Source File  |  1988-08-30  |  2.3 KB  |  85 lines
  1.  
  2.     TITLE    SEMICOLON_REVERSE
  3.  
  4. ; by  William C. Parke for George Page and CHUG Aug. 1988
  5. ; 
  6. ; This program is a Terminate-and-Stay-Resident routine which
  7. ; converts a semicolon to a colon and visa-versa when typed
  8. ; from the keyboard.  For those not drilled into QWERTY
  9. ; typing, the often used DOS colon is easier to type, not
  10. ; requiring a shift with the semicolon key.  Install the
  11. ; program in the AUTOEXEC.BAT file after testing.
  12.  
  13. ; Use DOS 2.11 or higher.
  14.  
  15. ; The resident portion of the program takes only 256 bytes.
  16. ; (It is actually contained in the original Program Segment
  17. ; Prefix. The child environment is de-allocated.)
  18.  
  19. ; This file assembled under MASM Version 4.0.
  20.  
  21. COD    SEGMENT BYTE PUBLIC 'CODE'
  22.     ASSUME  CS:COD, DS:COD, ES:COD, SS:COD
  23.  
  24.      ORG    100H
  25.  
  26. BEGIN:    JMP    INIT        ; initialize TSR for int 16h interception
  27.  
  28. INT16:    CMP    AH,2        ; int 16h function index
  29.     JC    NEW16        ; request for next char
  30.     DB    0EAH        ; far jump code
  31. JOFS    DW    0        ; original INT 16h vector 
  32. JSEG    DW    0
  33. NEW16:    PUSH    BP
  34.     PUSH    DX
  35.     MOV    BP,SP
  36.     MOV    DX,[BP+8]    ; get user flag
  37.     PUSH    DX        ; anticipate IRET after call
  38.     DB    9AH        ; far call code
  39. COFS    DW    0
  40. CSEG    DW    0
  41.     PUSHF
  42.     POP    DX        ; recover int 16h flags
  43.     MOV    [BP+8],DX    ; set user flag
  44.     POP    DX
  45.     POP    BP
  46.     CMP    AH,27H        ; scan code for colon key
  47.     JNZ    EXIT
  48.     XOR    AL,1        ; reverse to 3A/3B
  49. EXIT:    IRET
  50.  
  51. INIT:    MOV    DX,OFFSET MSG        ; tell user what will happen
  52.     MOV    AH,9
  53.     INT    21H
  54.     XOR    AX,AX
  55.     MOV    ES,AX            ; set for bios data segment
  56.     AND    BYTE PTR ES:[0417H],0DFH ; turn off NumLock
  57.     MOV    ES,DS:[002CH]        ; environ segment
  58.     MOV    AH,49H            ; free up environment
  59.     INT    21H
  60.     MOV    AX,3516H        ; get vector for int 16h
  61.     INT    21H
  62.     MOV    JOFS,BX            ; set double word far jump
  63.     MOV    JSEG,ES
  64.     MOV    COFS,BX            ; set double word far call
  65.     MOV    CSEG,ES
  66.     MOV    AX,CS
  67.     MOV    ES,AX    
  68.     MOV    DI,80H            ; use wasted psp buffer area
  69.     MOV    SI,OFFSET BEGIN
  70.     MOV    CX,40H
  71.     REP    MOVSW            ; move handler down to org 80h
  72.     MOV    DX,OFFSET INT16 - 80H    ; handler start address
  73.     MOV    AX,2516H        ; install keyboard preprocessor
  74.     INT    21H
  75.     MOV    DX,10H            ; para size of our interrupt handler
  76.     MOV    AX,3100H        ; terminate and stay resident
  77.     INT    21H
  78.  
  79. MSG DB 13,10,'Colon-Semicolon Reversed.'
  80.     DB 13,10,10,'$ COLON Version 1.0 ',13,10
  81.     DB 'William C. Parke for CHUG, 1988',13,10,10,'$'
  82.  
  83. COD    ENDS
  84.     END    BEGIN
  85.